home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / mskermit / msmdatap.scr < prev    next >
Text File  |  2020-01-01  |  5KB  |  139 lines
  1. ; FILE DATAPORT.SCR (MSMDATAP.SCR)
  2. ; 
  3. ; An MS-DOS Kermit script program for dialing the AT&T / Paradyne Dataport
  4. ; 14400 and Express modems, internal or external, to be used with MS-DOS
  5. ; Kermit 3.12 or later.  The modem is set for V.32bis, compression, error
  6. ; correction, all types of fallback, RTS/CTS flow control, fixed interface
  7. ; speed of 57600.
  8. ; 
  9. ; Rename this file to DATAPORT.SCR if necessary.
  10. ;
  11. ; To use: SET MODEM DATAPORT (in MS-DOS Kermit 3.14 or later)
  12. ;  or:    DEFINE _MODEM DATAPORT (in MS-DOS Kermit 3.00 or later)
  13. ;  or:    SET MODEM=DATAPORT (at DOS prompt or in AUTOEXEC.BAT)
  14. ; and:    Make sure Kermit executes the standard MSKERMIT.INI file.
  15. ; and then ... DIAL number.
  16. ;
  17. ; Authors: Christine M. Gianone, Frank da Cruz; Columbia U, September 1993.
  18. ; Revised Oct 94 for v3.14.
  19. ; Adapted to Dataport Express, Apr 95, by removing several commands that were
  20. ; available only in the original Dataport, but which were redundant.  Thanks
  21. ; to Mike Walsh (Cal State) and Armand Zakarian (U of Wisconsin) for info.
  22. ;
  23. def errfail echo \%1, hangup, goto fail ; Macro to handle failures.
  24. if < VERSION 312 errfail {MS-DOS Kermit 3.12 or later required.}
  25.  
  26. define chkerr if fail stop 1 \%1
  27. define chkok input 3 OK, if fail stop 1 \%1
  28.  
  29. set input echo on        ; So we can watch what happens.
  30. set input timeout proceed       ; Allow IF SUCCESS, IF FAILURE.
  31. set input case ignore        ; Use caseless string comparisons
  32.  
  33. set parity none            ; Avoid parity foulups
  34. set flow none            ; Avoid flow control deadlocks
  35. hangup                ; Begin by dropping DTR
  36.  
  37. ; Speed.  Don't worry about modem, it autobauds up to 57600 bps.
  38. ; NOTE: This modem doesn't seem to have a command for locking the
  39. ; interface speed.  But it seems to do it anyway.
  40. ;
  41. set speed 57600
  42. wait 5 dsr            ; Time to recover from HANGUP...
  43.  
  44. echo Configuring AT&T DataPort modem on \v(line).
  45.  
  46. :INIT
  47. output ATQ0V1\13        ; Enable word result codes
  48. chkok {Can't get modem's attention}
  49. ; X6  = Verbose result codes, show modulation speed
  50. ; &C1 = CD follows RS232
  51. ; &D2 = DTR follows RS232
  52. ; &Q0 = Asynchronous data mode, use AT command set
  53. ; L0  = Low speaker volume
  54. output AAAT E1 X6 &C1 &D2 &Q0 L0\13
  55. chkok {Can't initialize modem}
  56. output AT \92Q3\13        ; RTS/CTS hardware flow control
  57. chkok {Can't enable RTS/CTS}    ; On modem
  58. wait 5 cts
  59. if fail errfail {Modem is not asserting CTS!}
  60. set flow rts/cts        ; And in Kermit too, but only now
  61. pause 2                ; This is needed for internal model
  62. output AT %B14400 S78=0\13      ; Modulation = V.32bis with fallback
  63. chkok {Can't enable modulation and fallback}
  64. output AT \92N7%C1\13        ; Compression and EC enabled
  65. chkok {Can't enable compression and EC}
  66. output AT \92K5\13        ; Make modem pass BREAK transparently
  67. chkok {Can't become transparent to BREAK}
  68.  
  69. if def \%1 if not equal "\%1" "=" goto BEGIN
  70. echo Modem initialization complete, no number to dial
  71. end 0
  72.  
  73. :BEGIN                ; Now DIAL.
  74. clear                ; Clear INPUT buffer.
  75. set count 5                     ; Dialing retry counter, 5 tries allowed.
  76. echo Dialing \%1 on \v(line) at \v(speed) bps, wait...
  77. echo
  78. pause 1
  79. goto dial                       ; 1st time, skip pause and Redialing message
  80.  
  81. :REDIAL
  82. set alarm 30
  83. pause 30            ; Wait 30 seconds before redialing.
  84. if not alarm errfail {Dialing canceled.}
  85. echo Redialing...               ; Message for redialing.
  86. pause 1
  87.  
  88. :DIAL
  89. output ATD\%1\13                ; Dial the number.
  90. set alarm 90            ; (For detecting keyboard interruptions.)
  91. if > VERSION 312 clear input    ; Clear echo from INPUT buffer.
  92. if < VERSION 313 clear
  93. input 30 \10                    ; Wait for the linefeeds...
  94.  
  95. :GETMSG
  96. input 60 \10            ; ...that surround the response message.
  97. if success goto gotmsg        ; Got a message.
  98. if alarm errfail {No response from modem.} ; No response in 90 seconds.
  99. hangup                ; User interrupted from keyboard,
  100. output \13            ; cancel dialing by sending carriage return,
  101. goto again            ; and go try again right away.
  102.  
  103. :GOTMSG
  104. reinput 1 CONNECT               ; Got a message, was it CONNECT?
  105. if success goto done            ; If so, we're done.
  106. reinput 1 BUSY            ; Line is busy.
  107. if success goto busy        ; Go wait a while and then dial again.
  108. reinput 1 ERROR            ; Command syntax error.
  109. if success errfail {Dialing command error}
  110. reinput 1 NO CARRIER        ; Phone didn't answer or no carrier.
  111. if success errfail {No answer or no carrier}
  112. reinput 1 NO ANSWER        ; No answer
  113. if success errfail {No answer - try again later}
  114. reinput 1 NO DIALTONE        ; No dialtone when phone taken off hook.
  115. if success errfail {No dialtone - Is your modem connected to the phone line\63}
  116. goto getmsg            ; None of the above, get another message.
  117.  
  118. :BUSY
  119. if < \v(count) 2 goto quit    ; Don't wait 30 seconds if tries are used up.
  120. Echo Line is busy, will dial again in 30 seconds.
  121. echo Press any key to cancel...
  122. output \13            ; CR cancels dialing
  123. hangup                          ; Hang up.
  124. :AGAIN
  125. if count goto redial            ; Then go redial.
  126. :QUIT
  127. errfail {It never answers!  I give up.} ; Too many tries.
  128.  
  129. :DONE                           ; Connected.
  130. echo \7                         ; Celebrate with a beep.
  131. define errfail            ; Erase local macro definitions...
  132. end 0                ; Finished, return success code.
  133.  
  134. :FAIL                ; Dialing failed, no beep.
  135. define errfail            ; Erase local macro definitions...
  136. end 1                ; Return failure code.
  137.  
  138. ; End of DATAPORT.SCR
  139.