home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / luxorabc80 / kerm3.asm < prev    next >
Assembly Source File  |  2020-01-01  |  16KB  |  749 lines
  1. ; KERM3.ASM
  2. ; Anders Franz`n <5258>
  3. ; Stockholm 1987-09-20
  4.  
  5.  
  6. KERMIT   CALL KERMV
  7. KERM1    LD   HL,KERM4
  8.          LD   BC,KERM5-KERM4
  9.          CALL 0:11      Skriv promt
  10. KERM2    CALL 7:66
  11.          LD   HL,BUFF6
  12.          LD   BC,39
  13.          PUSH HL
  14.          CALL GETLINE
  15.          POP  HL
  16.          RST  32
  17.          CP   13
  18.          JRZ  KERM2     Tom rad
  19.          LD   BC,KERM1
  20.          PUSH BC        Returadress
  21.          LD   DE,CMDTAB
  22.          PUSH DE
  23.          CALL STRSCAN
  24.          POP  DE
  25.          RETC           Ambigious
  26.          JRNZ KERM3
  27.          LD   DE,CMDJTB
  28.          JP   1:58      Utnyttja ROM!
  29.  
  30. KERM3    PUSH DE
  31.          LD   HL,KERM5
  32.          LD   BC,KERM6-KERM5
  33.          CALL 0:11
  34.          POP  HL
  35.          JP   HELP1
  36.  
  37. KERM4    DM 13,10,"KERMIT"
  38. KERM5    DM 13,10,7,"Command must be"
  39. KERM6
  40.  
  41. GETLINE  LD   DE,3:78
  42.          LD   (253:251),DE
  43.          PUSH IX
  44.          LD   B,C
  45. GETL2    CALL 3:91
  46.          JRNZ GETL2
  47. GETL3    CALL 3:91
  48. GETL4    CALL 0:2
  49.          CP   9
  50.          CALLZ 3:72
  51.          CP   13
  52.          JPZ  2:229
  53.          CP   24
  54.          JRZ  GETL2
  55.          CP   8
  56.          JRZ  GETL3
  57.          PUSH HL
  58.          PUSH DE
  59.          PUSH BC
  60.          PUSH IX
  61.          PUSH AF
  62.          LD   HL,(ESCAPE)
  63.          CP   L
  64.          JRNZ GETL5
  65.          CALL CONNECT
  66.          JR   GETL6
  67.  
  68. GETL5    LD   HL,(TEDESC)
  69.          CP   L
  70.          CALLZ TED
  71. GETL6    POP  AF
  72.          POP  IX
  73.          POP  BC
  74.          POP  DE
  75.          POP  HL
  76.          CP   32
  77.          JRC  GETL4
  78.          LD   (DE),A
  79.          CP   96
  80.          JRC  GETL7
  81.          AND  95
  82. GETL7    LD   (HL),A
  83.          INC  HL
  84.          INC  (IX+1)
  85.          LD   A,(2:111)
  86.          CP   (IX+1)
  87.          CALLC 2:52
  88.          DJNZ GETL4
  89.          JP   2:228
  90.  
  91. CMDTAB   DM 128,"CLOSE"
  92.          DM 129,"CONNECT"
  93.          DM 130,"DELETE"
  94.          DM 131,"DIR"
  95.          DM 132,"DUMP"
  96.          DM 130,"ERASE"
  97.          DM 133,"EXIT"
  98.          DM 134,"HELP"
  99.          DM 130,"KILL"
  100.          DM 135,"LOG"
  101.          DM 136,"QUIT"
  102.          DM 137,"RECEIVE"
  103.          DM 138,"SAVE"
  104.          DM 139,"SEND"
  105.          DM 140,"SET"
  106.          DM 141,"SHOW"
  107.          DM 142,"TED"   Rensa tabell om
  108.          DM 143,"TYPE"
  109.          DM 255         TED saknas
  110.  
  111. CMDJTB   DW CLOSE       128
  112.          DW CONNECT     129
  113.          DW DELETE      130
  114.          DW DIRH        131
  115.          DW DUMP        132
  116.          DW BASIC       133
  117.          DW HELP        134
  118.          DW LOGG        135
  119.          DW QUIT        136
  120.          DW KERMREC     137
  121.          DW SAVE        138
  122.          DW KERMSEND    139
  123.          DW SET         140
  124.          DW SHOW        141
  125.          DW TED         142
  126.          DW TYPE        143
  127.  
  128. CONNECT  CALL KERMS
  129. CON1     CALL TERMINAL
  130.          LD   A,(FLAGG)
  131.          BIT  1,A
  132.          JPNZ TED1      TED-escape
  133.          CALL KERMV
  134.          LD   A,(FLAGG)
  135.          BIT  6,A
  136.          JRNZ CON2      TED full
  137.          BIT  7,A
  138.          RETZ           LOG/DUMP-FIL ok
  139.          LD   A,(FELKOD)
  140.          CALL ERROR
  141.          CALL CLOSE
  142.          LD   SP,STACK
  143.          JP   KERM1
  144.  
  145. CON2     LD   HL,CON3
  146.          LD   BC,CON4-CON3
  147.          CALL 0:11
  148.          LD   SP,STACK
  149.          JP   KERM1
  150.  
  151. CON3     DB 13,10,7
  152.          DM "TED filled",13,10
  153. CON4
  154.  
  155. TED      LD   A,(TEDFLG)
  156.          AND  A
  157.          RETZ           TED ej i minnet!
  158.          CALL KERMS
  159. TED1     LD   A,(DMP)
  160.          LD   C,A
  161.          LD   A,(LOG)
  162.          OR   C
  163.          JRZ  TED2      Ingen fil |ppen
  164.          CALL KERMV
  165.          CALL CLOSE     St{ng fil
  166.          LD   SP,STACK
  167.          JP   KERM1     Stanna i KERM
  168.  
  169. TED2     CALL TED3      Anropa TED
  170.          LD   A,(FLAGG)
  171.          BIT  1,A
  172.          JPNZ CON1      TED-escape
  173.          JP   KERMV
  174.  
  175. TED3     LD   (KERMSP),SP
  176.          LD   SP,(TEDSP)
  177.          RET            Till TED
  178.  
  179. TEDFLG   DB 0
  180.  
  181. KERMSEND CALL DRIVEFIX  Fixa filnamn
  182.          LD   A,21
  183.          JPC  ERROR
  184.          CALL CLOSE
  185.          CALL INIT      Rensa buffertar
  186.          CALL INTON     Sl} p} interrupt
  187.          CALL XON
  188.          CALL SEND
  189.          CALL XOFF
  190.          CALL INTOFF    Sl} av interrupt
  191.          CALL 7:66
  192.          RET
  193.  
  194. KERMREC  LD   (FILPEK),HL Ev filnamn
  195.          CALL CLOSE
  196.          CALL INIT      Rensa buffertar
  197.          CALL INTON     Sl} p} interrupt
  198.          CALL XON
  199.          CALL RECEIVE
  200.          CALL XOFF
  201.          CALL INTOFF    Sl} av interrupt
  202.          CALL 7:66
  203.          RET
  204.  
  205. QUIT     PUSH HL        Spara ev pgm
  206.          CALL CLOSE
  207.          CALL KERMS
  208.          LD   HL,254:64 Inga parametrar
  209.          LD   (HL),L    om QUIT KERM
  210.          POP  HL
  211.          CALL BASIC1    Anropa BASIC
  212. KERMV    LD   HL,KERMBILD
  213.          CALL VISABILD
  214.          RET
  215.  
  216. KERMS    LD   DE,KERMBILD
  217.          CALL SPARBILD
  218.          RET
  219.  
  220. BASIC    CALL CLOSE
  221.          JP   0:0
  222.  
  223. BASIC1   LD   (KERMSP),SP
  224.          LD   SP,(254:39)
  225.          LD   A,(13:76)
  226.          CP   231
  227.          JPZ  13:76     RUN i BASIC
  228.          JP   13:74
  229.  
  230. ;Visar vilka kommandon som finns
  231. HELP     LD   HL,CMDTAB
  232. HELP1    LD   B,1
  233. HELP2    DJNZ HELP3
  234.          CALL 7:66
  235.          LD   B,3
  236.          LD   A,(1:216)
  237.          CP   40
  238.          JRZ  HELP3
  239.          LD   B,5
  240. HELP3    LD   A,-10
  241.          LD   DE,SPACE
  242.          CALL SKRIVTAB
  243.          LD   A,(HL)
  244.          INC  A
  245.          JRNZ HELP2
  246.          CALL 7:66
  247.          RET
  248.  
  249. ;Visa parametrar
  250. SHOW     CALL 7:66
  251.          LD   IX,PARMAREA
  252.          LD   HL,SHOWTAB
  253.          PUSH HL
  254.          LD   HL,SETTAB
  255. SHOW1    LD   B,2       Antal/rad
  256.          LD   A,(1:216)
  257.          CP   40
  258.          JRZ  SHOW2
  259.          LD   B,3
  260. SHOW2    LD   A,-7      Rak v{nsterkant
  261.          LD   DE,PUNKTER
  262.          CALL SKRIVTAB
  263.          EX   (SP),HL
  264.          PUSH BC
  265.          LD   E,(HL)
  266.          INC  HL
  267.          LD   D,(HL)
  268.          INC  HL
  269.          LD   C,(HL)
  270.          INC  HL
  271.          LD   B,(HL)
  272.          INC  HL
  273.          PUSH HL
  274.          EX   DE,HL
  275.          LD   A,(IX)
  276.          INC  IX
  277.          OR   128
  278.          CP   254
  279.          JRZ  SHOW3
  280.          CP   255
  281.          JRZ  SHOW3
  282.          CPIR
  283.          JRZ  SHOW4
  284. SHOW3    AND  127
  285.          LD   L,A
  286.          LD   H,0
  287.          LD   A,9
  288.          LD   DE,PUNKTER
  289.          CALL SKRTAL
  290.          JR   SHOW5
  291.  
  292. SHOW4    DEC  HL
  293.          LD   A,9
  294.          LD   DE,PUNKTER
  295.          CALL SKRIVTAB
  296. SHOW5    POP  HL
  297.          POP  BC
  298.          EX   (SP),HL
  299.          LD   A,(HL)
  300.          INC  A
  301.          JRZ  SHOW6
  302.          PUSH HL
  303.          PUSH BC
  304.          LD   HL,SPACE
  305.          LD   BC,2
  306.          CALL 0:11
  307.          POP  BC
  308.          POP  HL
  309.          DJNZ SHOW2
  310.          CALL 7:66
  311.          JR   SHOW1
  312.  
  313. SHOW6    POP  HL
  314.          CALL 7:66
  315.          RET
  316.  
  317. ;IN  DE Typ av delare
  318. ;     A L{ngd f{lt >0 rak h|gerkant
  319. ;                  <0 rak v{nsterkant
  320. SKRIVTAB PUSH BC
  321.          LD   BC,-1
  322.          INC  HL        Skippa highbyte
  323.          PUSH HL
  324. SKRIVT1  BIT  7,(HL)
  325.          INC  HL
  326.          INC  BC        R{kna l{ngd ord
  327.          JRZ  SKRIVT1
  328.          DEC  HL
  329.          EX   (SP),HL   Spara n{sta ord
  330.          PUSH DE        Spara avskiljare
  331.          AND  A
  332.          JPM  SKRIVT2   Rak v{nsterkant
  333.          PUSH HL
  334.          PUSH BC
  335.          EX   DE,HL
  336.          SUB  C
  337.          LD   C,A
  338.          CALLNZ 0:11    Skriv avskiljare
  339.          XOR  A
  340.          POP  BC        L{ngd p} ord
  341.          POP  HL        Pekar p} ord
  342. SKRIVT2  PUSH AF
  343.          PUSH BC
  344.          CALL 0:11      Skriv ord
  345.          POP  BC
  346.          POP  AF
  347.          POP  HL        Avskiljare
  348.          NEG
  349.          SUB  C
  350.          LD   C,A
  351.          CALLP 0:11     Skriv avskiljare
  352.          POP  HL        N{sta ord
  353.          POP  BC
  354.          RET
  355.  
  356. PUNKTER  DM ".........."
  357.  
  358. ;[ndra parametrar
  359. SET      LD   DE,SETTAB
  360.          PUSH DE
  361.          CALL STRSCAN
  362.          POP  DE
  363.          RETC           Ambigious
  364.          JRNZ SET1
  365.          LD   DE,SETJTB
  366.          JP   1:58      Utnyttja ROM!
  367.  
  368. SET1     PUSH DE
  369.          LD   HL,SETF1
  370.          LD   BC,SETF2-SETF1
  371.          CALL 0:11      Felmeddelande
  372.          POP  HL
  373.          JP   HELP1
  374.  
  375. SET2     PUSH DE
  376.          LD   HL,SETF2
  377.          LD   BC,SETF3-SETF2
  378.          CALL 0:11      Felmeddelande
  379.          POP  HL
  380.          JP   HELP1
  381.  
  382. SETF1    DM 13,10,7,"Parameter must be"
  383. SETF2    DM 13,10,7,"Value must be"
  384. SETF3
  385.  
  386. SETTAB   DM 128,"ACCESS"
  387.          DM 129,"BAUD"
  388.          DM 130,"CHECK"
  389.          DM 131,"DEBUG"
  390.          DM 132,"DUPLEX"
  391.          DM 133,"EOL"
  392.          DM 134,"ESCAPE"
  393.          DM 135,"FILE"
  394.          DM 136,"FLOW"
  395.          DM 137,"LENGTH"
  396.          DM 138,"MARKER"
  397.          DM 139,"NEWLINE"
  398.          DM 140,"NUMPAD"
  399.          DM 141,"PADCHAR"
  400.          DM 142,"PARITY"
  401.          DM 143,"PAUSE"
  402.          DM 144,"QBIN"
  403.          DM 145,"QCTL"
  404.          DM 146,"REPT"
  405.          DM 147,"RETRY"
  406.          DM 148,"TEDESC"
  407.          DM 149,"TEDMODE"
  408.          DM 150,"TIMEOUT"
  409.          DM 255
  410.  
  411. SETJTB   DW [ACC        128
  412.          DW [BAUD       129
  413.          DW [CHECK      130
  414.          DW [DEBUG      131
  415.          DW [DUPL       132
  416.          DW [EOL        133
  417.          DW [ESCAPE     134
  418.          DW [FILE       135
  419.          DW [FLOW       136
  420.          DW [LENGTH     137
  421.          DW [MARKER     138
  422.          DW [NEWL       139
  423.          DW [NUMPAD     140
  424.          DW [PADCHAR    141
  425.          DW [PAR        142
  426.          DW [PAUSE      143
  427.          DW [QBIN       144
  428.          DW [QCTL       145
  429.          DW [REPT       146
  430.          DW [RETRY      147
  431.          DW [TEDESC     148
  432.          DW [TED        149
  433.          DW [TIME       150
  434.  
  435.  
  436. [BAUD    LD   DE,PBAUD
  437.          LD   BC,BAUD
  438.          CALL [TAB
  439.          JP   FIXBAUD
  440.  
  441. PBAUD    DM 128,"300/300"
  442.          DM 129,"1200/75"
  443.          DM 130,"75/1200"
  444.          DM 131,"1200/1200"
  445.          DM 132,"2400/2400"
  446.          DM 133,"4800/4800"
  447.          DM 255
  448. PBAUDS
  449.  
  450. [DUPL    LD   DE,PDUPL
  451.          LD   BC,DUPLEX
  452.          JP   [TAB
  453.  
  454. PDUPL    DM 128,"HALF"
  455.          DM 129,"FULL"
  456.          DM 255
  457. PDUPLS
  458.  
  459. [PAR     LD   DE,PPAR
  460.          LD   BC,PARITET
  461.          JP   [TAB
  462.  
  463. PPAR     DM 128,"NONE"
  464.          DM 129,"SPACE",129,"0"
  465.          DM 130,"MARK",130,"1"
  466.          DM 131,"EVEN"
  467.          DM 132,"ODD"
  468.          DM 255
  469. PPARS
  470.  
  471. [FLOW    LD   DE,PFLOW
  472.          LD   BC,FLOW
  473.          JP   [TAB
  474.  
  475. PFLOW    DM 128,"OFF"
  476.          DM 129,"XON/XOFF"
  477.          DM 255
  478. PFLOWS
  479.  
  480. [TIME    LD   DE,TIME
  481.          JR   [TAL
  482.  
  483. [RETRY   LD   DE,RETRY
  484. [TAL     PUSH DE
  485.          CALL G\RTAL
  486.          POP  BC
  487.          EX   DE,HL
  488.          LD   DE,PTAL
  489.          JPC  SET2
  490.          LD   A,H
  491.          AND  A
  492.          JPNZ SET2
  493.          LD   A,L
  494.          CP   1
  495.          JPC  SET2
  496.          CP   31
  497.          JPNC SET2
  498.          LD   (BC),A
  499.          CALL 7:66
  500.          AND  A
  501.          RET
  502.  
  503. PTAL     DM 254,"1-30"
  504.          DM 255
  505. PTALS
  506.  
  507. [FILE    LD   DE,PFILE
  508.          LD   BC,FILE
  509.          JP   [TAB
  510.  
  511. PFILE    DM 128,"TEXT"
  512.          DM 129,"BIN"
  513.          DM 130,"AUTO"
  514.          DM 255
  515. PFILES
  516.  
  517. [LENGTH  CALL G\RTAL
  518.          EX   DE,HL
  519.          LD   DE,PLENGTH
  520.          JPC  SET2
  521.          LD   A,H
  522.          AND  A
  523.          JPNZ SET2
  524.          LD   A,L
  525.          CP   20
  526.          JPC  SET2
  527.          CP   95
  528.          JPNC SET2
  529.          LD   (LENGTH),A
  530.          CALL 7:66
  531.          RET
  532.  
  533. PLENGTH  DM 254,"20-94"
  534.          DM 255
  535. PLENGTHS
  536.  
  537. [MARKER  LD   DE,MARKER
  538.          JP   [TKN
  539.  
  540. [CHECK   LD   DE,PCHECK
  541.          LD   BC,CHECK
  542. [TAB     PUSH DE
  543.          PUSH BC
  544.          CALL STRSCAN
  545.          POP  BC
  546.          POP  DE
  547.          RETC           Ambigious
  548.          JPNZ SET2
  549.          AND  127
  550.          LD   (BC),A
  551.          CALL 7:66
  552.          RET
  553.  
  554. PCHECK   DM 129,"1"
  555.          DM 130,"2"
  556.          DM 255
  557. PCHECKS
  558.  
  559. [EOL     LD   DE,EOL
  560.          JR   [TKN
  561.  
  562. [NUMPAD  LD   DE,NUMPAD
  563.          JR   [TKN
  564.  
  565. [PADCHAR LD   DE,PADCHAR
  566.          JR   [TKN
  567.  
  568. [QCTL    LD   DE,QCTL
  569.          JR   [TKN
  570.  
  571. [QBIN    LD   DE,QBIN
  572.          JR   [TKN
  573.  
  574. [ESCAPE  LD   DE,ESCAPE
  575.          JR   [TKN
  576.  
  577. [TEDESC  LD   DE,TEDESC
  578.          JR   [TKN
  579.  
  580. [REPT    LD   DE,REPT
  581. [TKN     PUSH DE        Spara variabel
  582.          CALL G\RTAL
  583.          POP  BC
  584.          EX   DE,HL
  585.          LD   DE,PTKN
  586.          JPC  SET2
  587.          LD   A,H
  588.          AND  A
  589.          JPNZ SET2
  590.          LD   A,L
  591.          BIT  7,A
  592.          JPNZ SET2
  593.          LD   (BC),A
  594.          CALL 7:66
  595.          AND  A
  596.          RET
  597.  
  598. PTKN     DM 254,"0-127"
  599.          DM 255
  600. PTKNS
  601.  
  602. [ACC     LD   DE,PACC
  603.          LD   BC,ACCESS
  604.          JP   [TAB
  605.  
  606. PACC     DM 128,"PREPARE"
  607.          DM 129,"KILL"
  608.          DM 130,"STOP"
  609.          DM 255
  610. PACCS
  611.  
  612. [DEBUG   LD   DE,PDEBUG
  613.          LD   BC,DEBUG
  614.          JP   [TAB
  615.  
  616. PDEBUG   DM 128,"OFF"
  617.          DM 129,"PACKET"
  618.          DM 130,"DUMP"
  619.          DM 255
  620. PDEBUGS
  621.  
  622. [TED     LD   DE,PTED
  623.          LD   BC,TEDSAVE
  624.          CALL [TAB
  625.          RET
  626.  
  627. PTED     DM 128,"OFF"
  628.          DM 129,"SAVE"
  629.          DM 130,"SEND"
  630.          DM 255
  631. PTEDS
  632.  
  633. [NEWL    LD   DE,PNEWL
  634.          LD   BC,NEWLINE
  635.          JP   [TAB
  636.  
  637. PNEWL    DM 128,"OFF"
  638.          DM 129,"ON"
  639.          DM 255
  640. PNEWLS
  641.  
  642. [PAUSE   LD   DE,PAUSE
  643.          JP   [TKN
  644.  
  645. SHOWTAB  DW PACC,PACCS-PACC         128
  646.          DW PBAUD,PBAUDS-PBAUD      129
  647.          DW PCHECK,PCHECKS-PCHECK   130
  648.          DW PDEBUG,PDEBUGS-PDEBUG   131
  649.          DW PDUPL,PDUPLS-PDUPL      132
  650.          DW PTKN,PTKNS-PTKN eol     133
  651.          DW PTKN,PTKNS-PTKN escape  134
  652.          DW PFILE,PFILES-PFILE      135
  653.          DW PFLOW,PFLOWS-PFLOW      136
  654.          DW PLENGTH,PLENGTHS-PLENGTH 137
  655.          DW PTKN,PTKNS-PTKN marker  138
  656.          DW PNEWL,PNEWLS-PNEWL      139
  657.          DW PTKN,PTKNS-PTKN numpad  140
  658.          DW PTKN,PTKNS-PTKN padchar 141
  659.          DW PPAR,PPARS-PPAR         142
  660.          DW PTKN,PTKNS-PTKN pause   143
  661.          DW PTKN,PTKNS-PTKN qbin    144
  662.          DW PTKN,PTKNS-PTKN qctl    145
  663.          DW PTKN,PTKNS-PTKN rept    146
  664.          DW PTAL,PTALS-PTAL retry   147
  665.          DW PTKN,PTKNS-PTKN TEDesc  148
  666.          DW PTED,PTEDS-PTED         149
  667.          DW PTAL,PTALS-PTAL time    150
  668.  
  669. FIXBAUD  LD   A,(BAUD)
  670.          INC  A
  671.          LD   HL,FIXBAUD2-5
  672.          LD   BC,5
  673. FIXBAUD1 ADD  HL,BC
  674.          DEC  A
  675.          JRNZ FIXBAUD1
  676.          LD   A,(HL)    Kort tid f|r
  677.          INC  HL        tangentrepeet
  678.          LD   (TAN1-1),A
  679.          LD   E,(HL)
  680.          INC  HL
  681.          LD   D,(HL)
  682.          INC  HL
  683.          LD   (BAUDSEND),DE
  684.          LD   E,(HL)
  685.          INC  HL
  686.          LD   D,(HL)
  687.          INC  HL
  688.          LD   (BAUDREC),DE
  689.          RET
  690.  
  691. FIXBAUD2 DB 3
  692.          DW BAUD300,BAUD300
  693.          DB 5
  694.          DW BAUD75,BAUD1200
  695.          DB 2
  696.          DW BAUD1200,BAUD75
  697.          DB 2
  698.          DW BAUD1200,BAUD1200
  699.          DB 2
  700.          DW BAUD2400,BAUD2400
  701.          DB 2
  702.          DW BAUD4800,BAUD4800
  703.  
  704. FIXTED   LD   A,(TEDFLG)
  705.          AND  A
  706.          RETZ           TED ej i minnet
  707.          CALL R[KNA     Ant rader i TED
  708.          LD   (TEDANRAD),DE
  709.          INC  DE
  710.          LD   (TEDINRAD),DE
  711.          CALL TILLBUFF
  712.          XOR  A
  713.          LD   (TEDKOL),A
  714.          LD   L,A
  715.          LD   H,A
  716.          LD   (TEDUTRAD),HL
  717.          RET
  718.  
  719. PARMAREA
  720.  
  721. ACCESS   DB 0    Kolla om fil finns
  722. BAUD     DB 1    Baud
  723. CHECK    DB 2    Checksummetyp
  724. DEBUG    DB 0    Debug-mode
  725. DUPLEX   DB 1    Duplex
  726. EOL      DB 13   End of packet
  727. ESCAPE   DB 27   Esccape-tkn terminal
  728. FILE     DB 2    Filtyp
  729. FLOW     DB 1    Flow controll
  730. LENGTH   DB 94   Packetl{ngd
  731. MARKER   DB 1    Start of packet
  732. NEWLINE  DB 0    Tolka <RETURN> som CRLF
  733. NUMPAD   DB 0    Antal PAD-tkn
  734. PADCHAR  DB 0    PAD-tecken
  735. PARITET  DB 0    Paritet
  736. PAUSE    DB 0    Paus innan packet s{nds
  737. QBIN     DB "&"
  738. QCTL     DB "#"
  739. REPT     DB "~"
  740. RETRY    DB 5    Antal omf|rs|k
  741. TEDESC   DB 0    Hopp-till-TED-tangent
  742. TEDSAVE  DB 0    Spara/s{nda text i TED
  743. TIME     DB 10   Timeout
  744.  
  745. PARMLEN  EQU $-PARMAREA
  746.  
  747. LOG      DB 0    Logga p} disk
  748. DMP      DB 0    S{nd iv{g fil
  749.