home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / misc / germitdoc.txt < prev    next >
Text File  |  2020-01-01  |  30KB  |  654 lines
  1.                           Eine Einfuehrung in Kermit
  2.  
  3.                      Gisbert W. Selke (RECK@DBNUAMA1.BITNET)
  4.                  Wissenschaftliches Institut der Ortskrankenkassen
  5.                  Kortrijker Strasse 1, D-5300 Bonn 1, West Germany
  6.                                  Oktober 1987
  7.  
  8.  
  9. 1.   Allgemeines
  10.  
  11. Kermit ist ein eingetragenes Warenzeichen der Henson Associates, der Muppet-
  12. Erfinder, und ausserdem ein urheberrechtlich geschuetztes Protokoll der
  13. Columbia-Universitaet, New York, fuer sicheren Datentransfer zwischen
  14. Computern. Programme, die auf diesem Protokoll beruhem werden kostenlos
  15. abgegeben (bis auf eine Gebuehr, um die Kopierkosten zu decken); es gibt
  16. solche Programme mittlerweile fuer eine sehr grosse, staendig wachsende Zahl
  17. von Rechnern, so dass ein relativ problemloser Austausch von Daten zwischen
  18. verschiedensten Systemen moeglich ist.
  19.  
  20. Ein solcher Transfer benutzt eine serielle Datenleitung; z.B. koennen zwei PCs
  21. ueber Modems miteinander verbunden sein, oder ein Rechner - der sog. "lokale
  22. Rechner" - kann an die Terminal-Leitung eines anderen Rechners - des
  23. "entfernten Rechners" oder "Wirtsrechners" - angeschlossen sein. (Wir werden
  24. es im weiteren nur mit dem zweiten Fall zu tun haben.) In diesem Fall gaukelt
  25. der Kermit auf dem lokalen Rechner, z.B. einem PC, dem Wirtsrechner, z.B.
  26. einer Modcomp oder einer VAX, vor, er habe es mit einem ganz normalen
  27. Terminal zu tun.
  28.  
  29. Das Arbeiten mit Kermit beginnt also damit, lokal ein Kermit-Programm zu
  30. starten - wir benutzen im folgenden den MS-Kermit als Beispiel - und dann
  31. diesem den Befehl zu geben, die Verbindung zum Wirtsrechner herzustellen und
  32. sich im weiteren wie ein Terminal zu verhalten. Kermit wird dadurch fast
  33. voellig transparent - durch einen speziellen Tastendruck ist es aber jederzeit
  34. moeglich, zur PC-Seite zurueckzukehren und dem lokalen Kermit Befehle zu geben;
  35. man kann auch das Programm beenden und auf die Betriebssystem-Ebene zurueck-
  36. kehren. (Dann sollten allerdings keine Daten mehr vom Wirtsrechner an sein
  37. - vermeintliches - Terminal abgeschickt werden...)
  38.  
  39. Fuer die eigentliche Aufgabe des Kermit-Protokolls, den sicheren Datentransfer,
  40. ist es aber noetig, dass sich zwei Kermits miteinander unterhalten. Dazu stellt
  41. man die Verbindung zum Wirtsrechner her und startet den dortigen Kermit. Dann
  42. gibt man diesem Kermit - dem Wirtsrechner-Kermit also - den Befehl, eine Datei
  43. zu senden (bzw. zu empfangen), geht schnell zurueck auf die PC-Seite, und
  44. fordert den lokalen Kermit auf, eine Datei zu empfangen (bzw. zu senden).
  45.  
  46. Jetzt kann man sich bequem zuruecklehnen, denn alles weitere geht automatisch:
  47. Die beiden Kermits unterhalten sich miteinander, wobei sie sicherstellen, dass
  48. sie sich nicht gegenseitig missverstehen; im Laufe dieser Unterhaltung werden
  49. die gewuenschten Daten uebertragen. Der Fortschritt der Unterhaltung wird auf
  50. dem Bildschirm angezeigt.
  51.  
  52. Nach Beendigung verbindet man sich wieder mit dem Wirtsrechner und gibt
  53. dem dortigen Kermit neue Kommandos oder beendet das Programm auf ordentliche
  54. Weise. Danach kann im Terminalbetrieb weitergearbeitet werden.
  55.  
  56. Die Benutzeroberflaechen verschiedener Kermits sind sich mehr oder weniger
  57. aehnlich; jeder bietet zusaetzlich zu den noetigsten Kommandos noch einige
  58. weitere, z.B. zum Setzen von Uebertragungsparametern (Baud rate, parity, ...),
  59. oder eine Betriebssystem-Schnittstelle. Jeder Kermit sollte das Kommando "HELP"
  60. verstehen; darueber hinaus kann es weitere Hilfsmittel zur Benutzerfuehrung
  61. geben. Wie man vom Wirtsrechner zum PC zurueckkehrt, wird i.a. auch jederzeit
  62. angezeigt.
  63.  
  64. Wir werden in den Beispielen davon ausgehen, dass der Wirtsrechner eine Mod-
  65. comp ist und KERMIV (von Setpoint Inc.) als Kermit-Programm zur Verfuegung
  66. steht. - Wenngleich das gesamte Kermit-Protokoll auf der ASCII-Repraesentation
  67. von Zeichen beruht, ist es uebrigens auch moeglich, mit EBCDIC-Wirtsrechnern zu
  68. kommunizieren. Der Wirtsrechner-Kermit besorgt in diesem Fall die Konversion.
  69.  
  70. - Zusammengefasst heisst das also, dass Kermit zwei verschiedene Aufgaben
  71. beherrscht, die Terminal-Emulation und den Dateitransfer. Waehrend des Datei-
  72. transfers stellt das Kermit-Protokoll durch den Dialog zweier Kermit-Programme
  73. sicher, dass die Daten korrekt uebertragen werden. Der Emulationsbetrieb ist
  74. hingegen nicht durch das Protokoll abgedeckt; der Betrieb ist nicht sicherer
  75. als der eines normalen Terminals. Der einzige Vorteil ist, dass auf Knopfdruck
  76. wahlweise andere Dienste des lokalen Rechners zur Verfuegung stehen.
  77.  
  78. 2.   Der Ablauf einer Kermit-Sitzung (PC-Wirtsrechner-Verbindung)
  79.  
  80. (Fuer Kermit-Befehle koennen Gross- und Kleinschreibung beliebig gemischt wer-
  81. den; Befehle koennen abgekuerzt werden, sofern sie eindeutig bleiben. Im fol-
  82. genden ist die Minimalform der Befehle durch grosse Buchstaben gekennzeichnet.
  83. Woerter in spitzen Klammern < ... > beschreiben, was der Benutzer hier eingeben
  84. soll. Ein Semikolon markiert den Anfang eines Kommentars.)
  85.  
  86. 2.1  Terminalbetrieb
  87.  
  88. 1.   <Starte den PC.>
  89. 2.   <Waehle das Directory an, das KERMIT.EXE enthaelt.>
  90. 3.   KERMIT
  91. 4.   Connect
  92. 5.   Shift-Alt-F1       ; guten Morgen, Modcomp
  93.      .
  94.      .
  95.      .
  96.  
  97. 1000. Shift-Alt-F2      ; tschues, Modcomp
  98. 1001. Alt-C             ; Zurueck zum PC
  99. 1002. Quit
  100. 1003. <Schalte den PC aus.>
  101.  
  102. Die Schritte 5 bzw. 1000 sehen bei anderen Wirtsrechnern natuerlich anders
  103. aus - sie muessen durch die jeweiligen Logon- bzw. Logoff-Schritte ersetzt
  104. werden.
  105.  
  106.  
  107. 2.2  Textdatei-Transfer
  108.  
  109. Bei vielen Wirtsrechnern wird der Ablauf einfacher sein als hier gezeigt; das
  110. liegt hauptsaechlich daran, dass auf der Modcomp keine allgemein verbindliche
  111. File-Manager-Schnittstelle vorliegt.
  112.  
  113.  1.  <Verbinde Dich mit der Modcomp wie in 2.1.1 ... 2.1.5.>
  114.  2.  <Attache alle USLs, aus denen bzw. in die Du Daten transferieren willst;
  115.      waehle als logical file name nicht USL!>
  116.  3.  KERMIT                            ; jetzt laeuft KERMIV
  117.  4.  SET Usl <logical file name>       ; USL zeigt dann auf eine Deiner USLs
  118.  5.a SENd <member name>   oder    5.b RECeive  ; vom Wirtsrechner aus gesehen
  119.  6.  Alt-C                             ; zurueck zum PC
  120.  7.a Receive              oder    7.b Send <dateiname> ; vom PC aus gesehen
  121.      .                                 ; warten!
  122.      .
  123.      .
  124.  8.  Connect                           ; zurueck zur Modcomp
  125.      <Wiederhole Schritte  4 ... 8 so oft wie noetig.>
  126.  9.  Quit                              ; Ende KERMIV
  127. 10.  <Beantworte ggf. alle Fragen, die KERMIV Dir stellt.>
  128. 11.  JOB
  129.      <Ab hier normaler Terminalbetrieb.>
  130.  
  131.  
  132. KERMIV arbeitet nur mit USL-Eintraegen; empfangene Dateien werden normalerweise
  133. unter einem Namen eintragen, der dem PC-Dateinamen aehnlich ist. Modcomp-
  134. Dateien werden auf dem PC normalerweise unter dem Originalnamen abgelegt (mit
  135. leerer Extension).
  136.  
  137.  
  138. 2.3  Transfer binaerer Dateien
  139.  
  140. Bei vielen Wirtsrechnern wird sich diese Art von Dateitransfer nicht vom
  141. Text-Transfer unterscheiden; bei richtigen Parametersetzungen (hauptsaechlich
  142. Paritaet) stellen die Kermits auch die Uebertragung von 8-Bit-Daten sicher. Ob
  143. Daten in der binaeren Darstellung des einen Rechners fuer den anderen Rechner
  144. ueberhaupt einen Sinn ergeben, ist i.a. natuerlich nicht klar. Die Modcomp-
  145. spezifische Art der Dateiverwaltung, die KERMIV benutzt, bereitet auch hier
  146. Probleme. Deswegen muessen solche Dateien vor- und nachbehandelt werden. Eine
  147. Moeglichkeit ist die einfache Hex-Codierung, die jedes Byte durch zwei Text-
  148. zeichen darstellt; in den Beispielen unten wird eine kompaktere Form benutzt
  149. - die BOO-Codierung -, die im wesentlichen je 3 Bytes durch 4 ASCII-Zeichen
  150. darstellt.
  151.  
  152. Fuer den Transfer vom PC zur Modcomp:
  153.  
  154.  1.  <Bereite den Dateitransfer vor wie in 2.2.1 ... 2.2.4.>
  155.  2.  Alt-P                             ; rufe den DOS-Kommando-Prozessor
  156.                                          des PC auf
  157.  3.  BIN2BOO <dateiname>               ; erzeugt ASCII-Datei gleichen Namens,
  158.                                          Extension .BOO
  159.  4.  EXIT                              ; zurueck in KERMIVs feuchte Arme
  160.  5.  <Transferiere die .BOO-Datei wie gehabt.>
  161.  6.  <Beende KERMIV ordentlich; aber ohne $JOB!>
  162.  7.  <Lege eine Datei an, die die binaeren Daten aufnehmen soll.>
  163.  8.  BOO2BIN <usl-member-name> <usl-lfn> <output-kanal>
  164.                                        ; erzeugt binaere Datei
  165.  9.  JOB
  166. 10.  <Loesche irgendwann die .BOO-Datei auf dem PC.>
  167.  
  168.  
  169. Fuer den Transfer von der Modcomp zum PC:
  170.  
  171.  1.  <Verbinde Dich mit der Modcomp wie in 2.1.1 ... 2.1.5.>
  172.  2.  <Attache die binaere Datei und eine USL zur Zwischenspeicherung.>
  173.  3.  BIN2BOO <input-kanal> <usl-member-name> <usl-lfn>  ; Asciifizieren
  174.  4.  <Transferiere den erzeugten USL-Eintrag wie in 2.2.3 ... 2.2.7.>
  175.  5.  PUsh                                    ; Wir sind noch am PC.
  176.  6.  RENAME <dateiname> <dateiname>.BOO      ; Extension .BOO muss sein!
  177.  7.  BOO2BIN <dateiname mit neuer Extension> ; ent-asciifiziert die Datei
  178.  8.  DEL <dateiname>.BOO                     ; Aufraeumen
  179.  9.  EXIT                                    ; zurueck zu MS-Kermit
  180. 10.  Connect                                 ; zurueck zu KERMIV
  181. 11.  <Weiter wie gehabt.>
  182.  
  183.  
  184. 3.   Die wichtigeren KERMIT-Befehle
  185.  
  186. 3.1  KERMIV
  187.  
  188. (Dies ist natuerlich ein Modcomp-spezifischer Abschnitt.)
  189.  
  190. SET Usl <logical file name>  : gibt an, wo zu sendende Dateien stehen
  191. SENd    <membername>         : sende den Eintrag aus der vorgewaehlten USL
  192. SENd    @<usl-lfn>           : sende alle Eintraege aus der angegebenen USL
  193. RECeive                      : empfange eine Datei oder ein Gruppe von Dateien
  194. Quit                         : Ende
  195. Help                         : liste die gueltigen Befehle
  196. STatus                       : zeige die gegenwaertigen Parameter an
  197.  
  198.  
  199. 3.2  MS-Kermit
  200.  
  201. Connect                      : verbinde mit dem entfernten Rechner
  202. Send <name>                  : sende diese Datei oder Gruppe von Dateien
  203. Receive                      : empfange eine Datei oder eine Gruppe von Dateien
  204. Quit                         : Ende
  205. Help                         : liste die gueltigen Befehle
  206. STatus                       : zeige die gegenwaertigen Parameter an
  207. SET Baud <baudrate>          : aendere die Baudrate
  208. SET PArity <paritaet>        : aendere die benutzte Paritaet
  209. SET DEFault-disk <disk>      : aendere die Default-Disk
  210. SET Key <tastencode> <text>  : definiere eine Taste um (fuer Emulationsmodus)
  211. DEFine <name> <kommando>     : definiere ein Macro
  212. DO <name>                    : fuehre ein Macro aus
  213. PUsh                         : rufe den DOS-Kommando-Prozessor auf
  214. TAke <name>                  : fuehre die in der angegebenen Datei stehenden
  215.                                Kermit-Kommandos aus
  216. ...                          : zusaetzlich einige DOS-Kommandos
  217.  
  218.  
  219. An jeder Stelle waehrend der Befehlseingabe kann man sich durch "?" anzeigen
  220. lassen, wie man die angefangene Eingabe fortsetzen kann; drueckt man stattdes-
  221. sen die "ESC"-Taste, wird der Befehl so weit vervollstaendigt, wie eindeutig
  222. moeglich ist. Noch nicht vollstaendig eingegebene Kommandos koennen i.a.
  223. durch Ctrl-C abgebrochen werden.
  224.  
  225. Waehrend der Verbindung mit dem Wirtsrechner koennen alle Tasten eine spezi-
  226. elle Bedeutung haben; auch koennen ankommende Zeichen in andere uebersetzt
  227. werden. Einige Uebersetzungen, die sich bei uns als sinnvoll erwiesen haben,
  228. sind im Anhang 1 verzeichnet; darueberhinaus kann fuer die richtige Handhabung
  229. deutscher Sonderzeichen gesorgt werden. Alle diese Belegungen werden durch das
  230. Einlesen der Datei MSKERMIT.INI erzeugt; ein Beispiel fuer deutsche Benutzer
  231. ist in Anhang 3 aufgelistet. - Dort sind auch zwei Macros  "DEUTSCH" bzw.
  232. "ENGLISCH" zum einfachen Umschalten zwischen deutscher Anzeige (mit Umlauten)
  233. und englischer Anzeige (mit eckigen Klammern usw.) enthalten sowie ein Macro
  234. "RUNDIA" zum Einloggen und Verbinden.
  235.  
  236. Weitere Sonderbedeutungen koennen in der Datei MSKERMIT.INI vorgegeben werden,
  237. die beim Start des Programms sofort eingelesen wird.
  238.  
  239. MS-Kermit kann komplette Ablauf-Szenarios, sogenannte Skripten oder TAKE-Files,
  240. verarbeiten; zum Beispiel lassen sich ganze Datei-Transfers automatisieren.
  241. Beispiele dafuer sind in Anhang 2 aufgefuehrt.
  242.  
  243.  
  244. 4.   Weiterfuehrende Literatur und Bezugsquellen
  245.  
  246. Zu jedem Kermit-Programm gibt es eine mehr oder weniger ausfuehrliche Bedie-
  247. nungsanleitung, die zusammen mit dem Programm selber verteilt werden sollte.
  248. Jeder Kermit-Benutzer darf (und sollte!) Programm und Dokumentation an alle
  249. Interessenten kostenlos weitergeben. Wer im Rechnerverbund zu den Computer-
  250. Netzen INTERNET oder BITNET Zugang hat, kann sich die aktuellen Programm-
  251. Versionen fuer alle verfuegbaren Systeme bei den Rechnern CU20B.COLUMBIA.EDU
  252. oder CUVMA.BITNET besorgen; INTERNET-Benutzer haben FTP-Zugang, BITNET-
  253. Benutzer koennen ein HELP-Kommando (interaktiv oder als Mail) an den Server
  254. KERMSRV schicken. Dort gibt es auch viele weitere Informationen ueber das
  255. Protokoll und seine Implementierungen sowie ein elektronisches Diskussions-
  256. forum fuer Probleme und Weiterentwicklungen des Systems.
  257.  
  258. Von Frank da Cruz, einem der Initiatoren des Kermit-Protokolls, gibt es
  259. ausserdem das Buch "KERMIT - A File Transfer Protocol" (erschienen bei
  260. Digital Press), das eine sehr gute und verstaendliche Darstellung der
  261. Probleme beim Datenaustausch zwischen Rechnern gibt und auch viele Hinweise
  262. fuer Programmierer enthaelt, die ein neues Kermit-Programm schreiben wollen
  263. oder muessen.
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  
  270.          Anhang 1: Ein Beispiel einer Tastenbelegung fuer MS-Kermit
  271.  
  272. Diese Tastenbelegungen gelten nur waehrend des Emulations-Betriebs, also auf
  273. der Wirtsrechner-Seite. Sie werden erzeugt durch das Einlesen der Datei
  274. MSKERMIT.INI, die in Anhang 3 aufgelistet ist.
  275.  
  276. 1.   Kermit-Kommandos
  277.      Ctrl-A             : <BREAK>
  278.      Alt-A              : <BREAK>
  279.      Alt-C              : zurueck zum PC
  280.      Alt-H              : Kommando-Hilfsmenue
  281.      Alt-P              : Aufruf des DOS-Kommando-Prozessors
  282.      Ctrl-PrtScr        : Statuszeile an/aus
  283.  
  284. 2.   Screen-Rollback
  285.      Ctrl-PgUp          : eine Seite zurueck
  286.      Ctrl-PgDn          : eine Seite nach unten
  287.      Shift-Ctrl-PgUp    : eine Zeile zurueck
  288.      Shift-Ctrl-PgDn    : eine Zeile nach unten
  289.      Ctrl-Home          : an den Anfang des Rollback-Puffers
  290.      Ctrl-End           : an das Ende des Rollback-Puffers
  291.  
  292. 3.   Zusaetzliche Belegungen fuer ECMA-Terminals (in VT102-Emulation)
  293.      Home               : HOME (ECMA: Pfeil nach links oben)
  294.      Cursor-Tasten      : wie ueblich
  295.      PgUp               : ECMA: PrevPage
  296.      PgDn               : ECMA: NextPage
  297.  
  298. 4.   Modcomp-Kurzbefehle
  299.      F1                 : JOB<CR>
  300.      F2                 : DISKINFO<CR>
  301.      F3                 : DUMP
  302.      F4                 : EXE SED<CR>
  303.      F5                 : HELP
  304.      F6                 : EXE LIST LM<CR>
  305.      F10                : ' (Apostroph bzw. accent aigu)
  306.      Shift-Alt-F1       : <BREAK>RUN DIA<CR>
  307.      Shift-Alt-F2       : <BREAK>STO DIA<CR>
  308.  
  309.  
  310.  
  311.  
  312.  
  313.  
  314.                            Anhang 2: Nuetzliche Dateien
  315.  
  316. Diese Szenarien sind natuerlich Wirtsrechner-spezifisch; weil aber die
  317. Modcomp, fuer die sie geschrieben sind, keine sehr freundliche Benutzer-
  318. Schnittstelle hat, sollte es nicht zu schwer sein, die Szenarien fuer
  319. andere, freundlichere Rechner abzuwandeln. - Der Inhalt der Dateien ist
  320. in Anhang 4 aufgelistet.
  321.  
  322.  
  323. 1.   RUNDIA.SCR:
  324.      Startet Terminal-Sitzung auf der Modcomp und verbindet.
  325.      Vom Kermit-Prompt aus aufrufen mit TAKE RUNDIA.SCR.
  326.  
  327. 2.   SEND.BAT:
  328.      Schickt eine ASCII-Datei vom PC zur Modcomp und lagert sie dort in eine
  329.      USL ein. Auf der Modcomp braucht vorher kein RUN DIA gegeben worden zu
  330.      sein.
  331.      (Benoetigt die Dateien PRESDRC.SCR, SEND1.SCR, SEND2.SCR.)
  332.      Vom DOS-Prompt aus aufrufen mit SEND <filename> <userid> <usl-name>.
  333.  
  334. 3.   RECV.BAT:
  335.      Schickt eine ASCII-Datei aus einer USL auf der Modcomp zum PC. Auf der
  336.      Modcomp braucht vorher kein RUN DIA gegeben worden zu sein.
  337.      (Benoetigt die Dateien PRESDRC.SCR, RECV1.SCR, RECV2.SCR.)
  338.      Vom DOS-Prompt aus aufrufen mit RECV <filename> <user-id> <usl-name>.
  339.  
  340. 4.   Fuer binaeren Datei-Transfer:
  341. a)   BIN2BOO.COM: formt binaere Datei um in eine ASCII-Datei. Die Ausgabe
  342.      erfolgt auf eine Datei gleichen Namens, aber mit Extension .BOO.
  343.      Vom DOS-Prompt aus aufrufen mit BIN2BOO <infile-name>.
  344. b)   BOO2BIN.COM: kehrt den Prozess von BIN2BOO um.
  345.      Die Eingabedatei muss den gleichen Namen, aber Extension .BOO haben.
  346.      Vom DOS-Prompt aus aufrufen mit BOO2BIN <outfile-name>.
  347.    Auf der Modcomp-Seite stehen entsprechend als Prozeduren in der AJC zur
  348.    Verfuegung:
  349. c)   BIN2BOO <user-id> <datei-fm-name> <usl-name> formt die binaere Datei
  350.      <user-id>_<datei-fm-name> in eine ASCII-Datei um und lagert sie unter dem
  351.      gleichen Namen in die USL <user-id>_<usl-name> ein.
  352. d)   BOO2BIN <user-id> <datei-fm-name> <usl-name> kehrt den Prozess von BIN2BOO
  353.      um. Die Eingabe wird gelesen vom Eintrag <datei-fm-name> in der USL
  354.      <user-id>_<usl-name>, die Ausgabe erfolgt auf die Datei
  355.      <user-id>_<datei-fm-name>, die vorher schon angelegt worden sein muss.
  356.  
  357.  
  358.  
  359.  
  360.  
  361.  
  362.                   Anhang 3: Ein Beispiel fuer MSKERMIT.INI
  363.  
  364. COMMENT --     MS-KERMIT-Initialisierungsfile fuer generellen Gebrauch
  365. COMMENT --     durch deutsche Benutzer unter besonderer Beruecksichtigung
  366. COMMENT --     der Modcomp-Erfordernisse
  367. COMMENT --     Gisbert W.Selke, WIdO, 19. November 1987
  368.  
  369. COMMENT    *** DIESE DATEI SOLLTE NICHT GEAENDERT WERDEN! ***
  370. COMMENT    (zwecks einfacherer Software-Wartung durch System-Menschen)
  371.  
  372. COMMENT --     Hier werden WIdO-Standard-Dinge definiert; am Ende wird
  373. COMMENT --     der TAKE-File MSLOCAL.INI aufgerufen, in dem jede
  374. COMMENT --     Benutzerin eigene Dinge vereinbaren kann.
  375.  
  376. COMMENT --     Weil diese Datei ueber BITNET uebertragen wurde, koennen
  377. COMMENT --     einige Zeichen dadurch verlorengegangen worden sein;
  378. COMMENT --     insbesondere Up-Arrow, eckige Klammern und senkrechte
  379. COMMENT --     Striche koennen Probleme machen.
  380.  
  381. set take-echo off       ; Das interessiert uns nicht.
  382. set terminal VT102      ; Emuliere ein DEC-VT102-Terminal
  383. set terminal roll on    ; Vor einer Eingabe zurueck an die richtige Stelle
  384. set terminal wrap on    ; Am Zeilenende herumwickeln
  385. set display regular 8-bit  ; Damit wir Umlaute haben
  386. set warning on          ; Keine existierenden Dateien ueberschreiben!
  387. set flow none           ; Kein xon/xoff
  388. set baud 19200          ; Die  meisten von uns koennen so schnell laufen.
  389. set send start 30       ; Modcomp mag kein Ctrl-A als start-of-packet.
  390. set rec  start 30       ; Modcomp mag kein Ctrl-A als start-of-packet.
  391. set send packet 76      ; Sicherheitshalber nur kurze Pakete
  392. set retry 63            ; Manchmal hakt es...
  393.  
  394. COMMENT        Allgemeine Tastaturbelegung im WIdO:
  395. set key \d1    \Kbreak               ; CA   : <BREAK>
  396. set key \d270  {\d8}    ; grauer grosser Links-Pfeil wird Backspace
  397. set key \d315  {JOB\d13}             ;   F1 : JOB<cr>
  398. set key \d316  {DISKINFO\d13}        ;   F2 : DISKINFO<cr>
  399. set key \d317  {DUMP }               ;   F3 : DUMP
  400. set key \d318  {EXE SED\d13}         ;   F4 : EXE SED<cr>
  401. set key \d319  {HELP }               ;   F5 : HELP
  402. set key \d320  {EXE LIST LM\d13}     ;   F6 : EXE LIST LM<cr>
  403. set key \d321  {}                    ;   F7 : nix!
  404. set key \d322  {}                    ;   F8 : nix!
  405. set key \d323  {}                    ;   F9 : nix!
  406. set key \d324  {'}                   ;   F10: accent aigu
  407. set key \d327  {\d27-H}              ;  Home: HOME
  408. ; set key \d328  \Kuparr             ;  Aufwaerts-Pfeil: (vordefiniert)
  409. set key \d329  {\d27`lbr`V}              ;  PgUp: PREV PAGE
  410. set key \d330  {-}                   ;  graues Minus   : -
  411. ; set key \d331  \Klfarr             ;  Links-Pfeil    : (vordefiniert)
  412. ; set key \d333  \Krtarr             ;  Rechts-Pfeil   : (vordefiniert)
  413. set key \d334  {+}                   ;  graues Plus    : +
  414. set key \d335  {}                    ;  End : nix!
  415. ; set key \d336  \Kdnarr             ;  Abwaerts-Pfeil : (vordefiniert)
  416. set key \d337  {\d27`lbr`U}              ;  PgDn: NEXT PAGE
  417. set key \d852  {}                    ;  SF1 : nix!
  418. set key \d853  {}                    ;  SF2 : nix!
  419. set key \d854  {}                    ;  SF3 : nix!
  420. set key \d855  {}                    ;  SF4 : nix!
  421. set key \d856  {}                    ;  SF5 : nix!
  422. set key \d857  {}                    ;  SF6 : nix!
  423. set key \d858  {}                    ;  SF7 : nix!
  424. set key \d859  {}                    ;  SF8 : nix!
  425. set key \d860  {}                    ;  SF9 : nix!
  426. set key \d861  {}                    ;  SF10: nix!
  427. set key \d1394 \Kmodeline            ;CPrtScr: Modeline an/aus
  428. set key \d1397 \Kendscn              ;  CEnd: roll down to end
  429. set key \d1398 \Kdnscn               ; CPgDn: roll down one screen
  430. set key \d1399 \Khomscn              ; CHome: roll up to beginning
  431. set key \d1412 \Kupscn               ; CPgUp: roll up   one screen
  432. set key \d1910 \Kdnone               ;SCPgDn: roll down one line
  433. set key \d1924 \Kupone               ;SCPgUp: roll up   one line
  434. set key \d2334 \Kbreak               ; AA   : <BREAK>
  435. set key \d2335 {}                    ; AS   : nix!
  436. ; set key \d2339 \Khelp              ; AH   : connect help (vordefiniert)
  437. set key \d2349 {}                    ; AX   : nix!
  438. set key \d2350 \Kexit                ; AC   : zurueck zum PC
  439. set key \d2352 {}                    ; AB   : nix!
  440. set key \d2434 {}                    ; A~   : nix!
  441. set key \d2435 {}                    ; A'   : nix!
  442. set key \d2920 {\d1                                RUN DIA\d13}
  443.                                      ; SAF1 : <BREAK>RUN DIA<cr>
  444. set key \d2921 {\d1                                STO DIA\d13}
  445.                                      ; SAF2 : <BREAK>STO DIA<cr>
  446.  
  447. COMMENT        Deutsche Spezialzeichen werden zu 7-bit ASCII:
  448. set key \d132  {\d123}  ; Umlaut-a wird zu linker geschweifter  Klammer
  449. set key \d142  {`lbr`}      ; Umlaut-A wird zu linker eckiger       Klammer
  450. set key \d148  {`vba`}      ; Umlaut-o wird zu senkrechtem Strich
  451. set key \d153  {\}      ; Umlaut-O wird zu umgekehrtem Schraegstrich
  452. set key \d129  {\d125}  ; Umlaut-u wird zu rechter geschweifter Klammer
  453. set key \d154  {`rbr`}      ; Umlaut-U wird zu rechter eckiger      Klammer
  454. set key \d225  {~}      ; "sz"     wird zu Tilde
  455.  
  456. COMMENT        Empfangene Sonderzeichen werden richtig dargestellt:
  457. set trans inp { \d132   ; linke  geschweifte Klammer als Umlaut-a
  458. set trans inp `lbr` \d142   ; linke  eckige      Klammer als Umlaut-A
  459. set trans inp `vba` \d148   ; senkrechter Strich         als Umlaut-o
  460. set trans inp \ \d153   ; umgekehrter Schraegstrich   als Umlaut-O
  461. set trans inp } \d129   ; rechte geschweifte Klammer als Umlaut-u
  462. set trans inp `rbr` \d154   ; rechte eckige      Klammer als Umlaut-U
  463. set trans inp ~ \d225   ; Tilde                      als "sz"
  464.  
  465. COMMENT        Zwei Macros zum einfacheren Umschalten:
  466. define deutsch  set translation input on   ; deutsche  Darstellung
  467. define englisch set translation input off  ; englische Darstellung
  468.  
  469. do deutsch              ; normalerweise deutsche Darstellung
  470.  
  471. define rundia  take rundia.scr    ; zum einfacheren Einloggen
  472.  
  473. COMMENT        Tabulatoren stehen da, wo der Editor SED sie vermutet:
  474. set terminal tabstops clear all   ; erst alle weg, und dann:
  475. set terminal tabstops at 7 21 36 73
  476.  
  477. COMMENT        IBM (Macro fuer Linemode-IBM-Mainframe-Verbindung) ist
  478. COMMENT        vordefiniert
  479.  
  480. COMMENT        Macro fuer typisches IBM-Mainframe-7171-Front-End:
  481. ; define 7171 set timer on,set par ev,set flo x,set hand no,set loc off,
  482.  
  483. COMMENT        Macro fuer Kommunikation mit DEC & anderen
  484. COMMENT        Full-Duplex-Rechnern:
  485. ; define DEC set timer off,set par no,set flo x,set hand no,set loc off,
  486.  
  487. COMMENT        Jetzt wird eine Benutzer-spezifische Konfigurations-Datei
  488. COMMENT        eingelesen:
  489. take mslocal.ini
  490.  
  491. COMMENT  --    Ende von MSKERMIT.INI
  492.  
  493.  
  494.  
  495.  
  496.  
  497.             Anhang 4:  Beispiele fuer TAKE- und Batch-Files
  498.  
  499. <<RUNDIA.SCR>>
  500. set take-echo off                 ; das interessiert den Benutzer nicht
  501. COMMENT           "Einloggen" bei der Modcomp
  502. COMMENT           Gisbert W.Selke, 29. Oktober 87
  503. echo     Bitte Geduld - das RUN DIA dauert etwas...\d13
  504. set input echo on                 ; das Echo der Modcomp interessiert aber
  505. clear                             ; Putzen der Leitung
  506. set input timeout proceed         ; sicherheitshalber
  507. output \b;                        ; ein BREAK
  508. pause 1                           ; langsam!
  509. output \b;                        ; noch ein BREAK - sicherheitshalber
  510. input 2 >;                        ; Ist er da, der TMP...
  511. pause 2                           ; langsam!
  512. output RUN DIA\d13;               ; Start
  513. pause 1                           ; falls sie schon lief:
  514. output \d32\d13;                  ; ein <CR>
  515. echo  Terminal-Sitzung ist gestartet!\d13
  516. connect
  517. COMMENT              Ende des RUNDIA-Scripts
  518.  
  519. <<SEND.BAT>>
  520. echo off
  521. Rem  Datei-Transfer-Utility PC -> Modcomp
  522. Rem  Gisbert W.Selke, 29. Oktober 1987, nach einer Idee von Joe Doupnik
  523. Rem  Zur Benutzung mit MS-Kermit 2.30 oder spaeter
  524. if ".%2" == "." goto gebrauch
  525. if ".%3" == "." goto gebrauch
  526. if exist %1 goto weiter
  527. echo       Angegebene Datei existiert nicht!
  528. :gebrauch
  529. echo       Gebrauchsanweisung:  SEND  filename  user-id usl-name
  530. goto fertig
  531. :weiter
  532. echo Ran an die Modcomp!  Datei-Transfer von %1 vom PC in die USL %2_%3
  533. kermit tak presdrc.scr,out AT %2 UUU %3\d13,tak send1.scr,s %1,tak send2.scr,
  534. if errorlevel 1 goto fehler
  535. echo  Datei-Transfer %1 vom PC in die Modcomp-USL %2_%3 ist beendet
  536. goto fertig
  537. :fehler
  538. echo Datei-Transfer von %1 vom PC in die Modcomp-USL %2_%3 ist schiefgegangen!
  539. :fertig
  540. echo on
  541.  
  542. <<PRESDRC.SCR>>
  543. set take-echo off                 ; uninteressant
  544. COMMENT         Datei-Transfer-Utility, Vorbereitungsteil
  545. COMMENT         Gisbert W.Selke, 29. Oktober 1987
  546. echo \d13\d10 Vorbereiten des Transfers...
  547. set input echo on                 ; Was sagt die MODCOMP dazu
  548. set input timeout proceed         ; notfalls am Ende eine Meldung
  549. clear                             ; Leitung putzen
  550. COMMENT         Sicherheitshalber ein Einloggen probieren...
  551. echo  \d13\d10Einloggen bei der MODCOMP  -- bitte etwas Geduld...
  552. output \b;                        ; ein BREAK
  553. pause 1                           ; langsam!
  554. output \b;                        ; noch ein BREAK - sicherheitshalber
  555. input 2 >;                        ; Ist er da, der TMP...
  556. pause 1                           ; langsam!
  557. output RUN DIA\d13;               ; Start
  558. pause 2                           ; und falls sie schon lief:
  559. output \d32\d13;                  ; nix tun, MODCOMP
  560. output JOB\d13;                   ; noch schnell aufraeumen
  561. input 60 $;                       ; in Ordnung
  562. COMMENT         Jetzt ein Attach, dann Take send1.scr / recv1.scr
  563.  
  564. <<SEND1.SCR>>
  565. COMMENT           Datei-Transfer-Utility PC -> Modcomp, Teil 1
  566. COMMENT           Gisbert W.Selke, 29. Oktober 1987
  567. pause 1                           ; langsam
  568. input 10 OPEN;                    ; Attach abwarten
  569. input 2 $;                        ; Attach beendet
  570. output KERMIT\d13;                ; Kermiv starten
  571. input 40 MAXIV>;                  ; Kermiv ist da
  572. output SET USL UUU\d13;           ; USL passend vorwaehlen
  573. input 10 MAXIV>;                  ; Prompt abwarten
  574. output RECEIVE\d13;               ; Erwarte die Datei
  575. pause 1                           ; langsam
  576. echo \d13\d10Datei-Senden beginnt
  577. COMMENT   Ende von Teil 1 - jetzt ein Send ..., dann Take send2.scr
  578.  
  579. <<SEND2.SCR>>
  580. COMMENT           Datei-Transfer-Utility PC -> Modcomp, Teil 2
  581. COMMENT           Gisbert W.Selke, 29. Oktober 1987
  582. echo \d13\d10Aufraeumen beginnt
  583. output \d32\d13;                  ; einmal nix tun
  584. pause 1                           ; langsam
  585. output quit\d13;                  ; Schluss, Kermiv
  586. input 10 (Y/N);                   ; Default-Werte annehmen
  587. pause 1                           ; langsam
  588. output Y\d13;                     ; ja, Default-Werte sind OK
  589. input 3  (C/R);                   ; Cat oder Recat
  590. pause 1                           ; langsam
  591. output R\d13;                     ; Recat sicherheitshalber
  592. input 60 $END;                    ; bist Du fertig
  593. input $;                          ; jetzt endgueltig
  594. pause 1                           ; Gnadenfrist
  595. output JOB\d13;                   ; Laden dicht machen
  596. input 60 $;                       ; das war's
  597. quit
  598.  
  599. <<RECV.BAT>>
  600. echo off
  601. Rem  Datei-Transfer-Utility Modcomp -> PC
  602. Rem  Gisbert W.Selke, 19. November 1987, nach einer Joe Doupnik
  603. Rem  Zur Benutzung mit MS-Kermit 2.30 oder spaeter
  604. if ".%1" == "." goto gebrauch
  605. if ".%2" == "." goto gebrauch
  606. if ".%3" == "." goto gebrauch
  607. goto weiter
  608. :gebrauch
  609. echo       Gebrauchsanweisung:  RECV  membername  user-id  usl-name
  610. goto fertig
  611. :weiter
  612. echo Ran an die Modcomp! Datei-Transfer von %1 aus der USL %2_%3 zum PC
  613. kermit ta presdrc.scr,o AT %2 USL %3\d13,ta recv1.scr,o send %1\d13,ta recv2.scr
  614. if errorlevel 2 goto fehler
  615. echo Datei-Transfer von %1 in der Modcomp-USL %2_%3 zum PC beendet
  616. goto fertig
  617. :fehler
  618. echo Datei-Transfer von %1 in der Modcomp-USL %2_%3 zum PC ist schiefgegangen!
  619. :fertig
  620. echo on
  621.  
  622. <<RECV1.SCR>>
  623. COMMENT       Datei-Transfer-Utility MODCOMP -> PC, Teil 1
  624. COMMENT       Gisbert W.Selke, 29. Oktober 1987
  625. echo \d13\d10MODCOMP-Kermit wird gestartet
  626. input 10 OPEN;                   ; Attach gelungen
  627. input 2 $;                       ; und beendet
  628. output KERMIT\d13;               ; Kermiv-Start
  629. input 40 MAXIV>;                 ; da ist er
  630. output SET DELAY 1\d13;          ; voran jetzt
  631. input 5  MAXIV>;                 ; da ist er
  632. COMMENT Jetzt ein Send ..., dann Take recv2.scr
  633.  
  634. <<RECV2.SCR>>
  635. COMMENT       Datei-Transfer-Utility MODCOMP -> PC, Teil 2
  636. COMMENT       Gisbert W.Selke, 15 Okt 87
  637. echo \d13\d10Datei-Empfang beginnt
  638. pause 1
  639. receive                          ; MS-Kermit
  640. echo \d13\d10Aufraeumen beginnt
  641. output \d32\d13;                 ; einmal nix tun
  642. output \d32\d13;                 ; nochmal nix tun
  643. input 5 MAXIV>;                  ; langsam zum Ende kommen
  644. output quit\d13;                 ; Kermiv-Ende
  645. input 10 $END;                   ; Prozedur beendet
  646. pause 1                          ; langsam ...
  647. output JOB\d13;                  ; und Schluss
  648. pause 1                          ; langsam
  649. quit                             ; MS-Kermit Ende
  650.  
  651. <<Ende der Beispiel-Dateien>>
  652.  
  653. (Ende der Kermit-Einfuehrung)
  654.