home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / ckscripts / twoscomplementv2 < prev    next >
Text File  |  2020-01-01  |  6KB  |  182 lines
  1. # Macros to convert signed decimal numbers to two's complement hexadecimal
  2. # notation.  This version does not use machine arithmetic; it does everything
  3. # with strings, so is able to handle integers of any size.  As written it
  4. # accommodates word sizes of 4, 8, 16, 32, 64, and 128 bits.  Other word
  5. # sizes can be added by changing the definitions at the top.
  6. # 
  7. # Because machine arithmetic is not used, this version is considerably slower
  8. # than the first one but it works for numbers that don't fit in 32 bits in
  9. # Kermit 95 and in 32-bit versions of C-Kermit.
  10. #
  11. # F. da Cruz, Columbia University, 28 December 2007
  12.  
  13. .legal = :4:8:16:32:64:128:             # Legal word sizes
  14.  
  15. # Largest positive integer for the supported word sizes
  16.  
  17. .maxint<4> = 7
  18. .maxint<8> = 127
  19. .maxint<16> = 32767
  20. .maxint<32> = 2147483647
  21. .maxint<64> = 9223372036854775807
  22. .maxint<128> = 340282366920938463463374607431768211455
  23.  
  24. # Ditto plus one (because we can't necessarily do arithmetic on big numbers)
  25.  
  26. .maxplusone<4> = 8
  27. .maxplusone<8> = 128
  28. .maxplusone<16> = 32768
  29. .maxplusone<32> = 2147483648
  30. .maxplusone<64> = 9223372036854775808
  31. .maxplusone<128> = 340282366920938463463374607431768211456
  32.  
  33. # Macro BINTOHEX converts a binary string to hex.
  34. #   \%1 = binary number (string)
  35. #   \%2 = word size in bits
  36. # 
  37. # \fradix() is constrained by machine integer word length
  38. # so we do it in pieces in case the number is too big.
  39. #
  40. define BINTOHEX {
  41.     undef \%6                                # Result accumulator
  42.     .\%1 := \flpad(\%1,\%2,0)                # Pad to size if necessary
  43.     for \%9 1 \%2 4 {                        # Do four bits at at a time
  44.         .\%8 := \fsubstr(\%1,\%9,4)          # Get chunk of 4
  45.         if not def \%8 break                 # Make sure we have one
  46.         .\%7 := \fradix(\%8,2,16)            # Convert to Hex digit
  47.         .\%6 := \%6\%7                       # Accumulate
  48.     }
  49.     return \%6
  50. }
  51.  
  52. def DIV2 {                                   # Divide decimal string by two
  53.     local \%i
  54.     undef \%6 \%7 result
  55.     for \%i 1 \flen(\%1) 1 {                 # One digit at a time.
  56.         .\%9 := \%7\:(\%1[\%i:1])            # Get a digit.
  57.         .\%8 ::= \%9/2                       # Divide it by 2
  58.         .\%7 ::= \%9%2                       # Get remainder
  59.         .\%6 := \%6\%8                       # Accumulate result
  60.     }
  61.     .result := \%6                           # Make result 
  62.     .remainder := \%7                        # and remainder visible
  63. }
  64.  
  65. def DTOB {                                   # Convert decimal string to binary
  66.     while true {                             # without using machine 
  67.         div2 \%1                             # arithmetic.
  68.         .\%6 := \m(remainder)\%6
  69.         .\%1 := \m(result)                    
  70.         if not \fverify(0,\%1) break
  71.     }        
  72.     return \%6
  73. }
  74. # Macro DECTOHEX converts a signed decimal number to 2's complement hex,
  75. # using the macros defined above as workers.
  76. #   \%1 = decimal number string (default 0)
  77. #   \%2 = word size in bits
  78. #         (must be a power of two, 4 or greater, default 32, max 128)
  79. #   Returns result in \v(result) and/or as value of \fexec(dectohex arg arg).
  80. #
  81. define DECTOHEX {
  82.     local digits
  83.     if not def \%1 .\%1 = 0                  # Supply default if no arg given
  84.     if not numeric \%1 return NOT_A_NUMBER:\%1  # Check that arg is a number
  85.     if not def \%2 .\%2 := 32                   # Use 32 bits if no second arg
  86.     if not \findex(:\%2:,\m(legal)) end 1 "UNSUPPORTED WORD SIZE - \%2"
  87.     .digits := \flen(\m(maxint<\%2>))           # Number of digits in it
  88.  
  89.     if eq "\fsubstr(\%1,1,1)" "+" .\%1 := \fsubstr(\%1,2) # strip any + sign
  90.     if not eq "\fsubstr(\%1,1,1)" "-" {      # If argument is not signed...
  91.         if lgt \flpad(\%1,\m(digits),0) \m(maxint<\%2>) return OVERFLOW
  92.         dtob \%1                             # Convert from decimal to binary
  93.         bintohex \v(return) \%2              # And from binary to hex
  94.         return \flpad(\v(return),(\%2/4),0)  # Return padded result
  95.     }
  96.     .\%1 := \fsubstr(\%1,2)                  # Negative number - remove sign
  97.     .\%1 := \flpad(\%1,\flen(\m(maxint<\%2>)),0) # Must use lexical comparison
  98.     if llt \m(maxplusone<\%2>) \%1 return UNDERFLOW # Check magnitude
  99.     dtob \%1                                 # Convert to binary
  100.     .\%9 := \flpad(\v(return),\%2,0)         # and pad
  101.     .\%8 ::= \frindex(1,\%9) - 1             # Find first 1 on the right
  102.     if == \%8 -1 return \frepeat(0,\%2 / 4)  # Watch out for negative 0
  103.     .\%7 := \fsubstr(\%9,1,\%8)              # Split string here
  104.     .\%6 := \fsubstitute(\%7,01,10)          # Complement bits in left part
  105.     .\%5 := \%6\fsubstr(\%9,\%8+1)           # Put back with right part
  106.     .\%4 := \fexec(bintohex \%5 \%2)         # Convert to hex
  107.     return \%4
  108. }
  109. # Test the functions...
  110.  
  111. def try {
  112.     # Note \v(time) lacks the fractional part in Windows for some reason.
  113.     .t1 := \v(ftime)                    # Current time
  114.     .result := \fexec(dectohex \%1 \%2) # Do the conversion
  115.     .t2 := \v(ftime)                    # New time
  116.     (setq t3 (- t2 t1))                 # Difference
  117.     echo \%1[\%2] = \m(result) [\ffpround(\m(t3),2) sec] # Print
  118. }
  119. try 7          # No word size specified
  120.  
  121. try  7 4       # 4-bit word
  122. try  8 4
  123. try -8 4
  124. try -9 4
  125. try 99 4
  126.  
  127. try  0 8        # 8-bit word
  128. try -0 8
  129. try  1 8
  130. try +1 8
  131. try  2 8
  132. try  3 8
  133. try  4 8
  134. try  5 8
  135. try  6 8
  136. try  7 8
  137. try -1 8
  138. try -2 8
  139. try -3 8
  140. try -4 8
  141. try -5 8
  142. try -6 8
  143. try -7 8
  144. try -8 8
  145. try 64 8
  146. try 65 8
  147. try -128 8
  148.  
  149. try 0 16       # 16-bit word
  150. try 64 16
  151. try 65 16
  152. try -128 16
  153. try -32768 16
  154. try 99999 16
  155. try -99999 16
  156.  
  157. try 0 32       # 32-bit word
  158. try 1 32
  159. try 16383 32
  160. try 2147483647 32
  161. try -1 32
  162. try -2 32
  163. try -2147483647 32
  164. try -2147483648 32
  165.  
  166. try 0 64       # 64-bit word
  167. try 2147483647 64
  168. try -1 64
  169. try -2 64
  170. try  1234567890 64
  171. try -2147483647 64
  172. try -2147483648 64
  173. try  8224373093854475231 64
  174.  
  175. try 0 128      # 128-bit word
  176. try 1 128
  177. try -1 128
  178. try -2 128
  179. try 317282366902934863643347307341786875499 128
  180.  
  181. if c-kermit exit
  182.