home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / mskermit / msxapr.asm < prev    next >
Assembly Source File  |  2020-01-01  |  44KB  |  1,167 lines
  1.         name msxapr
  2. ; File MSXAPR.ASM          ** current version, needs work **
  3. ; Kermit system dependent module for ACT Apricot
  4. ; 
  5. ; Last edit: 25 April 1988 [rwtc]
  6. ; Version 2.30
  7. ; This version runs ok on the FP portable and hopefully on the xi/pc
  8. ; I have removed all the microscreen stuff to reduce the size of the filew
  9. ; for editing convenience, it could be replaced if anyone feels the need
  10. ; of it. Other mods that were necessary were to the SENDBR command this
  11. ; now seems to work ok, also the log session command had got scrambled
  12. ; somewhere along the line this now works. 
  13. ; MSUAPR.ASM this works as a basic keyboard translator only, 
  14. ; work is still needed to provide comlete terminal emulation facilities.
  15. ;
  16. ; [rwtc] = Dick Carlton Department of Earth Sciences, The Open University
  17. ; Walton Hall, Milton Keynes MK7 6AA
  18. ;
  19. ; 27 May 1987 Add keyboard translator and input translation table rxtable,
  20. ; remove references to register bp, minor cleanups here and there. [jrd]
  21. ; ASSUMPTION: This module can use something like the Generic keyboard
  22. ;  translator MSUGEN.asm. Work needed to make MSUAPR.asm!
  23. ;
  24. ; 28 Sept 1986 Revise procedure Term to permit capturing, printer ready
  25. ;  testing, debug display. Revised other port procedures too. [jrd]
  26. ; 4 Sept 1986 Add Bob Goeke's change to move comms port table to a system
  27. ;  dependent module (typ msx---) to allow 3+ ports and localized idents. [jrd]
  28.  
  29. ; Added global entry point vtstat for use by Status in mssset.
  30. ; Added register save/restore in getbaud procedure.
  31. ; Also trimmed off trailing commas in publics. Joe R. Doupnik 12 March 1986
  32. ; Add global procedures ihosts and ihostr to handle host initialization
  33. ; when packets are to be sent or received by us,resp. 24 March 1986
  34. ; Add global procedure dtrlow (without worker serhng) to force DTR and RTS low
  35. ; in support of Kermit command Hangup. Says Not Yet Implemented. [jrd]
  36. ; Add global procedure Dumpscr, called by Ter in file msster, to dump screen
  37. ;  to a file. Just does a beep for now. 13 April 1986 [jrd]
  38. ; Move Hangup message out from middle of Show Key area (my goof).
  39. ;  23 April 1986 [jrd]
  40.         public  serini, serrst, clrbuf, outchr, coms, vts, vtstat, dodel
  41.         public  ctlu, cmblnk, locate, lclini, prtchr, dobaud, clearl
  42.         public  dodisk, getbaud, beep, trnprs, pcwait, termtb ;[rwtc]
  43.         public  count, xofsnt, puthlp, putmod, clrmod, poscur, shomodem
  44.         public  sendbr, sendbl, term, machnam, setktab, setkhlp, showkey
  45.         public  ihosts, ihostr, dtrlow, serhng, dumpscr, comptab ; [jrd]
  46.         public  chrout, cstatus, cquit, cquery, chang          ; kbd action verbs
  47.         public  snull, kdos, klogof, klogon, modlin, cpyktab, lng_br
  48.  
  49.         include a:\mssdef.h
  50.  
  51. if1
  52.     %out [Beginning pass 1]
  53. else
  54.     %out [Beginning pass 2]
  55. endif
  56.  
  57. false   equ     0
  58. true    equ     1
  59. instat  equ     6
  60. print_out equ   05h                     ; dos function to print to printer
  61. prtscr  equ     80h                     ; print screen pressed
  62. rddev   equ     3FH
  63. open    equ     3DH
  64. control equ     0FCH                    ; System Control Device
  65.  
  66. ; external variables used:
  67. ; drives - # of disk drives on system
  68. ; flags - global flags as per flginfo structure defined in pcdefs
  69. ; trans - global transmission parameters, trinfo struct defined in pcdefs
  70. ; portval - pointer to current portinfo structure (currently either port1
  71. ;           or port2)
  72. ; port1, port2 - portinfo structures for the corresponding ports
  73.  
  74. ; global variables defined in this module:
  75. ; xofsnt, xofrcv - tell whether we saw or sent an xoff.
  76.  
  77. modfrm  struc                           ; Format of mode line
  78.         db      'Esc chr: '
  79. m_echr  db      2 dup (?)
  80.         db      ', Speed: '
  81. m_baud  db      4 dup (?)
  82.         db      ', Parity: '
  83. m_par   db      4 dup (?)
  84.         db      ', Echo: '
  85. m_echo  db      3 dup (?)
  86.         db      ', Log: '
  87. m_log   db      3 dup (?)
  88.         db      ', Type '
  89. m_hlp   db      2 dup (?)
  90.         db      '? for Help$'
  91. modfrm  ends
  92.  
  93. datas   segment public  'datas'
  94.         extrn   drives:byte,  flags:byte, trans:byte
  95.         extrn   portval:word, port1:byte, port2:byte
  96.         extrn   comand:byte, dmpname:byte                       ; [jrd]
  97.         extrn   kbdflg:byte, rxtable:byte
  98.  
  99.  
  100. ;
  101. machnam db      'ACT Apricot$'
  102. erms20  db      cr,lf,'?Warning: System has no disk drives$'
  103. erms40  db      cr,lf,'?Warning: Unrecognized baud rate$'
  104. erms41  db      cr,lf,'?Warning: Cannot open com port$'
  105. erms50  db      cr,lf,'Error reading from device$'
  106. badbd   db      cr,lf,'Unimplemented baud rate$'
  107. noimp   db      cr,lf,'Command not implemented.$'
  108. shkmsg  db      'Not implemented.'
  109. shkmln  equ     $-shkmsg
  110. setktab db      0
  111. setkhlp db      0
  112. hngmsg  db      cr,lf,' The phone should have hungup.',cr,lf,'$' ; [jrd]
  113. hnghlp  db      cr,lf,' The modem control lines DTR and RTS for the current'
  114.         db      ' port are forced low (off)'
  115.         db      cr,lf,' to hangup the phone. Normally, Kermit leaves them'
  116.         db      ' high (on) when it exits.'
  117.         db      cr,lf,'$'                                       ; [jrd]
  118. rdbuf   db      80 dup (?)      ; temp buf [jrd]
  119. crlf    db      cr,lf,'$'
  120. delstr  db      BS,BS,' ',BS,'$'        ; Delete string.
  121. clrlin  db      cr,escape,'K$'             ; Clear line.
  122. clreol  db      escape,'K$'                ; Clear line.
  123. clrscr  db      escape,'H',escape,'J$'        ; Home and clear screen.
  124. ; Set High/Low intensity and/or Inverse video/Normal video
  125. ; rwtc 26.06.87.
  126. invseq  db      escape,'p$'                ; Inverse video mode.
  127. nrmseq  db      escape,'q$'                ; Normal video mode.
  128. hinton  db      escape,'($'                ; High intensity mode.
  129. hintof  db      escape,')$'                ; Low intensity mode.
  130. on25    db      escape,'j',escape,';$'        ; Save cursor posn, move to line 25
  131. off25   db      escape,'k$'                ; Restore cursor to saved position
  132. offmscr db      escape,'/',0,escape,'s$'      ; Turn off lights, clear, clock on
  133. onmscr  db      escape,'U',escape,'W'         ; Direct output to microscreen
  134.         db      escape,'c',escape,'B'         ; Disable scrolling, cursor down
  135.         db      'Break Close  Status  '
  136.         db      'Push   Help   Log'
  137.         db      escape,'V'                 ; Revert to normal screen
  138.         db      escape,'/',3FH             ; Turn on all keypad lights
  139.         db      '$'
  140. xofsnt  db      0                       ; Say if we sent an XOFF.
  141. count   dw      0                       ; Number of chars in int buffer.
  142. portin  db      0                       ; Port initialization flag
  143.  
  144. inited  db      0                       ; Terminal handler init flag
  145. argadr  dw      ?               ; address of arg blk from msster.asm
  146. parmsk  db      ?               ; 8/7 bit parity mask, for reception
  147. flowoff db      ?               ; flow-off char, Xoff or null (if no flow)
  148. flowon  db      ?               ; flow-on char, Xon or null
  149. captrtn dw      ?               ; routine to call for captured output
  150. tmp     db      ?,'$'
  151. temp    dw      0
  152. temp1   dw      ?                       ; Temporary storage.
  153. temp2   dw      ?                       ; Temporary storage.
  154.  
  155. ; Added from msxibm.asm [rwtc] 22.03.88 this is here just to make the
  156. ; status display look nicer (at the moment) [rwtc]
  157.                                         ; begin Terminal emulator data set
  158.  
  159. termtb  db      tttypes                 ; entries for Status, not Set
  160.         mkeyw   'Heath-19',ttheath
  161.         mkeyw   'none',ttgenrc
  162.         mkeyw   'Tek4010',tttek
  163.         mkeyw   'VT102',ttvt100
  164.         mkeyw   'VT52',ttvt52
  165.  
  166. ; shomodem messages from msxibm.asm [rwtc] 18.03.88 (just for show at present)
  167.  
  168. mdstreg db    0
  169. msmsg1  db      cr,lf,' Modem is not ready: DSR is off$'
  170. msmsg2  db      cr,lf,' Modem is ready:     DSR is on$'
  171. msmsg3  db      cr,lf,' no Carrier Detect:  CD  is off$'
  172. msmsg4  db      cr,lf,' Carrier Detect:     CD  is on$'
  173. msmsg5  db      cr,lf,' no Clear To Send:   CTS is off$'
  174. msmsg6  db      cr,lf,' Clear To Send:      CTS is on$'
  175.  
  176.  
  177. ; This character string is used to program various keys to return
  178. ; the correct ASCII characters.
  179.  
  180. kbdesc  db      escape,'43',44,'['-100O    ; Program CTRL-[ key
  181.         db      escape,'43',45,']'-100O    ; Program CTRL-] key
  182.         db      '$'
  183.  
  184. ;  This table is indexed by the baud rate definitions given in msdefs.h.
  185. ;  Unsupported baud rates should contain FF.
  186. bddat   label   word
  187.         dw      0FFH                    ;    45.5  Unsupported
  188.         dw      1                       ;    50
  189.         dw      2                       ;    75
  190.         dw      3                       ;   110
  191.         dw      4                       ;   134.5
  192.         dw      5                       ;   150
  193.         dw      6                       ;   300
  194.         dw      7                       ;   600
  195.         dw      8                       ;  1200
  196.         dw      9                       ;  1800
  197.         dw      0FFH                    ;  2000    Unsupported
  198.         dw      10                      ;  2400
  199.         dw      12                      ;  4800    (Have to skip 3600)
  200.         dw      14                      ;  9600    (Have to skip 7200)
  201.         dw      15                      ; 19200
  202.         dw      0FFH                    ; 38400    Unsupported
  203.  
  204. comptab db      2                       ; communciations port options [jrd]
  205.         mkeyw   '1',1
  206.         mkeyw   'COM1',1                ; no choice here
  207.  
  208. ourarg  termarg <>
  209. modbuf  modfrm  <>                      ; Mode line buffer
  210.  
  211. ; Some static data for the mode line.
  212. unkbaud db      'Unk '
  213. baudn   db      '45.5'
  214.         db      '  50'
  215.         db      '  75'
  216.         db      ' 110'
  217.         db      ' 135'
  218.         db      ' 150'
  219.         db      ' 300'
  220.         db      ' 600'
  221.         db      '1200'
  222.         db      '1800'
  223.         db      '2000'
  224.         db      '2400'
  225.         db      '4800'
  226.         db      '9600'
  227.         db      ' 19K'
  228.         db      ' 38K'
  229.  
  230. parnams db      'Even'
  231.         db      'Mark'
  232.         db      'None'
  233.         db      'Odd '
  234.         db      'Spc '
  235. offmsg  db      'Off'
  236. onmsg   db      'On '
  237. lclmsg  db      'Lcl'
  238. remmsg  db      'Rem'
  239. keyoff  dw      0
  240. keyseg  dw      0
  241.  
  242. datas   ends
  243.  
  244. code    segment public 'code'
  245.         extrn   comnd:near, dopar:near, prserr:near, atoi:near, prompt:near
  246.         extrn   sleep:near, msuinit:near, keybd:near            ; [jrd]
  247.         assume  cs:code,ds:datas
  248.  
  249. ; Produce a short beep.  The PC DOS bell is long enough to cause a loss
  250. ; of data at the port.  Returns normally.
  251.  
  252. BEEP    PROC    NEAR
  253.         mov     dl,bell
  254.         mov     ah,dconio
  255.         int     dos
  256.         ret
  257. BEEP    ENDP
  258.  
  259. ; Clear to the end of the current line.  Returns normally.
  260.  
  261. CLEARL  PROC    NEAR
  262.         mov     dx,offset clreol
  263.         jmp     tmsg                    ; Send terminal message
  264. CLEARL  ENDP
  265.  
  266. ; Clear the input buffer. This throws away all the characters in the
  267. ; serial interrupt buffer.  This is particularly important when
  268. ; talking to servers, since NAKs can accumulate in the buffer.
  269. ; Returns normally.
  270.  
  271. CLRBUF  PROC    NEAR
  272.         push    bx                      ; save regs. [jrd]
  273.         push    cx
  274.         mov     bx,34H                  ; Serial Device Driver
  275.         mov     cx,2                    ; Read serial port
  276. clrbf1: int     control                 ; Call System Control Device
  277.         cmp     ax,-1                   ; Read anything ?
  278.         jne     clrbf1                  ; Yes, try again
  279.         pop     cx                      ; [jrd]
  280.         pop     bx
  281.         ret
  282. CLRBUF  ENDP
  283.  
  284. ; clear the mode line written by putmod.  Returns normally.
  285.  
  286. CLRMOD  PROC    NEAR
  287.         mov     dx,offset on25          ; Move to line 25
  288.         call    tmsg
  289.         call    clearl                  ; Clear to end of line.
  290.         mov     dx,offset off25         ; Restore cursor position
  291.         call    tmsg
  292.         ret
  293. CLRMOD  ENDP
  294.  
  295. ; This routine blanks the screen.  Returns normally.
  296.  
  297. CMBLNK  PROC    NEAR
  298.         mov     dx,offset clrscr
  299.         jmp     tmsg                    ; Send terminal message.
  300. CMBLNK  ENDP
  301.  
  302. ; Set the current port.
  303.  
  304. COMS    PROC    NEAR
  305.         jmp     notimp
  306. COMS    ENDP
  307.  
  308. ; Make a copy of the keyboard table so that we can redefine some keys
  309. ; when we go into CONNECT state.
  310.  
  311.  
  312. CPYKTAB PROC    NEAR
  313.         push    ds
  314.         mov     ax,0
  315.         mov     es,ax                   ; ES -> lowest page in memory
  316.         mov     ax,es:[0712H]
  317.         mov     keyoff,ax               ; Save offset to keytable
  318.         mov     si,ax                   ; For the copy
  319.         mov     ax,es:[0714H]
  320.         mov     keyseg,ax               ; Save segment of keytable
  321. ;
  322.         mov     ds,ax                   ; DS:SI -> system keyboard table
  323.     call    keybd
  324.         mov     es,ax
  325.         mov     di,0                    ; ES:DI -> our keyboard table
  326. ;
  327.         mov     cx,0400H                ; Length of table
  328.         cld
  329.         rep     movsb                   ; Copy table
  330. ;
  331.     call    keybd
  332.     jmp    notimp
  333.         mov     ds,ax                   ; Point to our keyboard segment
  334. ;
  335.         mov     cx,12
  336.         cld
  337.         rep     movsb                   ; copy pointers
  338.         pop     ds                      ; restore DS
  339.         ret
  340. CPYKTAB ENDP
  341.  
  342.  
  343. ; Move the cursor to the left margin, then clear to end of line.
  344. ; Returns normally.
  345.  
  346. CTLU    PROC    NEAR
  347.         mov     dx,offset clrlin
  348.         jmp     tmsg
  349. CTLU    ENDP
  350.  
  351. ; Set the baud rate for the current port, based on the value
  352. ; in the portinfo structure.  Returns normally.
  353.  
  354. DOBAUD  PROC    NEAR
  355.         push    ax                      ; save regs. [jrd]
  356.         push    bx
  357.         push    cx
  358.         mov     bx,portval
  359.         mov     temp1,ax                ; Save new rate, don't zap old rate yet
  360.         mov     ax,[bx].baud            ; Check if new rate is valid.
  361.         mov     tmp,2
  362.         mul     tmp                     ; Get index into baud table.
  363.         mov     bx,offset bddat         ; Start of table.
  364.         add     bx,ax
  365.         mov     ax,[bx]                 ; The data to output to the port
  366.         cmp     ax,0FFH                 ; Unimplemented baud rate.
  367.         jne     dobd0
  368.         mov     ax,temp1                ; Get back original value.
  369.         mov     bx,portval
  370.         mov     [bx].baud,ax            ; Leave rate as is.
  371.         mov     dx,offset badbd         ; Give an error message.
  372.         call    tmsg
  373.         pop     cx
  374.         pop     bx
  375.         pop     ax
  376.         ret
  377. ;
  378. dobd0:  mov     dx,ax
  379.         mov     bx,34H                  ; Serial Device Driver
  380.         mov     cx,4                    ; Set transmit baud rate
  381.         int     control
  382.         mov     cx,5                    ; Set receive baud rate
  383.         int     control
  384.         mov     dx,1                    ; Turn on XON/XOFF just in case...
  385.         mov     cx,10                   ; Transmit XON/XOFF
  386.         int     control
  387.         mov     cx,11                   ; Receive XON/XOFF
  388.         int     control
  389.         mov     cx,3                    ; Install changes, zap line, etc...
  390.         int     control
  391.         mov     inited,0                ; Need to re-init on CONNECT
  392.         pop     cx
  393.         pop     bx
  394.         pop     ax
  395.         ret
  396. DOBAUD  ENDP
  397.  
  398. ; Delete a character from the terminal.  This works by printing
  399. ; backspaces and spaces.  Returns normally.
  400.  
  401. DODEL   PROC    NEAR
  402.         mov     dx,offset delstr        ; Erase weird character.
  403.         jmp     tmsg
  404. DODEL   ENDP
  405.  
  406. ; This is called by Kermit initialization.  It checks the
  407. ; number of disks on the system, sets the drives variable
  408. ; appropriately.  Returns normally.
  409.  
  410. DODISK  PROC    NEAR
  411.         mov     ah,gcurdsk              ; Current disk value to AL.
  412.         int     dos
  413.         mov     dl,al                   ; Put current disk in DL.
  414.         mov     ah,seldsk               ; Select current disk.
  415.         int     dos                     ; Get number of drives in AL.
  416.         mov     drives,al
  417.         ret
  418. DODISK  ENDP
  419.  
  420. ; Get the current baud rate from the serial card and set it
  421. ; in the portinfo structure for the current port.  Returns normally.
  422. ; This is used during initialization.
  423.  
  424. GETBAUD PROC    NEAR
  425.         push    ax                      ; save some regs [jrd]
  426.         push    bx
  427.         push    cx                      ; [jrd]
  428.         push    dx                      ; [jrd]
  429.         mov     bx,34H                  ; Serial Device Driver
  430.         mov     cx,4                    ; Transmit baud rate
  431.         mov     dx,-1                   ; Fetch data
  432.         int     control                 ; Go speak to Control Device Driver
  433.         mov     bx,offset bddat         ; -> baud rate table
  434.         mov     cl,0                    ; Keep track of index
  435. getb0:  cmp     ax,[bx]
  436.         je      getb1
  437.         inc     cl
  438.         cmp     cl,baudsiz              ; At the end of the list
  439.         jge     getb2
  440.         add     bx,2
  441.         jmp     getb0
  442. getb1:  mov     ch,0
  443.         mov     bx,portval
  444.         mov     [bx].baud,cx            ; Save rate index in port structure
  445.         jmp     getb3                   ; [jrd]
  446. getb2:  mov     dx,offset erms40
  447.         call    tmsg
  448. getb3:  pop     dx                      ; restore regs [jrd]
  449.         pop     cx                      ; [jrd]
  450.         pop     bx                      ; [jrd]
  451.         pop     ax                      ; [jrd]
  452.         ret
  453. GETBAUD ENDP
  454.  
  455. ; Initialize local variables and communications port.
  456.  
  457. LCLINI  PROC    NEAR
  458.         mov     flags.vtflg,0           ; Don't do terminal emulation.
  459.         mov     bx,34H                  ; Control Device Driver
  460.         mov     cx,0                    ; Initialise driver
  461.         mov     dx,0
  462.         int     control
  463.         mov     cx,6                    ; Set transmit bits per character
  464.         mov     dx,8                    ; to 8-bit bytes
  465.         int     control
  466.         mov     cx,8                    ; Set receive bits per character
  467.         mov     dx,7                    ; to 8-bit bytes
  468.         int     control
  469.         mov     cx,8                    ; Set number of stop bits
  470.         mov     dx,1                    ; to 1 stop bit
  471.         int     control
  472.         mov     cx,9                    ; Set parity type
  473.         mov     dx,0                    ; Parity handled by DOPAR.
  474.         int     control
  475.         mov     cx,10                   ; Transmit XON/XOFF
  476.         mov     dx,1                    ; Enabled
  477.         int     control
  478.         mov     cx,11                   ; Receive XON/XOFF
  479.         mov     dx,1                    ; Enabled
  480.         int     control
  481.         mov     cx,3                    ; Install changes
  482.         int     control
  483.         mov     dx,offset kbdesc
  484.         call    tmsg                    ; Re-program keyboard
  485.         call    msuinit                 ; init keyboard translator
  486.         ret
  487. LCLINI  ENDP
  488.  
  489. ; Homes the cursor.  Returns normally.
  490.  
  491. LOCATE  PROC    NEAR
  492.         mov     dx,0000H                ; Go to top left corner of screen.
  493.         jmp     poscur
  494. LOCATE  ENDP
  495.  
  496. ; Display mode line.
  497.  
  498. MODLIN  PROC    NEAR
  499.         mov     al,ourarg.escc
  500.         mov     modbuf.m_echr,' '
  501.         mov     modbuf.m_hlp,' '
  502.         cmp     al,32                   ; ESC char printable ?
  503.         jnb     modl1                   ; Yes, keep going
  504.         add     al,40H                  ; Convert to printable
  505.         mov     modbuf.m_echr,'~'       ; Note control char
  506.         mov     modbuf.m_hlp,'~'
  507. modl1:  mov     modbuf.m_echr+1,al      ; Fill in character
  508.         mov     modbuf.m_hlp+1,al
  509. ;
  510.         mov     al,ourarg.baudb         ; Get baud rate
  511.         mov     si,offset unkbaud       ; Just in case it falls out of range
  512.         cmp     al,baudsiz              ; Too big ?
  513.         jnb     modl2                   ; Yes, use default
  514.         mov     cl,2                    ; Each entry is 4 bytes
  515.         shl     al,cl
  516.         mov     ah,0
  517.         add     ax,offset baudn         ; ax -> baud rate string
  518.         mov     si,ax
  519. modl2:  mov     cx,size m_baud          ; length of baud space
  520.         mov     di,offset modbuf.m_baud
  521.         push    es                      ; save es
  522.         push    ds
  523.         pop     es                      ; set es to datas segment
  524.         cld
  525.         rep     movsb                   ; Copy over baud rate
  526. ;
  527.         mov     al,ourarg.parity        ; Get parity code
  528.         mov     cl,2                    ; Each entry is 4 bytes long
  529.         shl     al,cl
  530.         mov     ah,0
  531.         add     ax,offset parnams       ; ax -> parity setting
  532.         mov     si,ax
  533.         mov     cx,4
  534.         mov     di,offset modbuf.m_par
  535.         rep     movsb                   ; Copy over parity setting string
  536. ;
  537.         mov     si,offset remmsg        ; Assume remote echoing
  538.         test    ourarg.flgs,lclecho
  539.         jz      modl3
  540.         mov     si,offset lclmsg        ; Doing local echo
  541. modl3:  mov     cx,3
  542.         mov     di,offset modbuf.m_echo
  543.         rep     movsb
  544. ;
  545.         mov     si,offset offmsg        ; Assume not logging
  546.         test    ourarg.flgs,capt
  547.         jz      modl4
  548.         mov     si,offset onmsg         ; Logging input
  549. modl4:  mov     cx,3
  550.         mov     di,offset modbuf.m_log
  551.         rep     movsb
  552.         pop     es                      ; restore es
  553. ;
  554.         mov     dx,offset modbuf
  555.         call    putmod                  ; Print mode line
  556.         ret
  557. MODLIN  ENDP
  558.  
  559. ; Clear microscreen, redisplay time and revert to system keyboard table.
  560.  
  561. NOTIMP: mov     dx,offset noimp
  562.         call    tmsg
  563.         jmp     prserr
  564.  
  565. ; Put the number in ax into the buffer pointed to by di.  di is updated.
  566.  
  567. NOUT    PROC    NEAR
  568.         mov     dx,0
  569.         mov     bx,10
  570.         div     bx
  571.         push    dx
  572.         or      ax,ax
  573.         jz      nout1
  574.         call    nout
  575. nout1:  pop     ax
  576.         add     al,'0'
  577.         stosb
  578.         ret
  579. NOUT    ENDP
  580.  
  581. ; Put the char in AH to the serial port.  This assumes the
  582. ; port has been initialized.  XON/XOFF are handled by the port
  583. ; driver.  Skip returns on success, returns normally if the
  584. ; character cannot be written.
  585.  
  586. OUTCHR  PROC    NEAR
  587.         push    bx
  588.         push    cx
  589.         push    dx                      ; Save register.
  590.         sub     cx,cx
  591.         mov     al,ah                   ; Parity routine works on AL.
  592.         call    dopar                   ; Set parity appropriately.
  593.         mov     dl,al
  594.         mov     dh,0
  595.         mov     cx,1                    ; Transmit char
  596.         mov     bx,34H                  ; Serial Device Driver
  597.         int     control                 ; System Control Device
  598.         pop     dx
  599.         pop     cx
  600.         pop     bx
  601.         jmp     rskp
  602. OUTCHR  ENDP
  603.  
  604. ;  Position the cursor according to contents of DX:
  605. ;  DH contains row, DL contains column.  Origin (top left) = 0, 0
  606. ;  Returns normally. Revised 28 Sept 1986 by [jrd]
  607.  
  608. POSCUR  PROC    NEAR
  609.         push    ax                      ; [jrd]
  610.         mov     ah,conout               ; display on console
  611.         push    dx                      ; Save row & column position
  612.         mov     dl,escape                  ; Start cursor positioning sequence
  613.         int     dos                     ; [jrd]
  614.         mov     dl,'Y'
  615.         int     dos                     ; [jrd]
  616.         pop     dx                      ; Retrieve row position
  617.         push    dx                      ; save again [jrd]
  618.         mov     dl,dh
  619.         add     dl,' '                  ; add ascii bias [jrd]
  620.         int     dos
  621.         pop     dx
  622.         push    dx
  623.         add     dl,' '
  624.         int     dos
  625.         pop     dx
  626.         pop     ax                      ; [jrd]
  627.         ret
  628. POSCUR  ENDP
  629.  
  630. ; Use for DOS 2.0 and above.  Check the port status.  If no data, skip
  631. ; return.  Else, read in a char and return.
  632. ; Revised 28 Sept 1986 by [jrd]
  633. PRTCHR  PROC    NEAR
  634.         push    bx
  635.         push    cx
  636.         push    si
  637.         mov     bx,34H
  638.         mov     cx,2
  639.         int     control                 ; Read serial port
  640.         pop     si
  641.         pop     cx
  642.         pop     bx
  643.         cmp     ax,-1                   ; Character there ?
  644.         jne     prtch1                  ; Yes, process it...
  645.         jmp     rskp                    ; No character, skip return.
  646. prtch1: ret
  647. PRTCHR  ENDP
  648.  
  649. ; IHOSTS - Initialize the host by sending XON, or equivalent, and enter the
  650. ; cycle of clear input buffer, wait 1 second, test if buffer empty then exit
  651. ; else repeat cycle. Requires that the port be initialized before hand.
  652. ; Ihosts is used by the local send-file routine just after initializing
  653. ; the serial port.
  654. ; 22 March 1986 [jrd]
  655.  
  656. IHOSTS  PROC    NEAR
  657.         push    ax              ; save the registers
  658.         push    bx
  659.         push    cx
  660.         push    dx
  661.         mov     bx,portval      ; port indicator
  662.         mov     ax,[bx].flowc   ; put Go-ahead flow control char in ah
  663.         or      ah,ah           ; don't send null if flow = none
  664.         jz      ihosts1         ; z = null
  665.         call    outchr          ; send it (release Host's output queue)
  666.          nop                    ; outchr can do skip return
  667.          nop
  668.          nop
  669. ihosts1:call    clrbuf          ; clear out interrupt buffer
  670.         mov     ax,1            ; sleep for 1 second
  671.         call    sleep           ; procedure sleep is in msscom.asm
  672.         call    prtchr          ; check for char at port
  673.          jmp    ihosts1         ; have a char in al, repeat wait/read cycle
  674.          nop                    ; prtchr does skip return on empty buffer
  675.         pop     dx              ; empty buffer. we are done here.
  676.         pop     cx
  677.         pop     bx
  678.         pop     ax
  679.         ret
  680. IHOSTS  ENDP
  681.  
  682. ; IHOSTR - initialize the remote host for our reception of a file by
  683. ; sending the flow-on character (XON typically) to release any held
  684. ; data. Called by receive-file code just after initializing the serial
  685. ; port.         22 March 1986 [jrd]
  686. IHOSTR  PROC    NEAR
  687.         push    ax              ; save regs
  688.         push    bx
  689.         push    cx
  690.         mov     bx,portval      ; port indicator
  691.         mov     ax,[bx].flowc   ; put Go-ahead flow control char in ah
  692.         or      ah,ah           ; don't send null if flow = none
  693.         jz      ihostr1         ; z = null
  694.         call    outchr          ; send it (release Host's output queue)
  695.          nop                    ; outchr can do skip return
  696.          nop
  697.          nop
  698. ihostr1:pop     cx
  699.         pop     bx
  700.         pop     ax
  701.         ret
  702. IHOSTR  ENDP
  703.  
  704. DTRLOW  PROC    NEAR            ; Global proc to Hangup the Phone by making
  705.                                 ; DTR and RTS low.
  706.         mov ah,cmtxt            ; allow text to be able to display help
  707.         mov bx,offset rdbuf     ; dummy buffer
  708.         mov dx,offset hnghlp    ; help message
  709.         call comnd              ; get a confirm
  710.          jmp r
  711. ; not yet imp.  call serhng             ; drop DTR and RTS
  712.         mov ah,prstr            ; give a nice message
  713. ; not yet imp.  mov dx,offset hngmsg
  714.         mov dx,offset noimp     ; for now
  715.         int dos
  716.         jmp rskp
  717. DTRLOW  ENDP
  718.  
  719. ; Hang up the Phone. Similar to SERRST except it just forces DTR and RTS low
  720. ; to terminate the connection. 29 March 1986 [jrd]
  721. ; Calling this twice without intervening calls to serini should be harmless.
  722. ; Returns normally.
  723. ; SERHNG is Not Yet Implemented.
  724. SERHNG  PROC    NEAR
  725.         ret
  726. SERHNG  ENDP
  727.  
  728. ; Wait for the # of milliseconds in ax, for non-IBM compatibles.
  729. ; Based on 4.77 Mhz 8088 processor speeds.
  730. ; Thanks to Bernie Eiben for this one.
  731. pcwait  proc    near
  732.         mov     cx,240          ; inner loop counter for 1 millisecond
  733. pcwai1: sub     cx,1            ; inner loop takes 20 clock cycles
  734.         jnz     pcwai1
  735.         dec     ax              ; outer loop counter
  736.         jnz     pcwait          ; wait another millisecond
  737.         ret
  738. pcwait  endp
  739.  
  740.  
  741. ; Put a help message on the screen.
  742. ; Pass the message in ax, terminated by a null.  Returns normally.
  743.  
  744. PUTHLP  PROC    NEAR
  745.         push    ax                      ; preserve this
  746.         mov     dx,offset crlf
  747.         call    tmsg
  748.         mov     dx,offset hinton        ; Turn on high intensity
  749.         call    tmsg
  750.         pop     si                      ; point to string again
  751.         cld
  752. puthl3: lodsb                           ; get a byte
  753.         cmp     al,0                    ; end of string?
  754.         je      puthl4                  ; yes, stop
  755.         mov     dl,al
  756.         mov     ah,dconio
  757.         int     dos                     ; else write to screen
  758.         jmp     puthl3                  ; and keep going
  759. puthl4: mov     dx,offset hintof        ; Back to normal
  760.         call    tmsg
  761.         mov     dx,offset crlf
  762.         call    tmsg
  763.         ret
  764. PUTHLP  ENDP
  765.  
  766. ; Write a line in high intensity on line 25.  The line is pointed to by
  767. ; ds:dx, terminated by a $.  Returns normally.
  768.  
  769. PUTMOD  PROC    NEAR
  770.         push    dx                      ; preserve message pointer.
  771.         mov     dx,offset on25          ; Move down to line 25
  772.         call    tmsg
  773.         mov     dx,offset invseq        ; Turn on high intensity
  774.         call    tmsg
  775.         pop     dx                      ; get message back
  776.         call    tmsg                    ; write it out
  777.         mov     dx,offset nrmseq        ; Normal (low) intensity again
  778.         call    tmsg
  779.         mov     dx,offset off25         ; Restore cursor position
  780.         call    tmsg
  781.         ret                             ; and return
  782. PUTMOD  ENDP
  783.  
  784. ; Jumping here is the same as a ret.
  785.  
  786. R       PROC    NEAR
  787.         ret
  788. R       ENDP
  789.  
  790. ; Jumping to this location is like retskp.  It assumes the instruction
  791. ;   after the call is a jmp addr.
  792.  
  793. RSKP    PROC    NEAR
  794.         pop     bp
  795.         add     bp,3
  796.         push    bp
  797.         ret
  798. RSKP    ENDP
  799.  
  800. ; Send a break out to the serial port.  Returns normally.
  801. ; Need to handle port directly since ACT's Control Device doesn't
  802. ; have a 'send break' facility.
  803. ; altered the SIO port address from 62HEX to 1AHEX this works for FP
  804. ; I'm not sure about the XI/PC [rwtc] 25.04.88
  805.  
  806. SENDBR  PROC    NEAR
  807.         push    ax
  808.         push    bx
  809.         mov     al,5
  810.         out     1ah,al                  ; Select SIO write register 5
  811.         mov     al,0FAH
  812.         out     1ah,al                  ; Start break
  813.         mov     al,2
  814. sendb0: mov     bx,-1
  815. sendb1: dec     bx                      ; Delay for a while...
  816.         jnz     sendb1
  817.         dec     al
  818.         jnz     sendb0
  819.         mov     al,5
  820.         out     1ah,al                  ; Select SIO write register 5
  821.         mov     al,0EAH
  822.         out     1ah,al                  ; Finished sending break
  823.         pop     bx
  824.         pop     ax
  825.         clc
  826.         ret
  827. SENDBR  ENDP
  828. SENDBL  PROC    NEAR                    ; Send a long break
  829.         call    sendbr                  ; simulate long
  830.         call    sendbr
  831.         call    sendbr
  832.         call    sendbr
  833.         clc
  834.         ret
  835. SENDBL  ENDP
  836.  
  837. ; Initialization for using serial port.  XON/XOFF has already been set by
  838. ; the local initialization routine.  Returns normally.
  839. ; Revised 28 Sept 1986 by [jrd]
  840. SERINI  PROC    NEAR
  841.         cmp     portin,0                ; Initialized already ?
  842.         jne     serin0                  ; Yes, forget it.
  843.         cld                             ; Do increments in string operations
  844. ; Some day we may have an interrupt handler to install...
  845.         call    clrbuf                  ; Clear input buffer.
  846.         push bx
  847.         mov bx,portval          ; get port [jrd]
  848.         mov parmsk,0ffh         ; parity mask, assume parity is None. [jrd]
  849.         cmp [bx].parflg,parnon  ; is it None?
  850.         je serin1               ; e = yes
  851.         mov parmsk,07fh         ; no, pass lower 7 bits as data
  852. serin1: mov bx,[bx].flowc       ; get flow control chars
  853.         mov flowoff,bl          ; xoff or null
  854.         mov flowon,bh           ; xon or null
  855.         pop bx
  856.         mov     portin,1                ; Say we've been through once
  857. serin0: ret                             ; We're done.
  858. SERINI  ENDP
  859.  
  860. ; Reset the serial port.  This is the opposite of serini.  Calling
  861. ; this twice without intervening calls to serini should be harmless.
  862. ; Returns normally.
  863.  
  864. SERRST  PROC    NEAR
  865.         cmp     portin,0                ; Reset already ?
  866.         je      srst1                   ; Yes, forget it
  867. ; One day soon we may want to restore the interrupt handler, I hope...
  868.         mov     portin,0
  869. srst1:  ret                             ; All done.
  870. SERRST  ENDP
  871.  
  872. SHOWKEY PROC    NEAR
  873.         mov     ax,offset shkmsg
  874.         mov     cx,shkmln
  875.         ret
  876. SHOWKEY ENDP
  877.  
  878.  
  879. ; Dumb terminal emulator.
  880. ; Revised 28 Sept 1986 by [jrd]
  881. TERM    PROC    NEAR
  882.         mov     si,ax                   ; this is source
  883.         mov     di,offset ourarg        ; place to store arguments
  884.         push    es                      ; save es
  885.         push    ds
  886.         pop     es                      ; address destination segment
  887.         mov     cx,size termarg
  888.         cld
  889.         rep     movsb                   ; copy into our arg blk
  890.         pop     es                      ; recover es
  891.         and ourarg.flgs,not (prtscr)    ; no screen printing at startup [jrd]
  892.         mov ax,ourarg.captr
  893.         mov captrtn,ax                  ; buffer capture routine
  894.         mov parmsk,0ffh                 ; parity mask, assume parity = None
  895.         cmp ourarg.parity,parnon        ; is parity None?
  896.         je term0a                       ; e = yes, keep all 8 bits
  897.         mov parmsk,07fh                 ; else keep lower 7 bits
  898. term0a: test flags.remflg,d8bit         ; keep 8 bits for displays?
  899.         jnz term0b                      ; nz = yes, 8 bits if possible
  900.         mov parmsk,07fh                 ; else keep lower 7 bits
  901. term0b:
  902.         call    clrmod                  ; Clear mode line
  903.         test    ourarg.flgs,modoff      ; Is mode line disabled ?
  904.         jnz     term0                   ; Yes, skip this
  905.         call    modlin
  906. ;
  907. term0: 
  908.         cmp     inited,0                ; inited yet ?
  909.         jnz     term1                   ; yes, skip this bit...
  910.         mov     bx,34H
  911.         mov     dx,1
  912.         mov     cx,12                   ; Turn on RTS
  913.         int     control
  914.         mov     cx,13                   ; Turn on DTR
  915.         int     control
  916.         mov     inited,1                ; Remember we've inited
  917.  
  918. term1:  call portchr            ; get char from port, apply parity mask
  919.         jnc short term2         ; nc = no char, go on
  920.         call outtty             ; display and capture char
  921. term2:  call    keybd           ; read keyboard and send via translator
  922.         jnc     term1           ; nc = stay in Connect mode
  923.  
  924. term4:  call    clrmod
  925.         ret
  926. term    endp
  927.  
  928. ; put the character in al to the screen, do capture and printing,
  929. ; does translation for Set Input command.
  930. ; Adapted from msyibm.asm [jrd]
  931. outtty  proc    near
  932.         test    flags.remflg,d8bit      ; keep 8 bits for displays?
  933.         jnz     outnp9                  ; nz = yes, 8 bits if possible
  934.         and     al,7fh                  ; remove high bit
  935. outnp9: cmp     rxtable+256,0           ; translation turned off?
  936.         je      outnp7                  ; e = yes, no translation
  937.         push    bx
  938.         mov     bx,offset rxtable       ; address of translate table [jrd]
  939.         xlatb                           ; new char is in al
  940.         pop     bx
  941. outnp7: test    ourarg.flgs,prtscr      ; should we be printing?
  942.         jz      outnop                  ; no, keep going
  943.         push    ax
  944.         mov     ah,lstout               ; write to system printer device
  945.         mov     dl,al
  946.         int     dos
  947.         pop     ax
  948.         jnc     outnop                  ; nc = successful print
  949.         push    ax
  950.         call    beep                    ; else make a noise and
  951.         call    trnprs                  ;  turn off printing
  952.         pop     ax
  953. outnop: test    ourarg.flgs,capt        ; capturing output?
  954.         jz      outnoc                  ; no, forget this part
  955.         push    ax                      ; save char
  956.         call    captrtn                 ; give it captured character
  957.         pop     ax                      ; restore character and keep going
  958. outnoc: test    ourarg.flgs,trnctl      ; debug? if so use Bios tty mode
  959.         jz      outnp4                  ; z = no
  960.         mov     ah,print_out            ; Bios tty screen write
  961.         cmp     al,7fh                  ; Ascii Del char or greater?
  962.         jb      outnp1                  ; b = no
  963.         je      outnp0                  ; e = Del char
  964.         push    ax                      ; save the char
  965.         mov     dl,7eh                  ; output a tilde for 8th bit
  966.         int     dos
  967.         pop     ax                      ; restore char
  968.         and     al,7fh                  ; strip high bit
  969. outnp0: cmp     al,7fh                  ; is char now a DEL?
  970.         jne     outnp1                  ; ne = no
  971.         and     al,3fH                  ; strip next highest bit (Del --> '?')
  972.         jmp     outnp2                  ; send, preceded by caret
  973. outnp1: cmp     al,' '                  ; control char?
  974.         jae     outnp3                  ; ae = no
  975.         add     al,'A'-1                ; make visible
  976. outnp2: push    ax                      ; save char
  977.         mov     dl,5eh                  ; caret
  978.         int     dos                     ; display it
  979.         pop     ax                      ; recover the non-printable char
  980. outnp3: mov     dl,al
  981.         int     dos
  982.         ret
  983. outnp4: cmp     al,bell                 ; bell (Control G)? [jrd]
  984.         jne     outnp5                  ; ne = no
  985.         jmp     beep                    ; use short beep, avoid char loss.
  986. outnp5: or      al,al                   ; catch nulls
  987.         jz      outnp6                  ; z = null, ignore it
  988.         cmp     al,del                  ; catch dels
  989.         je      outnp6                  ; e = del, ignore it
  990.         mov     dl,al                   ; write without intervention.
  991.         mov     ah,conout
  992.         int     dos                     ; else let dos display char
  993. outnp6: ret                             ; and return
  994. outtty  endp
  995.  
  996. ; send the character in al out to the serial port; handle echoing.
  997. ; Can send an 8 bit char while displaying only 7 bits locally.
  998. outprt  proc    near
  999.         test    ourarg.flgs,lclecho     ; echoing?
  1000.         jz      outpr1                  ; z = no, forget it
  1001.         push    ax                      ; save char
  1002.         call    outtty                  ; print it
  1003.         pop     ax                      ; restore
  1004. outpr1: mov     ah,al                   ; this is where outchr expects it
  1005.         call    outchr                  ; output to the port
  1006.          nop
  1007.          nop
  1008.          nop                            ; skip returns...
  1009.         ret
  1010. outprt  endp
  1011.  
  1012. ; Get a char from the serial port manager
  1013. ; returns with carry on if a character is available
  1014. portchr proc    near
  1015.         call    prtchr                  ; character at port?
  1016.          jmp    short portc1            ; yes, go handle
  1017.          nop                            ; skip return is stupid...
  1018. portc0: clc                             ; no carry -> no character
  1019.         ret                             ; and return...
  1020. portc1: and     al,parmsk               ; apply 8/7 bit parity mask [jrd]
  1021.         push    bx                      ; Translate incoming char [jrd]
  1022.         mov     bx,offset rxtable       ; address of translate table [jrd]
  1023.         xlat                            ; new char is in al
  1024.         pop     bx
  1025.         or      al,al                   ; catch nulls
  1026.         jz      portc0                  ; z = null, ignore it
  1027.         cmp     al,del                  ; catch dels
  1028.         je      portc0                  ; e = del, ignore it
  1029.         stc                             ; have a character
  1030.         ret                             ; and return
  1031. portchr endp
  1032.  
  1033.  
  1034. ;; keyboard translator action routines, system dependent, called from msugen.
  1035. ; These are invoked by a jump instruction. Return carry clear for normal
  1036. ; processing, return carry set for invoking Quit (kbdflg has transfer char).
  1037.  
  1038. chrout: call    outprt                  ; put char in al to serial port
  1039.         clc                             ; stay in Connect mode
  1040.         ret
  1041.  
  1042. trnprs: push    ax                      ; toggle Copy screen to printer
  1043.         test    ourarg.flgs,prtscr      ; are we currently printing?
  1044.         jnz     trnpr2                  ; nz = yes, its on and going off
  1045.         mov     ah,ioctl
  1046.         mov     al,7                    ; get output status of printer
  1047.         push    bx
  1048.         mov     bx,4                    ; file handle for system printer
  1049.         int     dos
  1050.         pop     bx
  1051.         jc      trnpr1                  ; c = printer not ready
  1052.         cmp     al,0ffh                 ; Ready status?
  1053.         je      trnpr2                  ; e = Ready
  1054. trnpr1: call    beep                    ; Not Ready, complain
  1055.         jmp     trnpr3                  ; and ignore request
  1056. trnpr2: xor     ourarg.flgs,prtscr      ; flip the flag
  1057. trnpr3: pop     ax
  1058.         clc
  1059.         ret
  1060.  
  1061.  
  1062. klogon  proc    near                    ; resume logging (if any)
  1063.         test    flags.capflg,logses     ; session logging enabled?
  1064.         jz      klogn                   ; z = no, forget it
  1065.         or      ourarg.flgs,capt        ; turn on capture flag
  1066. klogn:  clc
  1067.         ret
  1068. klogon  endp
  1069.  
  1070. klogof  proc    near                    ; suspend logging (if any)
  1071.         and     argadr.flgs,not capt    ; stop capturing
  1072. klogo:  clc
  1073.         ret
  1074. klogof  endp
  1075.  
  1076. snull:  mov     ah,0                    ; send a null
  1077.         call    outchr                  ; send without echo or logging
  1078.          nop
  1079.          nop
  1080.          nop
  1081.         clc
  1082.         ret
  1083.  
  1084. lng_br    proc    near
  1085.     call    sendbl
  1086. lng_br    endp
  1087.  
  1088. kdos:   mov     al,'P'                  ; Push to DOS
  1089.         jmp     short cmdcom
  1090. cstatus:mov     al,'S'                  ; these commands exit Connect mode
  1091.         jmp     short cmdcom
  1092. cquit:  mov     al,'C'
  1093.         jmp     short cmdcom
  1094. chang:    mov    al,'H'            ; Hangup drop DTR & RTS
  1095.         jmp     short cmdcom
  1096. cquery: mov     al,'?'
  1097.         jmp     short cmdcom
  1098. cmdcom: mov     kbdflg,al               ; pass char to msster.asm via kbdflg
  1099.         stc                             ; say exit Connect mode
  1100.         ret
  1101.                                         ;; end of action routines
  1102.  
  1103. ; Print a message to the screen.  Returns normally.
  1104.  
  1105. TMSG    PROC    NEAR
  1106.         push    ax
  1107.         push    bx
  1108.         push    cx
  1109.         push    dx              ; dx has offset of message.
  1110.         mov     ah,prstr
  1111.         int     dos
  1112.         pop     dx
  1113.         pop     cx
  1114.         pop     bx
  1115.         pop     ax
  1116.         ret
  1117. TMSG    ENDP
  1118.  
  1119. SHOMODEM PROC   NEAR
  1120.         mov     ah,cmcfm                ; get a confirm
  1121.         call    comnd
  1122.          jmp    r                       ; no confirm
  1123.          nop
  1124.         call    serini                  ; activate port to get status
  1125.         call    serrst                  ; turn off port again
  1126.         mov     ah,prstr
  1127.         mov     dx,offset msmsg1        ; modem ready msg
  1128.         test    mdstreg,20h             ; is DSR asserted?
  1129.         jz      shomd1                  ; z = no
  1130.         mov     dx,offset msmsg2        ; say not asserted
  1131. shomd1: int     dos
  1132.         mov     dx,offset msmsg3        ; CD asserted msg
  1133.         test    mdstreg,80h             ; CD asserted?
  1134.         jz      shomd2                  ; z = no
  1135.         mov     dx,offset msmsg4        ; say not asserted
  1136. shomd2: int     dos
  1137.         mov     dx,offset msmsg5        ; CTS asserted msg
  1138.         test    mdstreg,10h             ; CTS asserted?
  1139.         jz      shomd3                  ; z = no
  1140.         mov     dx,offset msmsg6        ; say not asserted
  1141. shomd3: int     dos
  1142.         jmp     rskp
  1143. SHOMODEM ENDP
  1144.  
  1145. ; Set heath emulation on/off.
  1146.  
  1147. VTS     PROC    NEAR
  1148.         jmp     notimp
  1149. VTS     ENDP
  1150.  
  1151. VTSTAT  PROC    NEAR                    ; For use by Status in mssset [jrd]
  1152.         ret                             ; no emulator status to report
  1153. VTSTAT  ENDP
  1154.  
  1155. ; Save the screen to a buffer and then append buffer to a disk file. [jrd]
  1156. ; Default filename is Kermit.scn; actual file can be a device too. Filename
  1157. ; is determined by mssset and is passed as pointer dmpname.
  1158.  
  1159. DUMPSCR PROC    NEAR    ; Dumps screen contents to a file. Just Beeps here
  1160.         call beep       ; [jrd]
  1161.         ret
  1162. DUMPSCR ENDP
  1163.  
  1164.  
  1165. CODE    ENDS
  1166.         END
  1167.