home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / extra / nyenhuis3.arc / MSSKER.ASM < prev    next >
Assembly Source File  |  1990-01-17  |  61KB  |  1,933 lines
  1.     NAME    mssker
  2. ; File MSSKER.ASM
  3.     include mssdef.h
  4. ; Edit history:
  5. ; Last edit 16 Jan 1990
  6. ; 16 June Add SHELL= support for PUSH as suggested by Mike Brown, Purdue
  7. ;  University Computing Center.
  8. ;****************************** Version 3.00 ***************************** 
  9. ; KERMIT, Celtic for "free" 
  10. ;
  11. ; The name "Kermit" is a registered trade mark of Henson Associates, Inc.,
  12. ; used by permission.
  13. ;
  14. ;    Kermit-MS Program Version 3.00, 16 Jan 1990 
  15. ;    Kermit-MS Program Version 2.32, 11 Dec 1988 
  16. ;    Kermit-MS Program Version 2.31, 1 July 1988
  17. ;       Kermit-MS Program Version 2.30, 1 Jan 1988
  18. ;    Kermit-MS Program Version 2.29, 26 May 1986, plus later revisions.
  19. ;       Kermit-MS Program Version 2.27, December 6,1984
  20. ; 
  21. ;       Based on the Columbia University KERMIT Protocol.
  22. ; 
  23. ;       Copyright (C) 1982,1983,1984,1985,1986,1987,1988, 1989, 1990
  24. ;                 Trustees of Columbia University
  25. ;
  26. ;       Daphne Tzoar, Jeff Damens
  27. ;       Columbia University Center for Computing Activities
  28. ;       612 West 115th Street
  29. ;       New York, NY  10025
  30. ;
  31. ;    Joe R. Doupnik (version 2.29, 2.30, 2.31, 2.32, 3.00)
  32. ;    Dept of EE, and CASS
  33. ;    Utah State University
  34. ;    Logan, Utah 84322
  35. ;    jrd@cc.usu.Bitnet
  36. ; 
  37. ; Special thanks to Frank da Cruz, Bill Catchings, Steve Jensen, Herm Fischer,
  38. ; Vace Kundakci, Bernie Eiben and many many others for their help and
  39. ; contributions.
  40.  
  41.     public    dosnum, curdsk, fpush, isfile, sbrk, crun, errlev
  42.     public    takrd, takadr, taklev, filtst, maxtry, dskspace, thsep
  43.     public    lclsusp, lclrest, lclexit, cwdir, kstatus, verident, cdsr
  44.     public    spath, patched
  45.  
  46. env    equ    2CH            ; environment address in psp
  47. cline    equ    80H            ; offset in psp of command line
  48.  
  49. STACK    SEGMENT    PARA STACK 'STACK'    ; our stack
  50.     dw    200 dup(0)        ; initialize stack to all zeros
  51. msfinal    label    word            ; top of stack
  52. STACK    ENDS
  53.  
  54. data   segment public 'data'
  55.     extrn    buff:byte, comand:byte, flags:byte, trans:byte,    prmptr:word
  56.     extrn    machnam:byte, decbuf:byte, rstate:byte, sstate:byte
  57.  
  58. verident label    byte
  59.     verdef
  60.     db    '$'
  61. copyright db    cr,lf
  62.     db    'Copyright (C) Trustees of Columbia University 1982, 1990.'
  63.     db    cr,lf,'$'
  64. hlpmsg    db     cr,lf,'Type ? or HELP for help',cr,lf,'$'
  65. crlf    db      cr,lf,'$'
  66. ermes1    db    cr,lf,'?More parameters are needed$'
  67. ermes2    db    cr,lf,'?Unable to initialize memory$'
  68. ermes3  db      cr,lf,'?Command canceled$'
  69. ermes4    db    '?Unable to change directory',0            ; asciiz
  70. ermes5    db    cr,lf,'?Unable to complete initialization process$'
  71. ermes6    db    cr,lf,'Ignoring patch file MSKERMIT.PCH. '
  72.     db    'Version number mismatch.',cr,lf,'$'
  73. ermes7    db    cr,lf,'Patch file MSKERMIT.PCH was not found',cr,lf,'$'
  74. ermes8    db    cr,lf,'Fatal error in MSKERMIT.PCH! Please remove PATCH '
  75.     db    'command.',cr,lf,'$'
  76. erms30    db    cr,lf,'?Passed maximum nesting level for TAKE command$'
  77. erms31    db    cr,lf,'?Cannot find Take-file: $'
  78. erms34    db    cr,lf,'This program requires DOS 2.0 or above$'
  79. erms37    db    cr,lf,'?Unable to execute program$'
  80. badnam    db    cr,lf,'?No such file(s)$'
  81. filmsg    db    ' Filename$'
  82. dskmsg    db    ' disk drive letter or Return$'
  83. pthmsg    db    ' Name of new working directory and/or disk$'
  84. runmsg    db    ' program name and command line$'
  85. tophlp    db    cr,lf
  86.     db    '  Ask, Askq (read keybd to variable) '
  87.     db    '  Output text     (for scripts)'
  88.     db    cr,lf
  89.     db    '  Bye      (logout remote server)    '
  90.     db    '  Pause [seconds] (for scripts)'
  91.     db    cr,lf
  92.     db      '  C or Connect  (become a terminal)  '
  93.     db    '  Pop   (exit current Take file or macro)'
  94.     db    cr,lf
  95.     db    '  Clear    (clear serial port buffer)'
  96.     db    '  Push     (go to DOS, keep Kermit)'
  97.     db    cr,lf
  98.     db    '  Close    (logging file)            '
  99.         db      '  Quit     (leave Kermit)'
  100.     db    cr,lf
  101.     db    '  CWD or CD  (change dir &/or disk)  '
  102.         db      '  R or Receive  (opt local filename)'
  103.     db    cr,lf
  104.     db    '  Define/Assign   (a command macro)  '
  105.     db    '  Reinput  (script Input, reread buffer)'
  106.     db    cr,lf
  107.     db    '  Delete   (a file)                  '
  108.     db    '  Remote   (prefix for commands)'
  109.     db    cr,lf
  110.     db    '  Directory                          '
  111.     db    '  Replay   (file through term emulator)'
  112.     db    cr,lf
  113.     db    '  Disable  (selected server commands)'
  114.     db    '  Run      (a program)'
  115.     db    cr,lf
  116.     db    '  Do       (a macro)                 '
  117.         db      '  S or Send  local file   new name'
  118.     db    cr,lf
  119.     db    '  Echo text (show line on screen)    '
  120.     db    '  Server [timeout] (become a server)'
  121.     db    cr,lf
  122.     db    '  Enable   (selected server commands)'
  123.         db      '  Set      (most things)'
  124.     db    cr,lf         
  125.     db      '  EXIT     (leave Kermit)            '
  126.     db    '  Show     (most things)'
  127.     db    cr,lf
  128.     db    '  Finish   (to remote server)        '
  129.     db    '  Space    (free on current disk)'
  130.     db    cr,lf
  131.     db    '  Get      (remote file opt new name)'
  132.         db      '  Status   (show main conditions)'
  133.     db    cr,lf
  134.     db    '  Goto    (label, Take file or Macro)'
  135.     db    '  Stop     (exit all Take files & macros)'
  136.     db    cr,lf
  137.     db    '  Hangup   (drop DTR, hang up phone) '
  138.     db    '  Take     (do a command file)'
  139.     db    cr,lf
  140.     db    '  If [not] <condition> <command>     '
  141.     db    '  Transmit filespec [prompt] (raw upload)'
  142.     db    cr,lf
  143.     db    '  I or Input [timeout] text (scripts)'
  144.     db    '  Type     (a file)'
  145.     db    cr,lf
  146.     db    '  Log (Packet, Session, Transaction) '
  147.     db    '  Wait [timeout] on modem \cd \cts \dsr'
  148.     db    cr,lf
  149.     db    '  Logout   (remote server)           '
  150.     db    '  Write    <to log file> <object type>'
  151.     db    cr,lf
  152.     db    '  Mail     (file to host Mailer)'
  153.     db    cr,lf
  154.     db    '  Type HELP for an Introduction, use "?" within commands for'
  155.     db    ' specific help.$'
  156. ;;;    db    '  Load filespec (file translate tbl) '
  157. ;;;    db    '  Version  (show Kermit''s id)'
  158.  
  159.  
  160. qckhlp    db cr,lf
  161.     db '                    Introduction to MS-DOS Kermit',cr,lf
  162.     db 'o An MS-Kermit command is a line of words separated by spaces and'
  163.     db ' ending with',cr,lf,'  a carriage return <the Enter key>.'
  164.     db '  Example: SET SPEED 2400<Enter>',cr,lf
  165.     db 'o Most words can be abbreviated and can be completed by pressing'
  166.     db ' the Esc key.',cr,lf
  167.     db '  Example: SET SPE 24<Enter>  or even  SET SPE<Esc> 24<Esc>'
  168.     db '<Enter>',cr,lf
  169.     db 'o Help (detailed, specific): press the "?" key where a word would'
  170.     db ' appear.',cr,lf
  171.     db 'o Edit lines using the Backspace key to delete characters,'
  172.     db ' Control-W to delete',cr,lf
  173.     db '  words, and Control-U to delete the line.  Control-C cancels the'
  174.     db ' command.',cr,lf
  175.     db 'o Frequently used MS-Kermit commands:',cr,lf
  176.     db '  EXIT           Leave the Kermit program. QUIT does the same'
  177.     db ' thing.',cr,lf
  178.     db '  SET            PORT, PARITY, SPEED, TERMINAL and many other'
  179.     db ' parameters.',cr,lf
  180.     db '  SHOW or STATUS Display groups of important parameters.'
  181.     db ' SHOW ? for categories.',cr,lf,lf
  182.     db '  CONNECT        Establish a terminal connection to a remote'
  183.     db ' system or a modem.',cr,lf
  184.     db '  Control-$'
  185. qckhlp1    db ' C    (Control-$'
  186. qckhlp2    db '  followed by "C")  Return to MS-Kermit> prompt.',cr,lf,lf
  187.     db '  SEND filename  Send the file(s) to Kermit on the other'
  188.     db ' computer).',cr,lf
  189.     db '  RECEIVE        Receive file(s), SEND them from Kermit on the'
  190.     db ' other computer.',cr,lf
  191.     db '  GET filename   Ask the remote Kermit server to send the file(s)'
  192.     db ' to us.',cr,lf
  193.     db '  FINISH         Shut down remote Kermit but stay logged into'
  194.     db ' remote system.',cr,lf
  195.     db '  BYE            FINISH and logout of remote system and exit'
  196.     db ' local Kermit.',cr,lf
  197.     db 'o Common startup sequence: SET SPEED 9600, CONNECT, login, start'
  198.     db ' remote Kermit,',cr,lf
  199.     db '  put it into Server mode, escape back with Control-$'
  200. qckhlp3    db ' C, transfer'
  201.     db ' files with',cr,lf
  202.     db '  SEND x.txt, GET b.txt, BYE. Read more about it in "Using MS-DOS'
  203.     db ' Kermit".'
  204.     db cr,lf
  205.     db 'Press the "?" key for a summary of Kermit commands, or space for'
  206.         db ' prompt.$'
  207.  
  208. comtab  db    59            ; COMND tables
  209.     mkeyw    'Ask',ask
  210.     mkeyw    'Askq',askq
  211.     mkeyw    'Assign',assign
  212.     mkeyw    'Bye',bye
  213.     mkeyw    'C',telnet
  214.     mkeyw    'CD',cwdir
  215.     mkeyw    'Clear',scclr
  216.     mkeyw    'Close',clscpt
  217.     mkeyw    'Comment',comnt
  218.     mkeyw    'Connect',telnet
  219.     mkeyw    'CWD',cwdir
  220.     mkeyw    'Define',dodef
  221.     mkeyw    'Delete',delete
  222.     mkeyw    'Directory',direct
  223.     mkeyw    'Disable',srvdsa
  224.     mkeyw    'Do',docom
  225.     mkeyw    'Echo',scecho
  226.     mkeyw    'Enable',srvena
  227.     mkeyw    'Exit',exit
  228.     mkeyw    'Finish',finish
  229.     mkeyw    'Get',get
  230.     mkeyw    'goto',goto
  231.     mkeyw    'H',help
  232.     mkeyw    'Hangup',dtrlow
  233.     mkeyw    'Help',help
  234.     mkeyw    'If',ifcmd
  235.     mkeyw    'I',scinp
  236.     mkeyw    'Input',scinp
  237. ;;;    mkeyw    'Load',load
  238.     mkeyw    'Log',setcpt
  239.     mkeyw    'Logout',logout
  240.     mkeyw    'Mail',mail
  241.     mkeyw    'Output',scout
  242.     mkeyw    'Pause',scpau
  243.     mkeyw    'Pop',takclos
  244.     mkeyw    'Push',dopush
  245.     mkeyw    'Quit',exit
  246.     mkeyw    'R',read
  247.     mkeyw    'Receive',read
  248.     mkeyw    'Reinput',screinp
  249.     mkeyw    'Remote',remote
  250.     mkeyw    'Replay',replay
  251.     mkeyw    'Run',run
  252.     mkeyw    'S',send
  253.     mkeyw    'Send',send
  254.     mkeyw    'Server',server
  255.     mkeyw    'Set',setcom
  256.     mkeyw    'Show',showcmd
  257.     mkeyw    'Space',chkdsk
  258.     mkeyw    'Status',status
  259.     mkeyw    'Stay',stay
  260.     mkeyw    'Stop',takeqit
  261.     mkeyw    'Take',take
  262.     mkeyw    'Transmit',scxmit
  263.     mkeyw    'Type',typec
  264.     mkeyw    'Version',prvers
  265.     mkeyw    'Wait',scwait
  266.     mkeyw    'Write',write
  267.     mkeyw    ':',comnt        ; script labels, do not react
  268.     mkeyw    'Patch',patch
  269.  
  270. shotab    db    13            ; SHOW keyword
  271.     mkeyw    'Communications',shcom
  272.     mkeyw    'File',shfile
  273.     mkeyw    'Key',shokey
  274.     mkeyw    'Logging',shlog
  275.     mkeyw    'Macros',shomac
  276.     mkeyw    'Memory',shmem
  277.     mkeyw    'Modem',shomodem
  278.     mkeyw    'Protocol',shpro
  279.     mkeyw    'Scripts',shscpt
  280.     mkeyw    'Server',shserv
  281.     mkeyw    'Statistics',shosta
  282.     mkeyw    'Terminal',shterm
  283.     mkeyw    'Translation',shorx
  284.                     ; Kermit initing from Environment
  285. nulprmpt db    0            ; null prompt
  286. initab    db    2            ; Environment phrase dispatch table
  287.     mkeyw    'INPUT-buffer-length',setinpbuf ; Script INPUT buffer length
  288.     mkeyw    'Rollback',setrollb    ; number of Terminal rollback screens
  289. patched    db    1        ; 1 = enable patching; 0 = disable or done
  290.  
  291.     even
  292. lclsusp    dw    0        ; address of routine to call when going to DOS
  293. lclrest    dw    0        ; address of routine to call when returning
  294. lclexit    dw    0        ; address of routine to call when exiting
  295. ssave    dw    0        ; Original SS when doing Command.com
  296. in3ad    dw    0,0        ; Original break interrupt addresses
  297. ceadr    dd    0        ; DOS Critical Error interrupt address
  298. orgcbrk    db    0        ; original Control-Break Check state
  299. psp    dw    0        ; segment of Program Segment Prefix
  300. exearg    dw    0        ; segment addr of environment (filled in below)
  301.     dd    0        ; ptr to cmd line (filled in below)
  302.     dw    5ch,0,6ch,0    ; our def fcb's; segment filled in later
  303. dosnum    dw    0        ; dos version number, major=low, minor=high
  304. curdsk    db    0        ; Current disk
  305. origd    db    0        ; Original disk
  306. orgdir    db    64 dup (0)    ; original directory on original disk
  307. taklev    db    0        ; Take levels
  308. takadr    dw    takstr-(size takinfo) ; Pointer into structure
  309. takstr    db    (size takinfo) * maxtak dup(?)
  310. filtst    filest    <>        ; file structure for procedure isfile
  311. maxtry    db    defmxtry    ; Retry limit for data packet send/rcv
  312. ininm2    db    'MSKERMIT.INI',0 ; init file name for 2.0
  313. ptchnam    db    'MSKERMIT.PCH',0 ; patch file name
  314. delcmd    db    ' del ',0    ; delete command
  315. dircmd    db    ' dir ',0    ; directory command
  316. typcmd    db    ' type ',0    ; type command
  317. kerenv    db    'KERMIT=',0,0    ; Kermit= environment variable, + 2 nulls
  318. pthnam    db    'PATH='        ; Path environment variable
  319. pthlen    equ    $-pthnam    ;  length of that string
  320. pthadr    dw    0        ; offset of PATH= string
  321.  
  322. slashc    db    ' /c '        ; slashc Must directly preceed tmpbuf
  323. tmpbuf    db    128 dup (0)    ; temp space for file names and comments
  324. cmspnam    db    'COMSPEC='    ; Environment variable
  325. cmsplen    equ    $-cmspnam
  326. cmspbuf    db    '\command.com',30 dup (0) ; default name plus additional space
  327. shellnam db    'SHELL='    ; Environment variable
  328. shellen    equ    $-shellnam
  329. shellbuf db    40 dup (0)    ; buffer for name
  330. eexit    db    cr,'exit',cr
  331. leexit    equ    $-eexit
  332. mfmsg    db    '?Not enough memory to run Kermit$'
  333. mf7msg    db    '?Attempted to allocate a corrupted memory area$'
  334. spcmsg    db    ' bytes available on drive '
  335. spcmsg1    db    ' :',cr,lf,0
  336. spcmsg2    db    cr,lf,' Drive '
  337. spcmsg3    db    ' : is not ready',0
  338. errlev    db    0        ; DOS errorlevel to be returned
  339. kstatus    dw    0        ; command execution status (0 = success)
  340. thsep    db    0        ; thousands separator
  341. totpar    dw    0
  342. temp    dw    0
  343. data   ends
  344.  
  345. code    segment    public 'code' 
  346.     extrn    logout:near, mail:near, load:near
  347.     extrn    bye:near, telnet:near, finish:near, comnd:near, prompt:near
  348.     extrn    read:near, remote:near, send:near, status:near, get:near
  349.     extrn    serrst:near, setcom:near, dtrlow:near
  350.     extrn    clscpi:near, clscpt:near, scpini:near, setrollb:near
  351.     extrn    dodef:near, setcpt:near, docom:near, shomodem:near
  352.     extrn    server:near, lclini:near, shokey:near, shomac:near, shosta:near
  353.     extrn    strlen:near, strcpy:near, shserv:near, initibm:near
  354.     extrn    strcat:near, prtasz:near, shorx:near, lnout:near, lnouts:near
  355.     extrn    scout:near,scinp:near,scpau:near,scecho:near,scclr:near
  356.     extrn    scxmit:near, scwait:near, srvdsa:near, srvena:near
  357.     extrn    shcom:near, shlog:near, shpro:near, shterm:near, shscpt:near
  358.     extrn    shfile:near, takopen:near, takclos:near, ask:near, askq:near
  359.     extrn    assign:near, goto:near, screinp:near, ifcmd:near, write:near
  360.     extrn    setinpbuf:near, shmem:near, replay:near, atoi:near
  361.     extrn    katoi:near
  362.  
  363.         assume  cs:code, ds:data, ss:stack, es:nothing
  364.  
  365. START    PROC    FAR
  366.     mov    ax,data            ; initialize DS
  367.         mov    ds,ax
  368.     mov    psp,es            ; remember psp address
  369.  
  370.     mov    ah,dosver        ; get DOS version number (word)
  371.     int    dos
  372.     xchg    ah,al            ; major version to ah
  373.     mov    dosnum,ax        ; remember dos version
  374.     cmp    ax,200h            ; earlier than DOS 2.0?
  375.     jge    start1            ; ge = no
  376.     mov    ah,prstr
  377.     mov    dx,offset erms34    ; complain
  378.     int    dos
  379.     push    psp            ; set up exit for DOS 1
  380.     xor    ax,ax            ; and the IP
  381.     push    ax            ; make return addr of psp:0 for DOS 1
  382.     ret                ; and return far to exit now
  383. start1:    mov    ah,setdma        ; set disk transfer address
  384.     mov    dx,offset buff
  385.     int    dos
  386.  
  387.     call    setint            ; ^C, DOS critical error interrupts
  388.     mov    ah,gcurdsk        ; get current disk
  389.     int    dos
  390.     inc    al            ; make 1 == A (not zero)
  391.     mov    curdsk,al
  392.     mov    origd,al        ; remember original disk we started on
  393.     mov    si,offset orgdir     ; place for directory path w/o drive code
  394.     add    al,'A'-1        ; make al alphabetic disk drive again
  395.     mov    [si],al            ; put it into original path descriptor
  396.     inc    si
  397.     mov    byte ptr [si],':'    ; add drive specifier too
  398.     inc    si
  399.     mov    byte ptr [si],'\'    ; add root indicator as well
  400.     inc    si
  401.     mov    ah,gcd            ; get current directory (path really)
  402.     xor    dl,dl            ; use current drive
  403.     int    dos
  404.     call    getpath            ; get the path from the environment
  405.     call    gettsep            ; get thousands separator
  406.     mov    ah,gswitch
  407.     xor    al,al            ; pick up switch character
  408.     int    dos
  409.     mov    slashc+1,dl
  410.     and    maxtry,3fh        ; limit # packet retries
  411.     call    getcsp            ; get comspec from environment
  412.     call    getssp            ; get shellspec from environment
  413.     call    memini            ; initialize our memory usage
  414.     call    getparm            ; read "KERMIT=" Environment line
  415.     jc    start1b            ; c = fatal error
  416.     xor    cl,cl            ; counter, starts at 0
  417. start1a:mov    bx,offset kerenv+6    ; append "<digit>="  to "KERMIT"
  418.     mov    [bx],cl            ; binary digit
  419.     inc    cl
  420.     add    byte ptr [bx],'0'    ; to ascii
  421.     mov    byte ptr [bx+1],'='    ; append equals sign
  422.     call    getparm            ; read "KERMITn=" Environment line
  423.     jc    start1b            ; c = fatal error
  424.     cmp    cl,9            ; done all digits?
  425.     jbe    start1a            ; be = no
  426.                     ;
  427.     call    scpini            ; initialize script routines
  428.     jc    start1b            ; c = fatal error
  429.     call    lclini            ; do local initialization
  430.     cmp    flags.extflg,0        ; exit now?
  431.     je    start2            ; e = no
  432. start1b:mov    ah,prstr        ; announce our premature exit
  433.     mov    dx,offset ermes5    ; can't complete initialization
  434.     int    dos
  435.     jmp    krmend            ; quit immediately
  436. start2:    mov    comand.cmrprs,offset krmend ; address to go to on reparse
  437.     mov    comand.cmostp,sp    ; save for reparse too
  438.     call    gcmdlin            ; read command line
  439.     cmp    taklev,0        ; in a Take file?
  440.     jne    start3            ; ne = yes, skip help msg
  441.     mov    ah,prstr
  442.     mov    dx,offset machnam    ; display machine name
  443.     int    dos
  444.         mov    dx,offset verident    ; display version header
  445.         int    dos
  446.     mov    dx,offset copyright    ; display copyright notice
  447.     int    dos
  448.     mov    dx,offset hlpmsg
  449.     int    dos
  450. start3:    mov    flags.chrset,437    ; find default global char set
  451.     cmp    dosnum,0300h+30        ; DOS version 3.30 or higher?
  452.     jb    start4            ; b = no, no Code Pages
  453.     mov    ax,6601h        ; get global Code Page
  454.     int    dos            ; bx=active Code Page, dx=boot CP
  455.     mov    flags.chrset,bx        ; setup default SET FILE CHAR SET
  456. start4:    call    serrst            ; reset serial port (if active)
  457.     call    initibm            ; define IBM macro
  458.     call    rdinit            ; read kermit init file
  459.  
  460.  ; This is the main KERMIT loop.  It prompts for and gets the users commands
  461.  
  462. kermit:    mov    ax,ds
  463.     mov    es,ax            ; convenient safety measure
  464.     cmp    taklev,0        ; keep port open between script cmds
  465.     jne    kermt1            ; ne = in Take or Macro
  466.     call    serrst            ; reset serial port for CTTY DOS use
  467. kermt1:    mov    dx,prmptr        ; get prompt
  468.     call    prompt              ; prompt user, set reparse address
  469.     mov    flags.cxzflg,0        ; reset each time
  470.     and    flags.remflg,not dserver ; turn off server mode bit
  471.     mov    dx,offset comtab
  472.     mov    bx,offset tophlp
  473.     cmp    flags.extflg,0        ; exit flag set?
  474.     jne    krmend            ; ne = yes, jump to KRMEND
  475.     mov    comand.cmcr,1        ; allow bare CR's
  476.         mov    ah,cmkey
  477.     mov    comand.impdo,1        ; allow implied "DO macro"
  478.     call    comnd
  479.     jc    kermt3            ; c = failure
  480.     mov    comand.impdo,0        ; only on initial keyword, not here
  481.     mov    comand.cmcr,0        ; no more bare CR's
  482.     call    bx                  ; call the routine returned in BX
  483.     jc    kermt3            ; c = failure
  484.     cmp    flags.extflg,0        ; exit flag set?
  485.     jne    krmend            ; ne = yes, jump to KRMEND
  486.     jmp    short kermt5        ; do idle loop cleanup
  487.  
  488. kermt3:    cmp    flags.cxzflg,'C'    ; got here via Control-C?
  489.     jne    kermt7            ; ne = no
  490.     cmp    flags.extflg,0        ; exit flag set?
  491.     jne    kermt5            ; ne = yes, skip msg, do cleanup
  492.     mov    dx,offset ermes3    ; say command not executed
  493.     mov    ah,prstr        ; print    the error message in dx
  494.     int    dos
  495. kermt5:    cmp    flags.cxzflg,'C'    ; user Control-C abort?
  496.     jne    kermt7            ; ne = no, do normal operations
  497.     cmp    taklev,0        ; in a Take file?
  498.     je    kermt7            ; e = no        
  499.     call    takclos            ; close take file, release buffer
  500.     jmp    kermt5            ; close any other take files
  501. kermt7:    cmp    flags.extflg,0        ; exit flag set?
  502.     jne    krmend            ; ne = yes, Exit now
  503.     jmp    kermit            ; get next command
  504.  
  505. krmend: call    serrst            ; just in case the port wasn't reset
  506.     test    flags.capflg,0FFH    ; Logging active?
  507.     jz    krmend2            ; z = no
  508.     call    clscpi            ; close log files
  509. krmend2:cmp    lclexit,0        ; sys dependent routines want service?
  510.     je    krmend3            ; e = no
  511.     mov    bx,lclexit        ; addr of sys dependent exit routine
  512.     call    bx            ; call it
  513. krmend3:mov    dl,origd        ; original disk drive
  514.     dec    dl            ; want A == 0
  515.     mov    ah,seldsk        ; reset original disk just in case
  516.     int    dos
  517.     mov    dx,offset orgdir    ; restore original directory
  518.     mov    ah,chdir
  519.     int    dos
  520.     mov    dx,offset in3ad        ; restore Control-C interrupt vector
  521.     mov    al,23H            ; interrupt 23H
  522.     mov    ah,25H            ; set interrupt vector
  523.     int    dos            ; ah, that's better
  524.     mov    dx,offset ceadr        ; DOS's Critical Error handler
  525.     mov    al,24h            ; interrupt 24h
  526.     mov    ah,25h            ; do replacement (put it back)
  527.     int    dos
  528.     call    cbrestore        ; restore state of Control-Break Chk
  529.     mov    ah,4cH            ; terminate process
  530.     mov    al,errlev        ; return error level
  531.     int    dos
  532.     ret
  533. START    ENDP
  534.  
  535. ; This is the 'EXIT' command.  It leaves KERMIT and returns to DOS
  536.  
  537. EXIT    PROC    NEAR
  538.     mov    ah,cmeol
  539.     call    comnd            ; get a confirm
  540.     jc    exit1            ; c = failure
  541.     mov    flags.extflg,1        ; set the exit-Kermit flag
  542. exit1:    ret
  543. EXIT    ENDP
  544.  
  545. ; TAKE commands    from a file, and allow a path name
  546. TAKE    PROC    NEAR
  547.     mov    kstatus,0        ; global status, success
  548.     cmp    taklev,maxtak        ; at the limit?
  549.     jl    take1            ; l = no
  550.     mov    ah,prstr
  551.     mov    dx,offset erms30    ; complain
  552.     int    dos
  553.     stc                ; failure
  554.     ret
  555. take1:    mov    dx,offset tmpbuf    ; work buffer
  556.     mov    tmpbuf,0
  557.     mov    bx,offset filmsg    ; Help in case user types "?"
  558.     mov    ah,cmword        ; get file name
  559.     call    comnd
  560.     jc    take1a            ; c = failure
  561.     mov    ah,cmeol
  562.     call    comnd
  563.     jc    take1a            ; c = failure
  564.     mov    ax,offset tmpbuf    ; point to name again
  565.     cmp    tmpbuf,0        ; empty filespec?
  566.     jne    take2            ; ne = no
  567.     mov    ah,prstr
  568.     mov    dx,offset ermes1    ; say more parameters needed
  569.     int    dos
  570.     stc
  571. take1a:    ret
  572.                     ; TAKE2: enter with ax=filename ptr
  573. TAKE2:    call    spath            ; is it around?
  574.     jc    take3            ; no, go complain
  575.     mov    dx,ax            ; point to name from spath
  576.     mov    ah,open2        ; open file
  577.     xor    al,al            ; 0 = open for reading
  578.     cmp    dosnum,300h        ; at or above DOS 3?
  579.     jb    take2a            ; b = no, so no shared access
  580.     or    al,40h            ; open for reading, deny none
  581. take2a:    int    dos
  582.     jnc    take4            ; nc = opened ok, keep going
  583.     mov    ax,dx            ; recover filename pointer
  584. take3:    push    ax
  585.     mov    ah,prstr
  586.     mov    dx,offset erms31
  587.     int    dos
  588.     pop    ax
  589.     mov    dx,ax            ; asciiz file name
  590.     call    prtasz            ; display it
  591.     mov    kstatus,8        ; global status
  592.     clc                ; we've done all error displays
  593.     ret
  594.                     ; TAKE4: enter with ax=filename ptr
  595. TAKE4:    call    takopen            ; open take buffer in macro space
  596.     jc    take6            ; c = failure
  597.     push    bx
  598.     mov    bx,takadr        ; get current frame ptr
  599.     mov    [bx].takhnd,ax        ; save file handle
  600.     mov    [bx].taktyp,0feh     ; mark as 2.0 file handle
  601.     pop    bx
  602.     cmp    flags.takflg,0        ; echoing Take files?
  603.     je    take5            ; e = no
  604.     mov    ah,prstr
  605.     mov    dx,offset crlf
  606.     int    dos
  607. take5:    call    takrd            ; get a buffer full of data
  608.     clc                ; success
  609. take6:    ret
  610. TAKE    ENDP
  611.  
  612. TAKRD    PROC    NEAR
  613.     push    ax
  614.     push    bx
  615.     push    cx    
  616.     push    dx
  617.     mov    bx,takadr
  618.     cmp    [bx].taktyp,0feh    ; get type of take (file?)
  619.     jne    takrd1            ; ne = no, do not read from disk
  620.     mov    cx,tbufsiz-1        ; # of bytes to read
  621.     mov    ax,[bx].takbuf        ; segment of Take buffer
  622.     push    bx            ; save frame address
  623.     mov    bx,[bx].takhnd        ; file handle is stored here
  624.     push    ds            ; save ds
  625.     mov    ds,ax            ; set ds to Take buffer segment
  626.     mov    dx,1            ; ds:dx = buffer, skip count byte
  627.     mov    ah,readf2        ; read file
  628.     int    dos
  629.     pop    ds
  630.     pop    bx            ; restore frame address
  631.     jnc    takrd2            ; nc = successful read
  632. takrd1:    xor    ax,ax            ; error, say zero bytes read
  633. takrd2:    mov    [bx].takcnt,ax        ; number of bytes read
  634.     mov    [bx].takptr,1        ; offset of first new character
  635.     pop    dx
  636.     pop    cx
  637.     pop    bx
  638.     pop    ax
  639.     ret
  640. TAKRD    ENDP
  641.  
  642. ; TAKE-QUIT  (STOP)  Exit all Take files immediately but gracefully
  643.  
  644. TAKEQIT PROC    NEAR
  645.     mov    ah,cmeol
  646.     call    comnd
  647.     jnc    takqit1            ; nc = success
  648.     ret
  649. takqit1:xor    ch,ch
  650.     mov    cl,taklev        ; number of Take levels active
  651.     jcxz    takqit2            ; z = none
  652.     call    takclos            ; close current Take file
  653.     jmp    short takqit1        ; repeat until all are closed
  654. takqit2:clc                ; success
  655.     ret
  656. TAKEQIT    ENDP
  657.  
  658. ; put mskermit.ini onto take stack if it exists.  Just like
  659. ; the take command, except it doesn't read a filename
  660.  
  661. rdinit    proc    near            ; read kermit init file..
  662.     mov    ax,offset ininm2    ; default name to try
  663.     cmp    decbuf,0        ; alternate init file given?
  664.     je    rdini1            ; ne = no
  665.     mov    ax,offset decbuf    ; yes, use it
  666.     call    take2            ; let Take do error msgs
  667.     clc                ; force success
  668.     ret
  669. rdini1:    call    spath            ; is it around?
  670.     jc    rdini2            ; no, ignore file
  671.     mov    dx,ax            ; point to name from spath
  672.     mov    ah,open2        ; open file
  673.     xor    al,al            ; 0 = open for reading
  674.     cmp    dosnum,300h        ; at or above DOS 3?
  675.     jb    rdini1a            ; b = no, so no shared access
  676.     or    al,40h            ; open for reading, deny none
  677. rdini1a:int    dos
  678.     jc    rdini2            ; c = no ini file found, ignore
  679.     call    take4            ; use TAKE command to complete work
  680.     clc                ; ignore errors
  681. rdini2:    ret
  682. rdinit    endp
  683.  
  684.  
  685.  
  686.  
  687.  
  688. ; Patcher.  Patch file, MSKERMIT.PCH has the following format:
  689.  
  690. ; 300 \Xxxxx    ; optional comment.  300 for V3.00.  For xxxx, see below
  691. ; ; optional comment lines may appear anywhere after the 1st
  692. ; ; xxxx in 1st line total paragraphs in memory image.  Use \X if hex.
  693. ; DS:xxxx xx xx        ; optional comment.  DS (or CS) are case insensitive
  694. ; CS:xxxx xx xx xx    ; locations must be 4 hex chars, contents must be 2
  695.  
  696. ; CS & DS lines may be intermixed.
  697. ; This mechanism expects file msscmd.obj to be linked first.
  698.  
  699. PATCH    proc
  700.     mov    ah,cmeol    ; confirm please
  701.     call    comnd
  702.     jc    ptch2        ; c = no confirm
  703.     xor    ax,ax
  704.     xchg    al,patched    ; clear and test patched
  705.     test    al,al
  706.     jnz    ptch2        ; z = disabled or done
  707.     xchg    ah,flags.takflg    ; clear take flag -- don't echo patches
  708.     mov    byte ptr temp,ah; but save it
  709.     call    ptchr
  710.     mov    al,byte ptr temp; restore take flag
  711.     mov    flags.takflg,al
  712.     jnc    ptch2        ; nc = OK
  713.     mov    dx,offset ermes8; Fatal error
  714.     mov    ah,prstr
  715.     int    dos
  716.     jmp    krmend        ; force exit
  717.  
  718. ptchr:    mov    ax,offset ptchnam ; point to name of patch file
  719.     call    rdini1        ; let rdini try to find it & do take stuff
  720.     jnc    ptch15        ; nc = file mskermit.pch was found
  721.     mov    dx,offset ermes7 ; say file not found
  722.     mov    ah,prstr
  723.     int    dos
  724.     clc
  725.     ret
  726. ptch15:    mov    al,taklev    ; remember initial take level
  727.     mov    tmpbuf,al    ; when it changes, it's EOF & we're done
  728.     mov    comand.cmcr,1    ; bare cr's ok, to prevent prserr @EOF
  729.     mov    dx,offset tmpbuf+1 ; where to read
  730.     call    ptchrl        ; read 1st 'word'
  731.     jc    ptch0        ; c = trubble
  732.     mov    si,offset tmpbuf+1
  733.     call    atoi        ; convert version string to integer
  734.     jc    ptch0        ; c = bad number, or none
  735.     cmp    ax,version    ; does it match this version?
  736.     je    ptch3        ; e = yes
  737. ptch0:    mov    al,tmpbuf    ; if take level has changed,
  738.     xor    al,taklev    ;  we're already out of patch file
  739.     jnz    ptch1        ; nz = change in take level
  740.     call    takclos        ; close patch file
  741. ptch1:    mov    dx,offset ermes6
  742.     mov    ah,prstr    ; issue warning msg
  743.     int    dos
  744.     clc
  745. ptch2:    ret
  746.  
  747. ptch3:    mov    dx,offset tmpbuf+1
  748.     call    ptchrw        ; read 2nd "word", 1st line
  749.     jc    ptch0        ; c = NG
  750.     mov    si,offset tmpbuf+1
  751.     call    katoi        ; convert 2nd "magic number"
  752.     jc    ptch0        ; c = NG
  753.     cmp    ax,totpar    ; is it the total paragraphs memini computed?
  754.     jne    ptch0        ; ne = no
  755.  
  756. ptch4:    mov    dx,offset tmpbuf+1
  757.     call    ptchrl        ; read CS:xxxx or DS:xxxx
  758.     jc    ptch2
  759.     mov    si,offset tmpbuf
  760.     cld
  761.     lodsb            ; initial take level
  762.     xor    al,taklev    ; if unequal, it's EOF (clears carry)
  763.     jnz    ptch2        ; nz = EOF, we're done
  764.     test    ah,ah        ; empty (possibly ;comment) line?
  765.     jz    ptch4        ; z = yes; ignore it
  766.     mov    tmpbuf+64,al    ; clear replacement byte count
  767.     cmp    ah,7        ; were 7 chars read?
  768.     jne    ptch5        ; ne = no
  769.     and    word ptr[si],not 2020h ; convert to upper case
  770.     lodsb            ; get the 'C' or 'D'
  771.     cmp    word ptr[si],':S' ; S:, actually
  772.     je    ptch6        ; e = ok
  773. ptch5:    stc            ; error exit
  774.     ret
  775.  
  776. ptch6:    mov    bx,cs        ; assume CS
  777.     cmp    al,'C'
  778.     je    ptch7        ; e = good guess
  779.     cmp    al,'D'
  780.     jne    ptch5        ; ne = neither CS or DS
  781.     mov    bx,ds        ; modify assumption
  782.  
  783. ptch7:    mov    word ptr[si],'X\' ; put '\X' in front of hex for katoi
  784.     call    katoi        ; convert location
  785.     jc    ptch2        ; c= NG
  786.     push    bx        ; save seg being patched
  787.     push    ax        ; save location being patched
  788. ptch8:    mov    dx,offset tmpbuf+4
  789.     call    ptchrw        ; read replacement byte follwing '\X'
  790.     jnc    ptch10        ; nc = OK
  791. ptch9:    pop    ax        ; clean stack & error return
  792.     pop    ax
  793.     stc
  794.     ret
  795.  
  796. ptch10:    test    ah,ah        ; EOL?
  797.     jnz    ptch11        ; nz = no
  798.     mov    si,offset tmpbuf+64
  799.     cld
  800.     lodsb            ; replacement byte count
  801.     cmp    ah,al        ; were there any?
  802.     je    ptch9        ; e = no
  803.     mov    cx,ax        ; replacement count
  804.     pop    di        ; patch location
  805.     pop    es        ; patch segment
  806.     rep    movsb        ; make patch
  807.     jmp    ptch4        ; loop to read next line
  808.  
  809. ptch11:    cmp    ah,2        ; 2 chars req'd for replacement byte
  810.     jne    ptch9        ; ne = bad
  811.     mov    si,offset tmpbuf+2 ; convert it
  812.     call    katoi
  813.     jc    ptch9        ; c = bad number or none
  814.     mov    si,offset tmpbuf+64    ; --> replacement byte counted string
  815.     inc    byte ptr[si]    ; bump count
  816.     mov    bl,[si]
  817.     xor    bh,bh
  818.     mov    byte ptr[si+bx],al ; stash replacement byte
  819.     jmp    ptch8        ; loop for next byte
  820.  
  821. ptchrl:    mov    bp,dx
  822.     mov    dx,offset crlf
  823.     call    prompt
  824.     mov    dx,bp
  825. ptchrw:    mov    ah,cmword
  826.     mov    comand.cmper,1    ; prohibit substitution variable expansion
  827.     xor    bx,bx        ; 'help' ptr
  828.     call    comnd
  829.     ret
  830. PATCH    endp    
  831.  
  832. ; Get command line into a Take macro buffer. Allow "-f filspec" to override
  833. ; normal mskermit.ini initialization filespec, allow command "stay" to
  834. ; suppress automatic exit to DOS at end of command line execution. [jrd]
  835.  
  836. gcmdlin    proc    near
  837.     mov    word ptr decbuf,0    ; storage for new init filename
  838.     push    es
  839.     cld
  840.     mov    es,psp            ; address psp
  841.     xor    ch,ch
  842.     mov    cl,es:byte ptr[cline]    ; length of cmd line from DOS
  843.     jcxz    gcmdl1            ; z = empty line
  844.     mov    si,cline+1        ; point to actual line
  845. gcmdl0:    cmp    byte ptr es:[si],' '    ; skip over leading whitespace
  846.     ja    gcmdl2            ; a = non-whitespace
  847.     inc    si
  848.     loop    gcmdl0            ; fall through on all whitespace
  849. gcmdl1:    jmp    gcmdl14            ; common exit jump point
  850. gcmdl2:    inc    cx            ; include DOS's c/r
  851.     call    takopen            ; open take buffer in macro space
  852.     mov    bx,takadr
  853.     mov    byte ptr [bx].taktyp,0ffh ; mark as a macro
  854.     mov    [bx].takcnt,0        ; length of text
  855.     mov    es,[bx].takbuf        ; segment of buffer, from takopen
  856.     mov    di,1            ; skip count byte
  857.     push    psp
  858.     pop    ds            ; DS = PSP
  859. gcmdl3:    cmp    cx,0            ; anything left?
  860.     jle    gcmdl10            ; le = no
  861.     lodsb                ; get a byte from PSP's command line
  862.     dec    cx            ; one less char in input string
  863.     cmp    al,','            ; comma?
  864.     jne    gcmdl4            ; no, keep going
  865.     mov    al,cr            ; convert to cr
  866.     jmp    short gcmdl9        ; store it
  867. gcmdl4:    cmp    al,'-'            ; starting a flag?
  868.     jne    gcmdl9            ; ne = no
  869.     mov    ah,[si]            ; get flag letter
  870.     or    ah,20h            ; convert to lower case
  871.     cmp    ah,'f'            ; 'f' for init file replacement?
  872.     jne    gcmdl9            ; ne = no
  873.     inc    si            ; accept flag letter
  874.     dec    cx
  875. gcmdl5:    cmp    cx,0            ; anything to read?
  876.     jle    gcmdl10            ; le = exhausted supply
  877.     lodsb                ; get filespec char from psp
  878.     dec    cx            ; one less char in source buffer
  879.     cmp    al,' '            ; in whitespace?
  880.     jbe    gcmdl5            ; be = yes, scan it off
  881.     dec    si            ; backup to real text
  882.     inc    cx
  883.                     ; copy filspec to buffer decbuf
  884.     push    es            ; save current destination pointer
  885.     push    di            ;  which is in es:di (Take buffer)
  886.     mov    di,data            ; set es:di to regular decbuf
  887.     mov    es,di
  888.     lea    di,decbuf        ; where filespec part goes
  889.     mov    word ptr es:[di],0    ; plant safety terminator
  890. gcmdl6:    lodsb                ; get filespec char
  891.     dec    cx            ; one less available
  892.     cmp    al,' '            ; in printables?
  893.     jbe    gcmdl7            ; be = no, all done
  894.     cmp    al,','            ; comma command separator?
  895.     je    gcmdl7            ; e = yes, all done
  896.     stosb                ; store filespec char
  897.     cmp    cx,0            ; any chars left?
  898.     jg    short gcmdl6        ; g = yes
  899. gcmdl7:    mov    byte ptr es:[di],0    ; end filespec on a null
  900.     pop    di            ; recover destination pointer es:di
  901.     pop    es
  902. gcmdl8:    cmp    cx,0            ; strip trailing whitespace
  903.     jle    gcmdl10            ; le = nothing left
  904.     lodsb
  905.     dec    cx
  906.     cmp    al,' '            ; white space?
  907.     jbe    gcmdl8            ; be = yes, strip it
  908.     cmp    al,','            ; at next command?
  909.     je    gcmdl10            ; e = yes, skip our own comma
  910.     dec    si            ; back up to reread the char
  911.     inc    cx
  912.     jmp    gcmdl3            ; read more command text
  913.                     ; end of flag analysis
  914. gcmdl9:    stosb                ; deposit most recent char
  915. gcmdl10:cmp    cx,0            ; anything left to read?
  916.     jg    gcmdl3            ; g = yes, loop
  917.                     ;
  918.     mov    ax,data            ; restore segment registers
  919.     mov    ds,ax
  920.     mov    si,[bx].takbuf        ; get segment of Take buffer
  921.     mov    es,si
  922.     mov    si,1            ; skip count byte
  923.     mov    cx,di            ; current end pointer, (save di)
  924.     sub    cx,si            ; current ptr minus start offset
  925.     mov    [bx].takcnt,cx        ; chars in buffer so far
  926.     mov    es:byte ptr [0],cl    ; store count byte
  927.     cmp    cx,0
  928.     jg    gcmdl11            ; material at hand
  929.     call    takclos            ; empty take file
  930.     jmp    gcmdl14            ; finish up
  931.                     ; scan for command "stay"
  932. gcmdl11:mov    al,es:[si]        ; get a byte, cx and si are set above
  933.     inc    si
  934.     dec    cx
  935.     cmp    al,' '            ; separator?
  936.     jbe    gcmdl12            ; be = yes, keep looking
  937.     cmp    al,','             ; comma separator?
  938.     je    gcmdl12            ; e = yes
  939.     mov    ah,al            ; get first byte
  940.     mov    al,es:[si]        ; second byte after separator
  941.     inc    si
  942.     dec    cx
  943.     or    ax,2020h        ; convert to lower case
  944.     cmp    ax,'st'            ; first two letters of stay
  945.     jne    gcmdl12            ; ne = no match
  946.     mov    ax,es:[si]        ; next two letters (stay vs status)
  947.     add    si,2
  948.     sub    cx,2
  949.     or    ax,2020h        ; convert to lower case
  950.     cmp    ax,'ya'            ; same as our pattern?
  951.     jne    gcmdl12            ; ne = no match
  952.                     ; check for separator or end of macro
  953.     cmp    cx,0            ; at end of macro?
  954.     jle    gcmdl13            ; yes, consider current match correct
  955.     cmp    byte ptr es:[si],' '    ; next char is a separator?
  956.     jbe    gcmdl13            ; be = yes, found correct match
  957.     cmp    byte ptr es:[si],','    ; or comma separator?
  958.     je    gcmdl13            ; e = yes
  959. gcmdl12:cmp    cx,0            ; done yet? ("stay" not found)
  960.     jg    gcmdl11            ; g = not yet, look some more
  961.     mov    si,offset eexit        ; append command "exit"
  962.     mov    cx,leexit        ; length of string "exit"
  963.     add    [bx].takcnt,cx
  964.     rep    movsb            ; copy it into the Take buffer
  965. gcmdl13:mov    [bx].takptr,1        ; init buffer ptr
  966.     mov    cx,[bx].takcnt        ; count of bytes in buffer
  967.     mov    es:byte ptr [0],cl    ; count of bytes in Take buffer
  968. gcmdl14:pop    es
  969.     ret
  970. gcmdlin    endp
  971.  
  972. ; Enter with ax pointing to file name.  Searches path for given file,
  973. ; returns with ax pointing to whole name, or carry set if file can't be found.
  974. SPATH    proc    near
  975.     call    isfile            ; does it exist as it is?
  976.     jc    spath0            ; c = no, prepend path elements
  977.     test    byte ptr filtst.dta+21,10H ; subdirectory name?
  978.     jnz    spath0            ; nz = yes, not desired file
  979.     clc
  980.     ret
  981. spath0:    push    es            ; save es around work
  982.     push    bx
  983.     push    si
  984.     push    di
  985.     mov    bx,ax            ; save filename pointer in bx
  986.     mov    si,ax
  987.     xor    dl,dl            ; no '\' seen yet
  988.     cld
  989. spath1:    lodsb
  990.     cmp    al,2fh            ; contains fwd slash path characters?
  991.     je    spath1a
  992.     cmp    al,5ch            ; or backslash?
  993.     jne    spath2            ; no, keep going
  994. spath1a:mov    dl,1            ; remember we've seen them
  995. spath2:    or    al,al
  996.     jnz    spath1            ; copy name in
  997.     or    dl,dl            ; look at flag
  998.     jz    spath3            ; no path, keep looking
  999.     jmp    short spath9        ; embedded path, fail
  1000.  
  1001. spath3:    mov    si,pthadr        ; offset of PATH= string in environment
  1002.     mov    es,psp
  1003.     mov    di,es:word ptr[env]    ; pick up environment segment
  1004.     mov    es,di
  1005. spath4:    cmp    byte ptr es:[si],0    ; end of PATH= string?
  1006.     je    spath9            ; e = yes, exit loop
  1007.     mov    di,offset decbuf+64    ; place to put name
  1008. spath5:    mov    al,byte ptr es:[si]    ; get a byte from environment string
  1009.     inc    si
  1010.     cmp    al,';'            ; end of this part?
  1011.     je    spath7            ; yes, break loop
  1012.     or    al,al            ; maybe end of string?
  1013.     jnz    spath6            ; nz = no, keep going
  1014.     dec    si            ; back up to null for later rereading
  1015.     jmp    short spath7        ; and break loop
  1016. spath6:    mov    byte ptr [di],al    ; else stick in dest string
  1017.     inc    di
  1018.     jmp    spath5            ; and continue
  1019. spath7:    push    si            ; save this ptr
  1020.     mov    si,bx            ; this is user's file name
  1021.     cmp    byte ptr [di-1],2fh    ; does path end with switch char?
  1022.     je    spath8            ; yes, don't put one in
  1023.     cmp    byte ptr [di-1],5ch    ; how about this one?
  1024.     je    spath8            ; yes, don't put it in
  1025.     mov    byte ptr [di],5ch    ; else add one
  1026.     inc    di
  1027. spath8:    lodsb                ; get filename character
  1028.     mov    byte ptr [di],al    ; copy filename char to output buffer
  1029.     inc    di
  1030.     or    al,al            ; end of string?
  1031.     jnz    spath8            ; nz = no, copy rest of name
  1032.     pop    si            ; restore postion in path string
  1033.     mov    ax,offset decbuf+64
  1034.     call    isfile            ; is it a file?
  1035.     jc    spath4            ; c = no, keep looking
  1036.     test    byte ptr filtst.dta+21,10H ; subdirectory name?
  1037.     jnz    spath4            ; nz = yes
  1038.     pop    di
  1039.     pop    si
  1040.     pop    bx
  1041.     pop    es
  1042.     clc
  1043.     ret                ; return success (carry clear)
  1044. spath9:    mov    ax,bx            ; restore original filename pointer
  1045.     pop    di            ; restore regs
  1046.     pop    si
  1047.     pop    bx
  1048.     pop    es
  1049.     stc                ; no file found
  1050.     ret
  1051. spath    endp
  1052.  
  1053. ; Put offset of PATH= string in pthadr
  1054. getpath    proc    near
  1055.     push    bx
  1056.     push    cx
  1057.     push    dx
  1058.     mov    bx,offset pthnam    ; thing    to find
  1059.     mov    cx,pthlen        ; length of it
  1060.     mov    pthadr,0        ; init offset to zero
  1061.     call    getenv            ; get environment value
  1062.     mov    pthadr,dx
  1063.     pop    dx
  1064.     pop    cx
  1065.     pop    bx
  1066.     ret
  1067. getpath    endp
  1068.  
  1069. ; getcsp: copy COMSPEC= environment string into cmspbuf
  1070. ; getssp: copy SHELL=   environment string into shellbuf
  1071. getcsp    proc    near
  1072.     mov    bx,offset cmspnam    ; find COMSPEC=
  1073.     mov    cx,cmsplen        ; it's length
  1074.     mov    di,offset cmspbuf    ; where to store string
  1075.     jmp    short getccom        ; do common worker
  1076.  
  1077. getssp:    mov    bx,offset shellnam    ; find SHELL=
  1078.     mov    cx,shellen        ; it's length
  1079.     mov    di,offset shellbuf    ; where to store string
  1080.     
  1081. getccom:push    es
  1082.     call    getenv            ; get environment offset into dx
  1083.     mov    si,dx            ; address of COMSPEC= string
  1084.     mov    es,psp
  1085.     mov    bx,es:word ptr[env]    ; pick up environment address
  1086.     mov    es,bx
  1087.     push    ds            ; save ds
  1088.     push    ds            ; make ds point to environment seg
  1089.     push    es            ; make es point to data segment
  1090.     pop    ds
  1091.     pop    es
  1092.     cld
  1093. getcs1:    lodsb                ; get a byte from environment
  1094.     cmp    al,' '            ; space or less?
  1095.     jg    getcs2            ; g = no, keep copying
  1096.     xor    al,al            ; terminate string on spaces etc
  1097. getcs2:    stosb                ; store it in destination
  1098.     or    al,al            ; at end of string yet?
  1099.     jnz    getcs1            ; nz = no, keep copying
  1100.     pop    ds            ; recover ds
  1101.     pop    es
  1102.     ret
  1103. getcsp    endp
  1104.  
  1105. ; Get Kermit parameters from the Environment. Parameters are commands like
  1106. ; regular commands except they do not appear in the SET main table and are
  1107. ; separated from one another by semicolons. They appear after KERMIT=.
  1108. ; Do not allow Take/Macros to be created by any of these commands.
  1109. ; On fatal error exits with carry set and flags.extflg = 1
  1110. getparm    proc    near
  1111.     push    ax
  1112.     push    bx
  1113.     push    cx
  1114.     push    dx
  1115.     push    si
  1116.     push    di
  1117.     push    es
  1118.     mov    es,psp            ; segment of our PSP
  1119.     mov    ax,es:word ptr[env]    ; pick up environment address
  1120.     mov    es,ax
  1121.     mov    bx,offset kerenv    ; Environment word to find, asciiz
  1122.     mov    dx,bx
  1123.     call    strlen            ; length of its string to cx
  1124.     call    getenv            ; return dx = offset in environment
  1125.     jnc    getpar1            ; nc = success
  1126.     jmp    getpar9            ; c = not found
  1127. getpar1:PUSH    DS            ; save regular DS
  1128.     push    dx            ; push Environment offset, then seg
  1129.     push    es
  1130.     call    takopen            ; open Take buffer in macro space
  1131.     jnc    getpar2            ; nc = success
  1132.     mov    flags.extflg,1        ; say exit now
  1133.     pop    es            ; clean stack
  1134.     pop    dx
  1135.     pop    ds
  1136.     jmp    getparx            ; exit with fatal error
  1137.  
  1138. getpar2:mov    bx,takadr        ; bx = Take data structure
  1139.     mov    byte ptr [bx].taktyp,0ffh ; mark as a macro
  1140.     mov    [bx].takcnt,0        ; length of text
  1141.     mov    es,[bx].takbuf        ; ES = segment of buffer, from takopen
  1142.     mov    di,1            ; skip count byte field for es:di
  1143.     pop    DS            ; pop Environment segment (was in ES)
  1144.     pop    si            ;  and seg, DS:SI is now Environment
  1145.     xor    cx,cx            ; line length counter
  1146. getpar3:lodsb                ; read an Environment character
  1147.     or    al,al            ; null (EOL)?
  1148.     jz    getpar5            ; z = yes, stop here
  1149.     cmp    al,';'            ; semicolon separator?
  1150.     jne    getpar4            ; ne = no
  1151.     mov    al,CR            ; replace semicolon with carriage ret
  1152. getpar4:stosb                ; store char in Take buffer
  1153.     inc    cx            ; count line length
  1154.     jmp    short getpar3        ; get more text, until a null
  1155.  
  1156. getpar5:mov    al,CR            ; terminate line, regardless
  1157.     stosb
  1158.     inc    cx            ; count terminator
  1159.     POP    DS            ; restore regular DS
  1160.     mov    [bx].takcnt,cx        ; chars in Take/macro buffer
  1161.     mov    es:byte ptr [0],cl    ; store count byte
  1162.     mov    [bx].takptr,1        ; init buffer read ptr to first char
  1163.     jcxz    getpar8            ; z = nothing left, exit
  1164.                     ; parse each item as a command
  1165. getpar6:mov    comand.cmquiet,1    ; no screen display
  1166.     mov    dx,offset nulprmpt    ; set null prompt
  1167.     call    prompt
  1168.     cmp    flags.extflg,0        ; exit flag set?
  1169.     jne    getpar8            ; ne = yes, exit this routine now
  1170.     mov    dx,offset initab    ; table of initialization routines
  1171.     xor    bx,bx            ; no explict help text
  1172.     mov    comand.cmcr,1        ; allow bare CR's
  1173.     mov    comand.impdo,0        ; do not search Macro table
  1174.         mov    ah,cmkey        ; match a keyword
  1175.     call    comnd
  1176.     jc    getpar7            ; c = failure
  1177.     mov    comand.cmcr,0        ; no more bare CR's
  1178.     call    bx            ; call the routine returned in BX
  1179.                     ; ignore failures (carry bit set)
  1180. getpar7:cmp    taklev,0        ; finished Take file?
  1181.     je    getpar8            ; e = yes
  1182.     cmp    flags.extflg,0        ; exit flag set?
  1183.     je    getpar6            ; e = no, finish all commands
  1184.  
  1185. getpar8:call    takclos            ; close our take file, if open
  1186. getpar9:mov    flags.extflg,0        ; do not leave this flag set
  1187.     clc                ; clear for success
  1188. getparx:mov    comand.cmquiet,0    ; regular screen echoing
  1189.     pop    es
  1190.     pop    di
  1191.     pop    si
  1192.     pop    dx
  1193.     pop    cx
  1194.     pop    bx
  1195.     pop    ax
  1196.     ret
  1197. getparm    endp
  1198.  
  1199. ; Locate string variable in Environment
  1200. ; bx = variable to find (usually including =), cx = length of variable name.
  1201. ; Returns dx = offset within Environment of char following the name and
  1202. ; carry clear, else carry set and dx unchanged.
  1203. getenv    proc    near
  1204.     push    ax
  1205.     push    cx
  1206.     push    si
  1207.     push    di
  1208.     push    es
  1209.     mov    es,psp
  1210.     mov    ax,es:word ptr[env]    ; pick up environment address
  1211.     mov    es,ax
  1212.     xor    di,di            ; start at offset 0 in segment
  1213. geten1:    cmp    es:byte ptr [di],0    ; end of environment?
  1214.     je    geten3            ; yes, forget it
  1215.     push    cx            ; save counter
  1216.     push    di            ; and offset
  1217.     mov    si,bx
  1218.     cld
  1219.     repe    cmpsb            ; search for name
  1220.     pop    di
  1221.     pop    cx            ; restore these
  1222.     je    geten2            ; found it, break loop
  1223.     push    cx            ; preserve again
  1224.     mov    cx,0ffffh        ; bogus length
  1225.     xor    al,al            ; 0 = marker to look for
  1226.     repne    scasb            ; search for it
  1227.     pop    cx            ; restore length
  1228.     jmp    geten1            ; loop thru rest of environment
  1229. geten2:    add    di,cx            ; skip to definition
  1230.     mov    dx,di            ; store offset of string
  1231.     clc                ; carry clear for success
  1232.     jmp    short geten4
  1233. geten3:    stc                ; carry set for failure
  1234. geten4:    pop    es
  1235.     pop    di
  1236.     pop    si
  1237.     pop    cx
  1238.     pop    ax
  1239.     ret
  1240. getenv    endp
  1241.  
  1242. ; Get thousands separator from DOS Country Information
  1243. gettsep    proc    near
  1244.     mov    ah,38h            ; Get Country Information
  1245.     mov    dx,offset tmpbuf    ; temp buffer
  1246.     int    dos
  1247.     mov    bx,7            ; assume DOS 3+ position in buffer
  1248.     cmp    byte ptr dosnum+1,3    ; DOS 3 or above?
  1249.     jae    gettse1            ; ae = yes
  1250.     mov    bx,4            ; for DOS 2.1
  1251.     cmp    dosnum,210h        ; earlier than version 2.1?
  1252.     jae    gettse1            ; ae = no
  1253.     mov    al,','            ; use comma for old DOS's
  1254. gettse1:mov    al,tmpbuf[bx]        ; get thousands separator char
  1255.     mov    thsep,al        ; save it
  1256.     ret
  1257. gettsep    endp
  1258.  
  1259. STAY    PROC    NEAR
  1260.     clc
  1261.     ret
  1262. STAY    ENDP
  1263.  
  1264. COMNT    PROC    NEAR            ; COMMENT command
  1265.     mov    ah,cmline
  1266.     mov    bx,offset tmpbuf
  1267.     xor    dx,dx
  1268.     call    comnd
  1269.     ret
  1270. COMNT    ENDP
  1271.  
  1272. ; change working directory
  1273. cwdir    proc    near
  1274.     mov    kstatus,0        ; global status
  1275.     mov    ah,cmword
  1276.     mov    dx,offset tmpbuf
  1277.     mov    bx,offset pthmsg
  1278.     mov    word ptr tmpbuf,0
  1279.     call    comnd            ; get drive/dir spec, if any
  1280.     mov    ah,cmeol
  1281.     call    comnd
  1282.     jnc    cwd1
  1283.     ret                ; c = failure
  1284. cwd1:    mov    dx,offset crlf        ; msgs from cdsr don't include this
  1285.     mov    ah,prstr        ; so let's do it now
  1286.     int    dos
  1287.     mov    si,offset tmpbuf    ; cdsr wants drive/path ptr in si
  1288.     call    cdsr            ; common CD sub-routine
  1289.     jnc    cwd2            ; nc = success
  1290.     mov    kstatus,8        ; global status for unsuccess
  1291. cwd2:    call    prtasz            ; output current drive/path or err msg
  1292.     clc
  1293.     ret
  1294. cwdir    endp
  1295.  
  1296. ; CDSR processes both CD & REM CD.  Entered with si --> drive/path, it returns
  1297. ; dx --> ASCIIZ current drive/path, w/carry clear, if successful, or error msg
  1298. ; w/carry set, if not.
  1299. CDSR    PROC
  1300.     xor    cx,cx            ; 0 for default drive, if none
  1301.     cmp    byte ptr[si],ch        ; any drive/path?
  1302.     je    cdsr4            ; e = no, just format current drive/path
  1303.     cmp    byte ptr[si+1],':'    ; is drive specified?
  1304.     jne    cdsr1            ; ne = no
  1305.     mov    cl,[si]            ; drive letter
  1306.     cmp    byte ptr[si+2],ch    ; any path?
  1307.     jne    cdsr1            ; ne = yes
  1308.     mov    word ptr[si+2],'.'    ; append dot+null as path to kludge DOS
  1309. cdsr1:    call    dskspace        ; test for drive, spec'd by cl, ready
  1310.     jnc    cdsr2            ; nc = ready
  1311.     mov    spcmsg3,cl        ; insert drive letter ret'd by dskspace
  1312.     mov    dx,offset spcmsg2+2    ; in err msg.  dx --> msg w/o cr,lf
  1313.     ret                ; carry is set
  1314.  
  1315. cdsr2:    mov    dx,si            ; where chdir wants it
  1316.     mov    ah,chdir
  1317.     int    dos
  1318.     jnc    cdsr3            ; nc = success
  1319.     mov    dx,offset ermes4    ; ret carry set, dx --> err msg
  1320.     ret
  1321.  
  1322. cdsr3:    mov    dl,cl            ; uc drive letter ret'd by dskspace
  1323.     sub    dl,'A'            ; A = 0 for seldsk
  1324.     mov    ah,seldsk
  1325.     int    dos
  1326.     inc    dl            ; A = 1 for curdsk
  1327.     mov    curdsk,dl
  1328. cdsr4:    push    si            ; use caller's buffer for cur dr/path
  1329.     mov    ax,':@'            ; al = 'A' - 1, ah = ':'
  1330.     add    al,curdsk        ; al = drive letter
  1331.     mov    [si],ax            ; stash drive:
  1332.     inc    si
  1333.     inc    si
  1334.     mov    byte ptr[si],'\'    ; add \
  1335.     inc    si
  1336.     mov    ah,gcd            ; gcd fills in path as ASCIIZ
  1337.     xor    dl,dl            ; use current drive
  1338.     int    dos
  1339.     pop    dx            ; return caller's buffer pointer in dx
  1340.     clc
  1341.     ret
  1342. CDSR    ENDP
  1343.  
  1344. ; Erase specified file(s). Add protection of ignore hidden, subdir, volume
  1345. ; label and system files. 9 Jan 86 [jrd]
  1346. DELETE    PROC    NEAR            ; includes paths and "?*" wildcards
  1347.     mov    kstatus,0        ; global status
  1348.     mov    si,offset delcmd    ; del command
  1349.     mov    di,offset tmpbuf
  1350.     call    strcpy
  1351.     mov    dx,offset tmpbuf
  1352.     call    strlen            ; get its length
  1353.     add    di,cx            ; point at terminator
  1354.     mov    temp,di            ; remember starting spot
  1355.     mov    ah,cmline        ; get a line
  1356.     mov    bx,di            ; where to place the file spec
  1357.     mov    dx,offset filmsg    ; help message
  1358.     call    comnd
  1359.     jc    delet0            ; c = failure
  1360.     or    ah,ah            ; anything given?
  1361.     jnz    delet1            ; nz = yes
  1362.     mov    ah,prstr
  1363.     mov    dx,offset ermes1    ; say need something
  1364.     int    dos
  1365.     clc                ; say success
  1366. delet0:    ret
  1367.  
  1368. delet1:    mov    di,temp            ; start of filespec
  1369.     xor    cl,cl            ; disk drive letter
  1370.     cmp    byte ptr [di+1],':'    ; drive specified?
  1371.     jne    delet2            ; ne = no
  1372.     mov    cl,[di]            ; get drive letter
  1373. delet2:    call    dskspace        ; compute space, get letter into CL
  1374.     jnc    delet3            ; nc = success
  1375.     mov    spcmsg3,cl        ; put drive letter in msg
  1376.     mov    dx,offset spcmsg2    ; error message
  1377.     call    prtasz
  1378.     mov    kstatus,8        ; global status
  1379.     clc
  1380.     ret                ; and ignore this command
  1381. delet3:    mov    si,offset tmpbuf    ; del cmd
  1382.     jmp    crun            ; join run cmd from there
  1383. DELETE    ENDP
  1384.  
  1385. ; Space <optional drive letter>
  1386.  
  1387. CHKDSK    PROC    NEAR            ; Space command
  1388.     mov    kstatus,0        ; global status
  1389.     mov    dx,offset tmpbuf    ; buffer
  1390.     mov    tmpbuf,0        ; init to null
  1391.     mov    bx,offset dskmsg    ; help message
  1392.     mov    ah,cmword        ; get optional drive letter
  1393.     call    comnd            ; ignore errors
  1394.     mov    ah,cmeol
  1395.     call    comnd
  1396.     jnc    chkdsk1            ; nc = success
  1397.     ret                ; failure
  1398. chkdsk1:mov    cl,tmpbuf        ; set drive letter
  1399.     call    dskspace        ; compute space, get letter into CL
  1400.     jnc    chkdsk2            ; nc = success
  1401.     and    cl,5fh            ; to upper case
  1402.     mov    spcmsg3,cl        ; insert drive letter
  1403.     mov    dx,offset spcmsg2    ; say drive not ready
  1404.     call    prtasz
  1405.     mov    kstatus,8        ; global status
  1406.     clc
  1407.     ret
  1408.     
  1409. chkdsk2:mov    spcmsg1,cl        ; insert drive letter
  1410.     mov    di,offset tmpbuf    ; work space for lnout
  1411.     mov    word ptr[di],0a0dh    ; cr/lf
  1412.     mov    word ptr[di+2],'  '    ; add two spaces
  1413.     add    di,4
  1414.     call    lnouts            ; use thousands separator
  1415.     mov    si,offset spcmsg
  1416.     call    strcat            ; add text to end of message
  1417.     mov    dx,offset tmpbuf
  1418.     call    prtasz            ; print asciiz string
  1419.     clc
  1420.     ret
  1421. CHKDSK    ENDP
  1422.  
  1423. ; Compute disk free space (bytes) into long word dx:ax.
  1424. ; Enter with disk LETTER in CL (use null if current disk).
  1425. ; Returns uppercase drive letter in CL.
  1426. ; Returns carry set if drive access error. Changes AX, DX.
  1427.  
  1428. DSKSPACE PROC    NEAR
  1429.     mov    dl,cl            ; desired disk letter, or null
  1430.     or    dl,dl            ; use current disk?
  1431.     jnz    dskspa1            ; nz = no
  1432.     mov    ah,gcurdsk        ; get current disk
  1433.     int    dos
  1434.     add    al,'A'            ; make 0 ==> A
  1435.     mov    dl,al
  1436. dskspa1:and    dl,5fh            ; convert to upper case
  1437.     mov    cl,dl            ; return upper case drive letter in CL
  1438.     sub    dl,'A'-1        ; 'A' is 1, etc
  1439.     push    bx
  1440.     push    cx
  1441.     mov    ah,36h            ; get disk free space, bx=sect/cluster
  1442.     int    dos            ; dx:ax=sectors, cx=bytes/sector
  1443.     cmp    ax,0ffffh        ; error response?
  1444.     jne    dskspa2            ; ne = no
  1445.     pop    cx
  1446.     pop    bx
  1447.     stc                ; return error
  1448.     ret
  1449. dskspa2:mul    bx            ; sectors/cluster * clusters = sectors
  1450.     mov    bx,dx            ; save high word of sectors (> 64K)
  1451.     mul    cx            ; bytes = sectors * bytes/sector
  1452.     push    ax            ; save low word of bytes
  1453.     mov    ax,bx            ; recall sectors high word
  1454.     mov    bx,dx            ; save current bytes high word
  1455.     mul    cx            ; high word sectors * bytes/sector
  1456.     add    ax,bx            ; new high bytes + old high bytes
  1457.     mov    dx,ax            ; store high word in dx
  1458.     pop    ax            ; space is in dx:ax as a long word
  1459.     pop    cx
  1460.     pop    bx
  1461.     clc
  1462.     ret
  1463. DSKSPACE ENDP
  1464.  
  1465. ; Get directory    listing
  1466. DIRECT    PROC    NEAR
  1467.     mov    kstatus,0        ; global status
  1468.     mov    si,offset dircmd    ; dir command
  1469.     mov    di,offset tmpbuf
  1470.     call    strcpy
  1471.     mov    dx,offset tmpbuf
  1472.     call    strlen            ; get its length
  1473.     add    di,cx            ; point at terminator
  1474.     mov    temp,cx            ; remember length
  1475.     mov    ah,cmline        ; parse with cmline to allow switches
  1476.     mov    bx,di            ; next available byte
  1477.     mov    dx,offset filmsg    ; help message 
  1478.     call    comnd
  1479.     jnc    direct1            ; nc = success
  1480.     ret                ; failure
  1481. direct1:mov    word ptr [bx],0        ; plant terminator
  1482.     mov    cl,curdsk        ; current drive number ('A'=1)
  1483.     add    cl,'A'-1        ; make a letter
  1484.     mov    si,offset tmpbuf
  1485.     push    si
  1486.     add    si,temp            ; user's text after ' dir '
  1487.     cmp    byte ptr [si+1],':'    ; drive specified?
  1488.     jne    direct2            ; ne = no, use current drive
  1489.     mov    cl,[si]            ; get drive letter from buffer
  1490. direct2:call    dskspace        ; check for drive ready
  1491.     pop    si
  1492.     jnc    direct3            ; nc = drive ready
  1493.     mov    spcmsg3,cl        ; insert letter
  1494.     mov    dx,offset spcmsg2    ; say drive is not ready
  1495.     call    prtasz
  1496.     stc
  1497.     ret
  1498. direct3:jmp    crun            ; join run cmd from there
  1499. DIRECT    ENDP
  1500.  
  1501. ; This is the 'HELP' command.  It gives a list of the commands
  1502.  
  1503. HELP    PROC    NEAR
  1504.     mov    kstatus,0        ; global status
  1505.     mov    ah,cmeol
  1506.     call    comnd            ; get a confirm
  1507.     jnc    help1            ; nc = success
  1508.     ret                ; failure
  1509. help1:    mov    ah,prstr        ; show Quick help summary screen
  1510.     mov    dx,offset qckhlp
  1511.     int    dos
  1512.     mov    ah,conout
  1513.     mov    dl,trans.escchr        ; get Kermit escape character
  1514.     add    dl,40h            ; convert to printable
  1515.     push    dx            ; save it for repeats below
  1516.     int    dos
  1517.     mov    ah,prstr
  1518.     mov    dx,offset qckhlp1    ; more help text
  1519.     int    dos
  1520.     mov    ah,conout
  1521.     pop    dx
  1522.     push    dx
  1523.     int    dos
  1524.     mov    ah,prstr
  1525.     mov    dx,offset qckhlp2    ; more help text
  1526.     int    dos
  1527.     pop    dx            ; recover current escape char
  1528.     mov    ah,conout
  1529.     int    dos
  1530.     mov    ah,prstr
  1531.     mov    dx,offset qckhlp3    ; end of help message
  1532.     int    dos
  1533.     mov    ah,coninq        ; get a keystroke, quietly
  1534.     int    dos
  1535.     cmp    al,'?'            ; query mark?
  1536.     jne    helpx            ; ne = no, skip second screen
  1537.     mov    ah,prstr        ; show help summary screen
  1538.     mov    dx,offset crlf        ; a few blank lines
  1539.     int    dos
  1540.     int    dos
  1541.     int    dos
  1542.     mov    dx,offset tophlp    ; show usual cryptic help
  1543.     int    dos
  1544. helpx:    clc
  1545.     ret
  1546. HELP    ENDP
  1547.  
  1548. ; the version command - print our version number
  1549. prvers    proc    near
  1550.     mov    kstatus,0        ; global status
  1551.     mov    ah,cmeol
  1552.     call    comnd
  1553.     jc    prvers1            ; c = failure
  1554.     mov    ah,prstr
  1555.     mov    dx,offset crlf
  1556.     int    dos
  1557.     mov    ah,prstr
  1558.     mov    dx,offset machnam    ; display machine name
  1559.     int    dos
  1560.     mov    ah,prstr        ; display the version header
  1561.     mov    dx,offset verident
  1562.     int    dos
  1563.     clc
  1564. prvers1:ret
  1565. prvers    endp
  1566.  
  1567. ; the show command
  1568. showcmd    proc    near
  1569.     mov    kstatus,0        ; global status
  1570.     mov    ah,cmkey
  1571.     mov    dx,offset shotab
  1572.     xor    bx,bx            ; no canned help
  1573.     call    comnd
  1574.     jc    showc1            ; c = failure
  1575.     jmp    bx            ; execute the handler
  1576. showc1:    ret                ; failure
  1577. showcmd    endp
  1578.  
  1579. ; the type command - type out a file
  1580. typec    proc    near
  1581.     mov    kstatus,0        ; global status
  1582.     mov    si,offset typcmd    ; type command
  1583.     mov    di,offset tmpbuf
  1584.     call    strcpy
  1585.     mov    dx,offset tmpbuf
  1586.     call    strlen            ; get its length
  1587.     add    di,cx            ; point at terminator
  1588.     mov    temp,di            ; save place for later
  1589.     mov    ah,cmline        ; parse with cmline so we can have paths
  1590.     mov    bx,di            ; next available byte
  1591.     mov    dx,offset filmsg    ; In case user wants help
  1592.     call    comnd
  1593.     jc    typec1            ; c = failure
  1594.     or    ah,ah            ; any text given?
  1595.     jnz    typec2            ; nz = yes
  1596.     mov    ah,prstr
  1597.     mov    dx,offset ermes1    ; say need more info
  1598.     int    dos
  1599.     clc
  1600. typec1:    ret
  1601. typec2:    mov    byte ptr [bx],0        ; plant terminator
  1602.     mov    si,temp            ; start of filespec
  1603.     xor    cl,cl            ; say local drive
  1604.     cmp    byte ptr [si+1],':'    ; drive given?
  1605.     jne    typec3            ; ne = no
  1606.     mov    cl,[si]            ; get drive letter
  1607. typec3:    call    dskspace        ; check for drive ready
  1608.     jnc    typec4
  1609.     mov    spcmsg3,cl        ; put drive letter in msg
  1610.     mov    dx,offset spcmsg2    ; error message
  1611.     call    prtasz
  1612.     mov    kstatus,8        ; global status
  1613.     clc
  1614.     ret                ; and ignore this command
  1615. typec4:    mov    si,offset tmpbuf
  1616.     jmp    short crun        ; join run cmd from there
  1617. typec    endp
  1618.  
  1619. ; PUSH to DOS (run another copy of Command.com or equiv)
  1620. ; entry fpush (fast push...) pushes without waiting for a confirm
  1621. dopush    proc    near
  1622.     mov    ah,cmeol
  1623.     call    comnd
  1624.     jnc    fpush            ; nc = success
  1625.     ret                ; failure
  1626. fpush:    mov    si,offset tmpbuf    ; a dummy buffer
  1627.     mov    byte ptr [si],0        ; plant terminator
  1628.     mov    dx,offset cmspbuf    ; always use command.com
  1629.     cmp    shellbuf,0        ; SHELL= present?
  1630.     je    crun4            ; e = no, use COMSPEC= name
  1631.     mov    dx,offset shellbuf    ; use SHELL= name
  1632.     jmp    short crun4        ; go run it
  1633. dopush    endp
  1634.  
  1635. ; Run a program from within Kermit
  1636. RUN    PROC    NEAR
  1637.     mov    ah,cmline        ; get program name and any arguments
  1638.     mov    bx,offset tmpbuf    ; place for user's text
  1639.     mov    dx,offset runmsg    ; In case user wants help
  1640.     call    comnd
  1641.     jnc    run1            ; nc = success
  1642.     ret                ; failure
  1643. run1:    or    ah,ah            ; byte count
  1644.     jnz    run2            ; nz = have program name
  1645.     mov    ah,prstr        ; else complain
  1646.     mov    dx,offset ermes1    ; need more info
  1647.     int    dos
  1648.     clc
  1649.     ret
  1650. run2:    mov    si,offset tmpbuf    ; source of text
  1651.     jmp    short crun
  1652. RUN    ENDP
  1653.  
  1654. ; crun - run an arbitrary program.    Rewritten by [jrd]
  1655. ; Enter with ordinary asciiz command in si (such as Dir *.asm)
  1656. ; Append a c/r and a null terminator and then ask command.com to do it
  1657. ; Set errlev with DOS errorlevel from subprocess.
  1658. CRUN    proc    near
  1659.     mov    ah,prstr        ; output crlf before executing comnd
  1660.     mov    dx,offset crlf        ; [lba]
  1661.     int    dos
  1662.     mov    di,offset tmpbuf    ; where to put full command line text
  1663.     cmp    si,di            ; same place?
  1664.     je    crun1            ; e = yes, don't copy ourself
  1665.     call    strcpy            ; si holds source text
  1666. crun1:    mov    si,offset slashc    ; DOS command begins with slashc area
  1667.     mov    dx,offset slashc+1    ; si points to /c part of command line
  1668.     call    strlen            ; get its length into cx
  1669.     push    bx
  1670.     mov    bx,dx
  1671.     add    bx,cx
  1672.     mov    byte ptr [bx],cr    ; end string with a c/r for dos
  1673.     inc    cx            ; count the c/r
  1674.     mov    byte ptr [bx+1],0    ; and terminate
  1675.     pop    bx
  1676.     mov    [si],cl            ; put length of argument here
  1677.     mov    dx,offset cmspbuf    ; always use command.com
  1678. crun4:    mov    exearg+2,si        ; pointer to argument string
  1679.     mov    exearg+4,ds        ; segment of same
  1680.     cmp    lclsusp,0        ; sys dependent routine to call
  1681.     je    crun5            ; e = none
  1682.     mov    bx,lclsusp        ; address to call
  1683.     push    dx            ; preserve name in dx
  1684.     call    bx            ; call sys dependent suspend routine
  1685.     pop    dx
  1686. crun5:    push    dx            ; preserve name in dx
  1687.     call    serrst            ; reset serial port (if active)
  1688.     call    cbrestore        ; restore state of Control-Break Chk
  1689.     pop    dx
  1690.     mov    es,psp            ; point to psp again
  1691.     mov    exearg+8,es        ; segment of psp, use our def fcb's
  1692.     mov    exearg+12,es        ; segment of psp, ditto, for fcb 2
  1693.     mov    ax,es:word ptr [env]    ; get environment ptr
  1694.     mov    exearg,ax        ; put into argument block
  1695.     mov    ax,ds
  1696.     mov    es,ax            ; put es segment back
  1697.     mov    bx,offset exearg    ; es:bx points to exec parameter block
  1698.     xor    al,al            ; 0 = load and execute (DX has name)
  1699.     mov    ah,exec
  1700.     mov    ssave,sp        ; save stack ptr
  1701.     int    dos            ; go run the program
  1702.     mov    ax,data            ; restore segment registers
  1703.     mov    ds,ax            ; reset data segment
  1704.     mov    es,ax            ; and extra segment
  1705.     mov    ax,stack
  1706.     mov    ss,ax            ; and stack segment
  1707.     mov    sp,ssave        ; restore stack ptr
  1708.     pushf                ; save    flags
  1709.     mov    ah,setdma
  1710.     mov    dx,offset buff
  1711.     int    dos            ; restore dma address!!
  1712.     cmp    flags.chrset,1        ; user-defined table in use?
  1713.     je    crun6            ; e = yes
  1714.     mov    flags.chrset,437    ; find default global char set
  1715.     cmp    dosnum,0300h+30        ; DOS version 3.30 or higher?
  1716.     jb    crun6            ; b = no, no Code Pages
  1717.     mov    ax,6601h        ; get global Code Page
  1718.     int    dos            ; bx=active Code Page, dx=boot CP
  1719.     mov    flags.chrset,bx        ; setup default SET FILE CHAR SET
  1720. crun6:    call    cboff            ; turn off DOS BREAK check
  1721.     popf                ; recover flags
  1722.     jc    crun8            ; c = error, handle
  1723.     cmp    lclrest,0        ; sys dependent routine to call
  1724.     je    crun9            ; e = none
  1725.     mov    bx,lclrest        ; get routine's address
  1726.     call    bx            ; call sys dependent restore routine
  1727. crun9:    mov    ah,4dh            ; get subprocess return status
  1728.     int    dos
  1729.     mov    errlev,al        ; DOS errorlevel
  1730.     clc
  1731.     ret
  1732. crun8:    mov    ah,prstr
  1733.     mov    dx,offset erms37
  1734.     int    dos
  1735.     mov    kstatus,8        ; global status
  1736.     clc
  1737.     ret
  1738. CRUN    ENDP
  1739.  
  1740. ; Replace Int 23h and Int 24h with our own handlers
  1741. ; Revised to ask DOS for original interrupt vector contents, as suggested by
  1742. ; Jack Bryans. 9 Jan 1986 jrd
  1743. ; Modified again 30 August 1986 [jrd]
  1744. SETINT    PROC    NEAR
  1745.     push    es            ; save registers
  1746.     mov    al,23H            ; desired interrupt vector (^C)
  1747.     mov    ah,35H            ; Int 21H, function 35H = Get Vector
  1748.     int    dos            ; get vector in es:bx
  1749.     mov    in3ad,bx        ; save offset of original vector
  1750.     mov    in3ad+2,es        ;   and its segment
  1751.     mov    al,24h            ; DOS critical error, Int 24h
  1752.     mov    ah,35h
  1753.     int    dos
  1754.     mov    word ptr ceadr,bx    ; DOS's Critical Error handler, offset
  1755.     mov    word ptr ceadr+2,es    ;  and segment address
  1756.     push    ds            ; save ds around next DOS call
  1757.     mov    ax,cs            ; compose full address of ^C routine
  1758.     mov    ds,ax            ; segment is the code segment
  1759.     mov    dx,offset intbrk    ;   and offset is intbrk
  1760.     mov    al,23H            ; on ^C, goto intbrk
  1761.     mov    ah,25H            ; set interrupt address from ds:dx
  1762.     int    dos
  1763.     mov    dx,offset dosce        ; replacement Critical Error handler
  1764.     mov    al,24h            ; interrupt 24h
  1765.     mov    ah,25h            ; replace it
  1766.     int    dos
  1767.     pop    ds
  1768.     mov    ax,3300h        ; get state of Control-Break Check
  1769.     int    dos
  1770.     mov    orgcbrk,dl        ; save state here
  1771.     pop    es
  1772.     ret
  1773. SETINT    ENDP
  1774.  
  1775. ; Control Break, Interrupt 23h replacement
  1776. ; Always return with a Continue (vs Abort) condition since Kermit will cope
  1777. ; with failures. [jrd]
  1778. intbrk:    push ax
  1779.     push    ds    
  1780.     mov    ax,data            ; get Kermit's data segment
  1781.     mov    ds,ax
  1782.     mov    flags.cxzflg,'C'    ; say we saw a ^C
  1783.     mov    rstate,'E'
  1784.     mov    sstate,'E'
  1785.     pop    ds
  1786.     pop    ax
  1787.     iret               ; return to caller in a Continue condition
  1788.  
  1789. ; Set DOS' Control-Break Check to off
  1790. cboff    proc    near
  1791.     mov    ax,3301h        ; set Control-Break Chk state
  1792.     xor    dl,dl            ; set state to off
  1793.     int    dos
  1794.     ret
  1795. cboff    endp
  1796.  
  1797. ; Restore DOS's Control-Break Check to startup value
  1798. cbrestore proc    near
  1799.     push    dx
  1800.     mov    ax,3301h        ; set Control-Break Chk state
  1801.     mov    dl,orgcbrk        ; restore state to startup value
  1802.     int    dos
  1803.     pop    dx
  1804.     ret
  1805. cbrestore endp
  1806.  
  1807. ; Kermit's DOS Critical Error Handler, Int 24h. [jrd]
  1808. ; Needed to avoid aborting Kermit with the serial port interrupt active and
  1809. ; the Control Break interrupt redirected. See the DOS Tech Ref Manual for
  1810. ; a start on this material; it is neither complete nor entirely accurate
  1811. ; The stack is the Kermit's stack, the data segment is unknown, interrupts
  1812. ; are off, and the code segment is Kermit's. Note: some implementations of
  1813. ; MS DOS may leave us in DOS's stack. Called by a DOS Int 21h function
  1814. dosce:    test    ah,80h        ; block device (disk drive)?
  1815.     jnz    dosce1        ; nz = no; serial device, memory, etc
  1816.     mov    al,3        ; tell DOS to Fail the Int 21h call
  1817.     iret            ; return to DOS
  1818. dosce1:    add    sp,6        ; pop IP, CS, Flags regs, from DOS's Int 24h
  1819.     pop    ax        ; restore original callers regs existing
  1820.     pop    bx        ;  just before doing Int 21h call
  1821.     pop    cx
  1822.     pop    dx
  1823.     pop    si
  1824.     pop    di
  1825.     pop    bp
  1826.     pop    ds
  1827.     pop    es        
  1828.     mov    al,0ffh        ; signal failure (usually) the DOS 1.x way
  1829.     push    bp        ; Kermit's IP, CS, and Flags are on the stack
  1830.     mov    bp,sp        ;  all ready for an iret, but first a word ..
  1831.     or    word ptr[bp+8],1 ; set carry bit, signals failure DOS 2+ way
  1832.     pop    bp        ; this avoids seeing the Interrupt flag bit
  1833.     iret            ; return to user, simulate return from Int 21h
  1834.  
  1835. ISFILE    PROC    NEAR
  1836. ; Enter with ds:ax pointing at asciiz filename string
  1837. ; Returns carry set if the file pointed to by ax does not exist, else reset
  1838. ; Returns status byte, fstat, with DOS status and high bit set if major error
  1839. ; Does a search-for-first to permit paths and wild cards
  1840. ; Examines All kinds of files (ordinary, subdirs, vol labels, system,
  1841. ;  and hidden). Upgraded to All kinds on 27 Dec 1985. Revised 30 Aug 86 [jrd]
  1842. ; All registers are preserved
  1843.  
  1844.     push    dx            ; save regs
  1845.     push    cx
  1846.     push    ax
  1847.     mov    byte ptr filtst.dta+21,0 ; clear old attribute bits
  1848.     mov    byte ptr filtst.fname,0    ; clear any old filenames
  1849.     mov    filtst.fstat,0        ; clear status byte
  1850.     mov     cx,3fH            ; look at all kinds of files
  1851.     mov    dx,offset filtst.dta    ; own own temporary dta
  1852.     mov    ah,setdma        ; set to new dta
  1853.     int    dos
  1854.     pop    dx            ; get ax (filename string ptr)
  1855.     push    dx            ; save it again
  1856.     mov    ah,first2        ; search for first
  1857.     int    dos
  1858.     pushf                ; save flags
  1859.     mov    dx,offset buff        ; reset dma
  1860.     mov    ah,setdma
  1861.     int    dos
  1862.     popf                ; recover flags
  1863.     jnc    isfil1            ; nc = file found
  1864.     mov    filtst.fstat,al        ; record DOS status
  1865.     cmp    al,2            ; just "File Not Found"?
  1866.     je    isfil2            ; e = yes
  1867.     cmp    al,3            ; "Path not found"?
  1868.     je    isfil2            ; e = yes
  1869.     cmp    al,18            ; "No more files"?
  1870.     je    isfil2            ; e = yes
  1871.     or    filtst.fstat,80h    ; set high bit for more serious error
  1872.     jmp    short isfil2    
  1873. isfil1:    cmp    byte ptr filtst.fname,0    ; did DOS fill in a name?
  1874.     je    isfil2            ; z = no
  1875.     clc
  1876.     jmp    short isfil3
  1877. isfil2:    stc                ; else set carry flag bit
  1878. isfil3:    pop    ax
  1879.     pop    cx
  1880.     pop    dx
  1881.     ret                ; DOS sets carry if file not found
  1882. ISFILE    ENDP
  1883.  
  1884. ; initialize memory usage by returning to DOS anything past the end of kermit
  1885. memini    proc    near
  1886.     push    es
  1887.     mov    es,psp            ; address psp segment again
  1888.     mov    bx,offset msfinal + 15    ; end of pgm + roundup
  1889.     mov    cl,4
  1890.     shr    bx,cl            ; compute # of paragraphs in last seg
  1891.     mov    ax,stack        ; last segment
  1892.     sub    ax,psp            ; minus beginning
  1893.     add    bx,ax            ; # of paragraphs occupied
  1894.     mov    totpar,bx        ; save for patcher's magic number
  1895.     mov    ah,setblk
  1896.     int    dos
  1897.     jc    memin1
  1898.     pop    es
  1899.     ret
  1900. memin1:    pop    es
  1901.     mov    dx,offset ermes2
  1902.     mov    ah,prstr
  1903.     int    dos            ; complain
  1904.     jmp    krmend            ; exit Kermit now
  1905. memini    endp
  1906.  
  1907. ; Allocate memory.  Passed a memory size in ax, allocates that many
  1908. ; bytes (actually rounds up to a paragraph) and returns its SEGMENT in ax
  1909. ; The memory is NOT initialized.  Written by [jrd] to allow memory to
  1910. ; be allocated anywhere in the 1MB address space
  1911. sbrk    proc    near            ; K & R, please forgive us
  1912.     mov    bx,ax            ; bytes wanted
  1913.     add    bx,15            ; round up
  1914.     mov    cl,4
  1915.     shr    bx,cl            ; convert to # of paragraphs
  1916.     mov    cx,bx            ; remember quantity wanted
  1917.     mov    ah,alloc        ; DOS memory allocator
  1918.     int    dos
  1919.     jc    sbrkx            ; c = fatal
  1920.     cmp    cx,bx            ; paragraphs wanted vs delivered
  1921.     jb    sbrkx            ; b = not enough, fatal error
  1922.     ret                ; and return segment in ax
  1923. sbrkx:    mov    dx,offset mfmsg        ; assume not enough memory (ax = 8)
  1924.     cmp    ax,7            ; corrupted memory (ax = 7)?
  1925.     jne    sbrkx1            ; ne = no
  1926.     mov    dx,offset mf7msg    ; corrupted memory found
  1927. sbrkx1:    mov    ah,prstr
  1928.     int    dos
  1929.     jmp    krmend            ; exit Kermit now
  1930. sbrk    endp
  1931. code     ends
  1932.     end    start
  1933.