home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / mskermit / msxz10.asm < prev    next >
Assembly Source File  |  2020-01-01  |  63KB  |  2,157 lines
  1.     NAME    msxz10
  2. ; File MSXZ10.ASM
  3.     include mssdef.h
  4. ;       Copyright (C) 1982,1991, Trustees of Columbia University in the
  5. ;       City of New York.  Permission is granted to any individual or
  6. ;       institution to use, copy, or redistribute this software as long as
  7. ;       it is not sold for profit and this copyright notice is retained.
  8. ; Kermit system dependent module for Heath/Zenith Z100
  9. ; Edit history
  10. ; 2 March 1991 version 3.10
  11. ; Last change:    3 November 1990.
  12. ; 
  13. ; OUTCH2 defined as far label.
  14. ; Replay code in PRTCHR modified per ibm pc version and call serrst added at
  15. ; label coms0.    These two last changes are for version 3.02.
  16. ; New code for VTS and VTSTAT added and under revision but not active.    These
  17. ; two routines and corresponding data really belong in msy but the routines
  18. ; and some of their data are kept here to make msy small enough to assemble
  19. ; with MASM 4.    DUMPSCR moved to msyz10.asm.
  20. ; A number of calls to SPRTCH added in order to allow windowing for the non
  21. ; interupt driven S-100 modem ports COM3/COM4.    Some very limited success at
  22. ; 1200 baud would indicate that it might work at 300 (untested).
  23. ; SERISR optimized and performance improved for COM1/COM2.  However, there are
  24. ; still some problems from 19200 baud and up, in particular with windowing.
  25. ; OUTCHR significantly rewritten.  Modified CHKXON (COM1/2) and CHKXOF (COM3/4)
  26. ; to call OUTCH5 and OUTCH2 respectively rather than OUTCHAR.
  27. ; SERISR significantly modified to improve flow control for COM1/2 and SPRTCH
  28. ; fixed to ignore flow control for COM3/4 if not called for.
  29. ; Minor correction to WAIT01.  CLEARL and CTLU merged.
  30. ; PUTHLP display routine improved and replay command implemented.
  31. ; Increased size of buffilen and buffolen.  Added register save to BEEP.
  32. ; Added routines ENA_WRP and DIS_WRP and several calls to these to make serial
  33. ; display behave.  Help message for 'set port' improved.
  34. ; Various cosmetic changes.
  35. ;
  36. ; First version of this file for MS-Kermit 3.0:     8 May 1990.
  37. ; Bo Gedda
  38. ;
  39. ; Support for 2 US Robotics S-100 modems at ports 20H (com3) and 2EH (com4).
  40. ; com1 (1 in status list) means serial port B.
  41. ; com2 (2 in status list) means serial port A.
  42. ; com3 (3 in status list) means S-100 port 1 (20H).
  43. ; com4 (4 in status list) means S-100 port 2 (2EH).
  44. ; 
  45.     public    getbaud, serini, serrst, clrbuf, outchr, coms, vts, vtstat
  46.     public    ctlu, cmblnk, locate, prtchr, baudst, clearl, bdtab, dodel
  47.     public    beep, sprtch, klen, ktab, krpl, getivec, setivec, dupflg
  48.     public    count, xofsnt, puthlp, putmod, clrmod, poscur, pcwait
  49.     public    sendbr, sendbl, machnam, lclini, outch2, dis_scan
  50.     public    ihosts, ihostr, dtrlow, mdmhand, shomodem, getmodem
  51.     public    portval, port1, port2, port3, port4, serhng, ena_scan
  52.     public    flowon, flowoff, sescur, sesdisp, setnbios, peekcom, parmsk
  53.  
  54. off    equ    0
  55. false    equ    0
  56. true    equ    1
  57. bufon    equ    1        ; buffer level xon/xoff on-state control flag
  58. usron    equ    2        ; user level xon/xoff on-state control flag
  59. mntrgh    equ    bufsiz*3/4    ; High point = 3/4 of buffer full
  60. mntrgl    equ    bufsiz/4    ; Low point = 1/4 buffer full
  61. xoftime equ    15        ; 15 seconds time out for xoff, see timer
  62.  
  63. ; constants used by serial port handler
  64.  
  65. ; Z-100 standard serial ports A (J1) and B (J2), called COM2 and COM1 here.
  66. ; Note that A=J1=COM2=2 and B=J2=COM1=1.  Port B is the standard modem port
  67. ; similar to an IBM PC port.  Thats why.
  68. ; serial port information
  69. TSRE    EQU    004H
  70. THBE    EQU    001H
  71. DTR    EQU    002H
  72. DTROFF    EQU    0fdH
  73. RTS    EQU    020H
  74. RTSOFF    EQU    0dfH
  75. DCD    EQU    040H
  76. DSR    EQU    080H
  77. RDA    EQU    002H
  78. J1_ADDR EQU    0e8H
  79. J2_ADDR EQU    0ecH
  80. PDATA    EQU    0
  81. PSTATUS EQU    1
  82. PMODE    EQU    2
  83. PCOMM    EQU    3
  84. TXON    EQU    001H
  85. TXOFF    EQU    0feH
  86. RXON    EQU    004H
  87. RXOFF    EQU    0fbH
  88. MODE1    EQU    04dH
  89. MODE2    EQU    030H    ;  must be ORed with appropriate baud rate
  90. Z8259    EQU    0f2H
  91. EOI    EQU    020H
  92. J1INT    EQU    68
  93. J2INT    EQU    69
  94. BUFILEN EQU    bufsiz
  95. BUFOLEN EQU    bufsiz/2
  96.  
  97. BRKBIT    EQU    048H        ; Send-break bit.
  98.  
  99. mdmdat1 equ    J2_ADDR        ; Address of serial port B (J2)
  100. mdmcom1 equ    J2_ADDR + PCOMM ; Address of serial port B command
  101. mdmdat2 equ    J1_ADDR        ; Address of serial port A (J1)
  102. mdmcom2 equ    J1_ADDR + PCOMM ; Address of serial port A command
  103.  
  104. ;US Robotics S-100 modem using 8251A USART data
  105. mdmdat3 equ    020h        ; Address of USR S-100 port 1
  106. mdmcom3 equ    mdmdat3 + 1    ; Address of USR S-100 command port
  107. mdmdat4 equ    02eh        ; Address of USR S-100 port 2
  108. mdmcom4 equ    mdmdat4 + 1    ; Address of USR S-100 command port
  109. modsndb equ    1h        ; Bit to test for send S-100 modem
  110. modrcvb equ    2h        ; Bit to test for receive S-100 modem
  111. modperb equ    8h        ; Parity error detect bit S-100 modem
  112. modorub    equ    10h        ; Overrun error detect bit
  113. moddcdb equ    80h        ; Carrier detect bit S-100 modem
  114.  
  115. COLUMNS EQU    80        ; Characters per screen line.
  116. ROWS    EQU    24        ; Text lines per screen
  117. VID_CMD EQU    0d8h        ; Video-memory control port.
  118. PAR_GRN EQU    0e000h        ; Green video plane segment address.
  119.  
  120. ; external variables used:
  121. ; flags - global flags as per flginfo structure defined in pcdefs
  122. ; trans - global transmission parameters, trinfo struct defined in pcdefs
  123. ; portval - pointer to current portinfo structure (currently either port1,
  124. ;    port2, port3 or port4 )
  125. ; port1, port2, port3, port4 - portinfo structures for the corresponding ports
  126. ; monmode - color/monochrome mode of monitor
  127. ; dmpname - file name for screen dump file
  128.  
  129. ; global variables defined in this module:
  130. ; xofsnt, xofrcv - tell whether we saw or sent an xoff.
  131.  
  132. BIOS_SEG SEGMENT AT 40H        ; Define segment where BIOS really is
  133.     ORG    1*3
  134. BIOS_STATUS    LABEL FAR    ; Console input status
  135.     ORG    2*3
  136. BIOS_CONIN    LABEL FAR    ; Console input
  137.     ORG    3*3
  138. BIOS_CONOUT    LABEL FAR    ; Console output
  139.     ORG    4*3
  140. BIOS_PRINT    LABEL FAR    ; Printer output
  141.     ORG    6*3
  142. BIOS_AUXOUT    LABEL FAR    ; AUX output routine
  143.     ORG    25*3
  144. BIOS_PRNFUNC    LABEL FAR    ; PRN: FUNCTION
  145.     ORG    26*3
  146. BIOS_AUXFUNC    LABEL FAR    ; AUX: function
  147.     ORG    27*3
  148. BIOS_CONFUNC    LABEL FAR    ; CON: function
  149. BIOS_SEG ENDS
  150.  
  151. ;  Define functions of BIOS_CONFUNC, BIOS_PRNFUNC, and BIOS_AUXFUNC
  152. CHR_WRITE    EQU 0        ; Write function
  153. CHR_READ    EQU CHR_WRITE+1 ; Read function
  154. CHR_STATUS    EQU CHR_READ+1    ; Status function
  155.   CHR_SFGS      EQU 0          ; Get status subfunction
  156.     CHRS_WA        EQU 00000001B   ; <ETX> sent, waiting for <ACK>
  157.     CHRS_WD        EQU 00000010B   ; <DC3> seen, waiting for <DC1>
  158.     CHRS_SN        EQU 00000100B   ; Sending nulls
  159.     CHRS_TXR        EQU 10000000B   ; Transmitter ready to send data
  160.     CHRS_RXR        EQU 01000000B   ; Receiver has data 
  161.     CHRS_RXOF        EQU 00100000B   ; Receiver queue overflow
  162.     CHRS_RXE        EQU 00010000B   ; Other type of reciver error
  163.     CHRS_TXE        EQU 00001000B   ; Transmitter error
  164.   CHR_SFGC      EQU CHR_SFGS+1  ; Get configuration info subfunction
  165. CHR_CONTROL    EQU CHR_STATUS+1 ; Control function
  166.   CHR_CFSU      EQU 0          ; Setup new configuration parms subfunction
  167.   CHR_CFCI      EQU CHR_CFSU+1  ; Clear input subfunction
  168.   CHR_CFCO      EQU CHR_CFCI+1  ; Clear output subfunction
  169. CHR_LOOK    EQU CHR_CONTROL+1; Nondestructive read function
  170. CHR_FMAX    EQU CHR_LOOK    ; Maximum function number
  171.  
  172. ; storage for port configuration
  173. cfginfo struc
  174. cfclass db    0
  175. cfattr    db    0
  176. cfport    dw    0
  177. cfbaud    db    0
  178. cfhshk    db    0
  179. cfbctl    db    0
  180. cfecnt    db    0
  181. cfncnt    db    0
  182. cfnchr    db    0
  183. cfres    db    6 dup(?)
  184. cfsize    db    0
  185. cfginfo ends
  186.  
  187. ; structure for status information table sttab.
  188. stent    struc
  189. sttyp    dw    ?        ; type (actually routine to call)
  190. msg    dw    ?        ; message to print
  191. val2    dw    ?        ; needed value: another message, or tbl addr
  192. tstcel    dw    ?        ; address of cell to test, in data segment
  193. basval    dw    0        ; base value, if non-zero
  194. stent    ends
  195.  
  196. data    segment
  197.     extrn    flags:byte, trans:byte, taklev:byte, verident:byte
  198.     extrn    comptab:byte, termtb:byte, ontab:byte, scrtab:byte
  199.     extrn    cntltab:byte, beltab:byte, curtab:byte, chatab:byte
  200.     extrn    kpamtab:byte, dirtab:byte, doscol:byte
  201.     extrn    lclsusp:word, lclrest:word, lclexit:word, dosflg:byte
  202.     extrn    dosflg1:byte, repflg:byte, diskio:byte, kstatus:byte
  203.     extrn    holdscr:byte, vtemu:word, lincur:word
  204.     extrn    belltype:byte, vtroll:byte
  205.  
  206. oldoff    dw    0
  207. oldseg    dw    0
  208. sescur    dw    0
  209. dupflg    db    0        ; full (0) or half (1) duplex on port
  210. brkval    db    0        ; What to send for a break.
  211. brkdur    dw    0        ; Length of break in centiseconds
  212. badbd    db    cr,lf,'Unimplemented baud rate$'
  213. noimp    db    cr,lf,'Not implemented$'
  214. coms0msg db    cr,lf,'No US Robotics S-100 modem detected at this port!'
  215.     db    cr,lf,'$'
  216. comsmsg db    ' One of the following:'
  217.     db    cr,lf,'  1  2  3  4  COM1  COM2  COM3  COM4  A  B  J1  J2'
  218.     db    cr,lf,lf,'Where'
  219.     db    cr,lf,'  1 = COM1 = Serial Port B = J2'
  220.     db    cr,lf,'  2 = COM2 = Serial Port A = J1'
  221.     db    cr,lf,'  3 = COM3 = US Robotics S-100 modem at port 20H'
  222.     db    cr,lf,'  4 = COM4 = US Robotics S-100 modem at port 2EH$'
  223. vtsmsg    db    cr,lf,'The Z-100 terminal has inherent HEATH-19 support.'
  224.     db    cr,lf,' Set terminal none activates native Heath-19 '
  225.     db    'properties.',cr,lf
  226.     db    ' This deactivates key mapping and scan codes.$' 
  227. msmsg0    db    cr,lf,'  Modem may be ready: DSR is unknown$'
  228. msmsg1    db    cr,lf,'  Modem is not ready: DSR is off$'
  229. msmsg2    db    cr,lf,'  Modem is ready:     DSR is on$'
  230. msmsg3    db    cr,lf,'  no Carrier Detect:  CD  is off$'
  231. msmsg4    db    cr,lf,'  Carrier Detect:     CD  is on$'
  232. msmsg5    db    cr,lf,'  no Clear To Send:   CTS is off$'
  233. msmsg6    db    cr,lf,'  Clear To Send:      CTS is on$'
  234. msmsg7    db    cr,lf,'  Modem is not used by the Network$'
  235. not_z    db    'Sorry, wrong software!',cr,lf
  236.     db    'This Kermit will only run on the Z-100 -- a non '
  237.     db    'IBM PC compatible',cr,lf,lf
  238. machnam db    'Heath-Zenith_Z-100$'
  239. com3ms    db    'Carrier detected at S-100 Port 20H, COM3',cr,lf,'$'
  240. com4ms    db    'Carrier detected at S-100 Port 2EH, COM4',cr,lf,'$'
  241. com3ms1 db    'Modem   detected at S-100 Port 20H, COM3',cr,lf,'$'
  242. com4ms1 db    'Modem   detected at S-100 Port 2EH, COM4'
  243. crlf    db    cr,lf,'$'
  244. infmsg    db    'S-100 MODEM INITIALIZATION FAILURE',cr,lf,'$'
  245. wmsg    db    cr,lf,' CARRIER detected  --  disconnecting',cr,lf,'$'
  246. dscmsg    db    cr,lf,' DISCONNECTED',cr,lf,'$'
  247. ndscmsg db    cr,lf,' !!!  WARNING  >>>  NOT DISCONNECTED  !!!',cr,lf,'$'
  248. hngstr    db    '+++$'
  249. hngmsg    db    cr,lf,' The phone should have hungup.',cr,lf,'$' ; [jrd]
  250. hnghlp    db    cr,lf,' The modem control lines DTR and RTS for the current'
  251.     db    ' port are forced low (off)'
  252.     db    cr,lf,' to hangup the phone. Normally, Kermit leaves them'
  253.     db    ' high (on) when it exits.'
  254.     db    cr,lf,lf,' The USR S-100 modem is hung up using "+++".'
  255.     db    cr,lf,'$'                       
  256. rdbuf    db    80 dup (?)    ; temp buf [jrd]
  257. delstr    db    BS,BS,'  ',BS,BS,'$'    ; Delete string
  258. clrlin    db    BS,BS,'  ',cr,'$'    ; Clear line (just the cr part)
  259. home    db    ESCAPE,'H$'    ; Home cursor
  260. clrstr    db    ESCAPE,'E$'    ; Home cursor and erase entire display
  261. eeolstr db    ESCAPE,'K$'    ; Erase to end of line
  262. enamod    db    ESCAPE,'x1$'    ; Enable 25th line
  263. dismod    db    ESCAPE,'y1$'    ; Disable 25th line
  264. enascan db    ESCAPE,'y?$'    ; Enable scan codes, disable key expansion
  265. disscan db    ESCAPE,'x?$'    ; Disable scan codes, enable key expansion
  266. begrev    db    ESCAPE,'p$'    ; Enter reverse video
  267. endrev    db    ESCAPE,'q$'    ; Exit reverse video
  268. lin25    db    ESCAPE,'Y8 $'    ; Column 1 row 25
  269. savcur    db    ESCAPE,'j$'    ; Save current cursor position
  270. precur    db    ESCAPE,'k$'    ; Restore cursor to previous position
  271. monstr    db    ESCAPE,'i0$'    ; Return montior information
  272. portin    db    -1        ; Has comm port been initialized?
  273.                 ; -1=has not used, 1=is used, 0=has been used
  274. xofsnt    db    0        ; Say if we sent an XOFF
  275. xofrcv    db    0        ; Say if we received an XOFF
  276. parmsk    db    0ffh        ; parity mask, 0ffh for no parity, 07fh with
  277. flowoff db    0        ; flow-off char, Xoff or null (if no flow)
  278. flowon    db    0        ; flow-on char, Xon or null
  279. tmp    db    0,'$'
  280. temp    dw    0        ; Temporary storage.
  281. mddat0    dw    0        ; Storage for modem data port
  282. mdstat0 dw    0        ; Storage for modem status port
  283. savedi    dw    offset source    ; Temporary storage for di
  284. srcpnt    dw    offset source    ; where to read next serial port byte
  285. source    db    bufsiz dup(0)    ; S-100 port input buffer
  286. timer    db    0
  287. timer0    db    0
  288.                 ; begin Terminal emulator data set
  289. portmax equ    4        ; number of predefined ports
  290.  
  291. port1    prtinfo <0FFFH,0,defpar,1,0,defhand,floxon,0>
  292. port2    prtinfo <0FFFH,0,defpar,1,0,defhand,floxon,0>
  293. port3    prtinfo <0FFFH,0,defpar,1,0,defhand,floxon,0>
  294. port4    prtinfo <0FFFH,0,defpar,1,0,defhand,floxon,0>
  295.     rept    portmax-4
  296.     prtinfo <0FFFH,0,defpar,1,0,defhand,floxon,0>
  297.     endm
  298. portval dw    port1        ; Default is to use port 1
  299.  
  300. bdtab    db    16        ; 16 entries
  301.     mkeyw    '45.5',0
  302.     mkeyw    '50 ',1
  303.     mkeyw    '75 ',2
  304.     mkeyw    '110 ',3
  305.     mkeyw    '134.5',4
  306.     mkeyw    '150',5
  307.     mkeyw    '300',6
  308.     mkeyw    '600',7
  309.     mkeyw    '1200',8
  310.     mkeyw    '1800',9
  311.     mkeyw    '2000',10
  312.     mkeyw    '2400',11
  313.     mkeyw    '4800',12
  314.     mkeyw    '9600',13
  315.     mkeyw    '19200',14
  316.     mkeyw    '38400',15
  317.  
  318. bdtab12 db    16        ; 16 (yes 16) entries for com1 and com2 
  319.     mkeyw    '45.5',0
  320.     mkeyw    '50 ',1
  321.     mkeyw    '75 ',2
  322.     mkeyw    '110 ',3
  323. lbdtab12  equ    $-bdtab12    ; length of table
  324.  
  325.  
  326. bdtab34 db    4        ; 4 entries for com3 and com4, s-100 modem 
  327.     mkeyw    '150 ',0
  328.     mkeyw    '300',1
  329.     mkeyw    '600',2
  330.     mkeyw    '1200',3
  331.  
  332. ; this table is indexed by the baud rate definitions given in
  333. ; bdtab.  Unsupported baud rates should contain 0FFH.
  334. bddat    label    word
  335.     dw    0        ; 45.5 baud
  336.     dw    1        ; 50 baud
  337.     dw    2        ; 75 baud
  338.     dw    3        ; 110 baud
  339.     dw    4        ; 134.5 baud
  340.     dw    5        ; 150 baud
  341.     dw    6        ; 300 baud
  342.     dw    7        ; 600 baud
  343.     dw    8        ; 1200 baud
  344.     dw    9        ; 1800 baud
  345.     dw    10        ; 2000 baud
  346.     dw    11        ; 2400 baud
  347.     dw    12        ; 4800 baud
  348.     dw    13        ; 9600 baud
  349.     dw    14        ; 19200 baud
  350.     dw    15        ; 38400 baud
  351. lbddat    equ    $-bddat        ; length of table
  352.  
  353. bddat12 label    word        ; for com1 and com2 
  354.     dw    0        ; 45.5 baud
  355.     dw    1        ; 50 baud
  356.     dw    2        ; 75 baud
  357.     dw    3        ; 110 baud
  358.     dw    4        ; 134.5 baud
  359.     dw    5        ; 150 baud
  360.     dw    6        ; 300 baud
  361.     dw    7        ; 600 baud
  362.     dw    8        ; 1200 baud
  363.     dw    9        ; 1800 baud
  364.     dw    10        ; 2000 baud
  365.     dw    11        ; 2400 baud
  366.     dw    12        ; 4800 baud
  367.     dw    13        ; 9600 baud
  368.     dw    14        ; 19200 baud
  369.     dw    15        ; 38400 baud
  370.  
  371. bddat34 label    word        ; for com3 and com4, s-100 modem
  372.     dw    0        ; 150 baud
  373.     dw    1        ; 300 baud
  374.     dw    2        ; 600 baud
  375.     dw    3        ; 1200 baud
  376.     dw    0ffh 
  377.     dw    0ffh 
  378.     dw    0ffh 
  379.     dw    0ffh 
  380.     dw    0ffh 
  381.     dw    0ffh 
  382.     dw    0ffh 
  383.     dw    0ffh 
  384.     dw    0ffh 
  385.     dw    0ffh 
  386.     dw    0ffh 
  387.     dw    0ffh 
  388.  
  389. ; baud rate data for S-100 modem
  390. bd150    db    4fh        ; Low speed mode byte     (150/300)   
  391.     db    17h        ; Low speed command byte (150/600)
  392. bd300    db    4fh        ; Low speed mode byte     (150/300)
  393.     db    37h        ; High speed command byte(300/1200)
  394. bd600    db    4eh        ; High speed mode byte     (600/1200)
  395.     db    17h        ; Low speed command byte (150/600)
  396. bd1200    db    4eh        ; High speed mode byte     (300/1200)
  397.     db    37h        ; High speed command byte(300/1200)
  398.  
  399. ; S-100 COM3/COM4 default baud rate: 0=150, 1=300, 2=600, 3=1200 baud
  400. bds100    equ    3        ; Set to 0, 1, 2, or 3
  401.  
  402. ; S-100 modem set up string
  403. ; echo commands, use extended result codes, do not answer call
  404. set_str db    'ATE1X1S0=0',cr,'$'
  405.  
  406. auxconf cfginfo <>
  407.  
  408. ; variables for serial interrupt handler
  409.  
  410. count    dw    0        ; Number of chars in int buffer.
  411. buffin    db    BUFILEN+2 dup(?)  ; input buffer
  412. bufibeg dw    0
  413. bufiend dw    0
  414. buffout db    BUFOLEN+2 dup(?)  ; output buffer
  415. bufobeg dw    0
  416. bufoend dw    0
  417. portadr dw    0
  418. intin    db    0        ; port int installed flag
  419. mdmhand db    0        ; Modem status
  420.  
  421.  
  422. ourarg    termarg <>
  423.  
  424. klen    dw    ?        ; length of key redefinition table
  425. ktab    dw    ?        ; address of key redefinition table
  426. krpl    dw    ?        ; address of key replacement table
  427.  
  428. colortb    db    0,4,2,6,1,5,3,7        ; color reversed-bit setting bytes
  429. clrset    db    ?            ; Temp for SET Term Tabstops xxx
  430.  
  431. ; This is data for the extended set terminal parameters.  It was put here
  432. ; in order to keep the size of msyz10.asm within limits for assembly by
  433. ; MASM 4.  The corresponding code is conatained in VTS and VTSTAT below.
  434. erms41    db    cr,lf,'?More parameters are needed$'
  435. vthlp    db    ' one of the following:',cr,lf
  436.     db '  terminal types of: None, Heath-19, VT52, VT102, VT320,'
  437.     db    ' or Tek4010',cr,lf
  438.     db '  Newline-mode    Cursor-style        Character-set'
  439.     db     cr,lf
  440.     db '  Keyclick        Margin-bell         Screen-background'
  441.     db    ' (normal, reverse)',cr,lf
  442.     db '  Tabstops        Wrap (long lines)   Color (fore & background)'
  443.     db    cr,lf,'  Bell  audible or visual'
  444.     db    cr,lf,'  Clear-screen  (clears old startup screen)'
  445.     db    cr,lf,'  Controls 7-bit or 8-bit  (permits VT320 to use'
  446.     db    ' 8-bit control sequences (C1))'
  447.     db    cr,lf,'  Direction Left-to-right or Right-to-left'
  448.     db    ' (screen writing direction)'
  449.     db    cr,lf,'  Graphics  (type of display adapter when in Tek4010'
  450.     db    ' mode)'
  451.     db    cr,lf,'  Keypad numeric (normal) or application mode'
  452.     db     cr,lf,'  Replay filespec (display a file through the emulator)'
  453.     db    cr,lf,'  Rollback  (undo screen roll back before writing new'
  454.     db    ' chars, default=off)$'
  455. clrhlp    db    ' one of the following:'
  456.     db    cr,lf,'  AT #s  (to set tabs at column #s)    or'
  457.     db    ' AT start-column:spacing'
  458.     db    cr,lf,'  Clear AT #s (clears individual tabs) or'
  459.     db    ' AT start-column:spacing'
  460.     db    cr,lf,'  Clear ALL  (to clear all tabstops)'
  461.     db    cr,lf,'  Ex: Set term tab at 10, 20, 34        sets tabs'
  462.     db    cr,lf,'  Ex: Set term tab at 1:8        sets tabs at 1, 9,'
  463.     db    cr,lf,'  Ex: Set term tab clear at 9, 17, 65   clears tabs'
  464.     db    cr,lf,'  Ex: Set term tab clear at 1:8  clears tabs at 1, 9,'
  465.     db    ' 17,...$'
  466. tbserr    db    cr,lf,'?Column number is not in range 1 to screen width-1$'
  467. colhlp    db    cr,lf,'  Set Term Color  value, value, value, ...'
  468.     db    cr,lf,'   0 no-snow mode on an IBM CGA and white on black'
  469.     db    cr,lf,'   1 for high intensity foreground'
  470.     db    cr,lf,'  10 for fast CGA screen updating (may cause snow)'
  471.     db    cr,lf,'  Foreground color (30-37) = 30 + sum of colors'
  472.     db    cr,lf,'  Background color (40-47) = 40 + sum of colors'
  473.     db    cr,lf,'    where colors are  1 = red, 2 = green, 4 = blue'
  474.     db    cr,lf,'  Ex: 0, 1, 37, 44   IBM CGA(0), bright(1) white(37)'
  475.     db    ' chars on a blue(44) field'
  476.     db    cr,lf,'  Attributes are applied in order of appearance.$'
  477. colerr    db    cr,lf,'?Value not in range of 0, 1, 10, 30-37, or 40-47$'
  478. vtwrap    db    'Term wrap-lines: $'
  479. vtbellm    db    'Term margin-bell: $'
  480. vtnewln db    'Term newline: $'
  481. vtcur    db    'Term cursor-style: $'
  482. vtcset    db    'Term character-set: $'
  483. vtclik    db    'Term key-click: $'
  484. vtscrn    db    'Term screen-background: $'
  485. colst1    db    'Term color  foregnd:3$'
  486. colst2    db    ' backgnd:4$'
  487. vtrolst    db    'Term rollback: $'
  488. vtdir    db    'Term direction: $'
  489. vtcntst    db    'Term controls: $'
  490. vtkpst    db    'Term keypad: $'
  491. vtbset    db    'Term bell: $'
  492. vtgchst    db    'Term graph char: $'
  493.                         ; terminal emulator
  494. vtstbl    stent    <srchkw,vtcset,chatab,vtemu.vtchset>        ; char set
  495.     stent    <srchkb,vtclik,ontab,vskeyclick,vtemu.vtflgop>    ; keyclick
  496.     stent    <srchkb,vtwrap,ontab,vswrap,vtemu.vtflgop>    ; line wrap
  497.     stent    <srchkb,vtcntst,cntltab,vscntl,vtemu.vtflgop>    ; controls
  498.     stent    <srchkb,vtbellm,ontab,vsmarginbell,vtemu.vtflgop>;margin bell
  499.     stent    <srchkb,vtcur,curtab,vscursor,vtemu.vtflgop>    ; cursor type
  500.     stent    <srchkw,vtbset,beltab,belltype>            ; bell
  501.      stent    <srchkb,vtdir,dirtab,vswdir,vtemu.vtflgop>    ; write direct
  502.     stent    <srchkb,vtnewln,ontab,vsnewline,vtemu.vtflgop>    ; newline
  503.     stent    <srchkw,vtrolst,ontab,vtroll>            ; rollback
  504.     stent    <srchkb,vtkpst,kpamtab,deckpam,vtemu.vtflgop>    ; keypad
  505.     stent    <srchkb,vtscrn,scrtab,vsscreen,vtemu.vtflgop>    ; screen 
  506.     dw    0        ; end of table
  507.                         ; end of Terminal data set
  508.  
  509. vttbl    db    19            ; number of entries
  510.     mkeyw    'Bell',8800h        ; note 8800 flag for decoding
  511.     mkeyw    'Character-set',chaval+8300h
  512.     mkeyw    'Clear-screen',8500h    ; 8500h = marker here
  513.     mkeyw    'Color',8200H        ; screen fore/back colors; 200H=marker
  514.     mkeyw    'Controls',cntlval
  515.     mkeyw    'Cursor-style',curval
  516.     mkeyw    'Direction',dirval
  517.     mkeyw    'Graphics',8600h    ; Tek graphics board, 800h=marker
  518.     mkeyw    'Heath-19',ttheath+8100H; note 8100H flag for decoding here
  519.     mkeyw    'Keyclick',keyval
  520.     mkeyw    'Keypad',kpamval
  521.     mkeyw    'Margin-bell',marval
  522.     mkeyw    'None',ttgenrc+8100H
  523.     mkeyw    'Newline',newval
  524.     mkeyw    'Replay',8700h        ; note 8700H flag for file replaying
  525.     mkeyw    'Rollback',8400h    ; note 8400H flag for decoding
  526.     mkeyw    'Screen-background',scrval
  527.     mkeyw    'Tabstops',tabval
  528.     mkeyw    'Wrap',wraval
  529.  
  530. vtsflg equ    this word        ; define small digits xxxval
  531. newval    equ    $-vtsflg        ; 0   and mask for bit in byte
  532.     dw    vsnewline        ;  1
  533. wraval    equ    $-vtsflg        ; 2
  534.     dw    vswrap            ;  2
  535. chaval    equ    $-vtsflg        ; 4
  536.     dw    vsnrcm            ;  4
  537. dirval    equ    $-vtsflg        ; 6
  538.     dw    vswdir            ;  8
  539. keyval    equ    $-vtsflg        ; 8
  540.     dw    vskeyclick        ;  10h
  541. marval    equ    $-vtsflg        ; 10
  542.     dw    vsmarginbell        ;  20h
  543. curval    equ    $-vtsflg        ; 12
  544.     dw    vscursor        ;  40h
  545. scrval    equ    $-vtsflg        ; 14
  546.     dw    vsscreen        ;  80h
  547. cntlval    equ    $-vtsflg        ; 16
  548.     dw    vscntl            ;  100h
  549. kpamval    equ    $-vtsflg        ; 18
  550.     dw    deckpam            ;  400h
  551. numflgs equ    ($-vtsflg)/2        ;  10
  552. tabval    equ    $-vtsflg        ; 20
  553.     dw    0
  554. ;vtrtns    dw    numflgs dup (flgset), tabmod ; dispatch table for vtsflg
  555.  
  556. data    ends
  557.  
  558. code    segment public
  559.     extrn    comnd:near, dopar:near, defkey:near, getpos:near, atsclr:near
  560.     extrn    lclyini:near, setcol:near, srchkb:near, srchkw:near
  561.     extrn    csrtype:near
  562.     assume    cs:code, ds:data, es:nothing
  563.  
  564. ; local initialization
  565. LCLINI    proc    near
  566.     jmp    lclini1            ; Bypass the exit code
  567. not_z10:mov    ah,prstr
  568.     mov    dx,offset not_z        ; This is not a Z-100, IBM PC maybe?
  569.     int    dos            ; This program is for
  570.     mov    dx,offset verident    ; display version header
  571.     int    dos
  572.     mov    ah,4ch            ; terminate process
  573.     int    dos
  574. ; Find out if this is a Z-100
  575. ; We are doing that by looking for 0E9H at locations 0040:0000H
  576. ; and 0040:0003H which are in the Z-100 bios jump table.
  577. lclini1:mov    bx,BIOS_SEG    ; The segment at 40h        
  578.     mov    ax,es        ; Save es
  579.     mov    es,bx        ; Set up the extra segment
  580.     cmp    byte ptr es:0,0e9h ; Z-100?
  581.     jnz    not_z10        ; No, it's probably IBM compatible
  582.     cmp    byte ptr es:3,0e9h ;Z-100?
  583.     jnz    not_z10        ; No, it's probably IBM compatible
  584.     mov    es,ax        ; Restore es
  585. ;
  586.     mov    flags.vtflg,ttheath ; Set Heath-19 emulation mode, allows macs
  587.     mov    brkval,BRKBIT    ; What to send for a break
  588.     in    al,mdmcom4    ; Check this port
  589.     and    al,modperb    ; Is it there?
  590.     jnz    lclini3        ; No, skip
  591.     mov    dx,offset com4ms1
  592.     mov    ah,prstr    ; Tell user it is there
  593.     int    dos
  594.     in    al,mdmcom4    ; Check again    
  595.     and    al,moddcdb    ; Carrier?
  596.     jz    lclini3        ; No, skip
  597.     mov    flags.comflg,4    ; Indicate s-100 port 2 for now
  598.     mov    portval,offset port4
  599.     mov    mddat0,mdmdat4
  600.     mov    mdstat0,mdmcom4
  601.     mov    ah,prstr    ; Tell user
  602.     mov    dx,offset com4ms
  603.     int    dos
  604. lclini3:in    al,mdmcom3    ; Check this port
  605.     and    al,modperb    ; Is it there?
  606.     jnz    lclini4        ; No, skip
  607.     mov    dx,offset com3ms1
  608.     mov    ah,prstr    ; Tell user it is there
  609.     int    dos
  610.     in    al,mdmcom3    ; Check again    
  611.     and    al,moddcdb    ; Carrier?
  612.     jz    lclini4        ; No, skip
  613.     mov    flags.comflg,3    ; Indicate s-100 port 1
  614.     mov    portval,offset port3
  615.     mov    mddat0,mdmdat3
  616.     mov    mdstat0,mdmcom3
  617.     mov    ah,prstr    ; Tell user
  618.     mov    dx,offset com3ms
  619.     int    dos
  620. lclini4:
  621.     call    getbaud        ; Which port of COM1/COM2 is default?
  622.                 ; Get baud rate from UARTs for this
  623.     call    baudref        ; Set up baud rate references bdtab, bddat
  624.     mov    port3.baud,bds100  ; and put in default baud rate
  625.     mov    port4.baud,bds100  ; and put in default baud rate
  626.     mov    lclsusp,offset suspend ; call this when suspending to DOS
  627.     mov    lclrest,offset restore ; call this when returning from DOS
  628.     mov    lclexit,offset finexit ; call this when exiting Kermit
  629.      call    ena_wrp        ; Make terminal wrap to next line at line end
  630.     call    lclyini        ; let other modules initialize too...
  631.     ret            ; We are all done with lclini
  632. ;
  633. baudref:push    di        ; Rearrange bdtab and bddat
  634.     push    si
  635.     push    es
  636.     mov    ax,ds        ; Set up
  637.     mov    es,ax        ;  pointers
  638.     mov    di,offset bddat ;  to move baud
  639.     mov    si,offset bddat12 ; rate selection
  640.     mov    cx,lbddat    ;  length of table
  641.     cmp    flags.comflg,2    ; Ports 1/2
  642.     jle    lclini5        ;  or ports 3/4?
  643.     mov    si,offset bddat34 ;Port 4! 
  644. lclini5:cld            
  645.     rep    movsb        ; Move array
  646.     mov    di,offset bdtab ; This too
  647.     mov    si,offset bdtab12
  648.     mov    cx,lbdtab12    ; Length of table 
  649.     cmp    flags.comflg,2    ; Ports 1/2
  650.     jle    lclini6        ;  or ports 3/4?
  651.     mov    si,offset bdtab34 ;Port 4! 
  652. lclini6:rep    movsb        ; Move array
  653.     pop    es        ; Restore registers
  654.     pop    si
  655.     pop    di
  656.     ret            ; We're done
  657. LCLINI    endp
  658.  
  659. ; Call these routines when suspending Kermit to go to DOS
  660. suspend proc    near
  661.     call    ihosts        ; suspend the host
  662.     call    serrst
  663.     call    dis_scan    ; disable scan code generation
  664.     call    dis_wrp        ; disable sreen line wrap around
  665.     ret
  666. suspend endp
  667.  
  668. ; Call these routines when returning to Kermit from DOS
  669. restore proc    near
  670.     call    serini        ; reinit serial port
  671.     call    ihostr        ; resume the host
  672.     call    ena_wrp        ; enable screen line wrap around
  673.     ret
  674. restore endp
  675.  
  676. ; Call these routines when doing final exit of Kermit
  677. finexit proc    near
  678.     call    serrst        ; reset serial port
  679.     call    dis_scan    ; disable scan code generation
  680.     call    dis_wrp        ; disable sreen line wrap around
  681.     ret
  682. finexit endp
  683.  
  684. ; This routine, ena_scan, enables Z-100 scan code generation.  It also
  685. ; disables extended key code generation.  Modifies ax.
  686. ENA_SCAN PROC    NEAR
  687.     push    dx
  688.     mov    ah,prstr
  689.     mov    dx,offset enascan
  690.     int    dos 
  691.     or    dosflg1,1        ; say scan codes enabled
  692.     pop    dx
  693.     ret
  694. ENA_SCAN ENDP
  695.  
  696. ; This routine, dis_scan, disables Z-100 scan code generation.    It also
  697. ; enables extended key code generatin.    Modifies ax.
  698. DIS_SCAN PROC    NEAR
  699.     push    dx
  700.     mov    ah,prstr
  701.     mov    dx,offset disscan
  702.     int    dos 
  703.     and    dosflg1,0feh        ; say scan codes disabled
  704.     pop    dx
  705.     ret
  706. DIS_SCAN ENDP
  707.  
  708. ; This routine, ena_wrp, enables wrap around at end of line.
  709. ; Modifies ax.
  710. ENA_WRP PROC NEAR
  711.     push    dx
  712.     mov    ah,conout
  713.     mov    dl,ESCAPE
  714.     int    dos
  715.     mov    dl,'v'
  716.     int    dos
  717.     pop    dx
  718.     ret
  719. ENA_WRP ENDP
  720.  
  721. ; This routine, dis_wrp, disables wrap around at end of line.
  722. ; Modifies ax.
  723. DIS_WRP PROC NEAR
  724.     push    dx
  725.     mov    ah,conout
  726.     mov    dl,ESCAPE
  727.     int    dos
  728.     mov    dl,'w'
  729.     int    dos
  730.     pop    dx
  731.     ret
  732. DIS_WRP ENDP
  733.  
  734. ; SHOW MODEM, displays current status of lines DSR, CD, and CTS.
  735. ; Uses byte mdmhand, the modem line status register. [jrd]
  736. shomodem proc    near
  737.     mov    ah,cmeol        ; get a confirm
  738.     call    comnd
  739.     jc    shomd5            ; c = failure
  740.     mov    dx,offset msmsg7    ; no modem status for network
  741.     call    getmodem        ; get modem status
  742.     mov    ah,prstr
  743.     cmp    flags.comflg,2        ; port 1 or 2
  744.     jle    shomd0            ; yes, jump
  745.     mov    dx,offset msmsg0    ; not supported function
  746.     jmp    shomd1
  747. shomd0: mov    dx,offset msmsg1    ; modem not ready msg
  748.     test    mdmhand,20h        ; is DSR asserted?
  749.     jz    shomd1            ; z = not ready
  750.     mov    dx,offset msmsg2    ; modem ready msg
  751. shomd1: int    dos
  752.     mov    dx,offset msmsg3    ; CD not asserted msg
  753.     test    mdmhand,80h        ; CD asserted?
  754.     jz    shomd2            ; z = not asserted
  755.     mov    dx,offset msmsg4    ; CD asserted msg
  756. shomd2: int    dos
  757.     clc
  758. shomd5: ret
  759. shomodem endp
  760.  
  761. ; Get modem status and set global byte mdmhand. Preserve all registers but dx.
  762. ; Returns with byte mdmhand in al, ah=0.
  763. getmodem proc    near        ; gets modem status upon request
  764.     cmp    flags.comflg,2    ; COM1 or COM2?
  765.     jna    getmodem2    ; na = yes, jump to handle these
  766.     mov    dx,mdstat0    ; Port address
  767.     in    al,dx        ; Get status
  768.     and    al,moddcdb    ; Carrier?
  769.     mov    mdmhand,0    ; Everything off
  770.     jz    getmodem1    ; z = yes, no carrier, done
  771.     mov    mdmhand,80h    ; No, carrier detected
  772. getmodem1:jmp    getmodem4    ; Done with COM3/COM4
  773. getmodem2:mov    dx,portadr
  774.     add    dx,PSTATUS
  775.     in    al,dx
  776.     mov    mdmhand,0    ; Everything off
  777.     test    al,DSR        ; DSR indicated?
  778.     jz    getmodem3    ; z = no, go on
  779.     mov    mdmhand,20h    ; Indicate DSR
  780. getmodem3:test    al,DCD        ; CD indicated?
  781.     jz    getmodem4    ; z = no, go on
  782.     or    mdmhand,80h    ; Indicate CD, don't touch DSR
  783. getmodem4:mov    al,mdmhand    ; Promised it here
  784.     xor    ah,ah        ; A promise too
  785.     clc            ; Success
  786.     ret
  787. getmodem endp
  788.  
  789. ; Clear the input buffer. This throws away all the characters in the
  790. ; serial interrupt buffer.  This is particularly important when
  791. ; talking to servers, since NAKs can accumulate in the buffer.
  792. CLRBUF    PROC    NEAR
  793.     cmp    flags.comflg,2    ; Ports 1/2?
  794.     jg    clrbuf1        ; g = no, do S-100 stuff
  795.     cli
  796.     push    bx
  797.     xor    bx,bx
  798.     mov    bufoend,bx
  799.     mov    bufobeg,bx
  800.     mov    bufiend,bx
  801.     mov    bufibeg,bx
  802.     pop    bx
  803.     mov    count,0
  804.     sti    
  805.     ret
  806. clrbuf1:push    ax            ; First empty port
  807.     push    dx
  808.     mov    dx,mddat0        ; Get possible
  809.     in    al,dx            ;  character
  810.     pop    dx
  811.     pop    ax            ;  then do it
  812.     mov    count,0            ; Nothing in buffer
  813.     mov    srcpnt,offset source    ; Reset buffer
  814.     mov    savedi,offset source    ;  pointers
  815.     ret
  816. CLRBUF    ENDP
  817.  
  818. ; Put the char in AH to the serial port, assumimg the port is active.
  819. ; Returns carry clear if success, else carry set.
  820. ; 16 May 1987 Add entry point OUTCH2 for non-flow controlled sending to
  821. ; prevent confusion of flow control logic at top of outchr; used by receiver
  822. ; buffer high/low water mark flow control code. [jrd]
  823. ; 14 September 1990 add entry point OUTCH5 for priority sending of xon;
  824. ; used by CHKXON and SERISR.
  825. OUTCHR    PROC    NEAR
  826.     cmp    flowoff,0        ; Are we doing flow control
  827.     je    outch2            ; No, just continue
  828.     cmp    ah,flowoff        ; sending xoff?
  829.     jne    outch1            ; ne = no
  830.     mov    xofsnt,usron        ; indicate user level xoff being sent
  831.     jmp    outch12
  832. outch1:and    xofsnt,not usron    ; cancel user level xoff
  833.     cmp    ah,flowon        ; user sending xon?
  834.     jne    outch12            ; ne = no
  835.     mov    xofsnt,off    ; say an xon has been sent (cancels xoff)
  836. outch12:mov    timer,xoftime+1    ; Set delay to xoftime minimum, maximum+1 sec
  837. outch14:cmp    xofrcv,true    ; Are we being held (xoff received)?
  838.     jnz    outch2        ; no - it's OK to go on
  839.     cmp    flags.comflg,2    ; Check if S-100 ports
  840.     push    ax        ; Save regs
  841.     push    bx
  842.     push    cx
  843.     push    dx
  844.     jle    outch16        ; No, make it simple
  845.     push    es
  846.     mov    cx,1        ; No delay for sprtch
  847.     call    sprtch        ; Get possible char at port com3/4
  848.     pop    es
  849. outch16:mov    ah,gettim    ; Get time function
  850.     int    dos
  851.     cmp    dl,timer0    ; Normally 0
  852.     pop    dx
  853.     pop    cx
  854.     pop    bx
  855.     pop    ax
  856.     jnz    outch14        ; No, go loop
  857.     xor    timer0,50    ; Yes, move target 1/2 second
  858.     cmp    timer0,0    ; This is only true every second
  859.     jnz    outch14        ; No, continue looping
  860.     dec    timer        ; Yes, one second has passed (unless 1st time)
  861.     jnz    outch14        ; No, have more seconds left, try again
  862.     mov    xofrcv,off    ; Timed out, force it off and fall thru.
  863. OUTCH2    LABEL    NEAR           ; outch2 entry point without flow control
  864.     mov    al,ah        ; Routine works on AL.
  865.     call    dopar        ; Set parity appropriately.
  866.     cmp    repflg,0    ; Doing REPLAY from a file?
  867.     je    outch24        ; e = no
  868.     and    al,7fh        ; Strip parity
  869.     cmp    al,'C'-40h    ; Control-C? (to exit playback mode)
  870.     je    outch22        ; e = yes, return failure
  871.     clc            ; Return success, send nothing
  872.     ret
  873. outch22:stc            ; Return failure to exit playback mode
  874.     ret
  875. ;
  876. outch24:push    bx
  877.     push    dx
  878.     cmp    flags.comflg,2    ; Ports J1/J2
  879.     jle    outch4        ; Yes, go handle J1/J2
  880.     mov    bl,al        ; No, do S-100, save byte to send
  881.     push    cx
  882.     xor    cx,cx        ; Set loop counter
  883. outch26:push    bx        ; Check on input
  884.     push    cx
  885.     push    es
  886.     mov    cx,1        ; No delay
  887.     call    sprtch        ; Get char from port if any
  888.     pop    es
  889.     pop    cx
  890.     pop    bx
  891.     mov    dx,mdstat0
  892.     in    al,dx        ; Check this port
  893.     and    al,modsndb    ;  for ready
  894.     jnz    outch28        ; Ready, continue
  895.     loop    outch26        ; Not ready, loop until ready or timeout
  896.     jmp    short outch44    ; Timed out, return with carry set
  897. outch28:pop    cx
  898.     mov    al,bl        ; Get back byte to send
  899.     mov    dx,mddat0
  900.     out    dx,al        ; Send it out
  901.     jmp    outch8        ; All done S-100 modem    
  902. ;
  903. outch4: push    cx
  904.     xor    cx,cx        ; Set loop counter
  905. outch40:mov    bx,bufobeg    ; get pointer to beginning of que
  906.     sub    bx,bufoend    ; where are we?
  907.     jnl    outch42        ; we did not wrap
  908.     add    bx,BUFOLEN    ; we have wrapped
  909. outch42:cmp    bx,BUFOLEN-2    ; we have bx char in buffer; is it full?
  910.     jnae    outch53        ; no, go on
  911.     loop    outch40        ; yes, loop until there is space or timeout
  912. outch44:pop    cx        ; timed out
  913.     pop    dx
  914.     pop    bx
  915.     stc
  916.     ret
  917. ;
  918. outch5: push    bx        ; OUTCH5 entry for SERISR and CHKXON
  919.     push    dx        ;  ah will contain xon or xoff only
  920.     push    cx
  921.     xor    cx,cx        ; Set loop counter
  922. outch50:mov    bx,bufobeg    ; get pointer to beginning of que
  923.     sub    bx,bufoend    ; where are we?
  924.     jnl    outch51        ; we did not wrap
  925.     add    bx,BUFOLEN    ; we have wrapped
  926. outch51:cmp    bx,BUFOLEN    ; we have bx char in buffer; is it full?
  927.     jne    outch52        ; no, go on
  928.     loop    outch50        ; yes, loop until there is space or timeout
  929.     jmp    short outch44    ; timed out, no space
  930. outch52:mov    al,ah        ; Routine works on AL.
  931.     call    dopar        ; Set parity appropriately.
  932.     pop    cx
  933.     jmp    short outch54
  934.                 ;
  935. outch53:pop    cx        ; restore stack
  936.     cmp    bx,0        ; buffer empty?
  937.     jz    outch58        ; yes, skip
  938.     cmp    flowoff,0    ; Are we doing flow control
  939.     je    outch58        ; No, skip
  940.     cmp    al,flowoff    ; Is it xoff?
  941.     je    outch54        ; Yes, this is priority, expedite
  942.     cmp    al,flowon     ; Is it xon?
  943.     jne    outch58        ; No, skip
  944.                 ;
  945. outch54:cli
  946.     mov    bx,bufobeg    ; beginning of que
  947.     dec    bx        ; we want space in between, bx still >= 0
  948.     jae    outch56        ; yes, go on
  949.      mov    bx,BUFOLEN    ; wrap
  950. outch56:mov    bufobeg,bx    ; new beginning
  951.     mov    byte ptr buffout[bx],al     ; put char in it
  952.     sti
  953.     jmp    short outch6
  954.  
  955. outch58:mov    bx,bufoend
  956.     mov    byte ptr buffout[bx],al     ; put char in it
  957.     inc    bx        ; point to next spot in que
  958.     cmp    bx,BUFOLEN    ; looking at end of que ?
  959.     jne    outch6        ; no, OK
  960.     xor    bx,bx        ; yes, reset pointer
  961. outch6: mov    bufoend,bx    ; store new value
  962.     mov    dx,portadr
  963.     add    dx,PCOMM
  964.     cli
  965.     in    al,dx
  966.     test    al,TXON        ; TX already on ?
  967.     jnz    outch7        ; yes, OK
  968.     or    al,TXON        ; no, turn it on
  969.     out    dx,al        ;   it's on
  970. outch7: sti            ; done with 2661
  971. outch8: pop    dx
  972.     pop    bx
  973.     clc            ; success, return with carry cleared
  974.     ret
  975. OUTCHR    ENDP
  976.  
  977. ; Move the cursor to the left margin, then clear to end of line.
  978. CTLU    PROC    NEAR
  979.     mov    ah,prstr
  980.     mov    dx,offset clrlin
  981.     int    dos
  982.  
  983. ; Clear to the end of the current line
  984. CLEARL    PROC    NEAR
  985.     push    ax
  986.     push    dx
  987.     mov    ah,prstr
  988.     mov    dx,offset eeolstr    ; Erase to end of line
  989.     int    dos
  990.     pop    dx
  991.     pop    ax
  992.     ret
  993. CLEARL    ENDP
  994. CTLU    ENDP
  995.  
  996. ; This routine blanks the screen and homes the cursor.    Uses ax and dx.
  997. CMBLNK    PROC    NEAR
  998.     mov    ah,prstr
  999.     mov    dx,offset clrstr    ; Home cursor, blank screen
  1000.     int    dos
  1001.     ret
  1002. CMBLNK    ENDP
  1003.  
  1004. ; Locate: homes the cursor.  Uses ax and dx.
  1005. LOCATE    PROC    NEAR
  1006.     mov    ah,prstr
  1007.     mov    dx,offset home        ; Go to top left corner of screen.
  1008.     int    dos
  1009. LOCATE    ENDP
  1010.  
  1011. ; write a line in inverse video at the bottom of the screen...
  1012. ; the line is passed in dx, terminated by a $.
  1013. PUTMOD    PROC    NEAR
  1014.     push    ax        ; save regs
  1015.     push    dx        ; preserve message
  1016.     mov    ah,prstr
  1017.     mov    dx,offset savcur
  1018.     int    dos
  1019.     mov    dx,offset enamod
  1020.     int    dos
  1021.     mov    dx,offset lin25
  1022.     int    dos
  1023.     mov    dx,offset begrev
  1024.     int    dos
  1025.     pop    dx        ; get message back
  1026.     int    dos        ; write it out
  1027.     mov    dx,offset endrev
  1028.     int    dos
  1029.     mov    dx,offset precur
  1030.     int    dos
  1031.     pop    ax
  1032.     ret            ; and return
  1033. PUTMOD    ENDP
  1034.  
  1035. ; clear the mode line written by putmod.
  1036. CLRMOD    PROC    NEAR
  1037.     mov    ah,prstr
  1038.     mov    dx,offset dismod
  1039.     int    dos
  1040.     ret
  1041. CLRMOD    ENDP
  1042.  
  1043. BEEP    PROC    NEAR
  1044.     push    ax        ; save regs
  1045.     push    dx        ; preserve message
  1046.     mov    ah,conout
  1047.     mov    dl,BELL        ; ASCII BEL
  1048.     int    dos        ; Ring it
  1049.     pop    dx
  1050.     pop    ax
  1051.     clc
  1052.     ret
  1053. BEEP    ENDP
  1054.  
  1055. ; Put a help message on the screen.  This one uses reverse video...
  1056. ; pass the message in ax, terminated by a null.     Messes up ax, bx, cx, dx.
  1057. PUTHLP    PROC    NEAR
  1058.     push    si
  1059.     push    ax        ; preserve this
  1060.     mov    dx,offset crlf
  1061.     int    dos
  1062.     pop    si        ; point to string again
  1063.     jmp    short puthl3    ; assume message begins with cr and lf
  1064. puthl2:    call    getpos        ; get cursor pos into dx
  1065.     mov    ax,dx        ; from row ah, col al
  1066.     mov    bx,dx
  1067.     mov    bl,COLUMNS    ;  to row bh, col bl
  1068.     mov    dx,word ptr doscol ; dos color reversed
  1069.     call    setcol        ; set this color
  1070.     call    atsclr        ;  and clear the line
  1071. puthl3: mov    cx,COLUMNS - 1    ; characters on a line less one (starts at 0)
  1072. puthl4: lodsb            ; get a byte
  1073.     mov    ah,conout    ; print char
  1074.     cmp    al,0        ; end of string?
  1075.     je    puthl5        ; yes, stop
  1076.     cmp    al,lf        ; lf ?
  1077.     je    puthl7         ; end of line, do new one
  1078.     cmp    cx,0        ; last column
  1079.     je    puthl6        ; no more space on line, get new one
  1080.     mov    dl,al        ; else, print char
  1081.     int    dos
  1082.     jmp    short puthl3    ; get next char
  1083. puthl5: pop    si
  1084.     ret
  1085. puthl6: mov    dl,cr
  1086.     int    dos
  1087. puthl7: mov    dl,lf
  1088.     int    dos
  1089.     jmp    short puthl2
  1090.  
  1091. PUTHLP    ENDP
  1092.  
  1093. ; Set the baud rate for the current port, based on the value
  1094. ; in the portinfo structure.  Returns carry clear.
  1095. BAUDST    PROC    NEAR
  1096.     mov    dx,offset bdtab        ; baud rate table, ascii
  1097.     xor    bx,bx            ; help is the table itself
  1098.     mov    ah,cmkey        ; get keyword
  1099.     call    comnd
  1100.     jc    baudst1            ; c = failure
  1101.     push    bx            ; save result
  1102.     mov    ah,cmeol        ; get confirmation
  1103.     call    comnd
  1104.     pop    bx
  1105.     jc    baudst1            ; c = failure
  1106.     push    si
  1107.     mov    si,portval
  1108.     mov    ax,[si].baud        ; remember original value
  1109.     mov    [si].baud,bx        ; set the baud rate
  1110.     pop    si
  1111.     call    dobaud            ; use common code
  1112.     clc
  1113. baudst1:ret
  1114. BAUDST    ENDP
  1115.  
  1116. DOBAUD    PROC    NEAR
  1117.     push    ax            ; save some regs
  1118.     push    bx
  1119.     push    cx
  1120.     push    dx
  1121.     mov    bp,portval    ; Pointer to port data structure
  1122.     mov    temp,ax        ; Don't overwrite previous rate
  1123.     mov    ax,ds:[bp].baud ; Check if new rate is valid
  1124.     shl    ax,1        ; Get index into baud table
  1125.     mov    bx,offset bddat ; Start of table.
  1126.     add    bx,ax
  1127.     mov    ax,[bx]        ; The data to output to port.
  1128.     cmp    ax,0FFH        ; Unimplemented baud rate.
  1129.     jne    dobd0
  1130.     mov    ax,temp        ; Get back orginal value.
  1131.     mov    ds:[bp].baud,ax ; Leave baud rate as is.
  1132.     mov    ah,prstr
  1133.     mov    dx,offset badbd ; Give an error message.
  1134.     int    dos
  1135.     stc            ; Failure
  1136.     jmp    dobd2
  1137. dobd0:    mov    ds:[bp].baud,ax ; Put in new baud rate
  1138.     cmp    flags.comflg,2    ; is it J1/J2?
  1139.     jle    dobd1        ; yes, go do J1/J2 stuff
  1140.     call    serini        ; go set rate in S-100 modem
  1141.  
  1142.     jmp    dobd2
  1143. dobd1:    mov    dx,portadr    ; get addr to send it
  1144.     add    dx,PMODE
  1145.     push    ax        ; save baud
  1146.     mov    al,MODE1
  1147.     cli            ; none while setting 2661
  1148.     out    dx,al        ; mode reg 1/2
  1149.     pop    ax        ; get baud back
  1150.     and    al,0fH        ; make sure it's clean
  1151.     or    al,MODE2    ; make complete mode 2/2 command
  1152.     out    dx,al        ; set mode reg 2/2
  1153.     sti            ; done with 2661
  1154.     clc            ; Success
  1155. dobd2:    pop    dx        ; restore regs
  1156.     pop    cx
  1157.     pop    bx
  1158.     pop    ax
  1159.     ret
  1160. DOBAUD    ENDP
  1161.  
  1162. ; Get the current baud rate from the serial card and set it
  1163. ; in the portinfo structure for the current port.
  1164. ; Also finds out which serial port, A (COM2) or B (COM1), is defined
  1165. ; as default by Zenith Configur.
  1166. ; This is used during initialization.
  1167. GETBAUD PROC    NEAR
  1168.     cmp    flags.comflg,2    ; J1/J2?
  1169.     jg    getbau3        ; No, all done
  1170.     
  1171.     push    ax
  1172.     push    bx
  1173.     push    dx
  1174.     push    di
  1175.     cmp    portadr,0    ; Just started Kermit?
  1176.     jnz    getbau2        ; No, skip this
  1177.     mov    bx,ds        ; Set up pointer to config info
  1178.     mov    es,bx
  1179.     mov    bx,offset auxconf
  1180.     mov    ah,chr_status
  1181.     mov    al,chr_sfgc    ; Get current config info
  1182.     call    bios_auxfunc
  1183.     cmp    auxconf.cfport,mdmdat1 ; Is it B?
  1184.     jne    getbau1        ; ne = no
  1185.     mov    flags.comflg,1    ; Set flag to indicate port B
  1186.     mov    portval,offset port1
  1187.     mov    mddat0,mdmdat1
  1188.     mov    portadr,mdmdat1
  1189.     mov    mdstat0,mdmcom1
  1190.     jmp    getbau2
  1191. getbau1:mov    flags.comflg,2    ; Set flag to indicate port A
  1192.     mov    portval,offset port2
  1193.     mov    mddat0,mdmdat2
  1194.     mov    portadr,mdmdat2
  1195.     mov    mdstat0,mdmcom2           
  1196. getbau2:mov    dx,portadr    ; Get addr to retrieve mode from
  1197.     add    dx,PMODE
  1198.     in    al,dx        ; Read and discard mode 1/2
  1199.     in    al,dx        ; mode 2/2 has baud rate
  1200.     and    ax,000fH    ; Clean it up
  1201.     mov    bp,portval
  1202.     mov    ds:[bp].baud,ax ; Put it in portinfo struct
  1203.     pop    di
  1204.     pop    dx
  1205.     pop    bx
  1206.     pop    ax
  1207. getbau3:ret
  1208. GETBAUD ENDP
  1209.  
  1210. ; Get Char from serial port buffer.
  1211. ; returns carry set if no character available at port, otherwise prtchr
  1212. ; returns carry clear with char in al, # of chars in buffer in dx and count.
  1213. PRTCHR    PROC    NEAR
  1214.     cmp    flags.comflg,2    ; check if S-100 ports
  1215.     jg    prtch4        ; Yes, go do S-100 stuff
  1216.     call    chkxon        ; see if we need to xon
  1217.     cmp    repflg,0    ; REPLAY?
  1218.     je    prtch0        ; e = no
  1219.      jmp    prtch30        ; yes, do replay file reading
  1220. prtch0: cli            ; dont let intterrupts touch buffers
  1221.     mov    dx,bufiend    ; compute number of chars in
  1222.     sub    dx,bufibeg    ;   input que
  1223.     jge    prtch1        ; is it wrapped around
  1224.     add    dx,BUFILEN    ; yes, make it +
  1225. prtch1: cmp    dx,0        ; anything in there ?
  1226.     jne    prtch2        ; ne = yes. [jrd]
  1227.     mov    count,dx
  1228.     sti
  1229.     stc            ; no
  1230.     ret
  1231. prtch2: mov    bx,bufibeg    ; yes, get the char, get the position
  1232.     mov    al,byte ptr buffin[bx]    ; get the char
  1233.     inc    bx        ; bump the position ptr
  1234.     cmp    bx,BUFILEN    ; wrap it ?
  1235.     jne    prtch3
  1236.     xor    bx,bx        ; yes, reset pointer
  1237. prtch3: mov    bufibeg,bx    ; store new value
  1238.     dec    dx        ; we took one char out
  1239.     mov    count,dx    ; save
  1240.     sti
  1241.     clc            ; yes, got it
  1242.     ret
  1243. prtch4: 
  1244.     push    ax        ; First check port for possible input
  1245.     push    bx
  1246.     push    cx
  1247.     push    es
  1248.     mov    cx,1        ; Parameter for sprtch, cx=1 means don't loop
  1249.     call    sprtch        ; Read port
  1250.     pop    es
  1251.     pop    cx
  1252.     pop    bx
  1253.     pop    ax
  1254.     cmp    repflg,0    ; REPLAY?
  1255.     je    prtch41        ; e = no
  1256.      jmp    prtch30        ; yes, do replay file reading
  1257. prtch41:cmp    count,0        ; Buffer empty?
  1258.     jne    prtch5        ; ne = no, get char
  1259.     mov    dx,0        ; Nothing there        Is this needed?
  1260.     stc            ; Got nothing
  1261.     ret
  1262. prtch5: push    si        ; Don't mess up, used by spack
  1263.     mov    si,srcpnt    ; Point to next character in que
  1264.     cld
  1265.     lodsb            ; Get the next one
  1266.     cmp    si,offset source + bufsiz ; Bigger than buffer?
  1267.     jb    prtch6        ; No, keep going
  1268.     mov    si,offset source ; Yes, wrap around
  1269. prtch6: dec    count
  1270.     mov    dx,count
  1271.     mov    srcpnt,si
  1272.     pop    si        ; Left in good shape
  1273.     clc            ; Yes, got it
  1274.     ret
  1275. prtch30:cmp    repflg,2        ; at EOF already?
  1276.     jne    prtch31            ; ne = no
  1277.     stc                ; yes, return with no char
  1278.     ret
  1279. prtch31:push    bx            ; REPLAY, read char from a file
  1280.     push    cx
  1281.     xor    dx,dx
  1282.     test    xofsnt,usron        ; user level xoff sent?
  1283.     jz    prtch32            ; z = no
  1284.     pop    cx            ; suppress reading here
  1285.     pop    bx
  1286.     stc                ; return with no char
  1287.     ret
  1288. prtch32:mov    ax,100
  1289.     mov    bx,1
  1290.     jmp    $+2            ; flush lookahead buffer
  1291.     div    bx            ; burn some cpu cycles
  1292.     div    bx            ; because a 1 ms wait is too long
  1293.     div    bx
  1294.     div    bx
  1295.     mov    ah,readf2
  1296.     mov    bx,diskio.handle    ; file handle
  1297.     mov    cx,1            ; read one char
  1298.     mov    dx,offset rdbuf        ; to this buffer
  1299.     int    dos
  1300.     jc    prtch34            ; c = read failure
  1301.     cmp    ax,cx            ; read the byte?
  1302.     jne    prtch34            ; ne = no
  1303.     pop    cx
  1304.     pop    bx
  1305.     mov    al,rdbuf        ; get the char into al
  1306.     mov    dx,1            ; external char count
  1307.     clc
  1308.     ret                ; return it
  1309. prtch34:call    beep
  1310.     mov    ax,40            ; wait 40 millisec
  1311.     call    pcwait
  1312.     call    beep
  1313.     mov    repflg,2        ; say at EOF
  1314.     pop    cx
  1315.     pop    bx
  1316.     stc                ; say no char
  1317.     ret
  1318. PRTCHR    ENDP
  1319.  
  1320. ; Examine incoming communications stream for a packet SOP character.
  1321. ; Return CX= count of bytes starting at the SOP character (includes SOP)
  1322. ; and carry clear. Return CX = 0 and carry set if SOP is not present.
  1323. ; Destroys AL.
  1324. peekcom proc far
  1325.     mov    cx,count        ; qty in circular buffer
  1326.     cmp    cx,6            ; basic NAK
  1327.     jb    peekc4            ; b = two few chars, get more
  1328.     push    bx
  1329.     cli        ; interrupts off, to keep srcpnt & count consistent
  1330.     mov    bx,srcpnt        ; address of next available slot in buffer
  1331.     sub    bx,cx            ; minus number of unread chars in buffer
  1332.     cmp    bx,offset source    ; located before start of buf?
  1333.     jae    peekc1            ; ae = no
  1334.     add    bx,bufsiz        ; else do arithmetic modulo bufsiz
  1335. peekc1:    mov    al,[bx]
  1336.     cmp    al,trans.rsoh        ; packet receive SOP?
  1337.     je    peekc3            ; e = yes
  1338.     inc    bx
  1339.     cmp    bx,offset source+bufsiz ; beyond end of buffer?
  1340.     jb    peekc2            ; b = no
  1341.     mov    bx,offset source    ; wrap around
  1342. peekc2:    loop    peekc1            ; keep looking
  1343.     sti
  1344.     pop    bx
  1345.     stc                ; set carry for no SOP
  1346.     ret
  1347. peekc3:    sti                ; interrupts back on now
  1348.     pop    bx
  1349.     inc    cx            ; include SOP in count
  1350.     clc                ; say SOP found
  1351.     ret                ; CX has count remaining
  1352.     
  1353. peekc4:    xor    cx,cx            ; return count of zero
  1354.     stc                ; say no data
  1355.     ret
  1356. peekcom endp
  1357.  
  1358.  
  1359. ; local routine to see if we have to transmit an xon when com1/2
  1360. chkxon    proc    near
  1361.     cmp    xofsnt,false    ; have we sent an xoff?
  1362.     je    chkxo1        ; no, forget it
  1363.     cmp    flowoff,0    ; Are wo doing flow control?
  1364.     je    chkxo1        ; no, skip all this
  1365.     test    xofsnt,usron    ; did user send an xoff?
  1366.     jnz    chkxo1        ; nz = yes, don't contradict it here
  1367.     test    xofsnt,bufon    ; have we sent a buffer level xoff?
  1368.     jz    chkxo1        ; z = no, forget it
  1369.     cmp    count,mntrgl    ; below trigger?
  1370.     jae    chkxo1        ; no, forget it
  1371.     mov    ah,flowon    ; xon
  1372.     call    outch5        ; send it
  1373.     jc    chkxo1        ; failure
  1374.     and    xofsnt,false    ; remember we've sent the xon.
  1375. chkxo1: ret            ; and return
  1376. chkxon    endp
  1377.  
  1378. ; Local routine to see if we have to transmit an xoff or xon when com3/4
  1379. ; this is probably overdoing it
  1380. ; called by sprtch
  1381. chkxof    proc    near
  1382.     cmp    flowoff,0    ; Are wo doing flow control?
  1383.     je    chkxof1        ; no, skip all this
  1384.     test    xofsnt,usron    ; did user send an xoff?
  1385.     jnz    chkxof1        ; nz = yes, don't contradict it here
  1386.     test    xofsnt,bufon    ; have we sent a buffer level xoff?
  1387.     jz    chkxof1        ; z = no, forget it
  1388.     cmp    count,mntrgh    ; Buffer filling up?
  1389.     jb    chkxof3        ; no, go check that xon sent
  1390.     cmp    xofsnt,true    ; yes, have we sent an xoff?
  1391.     je    chkxof1        ; yes, all done
  1392.     mov    ah,flowoff    ; xoff
  1393.     mov    xofsnt,true    ; remember we've sent the xoff.
  1394.     jmp    short chkxof2    ; go send xoff
  1395. chkxof3:cmp    count,mntrgl    ; below trigger
  1396.     jae    chkxof1        ; no, forget it
  1397.     cmp    xofsnt,false    ; xon sent?
  1398.     je    chkxof1        ; all done
  1399.     mov    ah,flowon    ; xon
  1400. chkxof2:call    outch2        ; send it
  1401. chkxof1:ret            ; and return
  1402. chkxof    endp
  1403.  
  1404. ; Read the serial port for the S-100 modem and put input in buffer.
  1405. ; Call with delay loop count in cx, c = 1 means no delay.
  1406. ; Input stream is monitored for xon/xoff.
  1407. ; Called by outchr, prtchr and outtty.
  1408. ; Destroys ax, bx, cx, dx, es
  1409. SPRTCH    PROC    NEAR
  1410.     mov    bx,ds        ; Point to data segment
  1411.     mov    es,bx
  1412.     mov    dx,mdstat0    ; Check 
  1413.     in    al,dx        ;  status
  1414.     and    al,modrcvb    ; Character at port?
  1415.     jnz    sprtch2        ; Yes, go get it
  1416.     call    chkxof
  1417.     loop    sprtch0        ; Keep checking port if cx not=1
  1418.     ret            ; No data 
  1419.  
  1420. sprtch0:push    cx
  1421.     xor    cx,cx        ; This is a delay loop to expand the delay for
  1422.     mov    cl,trans.rtime    ;  screen escape sequencies and capture.
  1423.     or    cx,cx        ; avoid 0, it will loop for ever
  1424.     jnz    sprtch1
  1425.     inc    cx
  1426. sprtch1:loop    sprtch1        ;  The delay time is controlled through the
  1427.     pop    cx        ;   receive timeout setting.
  1428.     jmp    sprtch
  1429.  
  1430. sprtch2:mov    dx,mddat0    ; Get
  1431.     in    al,dx        ;  character
  1432.     mov    ah,al        ; Make working copy
  1433.     and    ah,parmsk    ; Strip parity
  1434.     mov    bx,portval
  1435.     cmp    [bx].floflg,0    ; Are we doing flow control.
  1436.     jz    sprtch4        ; No, skip
  1437.     mov    dx,[bx].flowc
  1438.     cmp    ah,dh        ; xon?
  1439.     jne    sprtch3        ; No, check xoff
  1440.     mov    xofrcv,off    ; Set flag to indicate xoff not received (xon)
  1441.     jmp    short sprtch6    ; Get the next char
  1442.  
  1443. sprtch3:cmp    ah,dl        ; xoff?
  1444.     jne    sprtch4        ; No, go do normal buffer handling
  1445.     mov    xofrcv,true    ; Set flag to indicatae xoff received
  1446.     jmp    short sprtch6    ; Get the next char
  1447.  
  1448. sprtch4:push    di
  1449.     mov    di,savedi    ; Point to last received char
  1450.     cld
  1451.     stosb            ; Save the next one
  1452.     cmp    di,offset source + bufsiz ; Bigger than buffer?
  1453.     jb    sprtch5        ; No, keep going
  1454.     mov    di,offset source ; Yes, wrap around
  1455. sprtch5:inc    count
  1456.     mov    savedi,di
  1457.     pop    di
  1458. sprtch6:call    chkxof
  1459.     loop    sprtch0        ; Keep checking port if cx not=0
  1460.     ret
  1461. SPRTCH    ENDP
  1462.  
  1463. ; IHOSTS - Initialize the host by sending XOFF, or equivalent.
  1464. ; Requires that the port be initialized before hand.
  1465. ; Do not send flow control if doing half duplex.
  1466. IHOSTS    PROC    NEAR
  1467.     push    ax        ; save the registers
  1468.     push    cx
  1469.     push    dx
  1470.     mov    xofrcv,off    ; clear old xoff received flag
  1471.     mov    xofsnt,off    ; and old xoff sent flag
  1472.     mov    ah,flowoff    ; put wait flow control char in ah
  1473.     or    ah,ah        ; check for null char
  1474.     jz    ihosts1        ; z = null, don't send it
  1475.     cmp    dupflg,0    ; full duplex?
  1476.     jne    ihosts1        ; ne = no, half
  1477.     call    outchr        ; send it
  1478. ihosts1:call    clrbuf        ; clear out interrupt buffer
  1479.     pop    dx        ; empty buffer. we are done here
  1480.     pop    cx
  1481.     pop    ax
  1482.     ret
  1483. IHOSTS    ENDP
  1484.  
  1485. ; IHOSTR - initialize the remote host for our reception of a file by
  1486. ; sending the flow-on character (XON typically) to release any held
  1487. ; data. Called by receive-file code just after initializing the serial
  1488. ; port.        22 March 1986 [jrd]
  1489. IHOSTR    PROC    NEAR
  1490.     push    ax        ; save regs
  1491.     push    bx
  1492.     push    cx
  1493.     mov    bx,portval    ; port indicator
  1494.     mov    ax,[bx].flowc    ; put Go-ahead flow control char in ah
  1495.     or    ah,ah        ; check for null char
  1496.     jz    ihostr1        ; z = null, don't send it
  1497.     call    outchr        ; send it (release Host's output queue)
  1498. ihostr1:pop    cx
  1499.     pop    bx
  1500.     pop    ax
  1501.     ret
  1502. IHOSTR    ENDP
  1503.  
  1504.  
  1505. ; Global proc to Hangup the Phone or Network by making DTR and
  1506. ; RTS low (phone).
  1507. DTRLOW    PROC    NEAR
  1508.     mov    ah,cmline    ; allow text, to be able to display help
  1509.     mov    bx,offset rdbuf        ; dummy buffer
  1510.     mov    dx,offset hnghlp    ; help message
  1511.     call    comnd            ; get a confirm
  1512.     jc    dtrlow3            ; c = failure
  1513.     cmp    flags.comflg,'0'    ; Bios?
  1514.     jb    dtrlow1            ; b = no, UART
  1515.     cmp    flags.comflg,'4'    ; Bios?
  1516.     jbe    dtrlow2            ; be = yes, can't access modem lines
  1517. dtrlow1:call    serhng            ; drop DTR and RTS
  1518.     cmp    taklev,0        ; in a Take file or macro?
  1519.     jne    dtrlow2            ; ne = yes, no message
  1520.     mov    ah,prstr        ; give a nice message
  1521.     mov    dx,offset hngmsg
  1522.     int    dos
  1523. dtrlow2:clc                ; success
  1524. dtrlow3:ret
  1525. DTRLOW    ENDP
  1526.  
  1527. ; Hang up the Phone. Similar to SERRST except it just forces DTR and RTS low
  1528. ; to terminate the connection. (com1 and com2)
  1529. ; The USR S-100 modem will not respond to dropping of DTR.  Instead the +++
  1530. ; sequence must be sent.
  1531. ; Calling this twice without intervening calls to serini should be harmless.
  1532. SERHNG    PROC    NEAR
  1533.     cmp    flags.comflg,2    ; Which port?
  1534.     jg    serhng1
  1535.     cli
  1536.     call    porton        ; Insure that DTR and RTS are high
  1537.     sti
  1538.     mov    dx,portadr
  1539.     add    dx,PCOMM
  1540.     in    al,dx
  1541.     xor    al,DTR        ; Drop DTR
  1542.     xor    al,RTS        ; Drop RTS 
  1543.     out    dx,al
  1544.     mov    ax,500        ; 500 millisec, for pcwait
  1545.     call    pcwait        ; keep lines low for at least 500 millisec
  1546.     clc
  1547.     ret
  1548. serhng1:mov    dx,mdstat0    ; Port address.     [19b]
  1549.     in    al,dx        ; Get status
  1550.     and    al,moddcdb    ; Carrier?
  1551.     jz    serhng4        ; No, tell user
  1552.     mov    ah,prstr    ; Yes, tell user to wait
  1553.     mov    dx,offset wmsg
  1554.     int    dos
  1555.     mov    ax,1100        ; 1100 milliseconds
  1556.     call    pcwait        ; Wait before sending '+++'
  1557.     push    si
  1558.     mov    si,offset hngstr  ; Point to '+++'
  1559.     cld
  1560.     lodsb            ; Get the first byte of string
  1561. serhng2:push    ax        ; We need the loaded byte later
  1562.     mov    dx,mdstat0    ; The status port
  1563. serhng3:in    al,dx        ; Get status
  1564.     and    al,modsndb    ; Mask for ready
  1565.     jz    serhng3        ; No, go on
  1566.     pop    ax        ; Get byte back
  1567.     mov    dx,mddat0    ; The data port
  1568.     out    dx,al        ; Send it out
  1569.     lodsb            ; Load next byte
  1570.     cmp    al,'$'        ; Finished?
  1571.     jnz    serhng2        ; No, process next
  1572.     pop    si
  1573.     mov    ax,1100        ; 1100 milliseconds
  1574.     call    pcwait        ; Wait after sending '+++'
  1575.     mov    dx,mdstat0    ; Port address.     [19b]
  1576.     in    al,dx        ; Get status
  1577.     and    al,moddcdb    ; Carrier?
  1578. serhng4:mov    ah,prstr
  1579.     mov    dx,offset dscmsg ; Point to message
  1580.     clc
  1581.     jz    serhng5        ; Yes, no carrier, go tell user
  1582.     inc    cl        ; No, carrier detected
  1583.     cmp    cl,3        ; Try three times
  1584.     jnz    serhng1        ; No, go try again
  1585.     mov    dx,offset ndscmsg ; Warn user
  1586. serhng5:int    dos        ;  all done 
  1587.     ret
  1588. SERHNG    ENDP
  1589.  
  1590. ; Send a break out the current serial port.
  1591. SENDBR    PROC    NEAR
  1592.     mov    brkdur,28        ; Normal break 280ms
  1593.     jmp    sendbr1
  1594. sendbl: mov    brkdur,180        ; Long break 1800ms
  1595.     jmp    sendbr1
  1596. sendbr1:push    cx
  1597.     push    dx
  1598.     push    ax
  1599.     mov    dx,mdstat0    ; Port address
  1600.     cmp    flags.comflg,2    ; Which port?
  1601.     jg    sendbr3         
  1602.     in    al,dx        ; Get current setting
  1603.     or    al,brkval    ; Set send-break bit(s)
  1604.     out    dx,al        ; Start the break
  1605.     mov    bx,brkdur    ; wait this long
  1606.     call    wait01        ; hold break for desired interval
  1607.     xor    al,brkval    ; Clear send-break bit(s)
  1608.     out    dx,al        ; Stop the break
  1609. sendbr2:pop    ax
  1610.     pop    dx
  1611.     pop    cx
  1612.     ret
  1613. sendbr3:call    pickspd        ; Point to speed
  1614.     mov    al,[bx+1]    ; Command byte
  1615.     sub    al,8h        ; Break byte 8h lower (1fh and 3fh)
  1616.     cmp    al,1fh
  1617.     je    sendbr4
  1618.     mov    al,3fh        
  1619. sendbr4:out    dx,al
  1620.     mov    bx,brkdur    ; wait this long
  1621.     call    wait01
  1622.     call    initmod
  1623.     jmp    sendbr2
  1624. SENDBR    ENDP
  1625.  
  1626. ; Position the cursor according to contents of DX:
  1627. ; DH contains row, DL contains column.
  1628. POSCUR    PROC    NEAR
  1629.     push    ax
  1630.     push    dx
  1631.     cmp    flags.comflg,2    ; Ports 1/2
  1632.     jna    poscur1        ; Yes, skip this
  1633.     push    bx        ; No, check input port
  1634.     push    cx
  1635.     push    es
  1636.     mov    cx,1        ; No delay
  1637.     call    sprtch        ; Get char from port if any
  1638.     pop    es
  1639.     pop    cx
  1640.     pop    bx
  1641. poscur1:mov    ah,conout
  1642.     mov    dl,ESCAPE
  1643.     int    dos
  1644.     mov    dl,'Y'
  1645.     int    dos
  1646.     pop    dx
  1647.     push    dx
  1648.     mov    dl,dh
  1649.     add    dl,' '
  1650.     int    dos
  1651.     pop    dx
  1652.     add    dl,' '
  1653.     int    dos
  1654.     pop    ax
  1655.     ret
  1656. POSCUR    ENDP
  1657.  
  1658.  
  1659. ; Delete a character from the terminal.     This works by printing
  1660. ; backspaces and spaces.
  1661. DODEL    PROC    NEAR
  1662.     mov    ah,prstr
  1663.     mov    dx,offset delstr ; Erase weird character.
  1664.     int    dos
  1665.     ret
  1666. DODEL    ENDP
  1667.  
  1668. ; select port to be current.  Returns with carry clear if success.
  1669. COMS    PROC    NEAR
  1670. ;    mov    kstatus,0        ; global status, success
  1671.     mov    dx,offset comptab    ; table of legal comms ports
  1672.     mov    bx,offset comsmsg    ; point to comsmsg
  1673.     mov    ah,cmkey        ; parse key word
  1674.     call    comnd
  1675.     jnc    coms0            ; nc = success
  1676.     ret                ; failure
  1677. coms0:    call    serrst            ; uninstall interrupt
  1678.     call    comstrt
  1679.     jnc    coms1
  1680.     mov    ah,prstr
  1681.     mov    dx,offset coms0msg    ; Point to no S-100 modem msg
  1682.     int    dos
  1683. coms1:    clc
  1684.     ret
  1685.  
  1686. comstrt:mov    al,flags.comflg
  1687.     mov    tmp,al            ; Save the old one in case
  1688.     mov    flags.comflg,bl        ; Set the comm port flag.
  1689.     cmp    bl,1            ; COM1 (port B)?
  1690.     je    coms2            ; Yes
  1691.     cmp    bl,2            ; COM2 (port A)?
  1692.     je    coms3            ; Yes        
  1693.     cmp    bl,3            ; COM3 (S-100 modem port 1)
  1694.     je    coms4            ; Yes
  1695.     in    al,mdmcom4        ; Check this port
  1696.     and    al,modperb        ; Is it there?
  1697.     jnz    coms6            ; No, skip
  1698.     mov    portval,offset port4    ; Must be COM4
  1699.     mov    mddat0,mdmdat4
  1700.     mov    mdstat0,mdmcom4
  1701.     jmp    coms5    
  1702. coms4:    in    al,mdmcom3        ; Check this port
  1703.     and    al,modperb        ; Is it there?
  1704.     jnz    coms6            ; No, skip
  1705.     mov    portval,offset port3
  1706.     mov    mddat0,mdmdat3
  1707.     mov    mdstat0,mdmcom3
  1708.     jmp    coms5        
  1709. coms2:    mov    mdstat0,mdmcom1        ; Set break address for B
  1710.     mov    portadr,mdmdat1        ; Set address for B
  1711.     mov    portval,offset port1    ; Point to portinfo for B
  1712.     jmp    coms5
  1713. coms3:    mov    mdstat0,mdmcom2        ; Set break address for A
  1714.     mov    portadr,mdmdat2        ; Set address for A
  1715.     mov    portval,offset port2    ; Point to portinfo for A
  1716. coms5:    call    baudref            ; Set up bdtab and bddat
  1717.     call    getbaud            ; See what is in the port now set
  1718.     clc                ; Success
  1719.     ret    
  1720. coms6:    mov    al,tmp
  1721.     mov    flags.comflg,al        ; Get the old one back
  1722.     stc                ; Failure
  1723.     ret
  1724. COMS    ENDP
  1725.  
  1726. ; Set heath emulation on/off.
  1727. ; SET Term parameters, especially for use with VT100 emulator. [jrd]
  1728. ; Taken from work done originally by James Harvey IUPUI.
  1729. ; VTS is called only by mssset to set terminal type and characteristics.
  1730. ; Enter via direct jmp. Exit ret with carry set for failure, else carry
  1731. ; cleared.
  1732. VTS    proc    near            ; SET TERM whatever
  1733.     mov    dx,offset termtb    ; terminal table, ascii
  1734.     xor    bx,bx            ; help is the table itself
  1735.     mov    ah,cmkey        ; get keyword
  1736.     call    comnd
  1737.     jnc    vset1            ; nc = success
  1738.     ret                ; failure
  1739. vset1:    mov    flags.vtflg,bx        ; Set the Heath emulation flag
  1740.     and    bx,bx            ; emulating?
  1741.     mov    dosflg,0ffh        ; set the flag, disable scan codes
  1742.     mov    flags.xltkbd,0        ; key translation disabled
  1743.     jz    vset2            ; nz=yes
  1744.     mov    dosflg,0        ; clear the flag, enable scan codes
  1745.     mov    flags.xltkbd,1        ; key translation enabled
  1746. vset2:    mov    dx,offset vtsmsg
  1747.     mov    ah,prstr
  1748.     int    dos
  1749.     clc                ; success
  1750.     ret
  1751. VTS    ENDP
  1752.  
  1753. VTSTAT    PROC    NEAR        ; For Status display [jrd]
  1754.     ret            ; no emulator status to display
  1755. VTSTAT    ENDP
  1756.  
  1757.  
  1758. ; simple routine to insure that the port has RXON and DTR high
  1759. ;  assumes int are off
  1760. porton    proc    near
  1761.     push    dx
  1762.     push    ax
  1763.     mov    dx,portadr
  1764.     add    dx,PCOMM
  1765.     in    al,dx
  1766.     or    al,RXON
  1767.     or    al,DTR
  1768.     or    al,RTS
  1769.     out    dx,al
  1770.     pop    ax
  1771.     pop    dx
  1772.     ret
  1773. porton    endp
  1774.  
  1775. ; routine to retrieve current int vector
  1776. ;  inputs:  al = int number
  1777. ;  outputs: cx = seg for current isr
  1778. ;        dx = offset for current isr
  1779. getivec proc    near
  1780.     push    es        ; save registers
  1781.     push    bx
  1782.     mov    ah,35H        ; Int 21H, function 35H = Get Vector.
  1783.     int    dos        ; get vector in es:bx
  1784.     mov    cx,es        ; addr of org vector (seg)
  1785.     mov    dx,bx        ;   and offset
  1786.     pop    bx
  1787.     pop    es
  1788.     ret
  1789. getivec endp
  1790.  
  1791. ; routine to set int vector
  1792. ;  inputs:  al = int number
  1793. ;        cx = seg for isr
  1794. ;        dx = offset for isr
  1795. setivec proc    near
  1796.     push    ds        ; save ds around next DOS call.
  1797.     mov    ds,cx
  1798.     mov    ah,25H        ; set interrupt address from ds:dx
  1799.     int    dos
  1800.     pop    ds
  1801.     ret
  1802. setivec endp
  1803.  
  1804.  
  1805. ; initialization for using serial port.     This routine performs
  1806. ; any initialization necessary for using the serial port, including
  1807. ; setting up interrupt routines, setting buffer pointers, etc.
  1808. ; Doing this twice in a row should be harmless (this version checks
  1809. ; a flag and returns if initialization has already been done).
  1810. ; SERRST below should restore any interrupt vectors that this changes.
  1811. SERINI    PROC    NEAR
  1812.     cmp    portin,0    ; did we initialize port already?
  1813.     je    serin1        ; e = yes
  1814.     jl    serin0        ; l = no, not yet
  1815.     jmp    serin2
  1816. serin0: mov    bl,flags.comflg ; pass current port ident
  1817.     call    comstrt        ; do SET PORT now
  1818.     jnc    serin1        ; nc = success
  1819.     ret            ; failed, exit now
  1820. serin1: cmp    flags.comflg,2    ; COM1 or COM2?
  1821.     jle    serini1        ; Go do COM1/COM2 stuff
  1822. serin2: cmp    flags.comflg,2    ; COM1 or COM2?
  1823.     jg    serini2        ; Go do COM3/COM4 stuff
  1824.     jmp    serini3        ; Update flow and leave
  1825. initmod:            ; The S-100 modem set up routine
  1826. serini2:call    pickspd        ; Select baud and speed info
  1827.     xor    al,al        ; Use this to reset modem
  1828.     mov    dx,mdstat0    ; Status port
  1829.     out    dx,al        ; Send to port
  1830.     jmp    $+2        ; Wait a little
  1831.     out    dx,al
  1832.     jmp    $+2        ; Wait a little
  1833.     out    dx,al
  1834.     jmp    $+2        ; Wait a little
  1835.     mov    al,40h
  1836.     out    dx,al
  1837.     jmp    $+2        ; Wait a little
  1838.     mov    al,[bx]
  1839.     out    dx,al
  1840.     jmp    $+2        ; Wait a little
  1841.     mov    al,[bx+1]
  1842.     out    dx,al
  1843.     jmp    $+2
  1844.     in    al,dx        ; Check port
  1845.     and    al,moddcdb    ;  for carrier
  1846.     jnz    serini0        ; Yes, don't do AT stuff
  1847.     mov    bx,10        ; Wait 10/100 seconds
  1848.     call    wait01        ; Call wait routine
  1849.     push    si
  1850.     mov    si,offset set_str;ATE1X1S0=0 sets up modem: echo commands, use
  1851.     cld            ;  extended response codes, don't answer
  1852.     lodsb            ; Get the first byte of string
  1853. serini5:push    ax        ; We need the loaded byte later
  1854. serini6:xor    cx,cx        ; Reset loop counter.  Loop to avoid hanging
  1855.     mov    dx,mdstat0    ; The status port
  1856. serini7:in    al,dx        ; Get status
  1857.     and    al,modsndb    ; Mask for ready
  1858.     jnz    serini8        ; Yes, go on
  1859.     inc    cx        ; No 
  1860.     or    cx,cx        ; Run out?
  1861.     jnz    serini7        ; No, try again
  1862.     mov    ah,prstr    ; Yes, tell user failure in initialization
  1863.     mov    dx,offset infmsg; Tell user init failed
  1864.     int    dos
  1865.     pop    ax        ; Restore stack
  1866.     pop    si
  1867.     stc            ; Failure
  1868.     ret
  1869. serini8:pop    ax        ; Get byte back
  1870.     mov    dx,mddat0    ; The data port
  1871.     out    dx,al        ; Send it out
  1872.     lodsb            ; Load next byte
  1873.     cmp    al,'$'        ; Finished?
  1874.     jnz    serini5        ; No, process next
  1875.     pop    si        ; Left in good order
  1876.     mov    bx,25        ; Wait 25/100 seconds
  1877.     call    wait01        ; Call wait routine
  1878.     call    prtchr        ; Purge modem
  1879.     jmp    serini3        ; Success
  1880.  
  1881. serini1:mov    ax,portval
  1882.     cmp    ax,offset port2
  1883.     je    seri2        ; setup for J1
  1884.     cmp    intin,2
  1885.     jne    seri0
  1886. serini0:clc            ; Success
  1887.     ret            ; J2 (com3, com4) already set up
  1888. seri0:    cmp    intin,1
  1889.     jne    seri1        ; J1 currently installed
  1890.     call    serrst        ; de-install current int
  1891. seri1:    mov    al,J2INT
  1892.     call    getivec
  1893.     mov    oldseg,cx
  1894.     mov    oldoff,dx
  1895.     mov    cx,cs
  1896.     mov    dx,offset serisr
  1897.     mov    al,J2INT
  1898.     call    setivec
  1899.     mov    portadr,J2_ADDR
  1900.     call    clrbuf
  1901.     call    porton
  1902.     mov    intin,2        ; show J2 installed
  1903.     jmp    serini3        ; Success
  1904. seri2:    cmp    intin,1
  1905.     jne    seri3
  1906.     clc            ; Success
  1907.     ret            ; J1 already set up
  1908. seri3:    cmp    intin,2
  1909.     jne    seri4        ; J2 currently installed
  1910.     call    serrst        ; de-install current int
  1911. seri4:    mov    al,J1INT
  1912.     call    getivec
  1913.     mov    oldseg,cx
  1914.     mov    oldoff,dx
  1915.     mov    cx,cs
  1916.     mov    dx,offset serisr
  1917.     mov    al,J1INT
  1918.     call    setivec
  1919.     mov    portadr,J1_ADDR
  1920.     call    clrbuf
  1921.     call    porton
  1922.     mov    intin,1        ; show J1 installed
  1923.  
  1924. serini3:push    bx
  1925.     mov    bx,portval        ; get port data structure
  1926.     mov    [bx].portrdy,1        ; say the comms port is ready
  1927.     mov    parmsk,0ffh        ; parity mask, assume parity is None
  1928.     cmp    [bx].parflg,parnon    ; is it None?
  1929.     je    serini3a        ; e = yes
  1930.     mov    parmsk,07fh        ; no, pass lower 7 bits as data
  1931. serini3a:xor    ax,ax
  1932.     cmp    [bx].floflg,0        ; flow control is off?
  1933.     je    serini3b        ; e = yes
  1934.     mov    ax,[bx].flowc        ; get flow control chars
  1935. serini3b:mov    flowoff,al        ; xoff or null
  1936.     mov    flowon,ah        ; xon or null
  1937.     mov    xofrcv,off        ; clear xoff received flag
  1938.     pop    bx
  1939.     mov    portin,1        ; say initialized
  1940.     clc                ; carry clear for success
  1941.     ret                ; We're done
  1942.  
  1943. pickspd:mov    bp,portval    ; Get speed for S-100 modem 'from' portval
  1944.     cmp    ds:[bp].baud,0    ; 150 baud?
  1945.     mov    bx,offset bd150
  1946.     jz    serini4
  1947.     cmp    ds:[bp].baud,1    ; 300 baud?
  1948.     mov    bx,offset bd300
  1949.     jz    serini4
  1950.     cmp    ds:[bp].baud,2    ; 600 baud?
  1951.     mov    bx,offset bd600
  1952.     jz    serini4
  1953.     mov    bx,offset bd1200; Default to 1200 baud
  1954. serini4:ret
  1955. SERINI    ENDP
  1956.  
  1957. ; Reset the serial port.  This is the opposite of serini.  Calling
  1958. ; this twice without intervening calls to serini should be harmless.
  1959. SERRST    PROC    NEAR
  1960.     cmp    portin,0    ; Reset already? 
  1961.     jg    serr0        ; g = no
  1962.     clc
  1963.     ret            ; e = yes, l=not used yet, just leave
  1964. serr0:    push    dx
  1965.     cmp    intin,0        ; is any isr installed
  1966.     je    serr2        ; no, all done
  1967.     push    cx
  1968.     push    ax
  1969.     mov    ax,J2INT    ; guess it's J2
  1970.     cmp    intin,2        ; yes,
  1971.     je    serr1        ;   reset it
  1972.     mov    ax,J1INT    ; no, must be J1
  1973. serr1:    mov    cx,oldseg    ; original isr
  1974.     mov    dx,oldoff    ;   address
  1975.     call    setivec        ; do it
  1976.     mov    intin,0        ; show nothing installed
  1977.     call    porton        ; Insure that DTR and RTS are high
  1978.     pop    ax
  1979.     pop    cx
  1980. serr2:    pop    dx
  1981.     mov    portin,0        ; reset flag
  1982.     push    bx
  1983.     mov    bx,portval        ; port data structure
  1984.     mov    [bx].portrdy,0        ; say port is not ready
  1985.     pop    bx
  1986.     clc
  1987.     ret
  1988. SERRST    ENDP
  1989.  
  1990. ; the serial port interrupt service routine
  1991. ;  this routine does int driven input and output
  1992. ;   once installed, it displaces the Z-100 serial isr
  1993. serisr: push    ax            ; Save regs
  1994.     push    bx
  1995.     push    cx
  1996.     push    dx
  1997.     push    ds            ; Save data seg
  1998.     mov    ax,seg data        ; Set our
  1999.     mov    ds,ax            ;  data seg
  2000.                     ;
  2001.     mov    dx,portadr        ; Get the port address
  2002.     mov    cx,dx            ;  and save a copy
  2003.     add    dx,PSTATUS
  2004.     in    al,dx                    ; Get port status
  2005.     mov    ah,al            ; Save it
  2006.     test    ah,RDA                   ; Check for data available
  2007.     jz    isr5            ; No, nothing to receive, go send
  2008.                     ;
  2009.     mov    dx,cx            ; Port address
  2010.     in    al,dx            ; Get the data
  2011.     cmp    flowoff,0        ; Are wo doing flow control?
  2012.     jz    isr2               ; No, skip
  2013.                     ;
  2014.      mov    ch,al            ; Make working copy of data
  2015.     and    ch,parmsk        ; Strip parity, if any
  2016.     cmp    ch,flowon         ; xon?
  2017.     jne    isr1            ; No, check xoff
  2018.     mov    xofrcv,false        ; Indicate xoff not received (xon)
  2019.                             ; Done with receiver
  2020.     jmp    short isr5        ;  there should be time for send
  2021. isr1:    cmp    ch,flowoff        ; xoff?
  2022.     mov    ch,0            ; We need this later in cx
  2023.     jnz    isr2            ; No, put regular char in buffer
  2024.       cmp    xofsnt,true         ; Did we send an outstanding xoff?
  2025.       jz     isr5                    ; Yes, ignore (possible echo), go send
  2026.     mov    xofrcv,true        ; Set flag to indicatae xoff received
  2027.                             ; Done with receiver
  2028.     jmp    short isr5        ;  there should still be time for send
  2029. isr2:    mov    bx,bufiend        ; Get where to put it
  2030.     cmp    count,BUFILEN        ; Buffer full?
  2031.     jne    isr3            ; No, jump
  2032.     dec    bx            ; Don't overwrite que
  2033.     mov    byte ptr buffin[bx],bell; Put Ctrl-G in the que as marker
  2034.     jmp    short isr5        ; We missed it anyway
  2035. isr3:    mov    byte ptr buffin[bx],al     ; Stick it in the que
  2036.     inc    bx            ; Bump que pointer
  2037.     inc    count            ; One more in que
  2038.     cmp    bx,BUFILEN        ; Pointing to end of que?
  2039.     jne    isr4             ; No, go on
  2040.     xor    bx,bx            ; Reset pointer
  2041. isr4:    mov    bufiend,bx        ; Store new pointer
  2042. ;    jmp    short isr12    ; Pick    ; We won't take time to send now
  2043.     jmp    short isr5    ;  one    ; There should still be time for send
  2044.                     ;
  2045. isr5:    test    ah,TSRE+THBE        ; Ready to send?
  2046.     jz    isr12             ; No, almost done
  2047.     mov    bx,bufobeg        ; Pointer to beginning of output buffer
  2048.     cmp    count,mntrgh        ; Past the high trigger point?
  2049.     jnae    isr6            ;  no, make it simple
  2050.     cmp    flowoff,0        ; Are we doing flow control?
  2051.     jz    isr6            ;  no, make it simple
  2052.     cmp    xofsnt,true         ; Did we send an xoff already?
  2053.     jz    isr6            ;  yes, make it simple
  2054.     mov    al,flowoff        ; xoff
  2055.     or    al,al            ; Null?
  2056.     jz    isr6            ; Don't send null
  2057.     call    dopar
  2058.     mov    dx,cx            ; Port address
  2059.     out    dx,al            ; Send the xoff out
  2060.     mov    xofsnt,true        ; Remember
  2061.     cmp    bx,bufoend        ; Buffer empty?
  2062.     jz    isr11             ; Yes, turn transmitter off
  2063.     jmp    short isr12               ; We have used transmitter already,
  2064.                     ;  so we need to go
  2065. isr6:    cmp    bx,bufoend        ; Buffer empty?
  2066.     jz    isr11             ; Yes, turn transmitter off
  2067.     mov    al,byte ptr buffout[bx] ; Get char to send
  2068.     cmp    flowoff,0        ; Are we doing flow control?
  2069.     jz    isr7            ; No, just go on
  2070.     mov    ah,al            ; Working copy
  2071.     and    ah,parmsk        ; Strip parity
  2072.     cmp    ah,flowoff        ; xoff?
  2073.     jz    isr7            ; Just send it
  2074.     cmp    ah,flowon         ; xon?
  2075.     jz    isr7            ; Just send it
  2076.     cmp     xofrcv,true        ; Being held?
  2077.     jz     isr12              ; Yes, don't send
  2078. isr7:    mov    dx,cx            ; Port address
  2079.     out    dx,al            ; Send it
  2080.     inc    bx            ; Point to next char to send
  2081.     cmp    bx,BUFOLEN        ; Pointing to end of que?
  2082.     jne    isr10
  2083.     xor    bx,bx             ; Reset pointer
  2084. isr10:    mov    bufobeg,bx        ; Save it
  2085.     jmp    short isr12        ; Almost done
  2086.                     ;
  2087. isr11:    mov    dx,cx            ; Port address
  2088.     add    dx,PCOMM
  2089.     in    al,dx            ; Get current mode
  2090.     and    al,TXOFF        ; Turn xmitter off
  2091.     out    dx,al            ; Do it.
  2092.                     ;
  2093. isr12:    mov    al,EOI            ; Tell interrupt controller
  2094.     out    Z8259,al        ;   that interrupt serviced
  2095.                     ;
  2096.     pop    ds            ; Restore regs
  2097.     pop    dx
  2098.     pop    cx
  2099.     pop    bx
  2100.     pop    ax
  2101.     iret
  2102.   
  2103. ;; Wait for the # of milliseconds in ax, for non-IBM compatibles.
  2104. pcwait    proc    near
  2105.     cmp    ax,0
  2106.     jz    pcwait2        ; no wait
  2107.     push    bx
  2108.     push    cx
  2109.     push    dx
  2110.     xor    dx,dx
  2111.     mov    cx,10        ; we can not make it finer than 10ms
  2112.     div    cx
  2113.     cmp    ax,0
  2114.     jnz    pcwait1
  2115.     inc    ax        ; make it 10ms for 1 to 9
  2116. pcwait1:mov    bx,ax        ; and 10ms for 10 to 19, 20ms for 20 to 29
  2117.     call    wait01        ; 10ms => 10 to 20ms by wait01
  2118.     pop    dx        ; 20ms => 20 to 30ms by wait01
  2119.     pop    cx
  2120.     pop    bx
  2121. pcwait2:ret
  2122. pcwait    endp
  2123.  
  2124. ; Wait for the # of hundredths seconds in bx. Range 1 to 0ffffh.
  2125. ; Accuracy within 10ms due to use of system clock.
  2126. ; This uses dos calls and is compatible with all msdos systems.
  2127. ; Preserves all registers.
  2128. wait01    proc    near
  2129.     push    ax
  2130.     push    cx
  2131.     push    dx
  2132.     push    di
  2133.     mov    ah,gettim    ; Get time function
  2134.     int    dos
  2135. wait011:mov    di,dx        ; Preset/reset di
  2136. wait012:int    dos
  2137.     cmp    dx,di        ; Changed?
  2138.     je    wait012        ; Yes, continue
  2139.     dec    bx        ; 1/100 second passed
  2140.     jnz    wait011        ; Did not time out, keep waiting
  2141.     pop    di        ; Timed out
  2142.     pop    dx
  2143.     pop    cx
  2144.     pop    ax
  2145.     ret
  2146. wait01    endp
  2147.  
  2148. ; Service SET NETBIOS-NAME name   command at Kermit prompt level
  2149. setnbios proc    near
  2150.     ret
  2151. setnbios endp
  2152. sesdisp    proc    near
  2153.     ret
  2154. sesdisp    endp
  2155. code    ends
  2156.     end
  2157.