home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / archives / msvp98b1.lzh / MSNUT1.ASM < prev    next >
Assembly Source File  |  1992-07-04  |  13KB  |  606 lines
  1.        NAME    MSNUT1
  2. ; File MSNUT1.ASM
  3. ; Provides various Intel 8088 level operations, including
  4. ; display facilities (via msg buffer or DOS) for char, strings, etc.
  5. ;
  6. ; Copyright 1991, University of Waterloo.
  7. ;  Copyright (C) 1985, 1992, Trustees of Columbia University in the 
  8. ;  City of New York.  Permission is granted to any individual or institution
  9. ;  to use this software as long as it is not sold for profit.  This copyright
  10. ;  notice must be retained.  This software may not be included in commercial
  11. ;  products without written permission of Columbia University.
  12. ; 
  13. ; Written by Erick Engelke of the University of Waterloo, Waterloo, 
  14. ;  Ontario, Canada,
  15. ;  and by Joe R. Doupnik, Utah State University, 
  16. ;  jrd@cc.usu.edu, jrd@usu.Bitnet.
  17. ;
  18. ; Edit history
  19. ; 6 Sept 1991 v3.11
  20. ; Last Edit
  21. ; 2 Feb 1992
  22.  
  23. cr    equ    0dh
  24. lf    equ    0ah
  25. conout    equ    2
  26. dos    equ    21h
  27.  
  28. ;[HF]BIOSCLK    equ    046ch
  29. ;[HF]HI_MAX    equ    018h
  30. ;[HF]LO_MAX    equ     0b0h
  31. HI_MAX    equ    262
  32. LO_MAX    equ    54784
  33.  
  34. _TEXT    SEGMENT  WORD PUBLIC 'CODE'
  35. _TEXT    ENDS
  36. _DATA    SEGMENT  WORD PUBLIC 'DATA'
  37. _DATA    ENDS
  38. CONST    SEGMENT  WORD PUBLIC 'CONST'
  39. CONST    ENDS
  40. _BSS    SEGMENT  WORD PUBLIC 'BSS'
  41. _BSS    ENDS
  42. DGROUP    GROUP    CONST, _BSS, _DATA
  43.     ASSUME  CS: _TEXT, DS: DGROUP, SS: DGROUP
  44.  
  45. _DATA    SEGMENT
  46.     extrn    _doslevel:word, _msgcnt:word, _msgbuf:byte,_display_mode:byte
  47. _DATA    ENDS
  48.  
  49. _TEXT    segment
  50.  
  51.         ; Compute 1's-complement sum of data buffer
  52.         ; unsigned checksum( unsigned word *buf, unsigned cnt)
  53.     extrn    _realclock:near        ; [HF]
  54.     public    _checksum
  55. _checksum proc    near
  56.     push    bp
  57.     mov    bp,sp
  58.     push    si
  59.     push    bx
  60.     push    cx
  61.     push    dx
  62.         mov     si,[bp+4+0]        ; offset of data to be checked
  63.     mov     cx,[bp+4+2]        ; cx = cnt
  64.     mov    bl,cl
  65.     shr     cx,1            ; group into words
  66.     xor    dx,dx            ; set checksum to 0
  67.         cld
  68.     jcxz    chk3
  69.         clc
  70. chk1:    lodsw
  71.     adc    dx,ax
  72.     loop    chk1
  73.                     ; resolve remainder
  74. chk2:    adc     dx,0
  75.         jc    chk2
  76. chk3:    and    bl,1
  77.     jz    chk5
  78.         xor     ah,ah
  79.     lodsb
  80.         clc
  81.         add     dx,ax
  82. chk4:    adc     dx,0
  83.     jc    chk4
  84. chk5:    mov    ax,dx            ; result into ax
  85.         or      ax,ax
  86.     jnz    chk6
  87.         mov     ax,0ffffh
  88. chk6:    pop    dx
  89.     pop    cx
  90.     pop    bx
  91.     pop    si
  92.     pop    bp
  93.     ret
  94. _checksum endp
  95.  
  96. ;  ntohl(longword x)    32 bit network (big endian) to host (little endian)
  97. ;  htonl(longword x)    32 bit host (little endian) to network (big endian)
  98. ;  intel(longword x)
  99. ;  Reverse order of 4 byte groups between big and little endian forms
  100. ;
  101.     public    _intel, _ntohl, _htonl
  102.  
  103. _intel    proc    near
  104. _ntohl    equ    this byte
  105. _htonl    equ    this byte
  106.     push    bp
  107.     mov    bp,sp
  108.     mov    ax,[bp+4+2]
  109.     mov    dx,[bp+4+0]
  110.     xchg    al,ah
  111.     xchg    dl,dh
  112.     pop    bp
  113.     ret
  114. _intel    endp
  115.  
  116. ;  ntohs(word x)    16 bit network (big endian) to host (little endian)
  117. ;  htons(word x)    16 bit host (little endian) to network (big endian)
  118. ;  intel16(word x)
  119. ;  Reverse order of 2 byte groups between big and little endian forms
  120.     public    _intel16, _ntohs, _htons
  121. _intel16 proc    near
  122. _ntohs    equ    this byte
  123. _htons    equ    this byte
  124.     push    bp
  125.     mov    bp,sp
  126.     mov    ax,[bp+4+0]
  127.     xchg    al,ah
  128.     pop    bp
  129.     ret
  130. _intel16 endp
  131.  
  132.  
  133. ; int ourmod(int top, int bottom)
  134. ; Perform modulo function on 16 bit quantities
  135.     public    _ourmod
  136. _ourmod    proc    near
  137.     push    bp
  138.     mov    bp,sp
  139.     push    bx
  140.     mov    ax,[bp+4+0]        ; top number
  141.     mov    bx,[bp+4+2]        ; bottom number (radix)
  142.     xor    dx,dx
  143.     or    bx,bx            ; bottom is zero?
  144.     jz    ourmod1            ; z = yes, return zero
  145.     div    bx
  146. ourmod1:mov    ax,dx            ; return remainder
  147.     pop    bx
  148.     pop    bp
  149.     ret
  150. _ourmod    endp
  151.  
  152. ; int ourdiv(int top, int bottom)
  153. ; Perform 16 bit integer division
  154.     public    _ourdiv
  155. _ourdiv    proc    near
  156.     push    bp
  157.     mov    bp,sp
  158.     push    bx
  159.     mov    ax,[bp+4+0]        ; top
  160.     mov    bx,[bp+4+2]        ; bottom
  161.     xor    dx,dx
  162.     or    bx,bx            ; divide by zero?
  163.     jz    outdiv1            ; z = yes, divide by one
  164.     div    bx
  165. outdiv1:pop    bx
  166.     pop    bp            ; quotient is returned in ax
  167.     ret
  168. _ourdiv    endp
  169.  
  170. ; int ourlmod(long top, int bottom)
  171. ; Perform 32 bit integer modulo function
  172.     public    _ourlmod
  173. _ourlmod proc    near
  174.     push    bp
  175.     mov    bp,sp
  176.     push    bx
  177.     mov    ax,[bp+4+0]        ; top lower 16 bits
  178.     mov    dx,[bp+4+2]        ; top upper 16 bits
  179.     mov    bx,[bp+4+4]        ; bottom
  180.     or    bx,bx            ; zero?
  181.     jz    outlmo1            ; z = yes divide by 2^16 and quit
  182.     div    bx
  183. outlmo1:mov    ax,dx            ; return remainder in ax
  184.     pop    bx
  185.     pop    bp
  186.     ret
  187. _ourlmod endp
  188.  
  189. ; int ourldiv(long top, int bottom)
  190. ; Perform 32 bit integer division of 32 bit quotient by 16 bit divisor
  191.     public    _ourldiv
  192. _ourldiv proc    near
  193.     push    bp
  194.     mov    bp,sp
  195.     push    bx
  196.     mov    ax,[bp+4+0]        ; top lower 16 bits
  197.     mov    dx,[bp+4+2]        ; top upper 16 bits
  198.     mov    bx,[bp+4+4]        ; bottom
  199.     cmp    dx,bx            ; about to overflow?
  200.     jae    ourldiv1        ; ae = yes, return 0xffffh
  201.     div    bx
  202.     xor    dx,dx            ; clear remainder (high order ret)
  203.     pop    bx
  204.     pop    bp            ; quotient is returned in dx:ax
  205.     ret
  206. ourldiv1:mov    ax,0ffffh        ; overflow indication
  207.     xor    dx,dx            ; clear high order
  208.     pop    bx
  209.     pop    bp
  210.     ret
  211. _ourldiv endp
  212.  
  213. ; long ourlmul(long top, int bottom)
  214. ; Perform 32 bit integer multiplication of 32 bit multiplicand by 16 bit mult
  215.     public    _ourlmul
  216. _ourlmul proc    near
  217.     push    bp
  218.     mov    bp,sp
  219.     push    bx
  220.     push    cx
  221.     mov    ax,[bp+4+2]        ; top upper 16 bits
  222.     mov    bx,[bp+4+4]        ; bottom
  223.     mul    bx
  224.     mov    cx,ax            ; save product (no overflow noted)
  225.     mov    ax,[bp+4+0]        ; top lower 16 bits
  226.     mul    bx
  227.     adc    dx,cx            ; new upper 16 bits
  228.     pop    cx
  229.     pop    bx
  230.     mov    sp,bp
  231.     pop    bp            ; long product is returned in dx:ax
  232.     ret
  233. _ourlmul endp
  234.  
  235. ; void * bcopy(src, dest, count)
  236. ; void *dest, *src;
  237. ; size_t count;
  238. ; copy count bytes from src to dest
  239.     public    _bcopy
  240. _bcopy proc    near
  241.     push    bp
  242.     mov    bp,sp
  243.     push    es
  244.     push    si
  245.     push    di
  246.     push    cx
  247.     mov    ax,ds            ; set to same data segment
  248.     mov    es,ax
  249.     mov    si,[bp+4+0]        ; offset of source
  250.     mov    di,[bp+4+2]        ; offset of destination
  251.     mov    cx,[bp+4+4]        ; count
  252.     cld
  253.     push    di            ; push dest address for return
  254.     jcxz    bcopy2            ; z = nothing to copy
  255.     or    di,di            ; is destination NULL?
  256.     jz    bcopy2            ; z = yes, don't do a thing
  257.     cmp    si,di            ; is source after destination?
  258.     ja    bcopy1            ; a = yes, no overlap problem
  259.     je    bcopy2            ; e = same place, do nothing
  260.     add    di,cx            ; start at the ends
  261.     dec    di
  262.     add    si,cx
  263.     dec    si
  264.     std                ; work backward
  265. bcopy1:    rep    movsb
  266. bcopy2:    pop    ax            ; recover return destination
  267.     cld
  268.     pop    cx
  269.     pop    di
  270.     pop    si
  271.     pop    es
  272.     mov    sp,bp
  273.     pop    bp
  274.     ret
  275. _bcopy endp
  276.  
  277. ; void * memset(dest, c, count)
  278. ; void *dest;
  279. ; char c;
  280. ; size_t count;
  281. ; Store count copies of byte c in destination area dest
  282.     public    _memset
  283. _memset    proc    near
  284.     push    bp
  285.     mov    bp,sp
  286.     push    es
  287.     push    di
  288.     push    cx
  289.     mov    ax,ds            ; setup data segment
  290.     mov    es,ax
  291.     mov    di,[bp+4+0]        ; offset of destination
  292.     or    di,di            ; is it NULL?
  293.     jz    memset1            ; z = yes, don't do a thing
  294.     push    di            ; save dest for return
  295.     mov    al,[bp+4+2]        ; byte of character c
  296.     mov    ah,al
  297.     mov    cx,[bp+4+4]        ; count
  298.     jcxz    memset1            ; z = do nothing
  299.     cld
  300.     shr    cx,1
  301.     jnc    memset2
  302.     stosb
  303. memset2:rep    stosw
  304.     pop    ax            ; return pointer to destination
  305. memset1:pop    cx
  306.     pop    di
  307.     pop    es
  308.     mov    sp,bp
  309.     pop    bp
  310.     ret
  311. _memset    endp
  312.  
  313. ;  Timer routines - use set_*timeout to receive a clock value which
  314. ;                   can later be tested by calling chk_timeout with
  315. ;                   that clock value to determine if a timeout has
  316. ;                   occurred.  chk_timeout returns 0 if NOT timed out.
  317. ;  Usage:   long set_timeout( int seconds );
  318. ;           long set_ttimeout( int bios_ticks );
  319. ;           int chk_timeout( long value );
  320. ;
  321. ;  (c) 1990 University of Waterloo,
  322. ;           Faculty of Engineering,
  323. ;           Engineering Microcomputer Network Development Office
  324. ;  version
  325. ;    0.1    7-Nov -1990   E. P. Engelke
  326.  
  327.     public    _set_ttimeout
  328. _set_ttimeout proc    near
  329.     push    bp
  330.     mov    bp,sp
  331. ;[HF]    push    es
  332. ;[HF]        xor     ax,ax
  333. ;[HF]        cwd
  334. ;[HF]        mov     es,ax
  335. ;[HF]        mov     ax,[bp+4+0]        ; initial Bios clock ticks
  336. ;[HF]    pushf                ; critical section
  337. ;[HF]    cli
  338. ;[HF]        add     ax,es:[BIOSCLK+0];
  339. ;[HF]        adc     dx,es:[BIOSCLK+2];
  340. ;[HF]    popf                ; end critical section
  341. ;[HF]    pop    es
  342.     call    _realclock        ;[HF]
  343.     add    ax,[bp+4+0]        ;[HF]
  344.     adc    dx,0            ;[HF]
  345.     pop    bp
  346.     ret
  347. _set_ttimeout endp
  348.  
  349.     public    _set_timeout
  350. _set_timeout proc near
  351.     push    bp
  352.     mov    bp,sp
  353. ;[HF]    push    es
  354. ;[HF]    push    cx
  355. ;[HF]    xor    ax,ax            ; reference low memory
  356. ;[HF]    mov    es,ax
  357. ;[HF]    mov    ax,[bp+4+0]        ; seconds
  358. ;[HF]    xor    dx,dx
  359. ;[HF]    mov    cx,1165
  360. ;[HF]    mul    cx            ; 1165/64 = 18.203...
  361. ;[HF]    mov    cx,6
  362. ;[HF]tmp:    shr    dx,1
  363. ;[HF]    rcr    ax,1
  364. ;[HF]    loop    tmp
  365. ;[HF]    pushf                ; critical section
  366. ;[HF]    cli
  367. ;[HF]    add    ax,es:[BIOSCLK+0]
  368. ;[HF]    adc    dx,es:[BIOSCLK+2]
  369. ;[HF]    popf                ; end critical section
  370. ;[HF]    pop    cx
  371. ;[HF]    pop    es
  372.     push    bx            ;[HF]
  373.     push    cx            ;[HF]
  374.     mov    ax,[bp+4+0]        ;[HF]
  375.     xor    dx,dx            ;[HF]
  376.     mov    cx,25            ;[HF] sec -> tic (40 msec)
  377.     mul    cx            ;[HF] dx:ax = tic counts
  378.     mov    bx,ax            ;[HF]
  379.     mov    cx,dx            ;[HF] save dx:ax -> cx:bx
  380.     call    _realclock        ;[HF] get current time in tic
  381.     add    ax,bx            ;[HF] add it (long word)
  382.     adc    dx,cx            ;[HF]
  383.     pop    cx            ;[HF]
  384.     pop    bx            ;[HF]
  385.     pop    bp
  386.     ret
  387. _set_timeout    endp
  388.  
  389.     public    _chk_timeout
  390. _chk_timeout    proc near
  391.     push    bp
  392.     mov    bp,sp
  393.     push    cx
  394. ;[HF]    push    es
  395. ;[HF]    xor    ax,ax
  396. ;[HF]    mov    es,ax
  397. ;[HF]    pushf                ; critical section
  398. ;[HF]    cli
  399. ;[HF]    mov    cx,es:[BIOSCLK+0]
  400. ;[HF]    mov    bx,es:[BIOSCLK+2]
  401. ;[HF]    popf                ; end critical section
  402. ;[HF]    pop    es
  403.     call    _realclock        ;[HF] get current time (dx:ax)
  404.     mov    cx,ax            ;[HF] copy dx:ax -> bx:cx
  405.     mov    bx,dx            ;[HF]
  406.     mov    ax,[bp+4+0]        ; timeout value
  407.     mov    dx,[bp+4+2]
  408.     cmp    dx,bx            ; if timeout < clock, has expired
  409.         jb      ret_tru
  410.     cmp    ax,cx
  411.         jbe    ret_tru
  412.                     ; may have gone over by one day
  413.     sub    ax,LO_MAX
  414.     sbb    dx,HI_MAX
  415.     jc    ret_fal            ; c = nope, timeout is today
  416.                     ; test timeout new values
  417.     cmp    dx,bx
  418.     jb    ret_tru
  419.     cmp    ax,cx
  420.     ja    ret_fal
  421. ret_tru:mov    ax,1            ; say have timed out
  422.     pop    cx
  423.     pop    bp
  424.     ret
  425.  
  426. ret_fal:xor    ax,ax            ; say have not timed out
  427.     pop    cx
  428.     pop    bp
  429.     ret
  430. _chk_timeout    endp
  431.  
  432. ; unsigned long realclock(void)
  433. ;[HF]    public    _realclock
  434. ;[HF]_realclock    proc near        ; get Bios time of day dword
  435. ;[HF]    push    es
  436. ;[HF]    xor    ax,ax            ; reference low memory
  437. ;[HF]    mov    es,ax
  438. ;[HF]    pushf                ; critical section
  439. ;[HF]    cli
  440. ;[HF]    mov    ax,es:[BIOSCLK+0]    ; return Bios time of day tick count
  441. ;[HF]    mov    dx,es:[BIOSCLK+2]
  442. ;[HF]    popf                ; end critical section
  443. ;[HF]    pop    es
  444. ;[HF]    ret
  445. ;[HF]_realclock endp
  446.  
  447. ; void _chkstk()
  448. ; Stack checker
  449. ; {
  450. ;  ;
  451. ; }
  452.     public    __chkstk, __aNchkstk
  453. __chkstk proc    near            ; MSC v5.1
  454. __aNchkstk equ    this byte        ; MSC v6.00
  455.     pop    bx            ; pop return address
  456.     sub    sp,ax            ; down adjust stack pointer
  457.     jmp    bx            ; return the no-stack way
  458. __chkstk endp
  459.  
  460.  
  461. ; void 
  462. ; outch(char ch)
  463. ; Sends character to the screen via the msgbuf buffer if operating at
  464. ; interrupt level, or via DOS if operating at task level.
  465.     public    _outch
  466. _outch    proc    near
  467.     push    bp
  468.     mov    bp,sp
  469.     push    ax
  470.     push    bx
  471.     cmp    _display_mode,0        ; quiet screen?
  472.     je    outch3            ; e = yes
  473.     mov    al,[bp+4]        ; get the character
  474.     cmp    _doslevel,0        ; at DOS task level?
  475.     je    outch1            ; e = no
  476.     mov    ah,conout        ; use DOS
  477.     push    dx
  478.     mov    dl,al
  479.     int    dos
  480.     pop    dx
  481.     jmp    short outch3
  482. outch1:    cmp    _msgcnt,256        ; is buffer filled?
  483.     ja    outch3            ; a = yes, discard this byte
  484.     mov    bx,_msgcnt
  485.     mov    _msgbuf[bx],al
  486.     inc    _msgcnt
  487. outch3:    pop    bx
  488.     pop    ax
  489.     mov    sp,bp
  490.     pop    bp
  491.     ret
  492. _outch    endp
  493.  
  494.  
  495. ; void 
  496. ; outsn(char * string, int count)
  497. ; display counted string
  498.     public    _outsn
  499. _outsn    proc    near
  500.     push    bp
  501.     mov    bp,sp
  502.     push    ax
  503.     push    si
  504.     mov    si,[bp+4]        ; string address
  505.     mov    cx,[bp+4+2]        ; string length
  506.     cld
  507. outsn1:    lodsb
  508.     or    al,al
  509.         jz      outsn2
  510.     push    ax            ; push arg
  511.         call    _outch
  512.     pop    ax            ; clean stack
  513.     loop    outsn1
  514. outsn2:    pop    si
  515.     pop    ax
  516.     mov    sp,bp
  517.     pop    bp
  518.     ret
  519. _outsn    endp
  520.  
  521. ; void 
  522. ; outs(char * string)
  523. ; display asciiz string
  524.     public    _outs
  525. _outs    proc    near
  526.     push    bp
  527.     mov    bp,sp
  528.     push    ax
  529.     push    si
  530.     mov    si,[bp+4]        ; asciiz string address
  531.     cld
  532. outs1:    lodsb
  533.         or      al,al            ; terminator ?
  534.     jz     outs2            ; z = yes
  535.     push    ax            ; push arg
  536.     call    _outch
  537.     pop    ax            ; clean stack
  538.     jmp    short outs1
  539. outs2:    pop    si
  540.     pop    ax
  541.     mov    sp,bp
  542.     pop    bp
  543.     ret
  544. _outs    endp
  545.  
  546. ; void
  547. ; outhex(char c)
  548. ; display char in hex
  549.     public _outhex
  550. _outhex    proc    near
  551.     push    bp
  552.     mov    bp,sp
  553.     push    ax
  554.         mov     ax,[bp+4]        ; incoming character
  555.         mov     cl, 4
  556.         shr     al, cl
  557.         call    outh
  558.         mov     ax,[bp+4]
  559.         call    outh
  560.     pop    ax
  561.     mov    sp,bp
  562.     pop    bp
  563.     ret
  564.  
  565. ; worker for outhex
  566. outh    proc    near
  567.     and     al,0fh
  568.         cmp     al,9
  569.         jbe     outh1
  570.         add     al,'A' - '9' - 1
  571. outh1:    add     al,'0'
  572.         push    ax
  573.         call    _outch
  574.         pop     ax
  575.         ret
  576. outh    endp
  577. _outhex    endp
  578.  
  579. ; output a string of hex chars
  580. ; void
  581. ; outhexes(char * string, int count )
  582.     public    _outhexes
  583. _outhexes proc    near
  584.     push    bp
  585.     mov    bp,sp
  586.     push    ax
  587.     push    si            ; preserve such things
  588.     mov    si,[bp+4]        ; get string pointer
  589.     mov    cx,[bp+4+2]        ; get char count
  590.     cld
  591. outhexs1:lodsb                ; read a byte
  592.     push    cx            ; save loop counter
  593.     push    ax
  594.     call    _outhex            ; display as hex pair
  595.     add    sp,2            ; clean stack
  596.     pop    cx
  597.     loop    outhexs1        ; do count's worth
  598.     pop    si
  599.     pop    ax
  600.     mov    sp,bp
  601.     pop    bp
  602.     ret
  603. _outhexes endp
  604. _TEXT    ends
  605.         end
  606.