home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / mskscripts / hayes.kds < prev    next >
Text File  |  2020-01-01  |  5KB  |  154 lines
  1. ; FILE HAYES.SCR
  2. ; 
  3. ; An MS-DOS Kermit script program for dialing a Hayes 1200 or 2400 SmartModem.
  4. ;
  5. ; Authors: C. Gianone & F. da Cruz, Columbia U, December 1996
  6. ;
  7. ; To use: SET MODEM=HAYES (in DOS, before starting Kermit or in AUTOEXEC.BAT)
  8. ; or:     SET MODEM HAYES (in Kermit, or in MSCUSTOM.INI)
  9. ; and:    Make sure Kermit has executed the standard MSKERMIT.INI file,
  10. ;         and then DIAL the desired number.
  11. ;
  12. ; Variables - define these prior to dialing if desired; they can be either
  13. ; Kermit variables or DOS environment variables:
  14. ; 
  15. ;   DIALPORT    - COM port to use for dialing (COM1, etc, default current port)
  16. ;   DIALSPEED   - Speed for dialing (the port's current speed by default)
  17. ;   DIALMETHOD  - TONE or PULSE (modem's default method is used by default)
  18. ;   DIALRETRIES - Maximum times to redial the call (default 5)
  19. ;   DIALTIMEOUT - How long to wait for result from modem (default 90 seconds)
  20. ;
  21. if < VERSION 315 stop 1 MS-DOS Kermit 3.15 or later required.
  22.  
  23. local __dm __parity spdchg errfail ; Local variables
  24.  
  25. def ERRFAIL echo \%1, forward FAIL
  26. def SPDCHG echo Changing speed to \%1..., set speed \%1
  27.  
  28. set carrier off                 ; Don't require carrier during dialing.
  29. set input echo on        ; So we can watch what happens.
  30. set input timeout proceed       ; Allow IF SUCCESS, IF FAILURE.
  31. set input case ignore        ; Use caseless string comparisons
  32.  
  33. :PORT
  34. if not def DIALPORT asg DIALPORT \$(DIALPORT)
  35. if not def DIALPORT forward SPEED
  36. set port \m(DIALPORT)
  37. if success forward SPEED
  38. echo SET PORT \m(DIALPORT) failed 
  39. end 1
  40.  
  41. :SPEED
  42. asg __parity \v(parity)        ; Save parity setting
  43. set parity none            ; Switch to none while dialing
  44. set flow none            ; Avoid flow control deadlocks
  45. hangup                ; Begin by dropping DTR
  46.  
  47. if not def DIALSPEED asg DIALSPEED \$(DIALSPEED)
  48. if not def DIALSPEED asg DIALSPEED \v(speed)
  49. set speed \m(DIALSPEED)
  50. if fail end 1 \m(DIALSPEED) - Speed not supported
  51.  
  52. ; Dial method, retry limit, and timeout...
  53.  
  54. xif numeric \fsubstr(\%1,1,1) {
  55.     if eq "\m(DIALMETHOD)" "TONE" asg __dm T
  56.     if eq "\m(DIALMETHOD)" "PULSE" asg __dm P
  57. }
  58. if not def DIALRETRIES asg DIALRETRIES \$(DIALRETRIES)
  59. if not def DIALRETRIES asg DIALRETRIES 5
  60.  
  61. if not def DIALTIMEOUT asg DIALTIMEOUT \$(DIALTIMEOUT)
  62. if not def DIALTIMEOUT asg DIALTIMEOUT 90
  63.  
  64. ; Begin the modem dialog...
  65.  
  66. echo Configuring Hayes SmartModem \v(line)...
  67. if not def DIALSPEED asg DIALSPEED \$(DIALSPEED)
  68. if not def DIALSPEED asg DIALSPEED \v(speed)
  69. if eq \m(DIALSPEED) 2400 forward S2400
  70. if eq \m(DIALSPEED) 1200 forward S1200
  71.  
  72. echo Trying \v(speed)...
  73. output ATQ0V1\13        ; Try at current speed
  74. input 3 OK
  75. if success forward gotok
  76. set speed 2400
  77. :S2400
  78. echo Trying \v(speed)...
  79. clear
  80. output ATQ0V1\13        ; Try at 2400
  81. input 3 OK
  82. if success forward gotok
  83. set speed 1200
  84. :S1200
  85. echo Trying \v(speed)...
  86. clear
  87. output ATQ0V1\13        ; Try at 1200
  88. input 3 OK
  89. if fail stop 1 {No response from modem - is it turned on and connected?}
  90.  
  91. :GOTOK
  92. mpause 500
  93. clear input            ; Clear INPUT buffer.
  94. clear device            ; Clear device buffer.
  95.  
  96. if not > \v(speed) 2400 echo Hayes \v(speed) detected.
  97. echo Dialing \%1 on \v(line) at \v(speed) bps, wait...
  98. echo
  99.  
  100. xif not < \v(speed) 2400 {    ; Enable CONNECT <speed> result codes
  101.     out ATX4\13
  102.     inp 3 OK            ; But don't fail if there's an error
  103. }
  104. for \%i 1 \m(DIALRETRIES) 1 {    ; Redial loop
  105.     xif > \%i 1 {
  106.         echo Redialing...       ; Message for redialing
  107.         hangup            ; Hang up first
  108.     }
  109.     pause 1            ; Wait a sec for modem to settle
  110.     output ATD\m(__dm)\%1\13    ; Dial the number.
  111.     minput \m(DIALTIMEOUT) -
  112.       CONNECT BUSY ERROR {NO CARRIER} {NO ANSWER} {NO DIALTONE} RING
  113.     xif fail { echo Call timed out, hangup, out \13, continue }
  114.     switch \v(minput) {
  115.       :1, forward done
  116.       :2, Echo Line is busy - will dial again in 30 seconds.
  117.           echo Press any key to cancel...
  118.           output \13
  119.           pause 30
  120.           if fail errfail Canceled
  121.           break
  122.       :3, errfail {Dialing command error}
  123.       :4, errfail {Call failed - no carrier}
  124.       :5, errfail {No answer - try again later}
  125.       :6, errfail {No dialtone - is your modem connected to the phone line?}
  126.       :7, decr \%i, break
  127.       :8, errfail {Call failed - your phone is ringing}
  128.       :default, break
  129.     }    
  130. }
  131. errfail {It never answers!  I give up.} ; Too many tries.
  132.  
  133. :DONE                           ; Connected.
  134. xif > \v(speed) 1200 {
  135.     minput 2 1200 2400        ; Change speed if necessary.
  136.     xif success {
  137.     if = \v(minput) 1 if not = \v(speed) 1200 spdchg 1200
  138.     if = \v(minput) 2 if not = \v(speed) 2400 spdchg 2400
  139.     }
  140. }
  141.  
  142. :BEEP
  143. echo \7                         ; Celebrate with a beep.
  144. set carrier on            ; Require carrier from now on.
  145. set parity \m(__parity)        ; Restore host parity setting
  146. end 0                ; Finished, return success code.
  147.  
  148. :FAIL
  149. set carrier off            ; Let them reconnect to see what's up.
  150. hangup
  151. end 1                ; Return failure code.
  152.  
  153. ; End of HAYES.SCR
  154.