home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / extra / nyenhuis3.arc / MSUIBM.ASM < prev    next >
Assembly Source File  |  1990-01-14  |  73KB  |  2,030 lines
  1.     NAME    msuibm
  2. ; File MSUIBM.ASM 
  3.     include mssdef.h
  4. ; Keyboard translator, by Joe R. Doupnik, Dec 1986
  5. ;  with contributions from David L. Knoell.
  6. ; edit history:
  7. ; Last edit 14 Jan 1990
  8. ; 7 Oct 1989 Add support for DEC LK250 keyboards, from Terry Kennedy.
  9. ; 2 August 1989 Allow verbs in definition strings [jrd]
  10. ; 21 Nov 1988 Version 2.32
  11. ; 12 Nov 1988 Add verbs terminalr and terminals, unassigned to keys.
  12. ; 1 July 1988 Version 2.31
  13. ; 20 May 1988 Add parser confirm requests below dfky13. [jrd]
  14. ; 10 March 1988 Add Holdscreen verb, holdscrn, for Terry Kennedy. [jrd]
  15. ; 27 Feb 1988 Add capability of stdin being a file rather than device. [jrd]
  16. ; 1 Jan 1988 version 2.30
  17.  
  18.     public    keybd, dfkey, shkey, msuinit, kbcodes
  19.     public    kbsusp, kbrest, kbhold        ;** LK250 support for IBM-PCs
  20.  
  21. ; some definitions
  22. kbint    equ    16h            ; IBM, Bios keyboard interrupt
  23. shift    equ    200h            ; IBM, synonym for right or left shift
  24. control    equ    400h            ; IBM, synonym for control shift
  25. alt    equ    800h            ; IBM, synonym for alt shift
  26. enhanced equ    1000h            ; IBM, enhanced keyboard code
  27.  
  28. rgt_shift equ    1            ; IBM shift state bits
  29. lft_shift equ    2
  30. ctl_shift equ    4
  31. alt_shift equ    8
  32. numlock      equ    20h
  33.  
  34. maxkeys    equ    200            ; maximum number of key definitions
  35. maxstng    equ    128            ; maximum number of multi-char strings
  36. stbuflen equ    1000            ; length of string buffer (bytes)
  37.  
  38. verb    equ    8000h            ; dirlist flag: use verb action table
  39. strng    equ    4000h            ; dirlist flag: use string action table
  40. scan    equ    100h            ; keycode flag: code is scan not ascii
  41. braceop    equ    7bh            ; opening curly brace
  42. bracecl    equ    7dh            ; closing curly brace
  43.  
  44. data    segment    public 'data'
  45.     extrn taklev:byte, comand:byte, flags:byte
  46.     extrn shkadr:word, stkadr:word, trans:byte, ttyact:byte
  47.                         ; system dependent references
  48.     extrn vtemu:byte, holdscr:byte        ; emulator data [jrd]
  49.     
  50. ;;;    System Independent local storage
  51.  
  52. tranbuf    db    132 dup (?)        ; 132 byte translator work buffer
  53. crlf    db    cr,lf,'$'
  54. dfhelp1    db    cr,lf,' Enter key',27h,'s identification as a character',cr,lf
  55.     db    '  or as its numerical equivalent \{b##} of ascii',cr,lf
  56.     db    '  or as its scan code \{b##}'
  57.     db    cr,lf,'  or as SCAN followed by its scan code',cr,lf
  58.     db    '    where b is O for octal, X for hex, or D for decimal'
  59.     db    ' (default).',cr,lf,'    Braces {} are optional.'
  60.     db    cr,lf,'    Follow the identification with the new definition.'
  61.     db    cr,lf,' or CLEAR to restore initial key settings'
  62.     db    cr,lf,' or ON (def) for Bios i/o or OFF to use DOS i/o.$' ;IBM
  63. dfaskky    db    cr,lf,' Push key to be defined: $'
  64. dfaskdf    db    ' Enter new definition: ',0        ; asciiz for prompt
  65. verbbad    db    cr,lf,' No such verb',cr,lf,'$'
  66. strbad    db    cr,lf,' Not enough space for new string',cr,lf,'$'
  67. keyfull    db    cr,lf,' No more space to define keys',cr,lf,'$'
  68. dfkoops    db    cr,lf,' Oops! That is Kermit',27h,'s Escape Char.'
  69.     db    ' Translation is not permitted.',cr,lf,'$'
  70. shkmsg1    db    cr,lf,'Push key to be shown (? shows all): $'
  71. shkmsg2    db    ' decimal is defined as',cr,lf,'$'
  72. shkmsg3    db    cr,lf,'... more, press a key to continue ...$'
  73. kwarnmsg db    cr,lf,' Notice: this form of Set Key is obsolete$'
  74.  
  75. ascmsg    db    ' Ascii char: $'
  76. scanmsg    db    ' Scan Code $'
  77. strngmsg db    ' String: $'
  78. verbmsg    db    ' Verb: $'
  79. noxmsg    db    ' Self, no translation.$'
  80. fremsg    db    cr,lf,' Free space: $'
  81. kyfrdef    db    ' key and $'
  82. stfrdef db    ' string definitions, $'
  83. stfrspc    db    ' string characters.',cr,lf,'$'
  84.                     ; translation tables
  85. keylist    dw    maxkeys dup (0)        ; 16 bit keycodes, paralled by dirlist
  86. dirlist    dw    maxkeys dup (0)        ; director {v+s} + {index | new char}
  87. sptable    dw    maxstng dup (0)        ; list of asciiz string offsets
  88. stbuf    dw    stbuflen dup (0)    ; buffer for strings
  89. strmax    dw    stbuf            ; first free byte in stbuf
  90. listptr    dw    ?            ; item number for keylist and dirlist
  91. nkeys    dw    0            ; number of actively defined keys
  92. keycode    dw    ?            ; ascii/scan code for key
  93. kbtemp    dw    ?            ; scratch storage for translator
  94. brace    db    ?            ; brace detected flag byte
  95. oldform    db    0            ; old form Set Key, if non-zero
  96. verblen    dw    ?            ; length of user's verb (work temp)
  97. kwcnt    dw    ?            ; number of keywords (work temp)
  98. msutake    db    ?            ; if being run from take file or not
  99. stringcnt dw    0            ; qty of string chars to be processed
  100. stringptr dw    0            ; address of next string char
  101. twelve    dw    12d
  102. dosflg    db    0
  103. ;;;    End System Independent Data Area
  104.  
  105. ;;;    System Dependent Data Area
  106. nrcptr    dw    0        ; pointer to code page to NRC table
  107. latinptr dw    0        ; pointer to code page to Latin1 table
  108. DECmnptr dw    0        ; pointer to code page to DEC-MCS table
  109. ;    edit dfhelp2 to include nice list of verbs for this system.
  110. dfhelp2 db    cr,lf,' Enter either  \Kverb  for a Kermit action verb',cr,lf
  111.     db    ' or a replacement string  (single byte binary numbers are'
  112.     db    ' \{b##})',cr,lf,' or push Return to undefine a key, ^C to'
  113.     db    ' retain current definition.'
  114.     db    cr,lf,' Braces {} are optional, and strings maybe enclosed in'
  115.     db    ' them.',cr,lf,' Strings may not begin with the character'
  116.     db    ' combinations of  \k  or  \{k',cr,lf
  117.     db    '    (start with a { brace instead).',cr,lf,lf
  118.     db    ' Verbs are as follows. VT320 keys (arrows and keypad):',cr,lf
  119.     db   '   uparr, dnarr, lfarr, rtarr, kpminus, kpcoma, kpdot, kpenter,'
  120.     db    cr,lf
  121.     db   '   Gold (same as PF1), PF1, PF2, PF3, PF4, kp0, ... kp9'
  122.     db    cr,lf,'   decFind, decInsert, decRemove, decSelect, decPrev,'
  123.     db    ' decNext'
  124.     db    cr,lf,'   User Definable Keys decF6, ...decF14, decHelp,'
  125.     db    ' decDO, decF17, ...decF20'
  126.     db    cr,lf,' Kermit screen control and actions:',cr,lf
  127.     db   '   upscn, dnscn, homscn, endscn, upone, dnone, prtscn, dump,'
  128.     db    cr,lf
  129.     db   '   logoff, logon, termtype, reset, holdscrn, modeline, break,'
  130.     db    ' lbreak, nethold,'
  131.     db    cr,lf
  132.     db   '   hangup, null (send one), terminalR, terminalS, DOS, help,'
  133.     db   ' status, exit'
  134.     db    cr,lf,'$'
  135.  
  136.     ; Aliaskey: keys having aliases - same ascii code but more than one
  137.     ; scan code, as on auxillary keypads. Use just scan codes with these.
  138.     ; Alternative use: force ascii keys to report out just scan codes.
  139.     ; Table format: high byte = scan code, low byte = ascii code. 
  140.     ; Contents are machine dependent.
  141. aliaskey dw    (14*scan)+bs        ; Backspace key [hi=scan, lo=ascii]
  142.     dw    (55*scan)+'*'        ; keypad asterisk
  143.     dw    (74*scan)+'-'        ; keypad minus
  144.     dw    (78*scan)+'+'        ; keypad plus
  145.     dw    (71*scan)+'7'        ; keypad numeric area
  146.     dw    (72*scan)+'8'
  147.     dw    (73*scan)+'9'
  148.     dw    (75*scan)+'4'
  149.     dw    (76*scan)+'5'
  150.     dw    (77*scan)+'6'
  151.     dw    (79*scan)+'1'
  152.     dw    (80*scan)+'2'
  153.     dw    (81*scan)+'3'
  154.     dw    (82*scan)+'0'
  155.     dw    (83*scan)+'.'
  156.     dw    (83*scan)+','        ; German keypad had comma vs dot
  157.     dw    (15*scan)+tab
  158.     dw    (28*scan)+cr        ; typewriter Enter key
  159. aliaslen equ    ($-aliaskey) shr 1    ; number of words in aliaskey table
  160.  
  161. kverbs    db    70            ; number of table entries below
  162.     mkeyw    'uparr',uparrw        ; independent of ordering and case!
  163.     mkeyw    'dnarr',dnarrw        ; mkeyw 'name',procedure entry point
  164.     mkeyw    'lfarr',lfarr
  165.     mkeyw    'rtarr',rtarr
  166.     mkeyw    'Gold',pf1
  167.     mkeyw    'PF1',pf1
  168.     mkeyw    'PF2',pf2
  169.     mkeyw    'PF3',pf3
  170.     mkeyw    'PF4',pf4
  171.     mkeyw    'KP0',kp0
  172.     mkeyw    'KP1',kp1
  173.     mkeyw    'KP2',kp2
  174.     mkeyw    'KP3',kp3
  175.     mkeyw    'KP4',kp4
  176.     mkeyw    'KP5',kp5
  177.     mkeyw    'KP6',kp6
  178.     mkeyw    'KP7',kp7
  179.     mkeyw    'KP8',kp8
  180.     mkeyw    'KP9',kp9
  181.     mkeyw    'kpminus',kpminus
  182.     mkeyw    'kpcoma',kpcoma
  183.     mkeyw    'kpenter',kpenter
  184.     mkeyw    'kpdot',kpdot
  185.     mkeyw    'decF6',decf6
  186.     mkeyw    'decF7',decf7
  187.     mkeyw    'decF8',decf8
  188.     mkeyw    'decF9',decf9
  189.     mkeyw    'decF10',decf10
  190.     mkeyw    'decF11',decf11
  191.     mkeyw    'decF12',decf12
  192.     mkeyw    'decF13',decf13
  193.     mkeyw    'decF14',decf14
  194.     mkeyw    'decHelp',dechelp
  195.     mkeyw    'decDo',decdo
  196.     mkeyw    'decF17',decf17
  197.     mkeyw    'decF18',decf18
  198.     mkeyw    'decF19',decf19
  199.     mkeyw    'decF20',decf20
  200.     mkeyw    'decFind',decfind
  201.     mkeyw    'decInsert',decinsert
  202.     mkeyw    'decRemove',decremove
  203.     mkeyw    'decSelect',decselect
  204.     mkeyw    'decPrev',decprev
  205.     mkeyw    'decNext',decnext
  206.     mkeyw    'termtype',vtans52
  207.     mkeyw    'reset',vtinit
  208.     mkeyw    'holdscrn',khold
  209.     mkeyw    'dnscn',dnwpg
  210.     mkeyw    'upscn',upwpg
  211.     mkeyw    'endscn',endwnd
  212.     mkeyw    'homscn',homwnd
  213.     mkeyw    'upone',upone
  214.     mkeyw    'dnone',dnone
  215.     mkeyw    'prtscn',trnprs
  216.     mkeyw    'dump',dmpscn
  217.     mkeyw    'modeline',trnmod
  218.     mkeyw    'break',sendbr
  219.     mkeyw    'lbreak',sendbl
  220.     mkeyw    'hangup',chang
  221.     mkeyw    'nethold',ubhold
  222.     mkeyw    'null',snull
  223.     mkeyw    'logon',klogon
  224.     mkeyw    'logoff',klogof
  225.     mkeyw    'terminalR',vtrmac
  226.     mkeyw    'terminalS',vtsmac
  227.     mkeyw    'DOS',cdos
  228.     mkeyw    'help',cquery
  229.     mkeyw    'status',cstatus
  230.     mkeyw    'exit',cquit
  231.  
  232.                     ; Initialization data.
  233. kbdinlst equ    this byte     ; Kermit IBM initialization time keyboard setup
  234.     mkeyw    '\kgold',scan+59    ; F1    mkeyw 'definition',keycode
  235.     mkeyw    '\kpf2',scan+60        ; F2
  236.     mkeyw    '\kpf3',scan+61        ; F3
  237.     mkeyw    '\kpf4',scan+62        ; F4
  238.     mkeyw    '\kkp0',scan+shift+90    ; VT100 keypad numeric area, SF7
  239.     mkeyw    '\kkp1',scan+shift+86    ; SF3
  240.     mkeyw    '\kkp2',scan+shift+87    ; SF4
  241.     mkeyw    '\kkp3',scan+shift+88    ; SF5
  242.     mkeyw    '\kkp4',scan+67        ; F9
  243.     mkeyw    '\kkp5',scan+68        ; F10
  244.     mkeyw    '\kkp6',scan+shift+84    ; SF1
  245.     mkeyw    '\kkp7',scan+63        ; F5
  246.     mkeyw    '\kkp8',scan+64        ; F6
  247.     mkeyw    '\kkp9',scan+65        ; F7
  248.     mkeyw    '\kkpenter',scan+shift+89 ; SF6
  249.     mkeyw    '\kkpcoma',scan+shift+85  ; SF2
  250.     mkeyw    '\kkpminus',scan+66    ; F8
  251.     mkeyw    '\kkpdot',scan+shift+91    ; SF8
  252.     mkeyw    '\kuparr',scan+72    ; VT100 cursor keys (arrows)
  253.     mkeyw    '\kdnarr',scan+80
  254.     mkeyw    '\klfarr',scan+75
  255.     mkeyw    '\krtarr',scan+77
  256.     mkeyw    '\kupscn',scan+73    ; PgUp  Kermit screen roll back keys
  257.     mkeyw    '\kdnscn',scan+81    ; PgDn
  258.     mkeyw    '\khomscn',scan+71    ; Home
  259.     mkeyw    '\kendscn',scan+79    ; End
  260.     mkeyw    '\kupone',scan+control+132 ; Ctrl PgUp    one line scrolls
  261.     mkeyw    '\kdnone',scan+control+118 ; Ctrl PgDn
  262.     mkeyw    '\kuparr',scan+enhanced+72 ; Enhanced kbd duplicate keys
  263.     mkeyw    '\kdnarr',scan+enhanced+80
  264.     mkeyw    '\klfarr',scan+enhanced+75
  265.     mkeyw    '\krtarr',scan+enhanced+77
  266.     mkeyw    '\kupscn',scan+enhanced+73 ; PgUp Kermit screen roll back keys
  267.     mkeyw    '\kdnscn',scan+enhanced+81 ; PgDn
  268.     mkeyw    '\khomscn',scan+enhanced+71 ; Home
  269.     mkeyw    '\kendscn',scan+enhanced+79    ; End
  270.     mkeyw    '\kupone',scan+control+enhanced+132 ;Ctrl PgUp one line scroll
  271.     mkeyw    '\kdnone',scan+control+enhanced+118 ; Ctrl PgDn
  272.     mkeyw    '\kmodeline',scan+74    ; Kermit toggle mode line  Keypad -
  273.     mkeyw    '\ktermtype',scan+alt+130 ; Kermit toggle terminal type  Alt -
  274.     mkeyw    '\kreset',scan+alt+131    ; Kermit reset terminal  Alt =
  275.     mkeyw    '\kprtscn',scan+control+114 ; Kermit toggle prn scrn  Ctrl *
  276.     mkeyw    '\kdump',scan+control+117 ; Kermit Dump Screen  Ctrl End
  277.     mkeyw    '*',scan+55        ; keypad asterisk
  278.     mkeyw    '*',scan+enhanced+55    ; Enhanced kbd keypad asterisk
  279.     mkeyw    '+',scan+78        ; keypad plus
  280.     mkeyw    '.',scan+shift+83    ; IBM numeric keypad
  281.     mkeyw    '0',scan+shift+82
  282.     mkeyw    '1',scan+shift+79
  283.     mkeyw    '2',scan+shift+80
  284.     mkeyw    '3',scan+shift+81
  285.     mkeyw    '4',scan+shift+75
  286.     mkeyw    '5',scan+shift+76
  287.     mkeyw    '6',scan+shift+77
  288.     mkeyw    '7',scan+shift+71
  289.     mkeyw    '8',scan+shift+72
  290.     mkeyw    '9',scan+shift+73
  291.     mkeyw    tab,scan+15        ; regular Tab key, made special
  292.     mkeyw    cr,scan+28        ; typewriter Enter key
  293.     mkeyw    cr,scan+enhanced+cr    ; Enhanced kbd grey Enter key
  294.     mkeyw    lf,scan+enhanced+control+lf ; Enhanced grey Control Enter
  295.     mkeyw    '/',scan+enhanced+'/'    ; Enhanced kbd grey foward slash
  296.     mkeyw    '\0',scan+control+3    ; Control at-sign sends null
  297.     mkeyw    '\0',scan+control+shift+3 ; Control Shift at-sign sends null
  298.     mkeyw    '\x7f',scan+83        ; Del key sends DEL
  299.     mkeyw    '\x7f',scan+enhanced+83 ; Enhanced duplicate DEL sends DEL
  300.     mkeyw    '\x7f',scan+14        ; Backspace key sends DEL
  301.     mkeyw    '\kexit',scan+alt+45    ; Exit connect mode  Alt X
  302.     mkeyw    '\kstatus',scan+alt+31    ; Connect mode status  Alt S
  303.     mkeyw    '\kbreak',scan+alt+48    ; Send a Break  Alt B
  304.     mkeyw    '\kbreak',scan+control+0; Control-Break sends a Break too
  305.     mkeyw    '\khelp',scan+alt+35    ; Connect mode drop down menu  Alt H
  306.     dw    0        ; end of table marker
  307.  
  308.                     ;** LK250 support begin
  309. kb250lst equ    this byte             ; Extensions for DEC LK250 keyboard
  310.     mkeyw    escape,scan+104        ; Compose maps to ESC
  311.         mkeyw   '\x7f',scan+14          ; Backspace key sends DEL
  312.         mkeyw   bs,scan+shift+14        ; Shift-Backspace key sends BS
  313.     mkeyw    cr,scan+28        ; Return key sends CR
  314.     mkeyw    lf,scan+shift+28    ; Shift-Return sends LF
  315.     mkeyw    tab,scan+15        ; Tab sends TAB
  316.                     ; the top-row function keys
  317.     mkeyw    '\kholdscrn',scan+59    ; DEC Hold
  318.     mkeyw    '\kprtscn',scan+60    ; DEC Print Screen
  319. ;;;;    mkeyw    '{\{kstatus}\{kexit}}',scan+61    ; DEC Set-Up
  320.     mkeyw    '\kbreak',scan+63    ; DEC Break
  321.     mkeyw    '\kdecF6',scan+64    ; DEC F6
  322.     mkeyw    '\kdecF7',scan+65    ; DEC F7
  323.     mkeyw    '\kdecF8',scan+66    ; DEC F8
  324.     mkeyw    '\kdecF9',scan+67    ; DEC F9
  325.     mkeyw    '\kdecF10',scan+68    ; DEC F10
  326.     mkeyw    '\kdecF11',scan+95    ; DEC F11
  327.     mkeyw    '\kdecF12',scan+96    ; DEC F12
  328.     mkeyw    '\kdecF13',scan+97    ; DEC F13
  329.     mkeyw    '\kdecF14',scan+98    ; DEC F14
  330.     mkeyw    '\kdecHelp',scan+99    ; DEC Help
  331.     mkeyw    '\kdecDo',scan+100    ; DEC DO
  332.     mkeyw    '\kdecF17',scan+101    ; DEC F17
  333.     mkeyw    '\kdecF18',scan+102    ; DEC F18
  334.     mkeyw    '\kdecF19',scan+103    ; DEC F19
  335.     mkeyw    '\kdecF20',scan+84    ; DEC F20
  336.                     ; the cursor/select cluster
  337.     mkeyw    '\kdecFind',scan+85    ; DEC Find
  338.     mkeyw    '\kdecInsert',scan+86    ; DEC Insert Here
  339.     mkeyw    '\kdecRemove',scan+87    ; DEC Remove
  340.     mkeyw    '\kdecSelect',scan+88    ; DEC Select
  341.     mkeyw    '\kdecPrev',scan+89    ; DEC Prev
  342.     mkeyw    '\kdecNext',scan+90    ; DEC Next
  343.     mkeyw    '\kuparr',scan+91    ; up arrow
  344.     mkeyw    '\klfarr',scan+92    ; left arrow
  345.     mkeyw    '\krtarr',scan+93    ; right arrow
  346.     mkeyw    '\kdnarr',scan+94    ; down arrow
  347.                     ; the DEC editing keypad
  348.     mkeyw    '\kgold',scan+106    ; F1
  349.     mkeyw    '\kpf2',scan+107    ; F2
  350.     mkeyw    '\kpf3',scan+108    ; F3
  351.     mkeyw    '\kpf4',scan+109    ; F4
  352.     mkeyw    '\kkp7',scan+shift+71    ; KP7
  353.     mkeyw    '\kkp8',scan+shift+72    ; KP8
  354.     mkeyw    '\kkp9',scan+shift+73    ; KP9
  355.     mkeyw    '\kkpminus',scan+74    ; KP-
  356.     mkeyw    '\kkp4',scan+shift+75    ; KP4
  357.     mkeyw    '\kkp5',scan+shift+76    ; KP5
  358.     mkeyw    '\kkp6',scan+shift+77    ; KP6
  359.     mkeyw    '\kkpcoma',scan+78    ; KP,
  360.     mkeyw    '\kkp1',scan+shift+79    ; KP1
  361.     mkeyw    '\kkp2',scan+shift+80    ; KP2
  362.     mkeyw    '\kkp3',scan+shift+81    ; KP3
  363.     mkeyw    '\kkpenter',scan+105    ; keypad enter
  364.     mkeyw    '\kkpenter',scan+shift+105 ; keypad enter
  365.     mkeyw    '\kkp0',scan+shift+82    ; KP0
  366.     mkeyw    '\kkpdot',scan+shift+83    ; KP.
  367.                     ; some useful Kermit keys
  368.         mkeyw   '\kupscn',scan+alt+89   ; PgUp  Kermit screen roll back keys
  369.         mkeyw   '\kdnscn',scan+alt+90   ; PgDn
  370.         mkeyw   '\khomscn',scan+alt+85  ; Home
  371.         mkeyw   '\kendscn',scan+alt+88  ; End
  372.         mkeyw   '\kupone',scan+control+89 ; Ctrl PgUp  one line scrolls
  373.         mkeyw   '\kdnone',scan+control+90 ; Ctrl PgDn
  374.         mkeyw   '\kexit',scan+alt+45    ; Exit connect mode  Alt X
  375.         mkeyw   '\kstatus',scan+alt+31  ; Connect mode status  Alt S
  376.         mkeyw   '\kbreak',scan+alt+48   ; Send a Break  Alt B
  377.         mkeyw   '\kbreak',scan+control+108 ; Control-Break sends a Break too
  378.         mkeyw   '\khelp',scan+alt+35    ; Connect mode drop down menu  Alt H
  379.         mkeyw   '\ktermtype',scan+alt+130 ; Kermit toggle terminal type  Alt -
  380.         mkeyw   '\kreset',scan+alt+131  ; Kermit reset terminal  Alt =
  381.         mkeyw   '\kprtscn',scan+control+109 ; Kermit toggle prn scrn  Ctrl *
  382.         mkeyw   '\kdump',scan+control+88 ; Kermit Dump Screen  Ctrl End
  383.     dw    0            ; end of table marker
  384. got250    db    0            ;** LK250 present if non-zero
  385.                     ;** LK250 support end
  386. kbcodes    dw    80h            ; keyboard read codes, 80h=not inited
  387. data    ends
  388.  
  389. ;            Documentation
  390. ;Translating a key:
  391. ;   The translator is called to obtain keyboard input; it sends characters to
  392. ; the serial port through standard controlled echo procedures or invokes
  393. ; named procedures. It returns carry clear when its operation is completed
  394. ; for normal actions and carry set when Connect mode must be exited. When
  395. ; Connect mode is exited the just read char should be passed in Kbdflg 
  396. ; to msster.asm for invoking actions such as Status, send a break,
  397. ; quit connect mode; system dependent procedure Term is responsible for this. 
  398. ;
  399. ;  Principal procedures are -
  400. ;    msuinit        Initializes keyboard translator in this file when
  401. ;            Kermit first begins. Installs dfkey and shkey as the
  402. ;            procedures used for Set Key and Show Key. Sys Indep.
  403. ;            Called from msx or msy init procs. System Independent.
  404. ;    keybd        Performs the translation, outputs chars to the serial
  405. ;            port or invokes a Kermit action routine. Sys Indep.
  406. ;    dfkey        Defines a key's translation. Reads command line
  407. ;            via Kermit's command parser comnd. System Independent.
  408. ;    shkey        Shows translation of a key. Requests user to push
  409. ;            selected key. System Independent.
  410. ;
  411. ;    kbdinit        optional. Initializes the translation tables when
  412. ;            Kermit starts up. Called by msuinit. System Dependent.
  413. ;    getkey        Performs the keyboard read and returns results in
  414. ;            a standardized system independent format. Sys Depend.
  415. ;    postkey        called by active translator after obtaining a keycode.
  416. ;            Used to provide extra local actions (keyclick) only
  417. ;            in Connect mode (not during Set/Show key commands).
  418. ;            Called by keybd. System dependent.
  419. ; Supporting system independent procedures are -
  420. ; shkfre (show string free space), tstkeyw (finds user's keyword in the verb
  421. ; table), insertst (insert string in buffer), remstr (delete string in buffer).
  422. ;
  423. ;   System dependent procedure Getkey reads a keycode (usually via a Bios
  424. ; call). On IBM compatible machines this yields <ah=scan code, al=ascii>
  425. ; for ordinary keys, or <ah=scan code, al=0> for special keys such as F1,
  426. ; or <ah=0, al=###> when Alt### is used.
  427. ; For any system, the canonical output form is the key's code in Keycode.
  428. ; Place the ascii code (or scan code if none) in byte Keycode and ancillary
  429. ; info (shift states plus marker bit for scan codes) in byte Keycode + 1.
  430. ; 
  431. ;   Table Aliaskey is a list of scan code/ascii codes for keys which appear
  432. ; more than once on a keyboard. This list is examined to distinguish such
  433. ; aliased keys (those on an auxillary keypad) from an ordinary ascii key,
  434. ; and the aliased key is then referenced by its scan code rather than by
  435. ; the ordinary ascii code. Aliaskey is machine and keyboard dependent.
  436. ;
  437. ;    Procedure Keybd calls Getkey for the Keycode, checks list of translatable
  438. ; keys Keylist, and then either sends an ascii string (one or more characters)
  439. ; or invokes a Kermit action verb. List Dirlist indicates what kind of 
  440. ; translation to do. Keybd is system independent but may contain system
  441. ; dependent special actions such as echoing keyclicks. Keybd calls system
  442. ; dependent procedure Postkey just after calling getkey so local actions
  443. ; such as keyclicks can be activated only during Connect mode operations.
  444. ;
  445. ;    Keylist is a packed but unordered list of 16 bit keycodes which need
  446. ; translation. The lower order byte holds a key code (ascii char or scan code)
  447. ; while the high byte holds a scan code marker bit (0 if ascii code in low
  448. ; byte) plus any ancillary keyboard information such as Control/Shift/Alt/Meta
  449. ; keys being held down; these are of use in Show Key presentations.
  450. ;    Dirlist parallels Keylist to provide the kind of translation, verb or
  451. ; string, in the two highest bits with the other bits holding either
  452. ; a single new replacement character or the item number in lists of verbs
  453. ; or strings. If neither verb nor strng type bits are set in a dirlist
  454. ; word then the translation is a single new character held in the lower
  455. ; eight bits of that dirlist word.
  456. ;
  457. ;    The number of key translations is assembly constant Maxkeys (def 128).
  458. ;    The maximum number of strings is assembly constant Maxstngs (def 64).
  459. ;    The maximum number of verbs is 256 and is set by building table Kverbs.
  460. ;
  461. ;   For verbs, use the Item number from the Director table Dirlist to select
  462. ; a procedure offset from the structured list Kverbs and jump to that offset.
  463. ; Most verb procedures return carry clear to stay within Connect mode.
  464. ; Verbs requiring exiting Connect mode return carry set and may set byte
  465. ; Kbdflg to a char code which will be read by msster.asm for activating a
  466. ; transient Kermit action such as send a break (Kbdflg = 'b').
  467. ; Kbdflg is stored in msster.asm (as zero initially, meaning ignore it).
  468. ; Action verb procedures are normally located in a system dependent file.
  469. ;
  470. ;   For multi-char strings, use Item number from Director table Dirlist to
  471. ; select a pointer to a string. The list of string pointers is Sptable
  472. ; (string pointer table) which holds the offset in the data segment of the
  473. ; strings stored in buffer Stbuf. In stbuf strings are held as: one byte of
  474. ; length of following text and then the text itself (permits embedded nulls).
  475. ;  Use Chrout to send each string character, and finally return from Keybd
  476. ; with carry clear.
  477. ;
  478. ;   For single character replacements obtain the new character from the lower
  479. ; order byte of Director table Dirlist. If the character is Kermit's present
  480. ; escape character return from Keybd carry set to leave connect mode.
  481. ; Otherwise, send the character via Chrout and return from Keybd carry clear.
  482.  
  483. ; Keylist table format:
  484. ;    7 bits   1 bit   8 bits
  485. ; +----------+----+------------+ scan bit = 1 if key's code is non-ascii
  486. ; | aux info |scan| key's code | aux info = system dependent, used only to
  487. ; +----------+----+------------+            help identify key
  488. ;
  489. ; Dirlist table format          v s    meaning
  490. ;   1   1      14 bits         0 0    copy out one byte translation
  491. ; +---+---+--------------------+  1 0    copy out multi-char string number Item
  492. ; | v | s | item # or new char |  0 1    do action verb number Item
  493. ; +---+---+--------------------+  1 1    (not used)
  494. ;
  495. ; Table kverbs is organized by macro mkeyw as -
  496. ;    kverbs    db    number of table entries
  497. ;    (each entry is in the form below:)
  498. ;        db    number of bytes in verbname
  499. ;        db    'verbname'        variable length
  500. ;        db    '$'            for printing
  501. ;        dw    value            offset of procedure
  502. ;
  503. ;
  504. ;   Dfkey defines a key to be itself (undefines it) or a single replacement
  505. ; character or a character string or a Kermit action verb. Dfkey requires
  506. ; a command line so that it may be invoked by Take files but can be forced
  507. ; to prompt an interactive user to push a key. Syntax is discussed below.
  508. ; Note that redefined keys have their old definitions cleared so that
  509. ; old string space is reclaimed automatically.
  510. ;
  511. ;   Shkey displays a key's definition and the user is asked to push the
  512. ; selected key. The free space for strings is always shown afterward. See
  513. ; below for syntax.
  514. ;
  515. ;   Kbdinit is an optional routine called when Kermit starts up. It fills in
  516. ; the translation tables with desirable default values to save having to
  517. ; use long mskermit.ini files. The default values are stored in a structured
  518. ; table similar to (but not the same as) Dfkey's command lines; the keycode
  519. ; values are preset by hand to 16 bit numbers.
  520.  
  521. ;Defining a key:
  522. ; Command is SET KEY <key ident><whitespace><definition>
  523. ;
  524. ; <key ident> is
  525. ;        a single ordinary ascii char or
  526. ;        the numerical equivalent of an ascii char or
  527. ;        a Scan Code written as a number or
  528. ;        keyword SCAN followed by a number.
  529. ;        ?    Displays help message.
  530. ;    Numbers and Binary codes are of the form
  531. ;        \123    a decimal number
  532. ;        \o456    an octal number        base letters o, d, x can be
  533. ;        \d213    a decimal number    upper or lower case
  534. ;        \x0d    a hex number
  535. ;        \{b###}  braces around above material following slash.
  536. ;
  537. ; <whitespace> is one or more spaces and or tabs.
  538. ;
  539. ; <definition> is
  540. ;    missing altogether which "undefines" a key.
  541. ;    \Kverb        for a Kermit action verb; upper or lower case K is ok
  542. ;    \{Kverb}    ditto. Verb is the name of an action verb.
  543. ;    text        a string with allowed embedded whitespace and embedded
  544. ;            binary chars as above. This kind of string may not
  545. ;            commence with sequences \K or \{K; use braces below.
  546. ;    {text}        string confined to material within but excluding
  547. ;            the braces. Note, where the number of opening braces
  548. ;            exceeds the number of closing braces the end of line
  549. ;            terminates the string: {ab{}{{c}d ==> ab{}{{c}d
  550. ;            but  {ab}{{c}d ==> ab.
  551. ;    ?        Displays help message and lists all action verbs.
  552. ;
  553. ;    If Set Key is given interactively, as opposed to within a Take
  554. ;    file, the system will prompt for inputs if none is on the command
  555. ;    line. The response to Push key to be defined cannot be edited.
  556. ;
  557. ;    Text which reduces to a single replacement character is put into a
  558. ;    table separate from the multi-character strings (maxstng of these).
  559. ;    A key may be translated into any single 8 bit code.
  560. ;    
  561. ;    Comments can follow a Kermit action verb or a braced string; no
  562. ;    semicolon is required since all are stripped out by the Take file
  563. ;    reader before the defining text is seen by SET KEY.
  564. ;
  565. ;    The current Kermit escape character cannot be translated without
  566. ;    subtrafuge.
  567. ;
  568. ;    Examples:
  569. ;        Set Key q z
  570. ;                makes key q send character z
  571. ;        Set Key \7 \27[0m
  572. ;                makes key Control G send the four byte
  573. ;                string  ESC [ 0 m
  574. ;        Set Key q
  575. ;                undefines key q so it sends itself (q) again.
  576. ;        Set Key \2349 \kexit
  577. ;                defines IBM Alt-X to invoke the leave connect
  578. ;                mode verb "exit" (Kermit's escape-char ^] C).
  579. ;        Set Key \x0c Login \{x0d}myname\{x0d}mypass\x0d
  580. ;                defines Control L to send the string
  581. ;                Login <cr>myname<cr>mypass<cr>
  582. ;
  583. ; Alternative Set Key syntax for backward compatibility with previous versions
  584. ;    The same forms as above except the key identification number must
  585. ;    be decimal and must Not have a leading backslash. Example:
  586. ;    Set Key Scan 59 This is the F1 key
  587. ;
  588. ;    If the definition is omitted it may be placed on the following line;
  589. ;    if that line is also empty the key is undefined (defined as Self).
  590. ;    A warning message about obsolete syntax will be given followed by
  591. ;    the key's modern numerical value and new definition. Only "special"
  592. ;    keys (those not producing ascii codes) are compatible with this
  593. ;    translator.
  594. ;
  595. ;Showing a key:
  596. ; Command is SHOW KEY <cr>
  597. ; System prompts user to press a key and shows the definition plus the
  598. ; free space for strings. Query response results in showing all definitions.
  599. ;            End Documentation
  600.  
  601. code    segment    public 'code'
  602.         ; system independent external items
  603.     extrn    comnd:near, prompt:near, iseof:near    ; in msscmd
  604.     extrn    strlen:near                ; in mssfil
  605.     extrn    cnvlin:near, katoi:near, decout:near    ; in msster
  606.         ; system dependent external items
  607.     extrn    beep:near, khold:near, ubhold:near    ; in msxibm &msyibm
  608.     extrn    vclick:near                ; in mszibm
  609.         ; these are system dependent action verbs, in msxibm & msyibm 
  610.     extrn    uparrw:near, dnarrw:near, rtarr:near, lfarr:near
  611.     extrn    pf1:near, pf2:near, pf3:near, pf4:near,    kp0:near, kp1:near
  612.     extrn    kp2:near, kp3:near, kp4:near, kp5:near, kp6:near, kp7:near
  613.     extrn    kp8:near, kp9:near, kpminus:near, kpcoma:near, kpenter:near
  614.     extrn    kpdot:near, decf6:near, decf7:near, decf8:near, decf9:near
  615.     extrn    decf10:near, decf11:near, decf12:near, decf13:near
  616.     extrn    decf14:near, dechelp:near, decdo:near, decf17:near
  617.     extrn    decf18:near, decf19:near, decf20:near, udkclear:near
  618.     extrn    decfind:near, decinsert:near, decremove:near
  619.     extrn    decselect:near, decprev:near, decnext:near
  620.     extrn    chrout:near, cstatus:near, cquit:near, cquery:near
  621.     extrn    vtans52:near, vtinit:near, dnwpg:near, upwpg:near
  622.     extrn    endwnd:near, homwnd:near, upone:near, dnone:near, trnprs:near
  623.     extrn    trnmod:near, sendbr:near, sendbl:near, dmpscn:near, snull:near
  624.     extrn    chang:near, klogon:near, klogof:near, cdos:near
  625.     extrn    vtrmac:near, vtsmac:near, cplatin:near, nrc2cp:near
  626.     extrn    cpdecsg:near
  627.     assume    cs:code, ds:data, es:data
  628.  
  629. ; Begin system independent Keyboard Translator code
  630.  
  631. ; MSUINIT performs Kermit startup initialization for this file.
  632. ; Note, shkadr and stkadr are pointers tested by Set/Show Key calls. If they
  633. ; are not initialized here then the older Set/Show Key procedures are called.
  634. MSUINIT    PROC    NEAR            ; call from msx/msy init code
  635.     call    kbdinit            ; optional: init translator tables
  636.     mov    shkadr,offset shkey    ; declare keyboard translator present
  637.     mov    stkadr,offset dfkey    ; via Show and Set Key proc addresses
  638.     ret
  639. MSUINIT    ENDP
  640.  
  641. ; Call Keybd to read a keyboard char (just returns carry clear if none) and
  642. ; 1) send the replacement string (or original char if not translated)
  643. ;    out the serial port, or
  644. ; 2) execute a Kermit action verb.
  645. ; Returns carry set if Connect mode is to be exited, else carry clear.
  646. ; Modifies registers ax and bx. 
  647. KEYBD    PROC    NEAR            ; active translator
  648.     mov    ttyact,1        ; doing single char output
  649.     cmp    stringcnt,0        ; any leftover string chars?
  650.     je    keybd0            ; e = no
  651.     jmp    keyst2            ; yes, finish string
  652. keybd0:    call    getkey            ; read keyboard
  653.     jnc    keybd1            ; nc = data available
  654.     jmp    keybdx            ; else just return carry clear
  655. keybd1:    call    postkey            ; call system dependent post processor
  656.     cmp    nkeys,0            ; is number of keys defined = 0?
  657.     jz    keybd3            ; z = none defined
  658.     push    di            ; search keylist for this keycode
  659.     push    cx            ; save some registers    
  660.     push    es
  661.     mov    di,offset keylist    ; list of defined keycode words
  662.     mov    ax,keycode        ; present keycode
  663.     mov    cx,nkeys        ; number of words to examine
  664.     push    ds
  665.     pop    es            ; make es:di point to data segment
  666.     cld
  667.     repne    scasw            ; find keycode in list
  668.     pop    es            ; restore regs
  669.     pop    cx
  670.     je    keybd1b            ; e = found, work with present di
  671.     pop    di            ; restore original di
  672.     test    keycode,scan        ; is this a scan code?
  673.     jz    keybd3            ; z = no, it's ascii, use al as char
  674.     call    beep            ; say key is a dead one
  675.     clc
  676.     ret                ; and exit with no action
  677.  
  678. keybd1b:sub    di,2            ; correct for auto increment
  679.     sub    di,offset keylist    ; subtract start of list ==> listptr
  680.     mov    ax,dirlist[di]        ; ax = contents of director word
  681.     pop    di            ; restore original di
  682.                     ; dispatch on Director code
  683.     test    ax,verb            ; verb only?
  684.     jnz    keyvb            ; e = yes
  685.     test    ax,strng        ; multi-char string only?
  686.     jnz    keyst            ; e = yes, else single char & no xlat.
  687.                     ;
  688.                     ; do single CHAR output (char in al)
  689. keybd3:    cmp    al,trans.escchr        ; Kermit's escape char?
  690.     je    keybd3a            ; e = yes, handle separately
  691.     call    xltkey            ; do character set translation
  692.     call    chrout            ; transmit the char
  693.     clc                ; return success
  694.     ret
  695. keybd3a:stc                ; set carry for jump to Quit
  696.     ret
  697.  
  698. keyvb:    and    ax,not(verb+strng)    ; VERB (ax=index, remove type bits)
  699.     mov    bx,offset kverbs    ; start of verb table
  700.     cmp    al,byte ptr [bx]    ; index > number of entries?
  701.     jae    keybdx            ; ae = illegal, indices start at 0
  702.     inc    bx            ; bx points to first entry
  703.     push    cx            ; save reg
  704.     mov    cx,ax            ; save the index in cx
  705.     inc     cx            ; counter, indices start at 0
  706. keyvb1:    mov    al,byte ptr [bx]    ; cnt value
  707.     xor    ah,ah
  708.     add    ax,4            ; skip text and '?' and value word
  709.     add    bx,ax            ; look at next slot
  710.     loop    keyvb1            ; walk to correct slot
  711.     sub    bx,2            ; backup to value field
  712.     pop    cx            ; restore reg
  713.     mov    bx,[bx]            ; get value field of this slot
  714.     cmp    bx,0            ; jump address defined?
  715.     je    keybdx            ; e = no, skip the action
  716.     jmp    bx            ; perform the function
  717.  
  718. keyst:    and    ax,not(verb+strng)    ; STRING (ax=index, remove type bits)
  719.     shl    ax,1            ; convert to word index
  720.     push    si            ; save working reg
  721.     mov    si,ax            ; word subscript in table
  722.     mov    si,sptable[si]        ; memory offset of selected string
  723.     xor    cx,cx            ; init string length to null
  724.     cmp    si,0            ; is there a string pointer present?
  725.     je    keyst1            ; e = no, skip operation
  726.     cld                ; scan forward
  727.     mov    cl,byte ptr [si]    ; get string length byte
  728.     inc    si
  729. keyst1:    mov    stringcnt,cx
  730.     mov    stringptr,si
  731.     pop    si
  732.     jcxz    keybdx            ; z = null length
  733.  
  734. keyst2:    push    si
  735.     mov    si,stringptr        ; pointer to next string char
  736.     cld
  737.     lodsb                ; get new string char into al
  738.     pop    si
  739.     dec    stringcnt        ; string chars remaining
  740.     inc    stringptr
  741.     cmp    stringcnt,0        ; end of the string?
  742.     jne    keyst3            ; ne = no
  743.     mov    ttyact,0        ; pretend not single char output
  744. keyst3:    call    keysv            ; scan for embedded verbs
  745.     jc    keyst4            ; c = not found, al has string char
  746.     jmp    bx            ; perform the verb (bx = address)
  747. keyst4:    call    xltkey            ; do character set translation
  748.     jmp    chrout            ; send out the char in al
  749.  
  750. keybdx:    clc                ; return success (nothing to do)
  751.     ret
  752. KEYBD    ENDP
  753.  
  754. ; Scan for keyboard verbs embedded in outgoing string. If found update
  755. ; string pointer and count to just beyond the verb and return action routine
  756. ; address in bx with carry clear. If failure return carry set and no change.
  757.  
  758. keysv    proc    near
  759.     push    ax
  760.     push    si
  761.     push    di
  762.     cmp    al,'\'            ; escape?
  763.     jne    keysv7            ; ne = no
  764.     mov    cx,stringcnt        ; chars remaining
  765.     mov    si,stringptr        ; address of next char to read
  766.     mov    brace,0            ; assume not using braces
  767.     cmp    byte ptr [si],braceop    ; starts with \{?
  768.     jne    keysv1            ; ne = no
  769.     inc    si            ; skip the opening brace
  770.     dec    cx
  771.     mov    brace,bracecl        ; expect closing brace
  772. keysv1:    cmp    byte ptr [si],'K'    ; starts with \{K or \K?
  773.     je    keysv2            ; e = yes
  774.     cmp    byte ptr [si],'k'    ; starts as \{k or \k?
  775.     jne    keysv7            ; ne = no, then it's a string
  776. keysv2:    inc    si            ; yes, skip the K too
  777.     dec    cx
  778.     mov    di,offset tranbuf    ; copy verb name to this work buffer
  779.     xor    ax,ax
  780.     mov    [di],ax            ; init the buffer to empty
  781. keysv3:    cld
  782.     jcxz    keysv4            ; z = no more string chars
  783.     lodsb                ; scan til closing brace or w/s or end
  784.     dec    cx
  785.     cmp    al,brace        ; closing brace?
  786.     je    keysv4            ; e = yes
  787.     cmp    al,spc            ; white space or control char?
  788.     jbe    keysv3            ; be = yes
  789.     mov    [di],ax            ; copy to tranbuf and terminate
  790.     inc    di
  791.     jmp    short keysv3
  792. keysv4:    push    si            ; save input reading position
  793.     mov    si,offset tranbuf    ; where verb starts (needs si)
  794.     call    tstkeyw            ; find keyword, bx = action routine
  795.     pop    si
  796.     jc    keysv7            ; c = no such verb
  797.     cmp    brace,0            ; need to end on a brace?
  798.     je    keysv6            ; e = no
  799.     dec    si            ; break position
  800.     inc    cx
  801.     cld
  802. keysv5:    jcxz    keysv6            ; z = no more string characters
  803.     lodsb                ; read string char
  804.     dec    cx
  805.     cmp    al,brace        ; the brace?
  806.     jne    keysv5            ; ne = no, repeat until it is found
  807. keysv6:    mov    stringptr,si        ; where we finished+1
  808.     mov    stringcnt,cx        ; new count of remaining chars
  809.     pop    di
  810.     pop    si            ; original si, starting place
  811.     pop    ax            ; original ax
  812.     clc
  813.     ret
  814. keysv7:    pop    di            ; verb not found
  815.     pop    si
  816.     pop    ax
  817.     stc
  818.     ret
  819. keysv    endp
  820. ; SET KEY - define a key   (procedure dfkey)
  821. ; SET KEY <key ident><whitespace><new meaning>
  822. ; Call from Kermit level. Returns as ret if failure or as rskp if success.
  823. ;  
  824. DFKEY    PROC    NEAR            ; define a key as a verb or a string
  825.     mov    keycode,0        ; clear keycode
  826.     mov    oldform,0        ; say no old form Set Key yet
  827.     or    byte ptr kbcodes,80h    ; say kbcodes not-initiated
  828.     mov    dx,offset tranbuf    ; our work space
  829.     mov    word ptr tranbuf,0    ; insert terminator
  830.     mov    bx,offset dfhelp1    ; first help message
  831.     mov    ah,cmword        ; parse a word
  832.     call    comnd            ; get key code or original ascii char
  833.     mov    al,taklev        ; reading from Take file
  834.     mov    msutake,al        ; save here
  835.     or    ah,ah            ; any text given?
  836.     jnz    dfkey12            ; nz = yes, so don't consider prompts
  837.                     ; interactive key request
  838.     cmp    taklev,0        ; in a Take file?
  839.     je    dfkey10            ; e = no, prompt for keystroke
  840.     jmp    dfkey0            ;  else say bad syntax
  841. dfkey10:mov    ah,prstr
  842.     mov    dx,offset dfaskky    ; ask for key to be pressed
  843.     int    dos
  844. dfkey11:call    getkey            ; read key ident from keyboard
  845.     jc    dfkey11            ; c = no response, wait for keystroke
  846.     mov    ah,prstr        ; display cr/lf
  847.     mov    dx,offset crlf
  848.     int    dos
  849.     call    shkey0            ; show current definition (in SHKEY)
  850.     jmp    dfkey1e            ; prompt for and process definition
  851.  
  852. dfkey12:                ; Look for word SCAN and ignore it
  853.     mov    dx,word ptr tranbuf    ; get first two characters
  854.     or    dx,2020h        ; map upper to lower case
  855.     cmp    dx,'cs'            ; first two letters of word "scan"?
  856.     je    dfkey            ; e = yes, skip the word
  857.     cmp    dx,'lc'            ; first two letters of word "clear"?
  858.     je    dfkey15            ; e = yes, reinit keyboard [2.31]
  859.     cmp    dx,'fo'            ; first two letters of "off"
  860.     je    dfkey13            ; e = yes, use DOS keyboard calls
  861.     cmp    dx,'no'            ; first two letters of "on"
  862.     je    dfkey14            ; e = yes, use standard kbd calls
  863.     cmp    ah,1            ; number of characters received
  864.     ja    dfkey1            ; a = more than one, decode
  865.     mov    ah,byte ptr tranbuf    ; get the single char
  866.     mov    byte ptr keycode,ah    ; store as ascii keycode
  867.     jmp    dfkey1b            ; go get definition
  868.  
  869. dfkey13:mov    dosflg,0ffh        ; set DOS keyboard read flag
  870.     jmp    short dfkey14a
  871. dfkey14:mov    dosflg,0        ; clear DOS keyboard read flag
  872. dfkey14a:mov    ah,cmeol        ; get end of line confirmation
  873.     call    comnd
  874.     ret
  875.  
  876. dfkey15:mov    ah,cmeol
  877.     call    comnd            ; confirm request before proceeding
  878.     jnc    dfkeyc            ; nc = success
  879.     ret                ; failure
  880.  
  881. dfkey0:    mov    dx,offset dfhelp1    ; say bad definition command
  882.     mov    ah,prstr
  883.     int    dos
  884.     stc                ; failure
  885.     ret
  886.  
  887. dfkeyc:                    ; CLEAR key defs, restore startup defs
  888.     mov    cx,maxkeys        ; size of keycode tables
  889.     push    es            ; save register
  890.     push    ds
  891.     pop    es            ; make es point to data segment
  892.     mov    ax,0            ; null, value to be stored
  893.     mov    di,offset dirlist    ; director table
  894.     cld
  895.     rep    stosw            ; clear it
  896.     mov    cx,maxkeys
  897.     mov    di,offset keylist    ; keycode table
  898.     rep    stosw            ; clear it
  899.     mov    cx,maxstng
  900.     mov    di,offset sptable    ; string pointer table
  901.     rep    stosw            ; clear it
  902.     pop    es            ; recover register
  903.     mov    strmax,offset stbuf    ; clear string buffer, free space ptr
  904.     mov    stbuf,0            ; first element of buffer 
  905.     mov    nkeys,0            ; clear number of defined keys
  906.     call    msuinit            ; restore startup definitions
  907.     clc                ; success
  908.     ret
  909.                     ; Multi-char key identification
  910. dfkey1:    mov    si,offset tranbuf    ; point to key ident text
  911.     cmp    byte ptr [si],'0'    ; is first character numeric?
  912.     jb    dfkey1a            ; b = no
  913.     cmp    byte ptr [si],'9'    ; in numbers?
  914.     ja    dfkey1a            ; a = no
  915.     mov    keycode,scan        ; setup keycode for scan value
  916.     mov    dx,si            ; get length of string in cx
  917.     call    strlen
  918.     push    ds
  919.     pop    es            ; make es point to data segment
  920.     push    si
  921.     add    si,cx            ; point at string terminator
  922.     mov    di,si
  923.     inc    di            ; place to store string (1 byte later)
  924.     inc    cx            ; include null terminator
  925.     std                ; work backward
  926.     rep    movsb            ; move string one place later
  927.     cld
  928.     pop    si
  929.     mov    byte ptr [si],'\'    ; make ascii digits into \nnn form
  930.     mov    oldform,0ffh        ; set old form flag
  931.     mov    dx,offset kwarnmsg    ; tell user this is old form
  932.     mov    ah,prstr
  933.     int    dos
  934. dfkey1a:call    katoi            ; convert ascii number to binary in ax
  935.     jc    dfkey0            ; c = no number converted
  936.     or    keycode,ax        ; store in keycode
  937.  
  938. dfkey1b:                ; Get Definition proper
  939.     test    oldform,0ffh        ; old form Set Key active?
  940.     jz    dfkey1f            ; z = no
  941.     mov    bx,offset tranbuf    ; get new definition on main cmd line
  942.     mov    word ptr [bx],0        ; insert terminator
  943.     mov    dx,offset dfhelp2    ; help for definition of key
  944.     mov    ah,cmline        ; read rest of line into tranbuf
  945.     call    comnd            ; allow null definitions
  946.     or    ah,ah            ; char count zero?
  947.     jz    dfkey1e            ; z = zero, prompt for definition
  948.     jmp    dfkey1g            ; process definition
  949.  
  950. dfkey1e:mov    ah,prstr
  951.     mov    dx,offset crlf
  952.     int    dos
  953.     mov    dx,offset dfaskdf    ; prompt for definition string
  954.      call    prompt            ; Kermit prompt routine
  955.     mov    comand.cmcr,1        ; permit bare carriage returns
  956.     mov    comand.cmwhite,1    ; allow leading whitespace
  957. dfkey1f:mov    bx,offset tranbuf    ; get new definition
  958.     mov    word ptr [bx],0        ; insert terminator
  959.     mov    dx,offset dfhelp2    ; help for definition of key
  960.     mov    ah,cmline        ; read rest of line into tranbuf
  961.     call    comnd
  962.     jc    dfkey1x            ; exit now on ^C from user
  963.     cmp    comand.cmcr,0        ; prompting for definition?
  964.     je    dfkey1g            ; e = no, trim leading whitespace
  965.     mov    comand.cmcr,0        ; turn off allowance for bare c/r's
  966.     jmp    dfkey2            ; interactive, allow leading whitespace
  967. dfkey1x:ret                ; failure exit
  968.  
  969. dfkey1g:xchg    ah,al            ; put byte count in al
  970.     xor    ah,ah            ; clear high byte
  971.     mov    kbtemp,ax        ; and save count in kbtemp
  972.     mov    ah,cmeol        ; get a confirm
  973.     call    comnd
  974.     jc    dfkey1x            ; none so declare parse error
  975.     mov    cx,kbtemp        ; string length
  976.     
  977. dfkey2:                    ; Examine translation
  978.     mov    al,trans.escchr        ; current escape char (port dependent)
  979.     cmp    al,byte ptr keycode    ; is this Kermit's escape char?
  980.     jne    dfkey2a            ; ne = no
  981.     test    keycode,scan        ; see if scan code
  982.     jnz    dfkey2a            ; nz = scan, so not ascii esc char
  983.     mov    dx,offset dfkoops    ; Oops! msg
  984.     mov    ah,prstr        ; complain and don't redefine
  985.     int    dos
  986.     stc                ; failure
  987.     ret
  988.  
  989. dfkey2a:push    di            ; get a director code for this key
  990.     push    cx    
  991.     mov    di,offset keylist    ; list of keycodes
  992.     mov    cx,nkeys        ; number currently defined
  993.     mov    ax,keycode        ; present keycode
  994.     jcxz    dfkey2b            ; cx = 0 means none defined yet
  995.     cld
  996.     push    ds
  997.     pop    es
  998.     repne    scasw            ; is current keycode in the list?
  999.     jne    dfkey2b            ; ne = not in list
  1000.     sub    di,2            ; correct for auto increment
  1001.     sub    di,offset keylist
  1002.     mov    listptr,di        ; list pointer for existing definition
  1003.     pop    cx
  1004.     pop    di
  1005.     jmp    dfkey3            ; go process definition
  1006.  
  1007. dfkey2b:pop    cx            ; key not currently defined so
  1008.     pop    di            ;  make a new director entry for it
  1009.     mov    bx,nkeys        ; number of keys previously defined
  1010.     cmp    bx,maxkeys        ; enough space?
  1011.     jae    dfkey2c            ; ae = no, complain
  1012.     shl    bx,1            ; count words
  1013.     mov    listptr,bx        ; index into word list
  1014.     mov    ax,keycode        ; get key's code
  1015.     mov    keylist[bx],ax        ; store it in list of keycodes
  1016.     mov    dirlist[bx],0        ; clear the new director entry
  1017.     inc    nkeys            ; new number of keys
  1018.     jmp    dfkey3            ; go process definition
  1019.  
  1020. dfkey2c:mov    dx,offset keyfull    ; say key space is full already
  1021.     mov    ah,prstr
  1022.     int    dos
  1023.     stc                ; failure
  1024.     ret
  1025.  
  1026. ; listptr has element number in keylist or dirlist; keycode has key's code.
  1027.  
  1028. ; Parse new definition. First look for Kermit verbs as a line beginning
  1029. ; as \K or \{K. Otherwise, consider the line to be a string.
  1030. ; In any case, update the Director table for the new definition.
  1031.  
  1032. dfkey3:    mov    brace,0            ; assume not using braces
  1033.     mov    si,offset tranbuf    ; start of definition text
  1034.     cmp    byte ptr [si],'\'    ; starts with escape char?
  1035.     jne    dfkey5            ; ne = no, so we have a string
  1036.     inc    si            ; skip the backslash
  1037.     cmp    byte ptr [si],braceop    ; starts with \{?
  1038.     jne    dfkey3a            ; ne = no
  1039.     inc    si            ; skip the opening brace
  1040.     mov    brace,bracecl        ; expect closing brace
  1041. dfkey3a:cmp    byte ptr [si],'K'    ; starts with \{K or \K?
  1042.     je    dfkey3b            ; e = yes
  1043.     cmp    byte ptr [si],'k'    ; starts as \{k or \k?
  1044.     jne    dfkey5            ; ne = no, then it's a string
  1045. dfkey3b:inc    si            ; yes, skip the K too
  1046.                     ; Kermit action VERBS
  1047.     push    si            ; save verb name start address
  1048. dfkey4:    cld
  1049.     lodsb                ; scan til closing brace or w/s or end
  1050.     cmp    al,0            ; premature end?
  1051.     je    dfkey4b            ; e = yes, accept without brace
  1052.     cmp    al,brace        ; closing brace?
  1053.     je    dfkey4b            ; e = yes
  1054.     cmp    al,spc            ; white space or control char?
  1055.     ja    short dfkey4        ; a = no, so not at end yet
  1056. dfkey4b:mov    byte ptr[si-1],0    ; insert null terminator
  1057.     pop    si            ; recover start address
  1058.     call    tstkeyw            ; find keyword, kw # returned in kbtemp
  1059.     jc    dfkey4d            ; c = no keyword found, complain
  1060.     call    remstr            ; clear old string, if string
  1061.     mov    ax,kbtemp        ; save keyword number
  1062.     and    ax,not(verb+strng)    ; clear verb / string field
  1063.     or    ax,verb            ; set verb ident
  1064.     mov    si,listptr
  1065.     mov    dirlist[si],ax        ; store info in Director table
  1066.     jmp    dfkey7            ; show results and return success
  1067.  
  1068. dfkey4d:mov    dx,offset verbbad    ; say no such verb
  1069.     mov    ah,prstr
  1070.     int    dos
  1071.     stc                ; failure
  1072.     ret
  1073.  
  1074. ; Here we are left with the definition string; si points to its start, and
  1075. ; kbtemp holds its length (number of bytes). Null termination. If the string
  1076. ; begins with an opening brace it terminates on a matching closing brace
  1077. ; or the end of line, whichever occurs first. Trailing whitespace removed
  1078. ; before examining braces.
  1079. ; Null length strings mean define key as Self.
  1080.                     ; STRING definitions
  1081. dfkey5:    call    remstr            ; first, clear old string, if any
  1082.     mov    si,offset tranbuf    ; si=source, di=dest, convert in-place
  1083.     mov    di,si
  1084.     call    cnvlin            ; convert numbers, cx gets line length
  1085.     mov    si,offset tranbuf    ; provide address of new string
  1086.     cmp    cx,1            ; just zero or one byte to do?
  1087.     jbe    dfkey6            ; e = yes, do as a char
  1088.     call    insertst        ; insert new string, returns reg cx.
  1089.     jc    dfkey5h            ; c = could not do insert
  1090.     mov    si,listptr        ; cx has type and string number
  1091.     mov    dirlist[si],cx        ; update Director table from insertst
  1092.     jmp    dfkey7            ; show results and return success
  1093.  
  1094. dfkey5h:mov    dx,offset strbad    ; display complaint
  1095.     mov    ah,prstr
  1096.     int    dos
  1097.     stc                ; failure
  1098.     ret
  1099.  
  1100.         ; define SINGLE CHAR replacement or CLEAR a key definition.
  1101.         ; cx has char count 1 (normal) or 0 (to undefine the key).
  1102. dfkey6:    jcxz    dfkey6c            ; z = cx= 0, clear definition
  1103.     mov    al,byte ptr [si]    ; get first byte from definition
  1104.     xor    ah,ah            ; set the type bits to Char
  1105.     mov    si,listptr
  1106.     mov    dirlist[si],ax        ; store type and key's new code
  1107.     jmp    dfkey7            ; return success
  1108.  
  1109. dfkey6c:push    si            ; clear a definition,
  1110.     push    di            ; listptr points to current def
  1111.     mov    si,listptr        ; starting address to clear
  1112.     add    si,offset dirlist
  1113.     mov    di,si            ; destination
  1114.     add    si,2            ; source is next word
  1115.     mov    cx,nkeys        ; current number of keys defined
  1116.     add    cx,cx            ; double for listptr being words
  1117.     sub    cx,listptr        ; cx = number of words to move
  1118.     shr    cx,1            ; convert to actual number of moves
  1119.     jcxz    dfkey6d            ; z = none, just remove last word
  1120.     push    es
  1121.     push    ds
  1122.     pop    es            ; make es:di point to data segment
  1123.     cld
  1124.     push    cx            ; save cx
  1125.     rep    movsw            ; move down higher list items
  1126.     pop    cx
  1127.     mov    si,listptr        ; do keylist too, same way
  1128.     add    si,offset keylist
  1129.     mov    di,si
  1130.     add    si,2
  1131.     rep    movsw
  1132.     pop    es
  1133. dfkey6d:mov    si,nkeys        ; clear old highest list element
  1134.     shl    si,1            ; address words
  1135.     mov    dirlist[si],0        ; null the element
  1136.     mov    keylist[si],0        ; null the element
  1137.     dec    nkeys            ; say one less key defined now
  1138.     pop    di            ; restore saved registers
  1139.     pop    si
  1140.  
  1141. dfkey7:    mov    ah,msutake        ; Finish up. In a Take file?
  1142.     or    ah,taklev        ; or even directly
  1143.     cmp    ah,0
  1144.     je    dfkey7a            ; e = no
  1145.     cmp    flags.takflg,0        ; echo Take commands?
  1146.     je    dfkey7b            ; e = no
  1147. dfkey7a:mov    ah,prstr        ; display cr/lf
  1148.     mov    dx,offset crlf
  1149.     int    dos
  1150.     call    shkey0            ; show new definition (in SHKEY)
  1151.     call    shkfre            ; show free string space
  1152. dfkey7b:clc                ; return success
  1153.     ret
  1154. DFKEY    ENDP
  1155.  
  1156. ; SHOW KEY <cr> command. Call from Kermit level. Vectored here by SHOW
  1157. ; command. Replaces obsolete procedure in msx---.
  1158. ; Prompts for a key and shows that key's (or all if ? entered) keycode,
  1159. ; definition, and the key definition free space remaining.
  1160.  
  1161. SHKEY    PROC    NEAR            ; Show key's definition command
  1162.     mov    ah,cmeol        ; get a confirm
  1163.     call    comnd            ; ignore any additional text
  1164.     push    bx
  1165.     mov    dx,offset shkmsg1    ; ask for original key
  1166.     mov    ah,prstr
  1167.     int    dos
  1168.     or    byte ptr kbcodes,80h    ; say kbcodes not-initiated
  1169. shky0:    call    getkey            ; read keyboard, output to keycode
  1170.     jc    shky0            ; wait for a key (c = nothing there)
  1171.     cmp    byte ptr keycode,'?'    ; query for all keys?
  1172.     jne    shky0a            ; ne = no, not a query
  1173.     test    keycode,scan        ; is this a scan code, vs ascii query?
  1174.     jz    shky0c            ; z = no Scan, so it is a query
  1175.  
  1176. shky0a:    mov    ah,prstr        ; show single key. Setup display
  1177.     mov    dx,offset crlf
  1178.     int    dos
  1179.     call    shkey0            ; show just one key
  1180. shky0b:    call    shkfre            ; show free string space
  1181.     jmp    shkeyx            ; exit
  1182.  
  1183. shky0c:    mov    cx,nkeys        ; Show all keys. nkeys = number defined
  1184.     jcxz    shky0b            ; z = none to show
  1185.     mov    si,offset keylist    ; list of definitions
  1186.     push    si            ; save pointer
  1187. shky1:    pop    si            ; recover pointer
  1188.     cld
  1189.     lodsw                ; get a keycode
  1190.     push    si            ; save pointer
  1191.     push    cx            ; save counter
  1192.     mov    keycode,ax        ; save new keycode
  1193.     mov    ah,prstr
  1194.     mov    dx,offset crlf
  1195.     int    dos
  1196.     call    shkey0            ; show this keycode
  1197.  
  1198.     pop    cx            ; pause between screens, recover cntr
  1199.     push    cx            ; save it again
  1200.     dec    cx            ; number yet to be shown
  1201.     jcxz    shky1b            ; z = have now shown all of them
  1202.     mov    ax,nkeys        ; number of defined keys
  1203.     sub    ax,cx            ; minus number yet to be displayed
  1204.     xor    dx,dx            ; clear extended numerator
  1205.     div    twelve            ; two lines per definition display
  1206.     or    dx,dx            ; remainder zero (12 defs shown)?
  1207.     jnz    shky1b            ; nz = no, not yet so keep going
  1208.     mov    ah,prstr
  1209.     mov    dx,offset shkmsg3    ; "push any key to continue" msg
  1210.     int    dos
  1211. shky1a:    call    getkey            ; get any key
  1212.     jc    shky1a            ; c = nothing at keyboard yet, wait
  1213. shky1b:    pop    cx            ; resume loop
  1214.     loop    shky1
  1215.     pop    si            ; clean stack
  1216.     call    shkfre            ; show free string space
  1217.     jmp    shkeyx            ; exit
  1218.  
  1219.         ; show key worker routine, called from above
  1220.                     ; SHKEY0 called by DFKEY just above
  1221. SHKEY0:    test    keycode,scan        ; scan code?
  1222.     jz    shkey1            ; z = no, regular ascii
  1223.  
  1224.                     ; SCAN codes
  1225.     mov    dx,offset scanmsg    ; say Scan Code:
  1226.     mov    ah,prstr
  1227.     int    dos
  1228.     mov    ah,conout
  1229.     mov    dl,'\'            ; add backslash before number
  1230.     int    dos
  1231.     mov    ax,keycode        ; get key's code again
  1232.     call    decout            ; display 16 bit decimal keycode
  1233.     jmp    shkey2            ; go get definition
  1234.  
  1235. shkey1:    mov    dx,offset ascmsg    ; say ASCII CHAR
  1236.     mov    ah,prstr
  1237.     int    dos
  1238.     mov    dl,byte ptr keycode    ; get ascii code (al part of input)
  1239.     mov    ah,conout
  1240.     cmp    dl,spc            ; control code?
  1241.     jae    shkey1a            ; ae = no
  1242.     push    dx            ; save char
  1243.     mov    dl,5eh            ; show caret first
  1244.     int    dos
  1245.     pop    dx
  1246.     add    dl,'A'-1        ; ascii bias
  1247. shkey1a:cmp    dl,del            ; DEL?
  1248.     jne    shkey1b            ; ne = no
  1249.     mov    dl,'D'            ; spell out DEL
  1250.     int    dos
  1251.     mov    dl,'E'
  1252.     int    dos
  1253.     mov    dl,'L'
  1254. shkey1b:int    dos
  1255.     mov    dl,spc            ; add a couple of spaces
  1256.     int    dos
  1257.     int    dos
  1258.     mov    dl,'\'            ; add backslash before number
  1259.     int    dos
  1260.     mov    ax,keycode        ; show 16 bit keycode in decimal
  1261.     call    decout            ; and go get definiton
  1262.  
  1263.                     ; Display defintion
  1264. shkey2:    mov    dx,offset shkmsg2    ; intermediate part of reply
  1265.     mov    ah,prstr        ; " is defined as "
  1266.     int    dos
  1267.     push    di            ; get a director code for this key
  1268.     push    cx    
  1269.     mov    di,offset keylist    ; list of keycodes
  1270.     mov    cx,nkeys        ; number currently defined
  1271.     jcxz    shkey2a            ; z = none
  1272.     mov    ax,keycode        ; present keycode
  1273.     push    ds
  1274.     pop    es            ; use data segment for es:di
  1275.     cld
  1276.     repne    scasw            ; is current keycode in the list?
  1277.     jne    shkey2a            ; ne = not in list
  1278.     sub    di,2            ; correct for auto increment
  1279.     sub    di,offset keylist
  1280.     mov    listptr,di        ; list pointer for existing definition
  1281.     pop    cx
  1282.     pop    di
  1283.     jmp    shkey3            ; go process definition
  1284.  
  1285. shkey2a:pop    cx
  1286.     pop    di
  1287.     mov    dx,offset noxmsg    ; say Self (no translation)
  1288.     mov    ah,prstr
  1289.     int    dos
  1290.     ret                ; return to main show key loop
  1291.  
  1292. shkey3:                    ; translations, get kind of.
  1293.     mov    si,listptr
  1294.     test    dirlist[si],verb    ; defined as verb?
  1295.     jnz    shkey6            ; nz = yes, go do that one
  1296.     test    dirlist[si],strng    ; defined as string?
  1297.     jz    shkey3a            ; z = no
  1298.     jmp    shkey8            ; yes, do string display
  1299. shkey3a:
  1300.     mov    dx,offset ascmsg    ; CHAR. say 'Ascii char:'
  1301.     mov    ah,prstr
  1302.     int    dos
  1303.     mov    ax,dirlist [si]        ; get type and char
  1304.     mov    dl,al            ; put char here for display
  1305.     push    ax            ; save here too
  1306.     mov    ah,conout
  1307.     cmp    dl,spc            ; control code?
  1308.     jae    shkey4            ; ae = no
  1309.     push    dx
  1310.     mov    dl,5eh            ; show caret
  1311.     int    dos
  1312.     pop    dx
  1313.     add    dl,'A'-1        ; add ascii bias
  1314. shkey4:    cmp    dl,del            ; DEL?
  1315.     jne    shkey4a            ; ne = no
  1316.     mov    dl,'D'            ; spell out DEL
  1317.     int    dos
  1318.     mov    dl,'E'
  1319.     int    dos
  1320.     mov    dl,'L'
  1321. shkey4a:int    dos
  1322.     mov    dl,spc            ; add a couple of spaces
  1323.     mov    ah,conout
  1324.     int    dos
  1325.     int    dos
  1326.     mov    dl,'\'            ; add backslash before number
  1327.     int    dos
  1328.     pop    ax            ; recover char
  1329.     xor    ah,ah            ; clear high byte
  1330.     call    decout            ; show decimal value
  1331.     ret                ; return to main show key loop
  1332.  
  1333. shkey6:    mov    ah,prstr        ; VERB
  1334.     mov    dx,offset verbmsg    ; say 'verb'
  1335.     int    dos
  1336.     mov    si,listptr        ; get verb index from director
  1337.     mov    dx,dirlist[si]
  1338.     and    dx,not(verb+strng)    ; remove type bits, leaves verb number
  1339.     mov    bx,offset kverbs    ; table of verbs & actions
  1340.     mov    al,byte ptr [bx]    ; number of keywords
  1341.     xor    ah,ah
  1342.     dec    ax
  1343.     mov    kwcnt,ax        ; save number of last one here
  1344.     cmp    dx,ax            ; asking for more than we have?
  1345.     ja    shkeyx            ; a = yes, exit bad
  1346.     inc    bx            ; point to first slot
  1347.     mov    cx,0            ; current slot number
  1348. shkey6b:cmp    cx,dx            ; this slot?
  1349.     je    shkey6c            ; e = yes, print the text part
  1350.     ja    shkeyx            ; a = beyond, exit bad
  1351.     mov    al,byte ptr [bx]    ; get cnt (keyword length)
  1352.     xor    ah,ah
  1353.     add    ax,4            ; skip over '$' and two byte value
  1354.     add    bx,ax            ; bx = start of next keyword slot
  1355.     inc    cx            ; current keyword number
  1356.     jmp    short shkey6b        ; try another
  1357. shkey6c:inc    bx            ; look at text field
  1358.     mov    dx,bx            ; offset for printing
  1359.     mov    ah,prstr
  1360.     int    dos
  1361.     mov    ah,conout
  1362.     mov    dl,spc            ; add a couple of spaces
  1363.     int    dos
  1364.     int    dos
  1365.     mov    dl,'\'            ; show verb name as \Kverb
  1366.     int    dos
  1367.     mov    dl,'K'
  1368.     int    dos
  1369.     mov    ah,prstr
  1370.     mov    dx,bx            ; show name part again
  1371.     int    dos
  1372.     ret                ; return to main show key loop
  1373.  
  1374. shkey8:    mov    ah,prstr        ; STRING
  1375.     mov    dx,offset strngmsg    ; say String:
  1376.     int    dos
  1377.     mov    si,listptr        ; get index from director
  1378.     mov    bx,dirlist[si]
  1379.     and    bx,not(verb+strng)    ; remove type bits
  1380.     shl    bx,1            ; index words
  1381.     mov    si,sptable[bx]        ; table of string offsets
  1382.     mov    cl,byte ptr [si]    ; get string length byte
  1383.     xor    ch,ch
  1384.     inc    si            ; point to string text
  1385.     mov    ah,conout
  1386. shkey8a:cld
  1387.     lodsb                ; get a byte
  1388.     cmp    al,spc            ; control code?
  1389.     jae    shkey8b            ; ae = no
  1390.     push    ax
  1391.     mov    dl,5eh            ; show caret first
  1392.     int    dos
  1393.     pop    ax
  1394.     add    al,40h            ; convert to printable for display
  1395. shkey8b:mov    dl,al
  1396.     int    dos            ; display it
  1397.     loop    shkey8a            ; do another
  1398.     ret                ; return to main show key loop
  1399.     
  1400. shkeyx:    pop    bx            ; restore reg
  1401.     clc                ; return success
  1402.     ret
  1403. SHKEY    ENDP
  1404.  
  1405. ;;;    keyboard translator local support procedures, system independent
  1406.  
  1407. ; Tstkeyw checks text word pointed to by si against table of keywords (pointed
  1408. ; to by kverbs, made by mkeyw macro); returns in bx either action value or 0.
  1409. ; Returns in kbtemp the number of the keyword and carry clear, or if failure
  1410. ; returns kbtemp zero and carry set.
  1411. ; Keyword structure is:         db    cnt    (length of string 'word')
  1412. ;                 db    'word'    (keyword string)
  1413. ;                 db    '$'    (printing terminator)
  1414. ;                 dw    value    (value returned in bx)
  1415. ; Make these with macro mkeyw such as   mkeyw 'test',15   with the list of
  1416. ; such keywords headed by a byte giving the number of keywords in the list.
  1417. tstkeyw    proc    near
  1418.     push    ax
  1419.     push    cx
  1420.     push    si
  1421.     mov    verblen,0        ; verblen will hold verb length
  1422.     push    si            ; save user's verb pointer
  1423. tstkw1:    cld
  1424.     lodsb                ; get a verb character
  1425.     cmp    al,spc            ; verbs are all non-spaces and above
  1426.     jbe    tstkw2            ; be = done (space or control char)
  1427.     inc    verblen            ; count verb length
  1428.     jmp    short tstkw1        ; printable char, look for more
  1429. tstkw2:    pop    si            ; pointer to verb
  1430.     mov    bx,offset kverbs    ; table of Kermit verb keywords
  1431.     mov    al,byte ptr [bx]    ; number of keywords
  1432.     xor    ah,ah
  1433.     mov    kwcnt,ax        ; save number of keywords here
  1434.     inc    bx            ; point bx to first slot
  1435.     mov    kbtemp,0        ; remember which keyword
  1436.  
  1437. tstkw3:                    ; match table keyword and text word
  1438.     mov    cx,verblen        ; length of user's verb
  1439.     cmp    byte ptr [bx],cl    ; compare length vs table keyword
  1440.     jne    tstkw4            ; ne = not equal lengths, try another
  1441.     push    si            ; lengths match, how about spelling?
  1442.     push    bx
  1443.     inc    bx            ; point at start of keyword
  1444. tstkw3a:mov    ah,byte ptr [bx]    ; keyword char
  1445.     mov    al,byte ptr [si]    ; text char
  1446.     cmp    ah,'A'
  1447.     jb    tstkw3b            ; b = control chars
  1448.     cmp    ah,'Z'
  1449.     ja    tstkw3b            ; a = not upper case alpha
  1450.     add    ah,'a'-'A'        ; convert upper case to lower case
  1451. tstkw3b:cmp    al,'A'
  1452.     jb    tstkw3c
  1453.     cmp    al,'Z'
  1454.     ja    tstkw3c
  1455.     add    al,'a'-'A'        ; convert upper case to lower case
  1456. tstkw3c:cmp    al,ah            ; test characters
  1457.     jne    tstkw3d            ; ne = no match
  1458.     inc     si            ; move to next char
  1459.     inc    bx
  1460.     loop    tstkw3a            ; loop through entire length
  1461. tstkw3d:pop    bx
  1462.     pop    si
  1463.     jcxz    tstkw5            ; z: cx = 0, exit with match;
  1464.                     ;  else select next keyword
  1465. tstkw4:    inc    kbtemp            ; number of keyword to test next
  1466.     mov    cx,kbtemp
  1467.     cmp    cx,kwcnt        ; all done? Recall kbtemp starts at 0
  1468.     jae    tstkwx            ;ae = exhausted search, unsuccessfully
  1469.     mov    al,byte ptr [bx]    ; cnt (keyword length from macro)
  1470.     xor    ah,ah
  1471.     add    ax,4            ; skip over '$' and two byte value
  1472.     add    bx,ax            ; bx = start of next keyword slot
  1473.     jmp    tstkw3            ; do another comparison
  1474.  
  1475. tstkw5:                    ; get action pointer
  1476.     mov    al,byte ptr [bx]    ; cnt (keyword length from macro)
  1477.     xor    ah,ah
  1478.     add    ax,2            ; skip over '$'
  1479.     add    bx,ax            ; now bx points to dispatch value
  1480.     mov    bx,[bx]            ; bx holds dispatch value
  1481.     clc                ; carry clear for success
  1482.     jmp    short tstkwxx        ; exit
  1483.     ret
  1484. tstkwx:    xor    bx,bx            ; exit when no match
  1485.     mov    kbtemp,bx        ; make verb number be zero too
  1486.     stc                ; carry set for failure
  1487. tstkwxx:pop    si
  1488.     pop    cx
  1489.     pop    ax
  1490.     ret
  1491. tstkeyw    endp
  1492.  
  1493. ; Insert asciiz string pointed to by si into string buffer stbuf.
  1494. ; Reg cx has string length upon entry.
  1495. ; Success: returns offset of first free byte (strmax) in string buffer stbuf,
  1496. ; cx = type and Index of new string, and carry clear.
  1497. ; Failure = carry set.
  1498. insertst proc    near
  1499.     push    bx
  1500.     push    dx
  1501.     push    si
  1502.     push    di
  1503.     push    kbtemp        ; save this variable too
  1504.     mov    dx,cx        ; save length of incoming string in dx
  1505.     mov    bx,offset sptable ; table of string offsets
  1506.     mov    kbtemp,0    ; slot number
  1507.     mov    cx,maxstng    ; number of entries, find an empty slot
  1508. insert1:cmp    word ptr[bx],0    ; slot empty?
  1509.     je    insert2        ; e = yes
  1510.     inc    kbtemp        ; remember slot number
  1511.     add    bx,2        ; look at next slot
  1512.     loop    insert1        ; keep looking
  1513.     jmp    short insert4    ; get here if no empty slots
  1514. insert2:            ; see if stbuf has sufficient space
  1515.     mov    cx,dx        ; length of new string to cx
  1516.     mov    di,strmax    ; offset of first free byte in stbuf
  1517.     add    di,cx        ; di = address where this string would end
  1518.     cmp    di,offset stbuf+stbuflen ; beyond end of buffer?
  1519.     jae    insert4        ; ae = yes, not enough room
  1520.     mov    di,strmax    ; point to first free slot in stbuf
  1521.     mov    [bx],di        ; fill slot with address offset of buffer
  1522.     push    es
  1523.     push    ds
  1524.     pop    es        ; point es:di to data segment
  1525.     cld
  1526.     mov    byte ptr [di],cl ; length of text for new string
  1527.     inc    di        ; move to next storage slot
  1528.     rep    movsb        ; copy string text
  1529.     pop    es
  1530.     mov    strmax,di    ; offset of next free byte
  1531.     mov    cx,kbtemp    ; return new slot number with Director Index
  1532.     and    cx,not(strng+verb) ; clear type bits
  1533.     or    cx,strng    ; say type is multi-char string
  1534.     clc            ; say success
  1535.     jmp    short insertx    ; exit
  1536. insert4:stc            ; say no-can-do
  1537. insertx:pop    kbtemp
  1538.     pop    di
  1539.     pop    si
  1540.     pop    dx
  1541.     pop    bx
  1542.     ret
  1543. insertst endp
  1544.  
  1545. ; Remove (delete) string. Enter with listptr preset for director entry.
  1546. ; Acts only on existing multi-char strings; recovers freed space.
  1547. ; All registers preserved.
  1548. remstr    proc    near        
  1549.     push    si
  1550.     mov    si,listptr        ; list pointer
  1551.     test    dirlist[si],strng    ; multi-char string?
  1552.     pop    si
  1553.     jnz    remst1            ; nz = a multi-char string
  1554.     ret                ; else do nothing
  1555. remst1:    push    ax
  1556.     push    bx
  1557.     push    cx
  1558.     push    dx
  1559.     push    si
  1560.     mov    si,listptr
  1561.     mov    ax,dirlist[si]         ; Director table entry
  1562.     and    ax,not(strng+verb) ; clear type bits, leave string's pointer
  1563.     mov    dirlist[si],0        ; clear Director table entry
  1564.     shl    ax,1            ; index words not bytes
  1565.     mov    si,offset sptable     ; list of string offsets in stbuf
  1566.     add    si,ax            ; plus index = current slot
  1567.     mov    bx,[si]            ; get offset of string to be deleted
  1568.     mov    dx,bx            ; save in dx for later
  1569.     mov    cl,byte ptr [bx]    ; get length byte
  1570.     xor    ch,ch            ; get length of subject string
  1571.     inc    cx            ; length byte too, cx has whole length
  1572.     sub    strmax,cx    ; count space to be freed (adj end-of-buf ptr)
  1573.     mov    word ptr [si],0    ; clear sptable of subject string address
  1574.     push    cx            ; save length of purged string
  1575.     push    di            ; save di
  1576.     push    si
  1577.     push    es            ; save es
  1578.     push    ds
  1579.     pop    es        ; setup es:di to be ds:offset of string
  1580.     mov    di,dx        ; destination = start address of purged string
  1581.     mov    si,dx        ; source = start address of purged string
  1582.     add    si,cx        ;  plus string length of purged string.
  1583.     mov    cx,offset stbuf+stbuflen ; 1 + address of buffer end
  1584.     sub    cx,si            ; 1 + number of bytes to move
  1585.     dec    cx            ; number of bytes to move
  1586.     jcxz    remst2            ; z = none
  1587.     cld                ; direction is forward
  1588.     rep    movsb            ; move down preserved strings
  1589. remst2:    pop    es            ; restore regs
  1590.     pop    di
  1591.     pop    si
  1592.     pop    ax        ; recover length of purged string (was in cx)
  1593.     mov    bx,offset sptable     ; string pointer table
  1594.     mov    cx,maxstng        ; max mumber of entries
  1595. remst4:    cmp    [bx],dx        ; does this entry occur before purged string?
  1596.     jbe    remst5        ; be = before or equal, so leave it alone
  1597.     sub    [bx],ax        ; recompute address (remove old string space)
  1598. remst5:    add    bx,2            ; look at next list entry
  1599.     loop    remst4            ; do all entries in sptable
  1600.     pop    si
  1601.     pop    dx
  1602.     pop    cx
  1603.     pop    bx
  1604.     pop    ax
  1605.     ret
  1606. remstr    endp
  1607.  
  1608. shkfre    proc    near            ; show free key & string defs & space
  1609.     push    ax            ; preserves all registers.
  1610.     push    bx
  1611.     push    cx
  1612.     push    dx
  1613.     push    kbtemp
  1614.     mov    dx,offset fremsg
  1615.     mov    ah,prstr
  1616.     int    dos
  1617.     mov    ax,maxkeys        ; max number of key defs
  1618.     sub    ax,nkeys        ; number currently used
  1619.     call    decout            ; show the value
  1620.     mov    ah,prstr
  1621.     mov    dx,offset kyfrdef    ; give key defs msg
  1622.     int    dos
  1623.     mov    bx,offset sptable    ; table of string pointers
  1624.     mov    cx,maxstng        ; number of pointers
  1625.     mov    kbtemp,0        ; number free
  1626. shkfr1:    cmp    word ptr [bx],0        ; slot empty?
  1627.     jne    shkfr2            ; ne = no
  1628.     inc    kbtemp            ; count free defs
  1629. shkfr2:    add    bx,2            ; look at next slot
  1630.     loop    shkfr1            ; do all of them
  1631.     mov    ax,kbtemp        ; number of free defs
  1632.     call    decout            ; display
  1633.     mov    dx,offset stfrdef    ; say free string defs
  1634.     mov    ah,prstr
  1635.     int    dos
  1636.     mov    ax,offset stbuf+stbuflen ; 1 + last byte in stbuf
  1637.     sub    ax,strmax        ; offset of last free byte in stbuf
  1638.     call    decout
  1639.     mov    dx,offset stfrspc    ; give free space part of msg
  1640.     mov    ah,prstr
  1641.     int    dos
  1642.     pop    kbtemp
  1643.     pop    dx
  1644.     pop    cx
  1645.     pop    bx
  1646.     pop    ax
  1647.     ret
  1648. shkfre    endp
  1649.  
  1650. ; Initialize the keyboard tables at Kermit startup time. Optional procedure.
  1651. ; Requires kbdinlst to be configured with mkeyw macro in the form
  1652. ;    mkeyw    'definition',keytype*256+keycode
  1653. ; keytype is 0 for scan codes and non-zero for ascii.
  1654. ; Returns normally.
  1655. kbdinit    proc     near            ; read keyword kbdinlst and setup
  1656.     or    byte ptr kbcodes,80h    ; say kbcodes not-initiated
  1657.     push    ds            ;  initial keyboard assignments.
  1658.     pop    es            ; set es:di to data segment
  1659.     inc    taklev            ; pretend that we are in Take file
  1660.     call    chk250            ;** LK250 support begin
  1661.     cmp    got250,1        ;** is it installed?
  1662.     jne    kbdini0            ;** ne = no
  1663.     call    kbrest            ;** else initialize to DEC mode
  1664.     mov    si,offset kb250lst    ;** load extensions
  1665.     jmp    short kbdini1        ;** LK250 support end
  1666. kbdini0:mov     si,offset kbdinlst      ; start of list of definitions
  1667. kbdini1:mov    cl,byte ptr [si]    ; cnt field (keyword length of macro)
  1668.     xor    ch,ch
  1669.     jcxz    kbdinix            ; z = null cnt field = end of list
  1670.     inc    si            ; look at text field
  1671.     mov    di,offset tranbuf    ; where defkey expects text
  1672.     cld
  1673.     rep    movsb            ; copy cx chars to tranbuf
  1674.     mov    byte ptr [di],0        ; insert null terminator
  1675.     inc    si            ; skip '$' field
  1676.     mov    ax,word ptr [si]    ; get value field
  1677.     mov    keycode,ax        ; set key ident value
  1678.     push    si
  1679.     call    dfkey2            ; put dfkey to work
  1680.     pop    si
  1681.     add    si,2            ; point to next entry
  1682.     jmp    kbdini1            ; keep working
  1683. kbdinix:dec    taklev            ; reset Take file level
  1684.     call    udkclear        ; clear User Definable Keys
  1685.     ret
  1686. kbdinit    endp
  1687. ;;;    End of System Independent Procedures
  1688.  
  1689. ;;;    Begin System Dependent Procedures
  1690.  
  1691. ; Read keyboard. System dependent.
  1692. ; Return carry set if nothing at keyboard.
  1693. ; If char present return carry clear with key's code in Keycode.
  1694. ; If key is ascii put that in the low byte of Keycode and clear bit Scan in
  1695. ; the high byte; otherwise, put the scan code in the lower byte and set bit
  1696. ; Scan in the high byte.
  1697. ; Bit Scan is set if key is not an ascii code.
  1698. ; Two methods are used: Bios reading for Set Key ON, and DOS reading for
  1699. ; Set Key OFF. DOS scan codes are coerced to Bios values as much as possible.
  1700. ; Modifies register ax.
  1701. getkey    proc    near
  1702.     mov    keycode,0        ; clear old keycode
  1703.     cmp    dosflg,0        ; do DOS keyboard reading?
  1704.     jne    getky7            ; ne = yes, DOS
  1705.     jmp    getky6            ; do full Bios form
  1706.                     ; ;;;;;;;; D O S ;;;;;;;;;;
  1707. getky7:    test    byte ptr kbcodes,80h    ; kbcodes initiated?        [dan]
  1708.     jz    getky5            ; z = yes            [dan]
  1709.     push    si
  1710.     call    nrc2cp            ; point SI at this code page to NRC
  1711.     mov    nrcptr,si
  1712.     pop    si
  1713.     push    bx
  1714.     call    cplatin            ; code page to Latin1, BX gets ptr
  1715.     mov    latinptr,bx
  1716.     call    cpdecsg            ; code page to DEC-MCS, BX gets ptr
  1717.     mov    decmnptr,bx
  1718.     pop    bx
  1719.     and    byte ptr kbcodes,not 80h ; say kbcodes initiated
  1720. getky5:    call    iseof            ; is stdin at eof?
  1721.     jnc    getky5k            ; nc = not eof, get more
  1722.      mov    al,trans.escchr        ; Kermit's escape char
  1723.     mov    byte ptr keycode,al    ; save ascii char
  1724.     clc                ;  to get out gracefully at EOF
  1725.     ret                ; and exit
  1726.  
  1727. getky5k:mov    dl,0ffh            ; DOS read operation
  1728.     mov    ah,dconio        ; from stdin
  1729.     int    dos
  1730.     jnz    getky5a            ; nz = char available
  1731.     stc                ; carry set = nothing available
  1732.     ret                ; exit on no char
  1733. getky5a:cmp    al,0            ; scan code precursor?
  1734.     je    getky5d            ; e = yes
  1735.     cmp    al,16            ; Control P?
  1736.     jne    getky5b            ; ne = no
  1737.     mov    al,114            ; force Control PrtSc scan code
  1738.     jmp    short getky5e        ; process as scan code
  1739. getky5b:cmp    al,BS            ; backspace key?
  1740.     jne    getky5c            ; ne = no
  1741.     mov    al,14            ; force scan code for BS key
  1742.     jmp    short getky5e        ; process as scan code
  1743. getky5c:mov    byte ptr keycode,al    ; save ascii char
  1744.     clc                ; carry clear = got a char
  1745.     ret                ; and exit
  1746.  
  1747. getky5d:mov    dl,0ffh            ; read second byte (actual scan code)
  1748.     mov    ah,dconio        ; read via DOS
  1749.     int    dos
  1750.     jnz    getky5e            ; nz = got a char
  1751.     stc                ; none, declare bad read
  1752.     ret
  1753.                     ; Check and modify to Bios scan codes
  1754. getky5e:mov    byte ptr keycode,al    ; save char code
  1755.     cmp    al,1            ; Alt escape
  1756.     je    getkya            ; set Alt bit
  1757.     cmp    al,16            ; back tab
  1758.     jb    getky5g            ; these remain unchanged
  1759.     cmp    al,50            ; start of meta keys
  1760.     jb    getkya            ; b = set Alt bit
  1761.     cmp    al,84            ; Shift F1
  1762.     jb    getky5g            ; b = no change
  1763.     cmp    al,94            ; Control F1
  1764.     jb    getkys            ; set Shift bit
  1765.     cmp    al,104            ; Alt F1
  1766.     jb    getkyc            ; set Control bit
  1767.     cmp    al,114            ; Control PrtSc
  1768.     jb    getkya            ; set Alt bit
  1769.     cmp    al,120            ; Alt top rank
  1770.     jb    getkyc            ; set Control bit
  1771.     cmp    al,132            ; Control PgUp
  1772.     jb    getkya            ; set Alt bit
  1773.     je    getkyc            ; set Control bit
  1774.     cmp    al,135            ; Shift F11, for Enhanced keyboard
  1775.     jb    getky5g            ; no change
  1776.     cmp    al,137            ; Control F11
  1777.     jb    getkys            ; set Shift bit
  1778.     cmp    al,139            ; Alt F11
  1779.     jb    getky5c            ; set Control bit
  1780.     cmp    al,141            ; Control Up
  1781.     jb    getkya            ; set Alt bit
  1782.     cmp    al,151            ; Alt Home
  1783.     jb    getkyc            ; set Control bit
  1784.     jmp    short getkya        ; set Alt bit
  1785. getkyc:    or    keycode,control        ; set Control bit
  1786.     jmp    short getky5g
  1787. getkys:    or    keycode,shift        ; set Shift bit
  1788.     jmp    short getky5g
  1789. getkya:    or    keycode,alt        ; set Alt bit
  1790. getky5g:or    keycode,scan        ; ensure scan bit is set
  1791.     clc                ; report we have a scan keycode
  1792.     ret                ; and exit
  1793.  
  1794.                     ; ;;;;;;;;;; B I O S ;;;;;;;;;;;;;
  1795. getky6:                    ; full BIOS keyboard reading
  1796.     test    byte ptr kbcodes,80h    ; kbcodes initiated?        [dan]
  1797.     jz    getky6a            ; z = yes            [dan]
  1798.     mov    kbcodes,0001h        ; low byte = status, high = read char
  1799.     push    cx            ; save registers
  1800.     push    es
  1801.     mov    cx,40h            ; segment 40h
  1802.     mov    es,cx
  1803.     mov    cl,byte ptr es:[96h]    ; kbd_flag_3, Enhanced keyboard area
  1804.     and    cl,10h            ; select Enhanced kbd presence bit
  1805.     mov    ch,cl            ; copy, for both status and read
  1806.     or    kbcodes,cx        ; 0 = regular kbd, 10h = enhanced kbd
  1807.     pop    es
  1808.     pop    cx
  1809.     push    si
  1810.     call    nrc2cp            ; point SI at this code page to NRC
  1811.     mov    nrcptr,si
  1812.     pop    si
  1813.     push    bx
  1814.     call    cplatin            ; code page to Latin1, BX gets ptr
  1815.     mov    latinptr,bx
  1816.     call    cpdecsg            ; code page to DEC-MCS, BX gets ptr
  1817.     mov    decmnptr,bx
  1818.     pop    bx
  1819.  
  1820. getky6a:mov    ah,byte ptr kbcodes    ; anything at keyboard?
  1821.     xor    al,al
  1822.     int    kbint            ; Bios keyboard interrupt
  1823.     jnz    getky1            ; nz = char available
  1824.     cmp    al,240            ; Bios "special ascii code" 0f0h?
  1825.     je    getky1            ; e = yes, Bios makes error, is a key
  1826.     stc                ; carry set = nothing available
  1827.     ret                 ; exit on no char available
  1828. getky1:    mov    ah,byte ptr kbcodes+1    ; read, no echo, wait til done
  1829.     int    kbint            ; ==> ah = scan code, al = char value
  1830.     cmp    ah,0            ; keycode entered by ALT ###?
  1831.     je    getky1c            ; e = yes, not enhanced
  1832.     cmp    ah,0e0h            ; Enhanced kbd Enter, fwd slash keys?
  1833.     jne    getky1b            ; ne = no
  1834.     xchg    ah,al            ; interchange scan and ascii fields
  1835. getky1b:cmp    al,0E0h            ; enhanced key hidden code?
  1836.     jne    getky1c            ; ne = no
  1837.     mov    byte ptr keycode,ah    ; retain scan code, supress 0e0h
  1838.     or    keycode,scan+enhanced    ; set scan and enhanced idents
  1839.     mov    ah,2            ; use regular keyboard op code here
  1840.     int    kbint            ; get current shift state
  1841.     mov    bl,al            ; copy for a moment
  1842.     and    bl,rgt_shift        ; mask out all but right shift
  1843.     shl    bl,1            ; move right shift to left shift pos
  1844.     or    al,bl            ; collapse shift bits
  1845.     and    al,(lft_shift + alt_shift + ctl_shift)
  1846.     or    byte ptr keycode+1,al    ; store in type field of keycode
  1847.     clc                ; say have a keystroke
  1848.     jmp    getkyx            ; Enhanced kbd end. Skip other tests
  1849.  
  1850. getky1c:push    cx
  1851.     mov    cx,aliaslen        ; number of aliased keys
  1852.     or    cx,cx
  1853.     pop    cx
  1854.     jz    getky2            ; z = none
  1855.     push    di            ; check key (ax) for aliases
  1856.     push    cx
  1857.     push    es
  1858.     push    ds
  1859.     pop    es            ; make es:di refer to data segment
  1860.     mov    di,offset aliaskey    ; list of aliased keys
  1861.     mov    cx,aliaslen        ; number of entries
  1862.     cld
  1863.     repne    scasw            ; look for a match
  1864.     pop    es
  1865.     pop    cx
  1866.     pop    di
  1867.     jne    getky2            ; ne = not there
  1868.     mov    al,0            ; force use of scan code (in ah)
  1869. getky2:    or    al,al            ; scan code being returned?
  1870.     jnz    getky3            ; nz = no
  1871.     mov    byte ptr keycode,ah    ; store scan code for gsh
  1872.     push    ax
  1873.     push    bx
  1874.     call    gsh            ; get modified shift state
  1875.     or    byte ptr keycode+1,al    ; store in type field of keycode
  1876.     pop    bx
  1877.     pop    ax
  1878.     xchg    ah,al            ; put scan code in al
  1879.     or    keycode,scan        ; set scan flag (vs ascii)
  1880. getky3:    mov    byte ptr keycode,al    ; return key's code (usually ascii)
  1881.     clc                ; carry clear = got a char
  1882. getkyx:    ret
  1883. getkey    endp
  1884.  
  1885. ; Return modified char code, depending on SET TERM CHAR-SET and active
  1886. ; Code Page. Enter and exit with char in AL.
  1887. xltkey    proc    near
  1888.     cmp    flags.xltkbd,0        ; keyboard translation is off?
  1889.     je    xltkey2            ; e = yes
  1890.     cmp    vtemu.vtchset,0        ; NRC's, using ASCII already?
  1891.     je    xltkey2            ; e = yes, use char in AL
  1892.     cmp    vtemu.vtchset,12    ; 1-12 for NCRs?
  1893.     ja    xltkey3            ; a = no
  1894.     push    si
  1895.     push    di
  1896.     push    ax
  1897.     mov    si,nrcptr        ; point SI at this code page to NRC
  1898.     pop    ax
  1899.     mov    di,si            ; start of table are ASCII chars
  1900.     mov    cl,vtemu.vtchset    ; get set number (1-12)
  1901.     xor    ch,ch
  1902.     sub    di,cx            ; minus one byte per set
  1903.     shl    cx,1            ; 15 bytes per NRC entry
  1904.     shl    cx,1
  1905.     shl    cx,1
  1906.     shl    cx,1
  1907.     add    di,cx            ; +16, source, point at this entry
  1908.     mov    cx,12            ; do first 12 bytes of them
  1909.     push    es
  1910.     push    ds
  1911.     pop    es
  1912.     cld
  1913.     repne    scasb            ; look for this byte code in table
  1914.     pop    es
  1915.     jne    xltkey1            ; ne = not found, use char in AL
  1916.     inc    cx
  1917.     sub    cx,12            ; compute char index
  1918.     neg    cx
  1919.     add    si,cx            ; index into ASCII table
  1920.     mov    al,[si]            ; get matching ASCII char (set 0)
  1921. xltkey1:pop    di
  1922.     pop    si
  1923. xltkey2:ret
  1924.                     ; LATIN1 set
  1925. xltkey3:test    al,80h            ; high bit set?
  1926.     jz    xltkey2            ; z = no, no translation
  1927.     cmp    vtemu.vtchset,15    ; set term character-set LATIN1?
  1928.     jne    xltkey4            ; ne = no
  1929.     and    al,not 80h        ; remove high bit
  1930.     push    bx
  1931.     mov    bx,latinptr        ; Code Page to Latin1
  1932.     xlatb                ; translate to Latin1 in AL
  1933.     pop    bx
  1934.     ret
  1935. xltkey4:cmp    vtemu.vtchset,16    ; set term character-set DEC-MCS?
  1936.     jne    xltkey2            ; ne = no
  1937.     and    al,not 80h        ; remove high bit
  1938.     push    bx
  1939.     mov    bx,DECmnptr        ; Code Page to DEC-MCS
  1940.     xlatb                ; translate to DEC-MCS in AL
  1941.     pop    bx
  1942.     ret
  1943. xltkey    endp
  1944.  
  1945. ; get shift state into al.  We care about only shift, ctl, and alt keys.
  1946. ; right shift is collapsed into left shift. NumLock offsets Shift on keypad
  1947. ; white keys.
  1948. gsh    proc    near
  1949.     mov    ah,2
  1950.     int    kbint            ; get current shift state
  1951.     mov    bl,al            ; copy for a moment
  1952.     and    bl,rgt_shift        ; mask out all but right shift
  1953.     shl    bl,1            ; move right shift to left shift pos
  1954.     or    al,bl            ; collapse shift bits
  1955.     cmp    byte ptr keycode,71    ; below numeric key pad?
  1956.     jb    gsh1            ; b = yes
  1957.     cmp    byte ptr keycode,83    ; above numeric key pad?
  1958.     ja    gsh1            ; a = yes
  1959.     cmp    byte ptr keycode,74    ; grey - key ?
  1960.     je    gsh1            ; e = yes
  1961.     cmp    byte ptr keycode,78    ; grey + key
  1962.     je    gsh1            ; e = yes
  1963.     test    al,numlock        ; numlock set?
  1964.     jz    gsh1            ; z = no
  1965.     xor    al,lft_shift        ; numlock offsets shift and vice versa
  1966. gsh1:    and    al,(lft_shift + alt_shift + ctl_shift)
  1967.     ret
  1968. gsh    endp
  1969.  
  1970.  
  1971. ; Do any local processing after reading a key during active translation
  1972. ; Avoids same actions if a key is being defined or shown.
  1973. postkey    proc    near
  1974.                     ; Key Click code for VT102 emulator
  1975.     cmp    flags.vtflg,0        ; emulating? (0 = no)
  1976.     je    postke1            ; e = extra clicks not available
  1977.     test    vtemu.vtflgst,vskeyclick ; flags from SET TERM
  1978.     jz    postke1            ; z = extra clicks not wanted
  1979.     call    vclick            ; click, what else?
  1980. postke1:ret
  1981. postkey    endp
  1982.  
  1983.                     ;** start of LK250 stuff
  1984. chk250    proc    near            ; presence test for DEC LK250 keyboard
  1985.     mov    got250,0        ; assume no LK250 keyboard
  1986.     mov    ax,5000h        ; see if the keyboard is loaded
  1987.     int    15h            ; look for DOS->DEC mode driver
  1988.     cmp    ax,1234h        ; find marker 1234h
  1989.     jne    chk250x            ; ne = marker not present, no driver
  1990.     mov    got250,1        ; else say we have an LK250
  1991. chk250x:ret
  1992. chk250    endp
  1993.  
  1994. kbrest    proc    near            ; set LK250 to DEC mode
  1995.     cmp    got250,1        ; LK250 present?
  1996.     jne    kbrest1            ; ne = no
  1997.     push    es            ; save reg
  1998.     mov    ax,40h            ; point to low memory
  1999.     mov    es,ax
  2000.     or    byte ptr es:[17h],20h    ; ensure Num Lock is on
  2001.     and    byte ptr es:[17h],0efh    ;  and Scroll is off
  2002.     pop    es            ; restore our [DS]
  2003.     mov    ax,5001h        ; issue set mode DEC to keyboard
  2004.     int    15h
  2005. kbrest1:ret
  2006. kbrest    endp
  2007.  
  2008. kbsusp    proc    near            ; set LK250 to DOS mode
  2009.     cmp    got250,1        ; LK250 present?
  2010.     jne    kbsusp1            ; ne = no
  2011.     mov    ax,5000h        ; unload extensions
  2012.     int    15h
  2013. kbsusp1:ret
  2014. kbsusp    endp
  2015.  
  2016. kbhold    proc    near
  2017.     cmp    got250,1        ; LK250 present?
  2018.     jne    kbhold1            ; ne = no
  2019.     mov    ax,5002h        ; issue SET LEDS
  2020.     mov    bl,0edh
  2021.     int    15h
  2022.     mov    ax,5002h
  2023.     mov    bl,holdscr        ; get the hold state
  2024.     or    bl,2            ; OR in Num Lock
  2025.     int    15h
  2026. kbhold1:ret
  2027. kbhold    endp                ;** end of LK250 stuff
  2028. code    ends
  2029.     end
  2030.