home *** CD-ROM | disk | FTP | other *** search
/ Columbia Kermit / kermit.zip / archives / msk316src.zip / MSSTER.ASM < prev    next >
Assembly Source File  |  1999-04-24  |  79KB  |  2,744 lines
  1.      NAME    msster
  2. ; File MSSTER.ASM
  3.     include mssdef.h
  4. ;    Copyright (C) 1982, 1999, Trustees of Columbia University in the 
  5. ;    City of New York.  The MS-DOS Kermit software may not be, in whole 
  6. ;    or in part, licensed or sold for profit as a software product itself,
  7. ;    nor may it be included in or distributed with commercial products
  8. ;    or otherwise distributed by commercial concerns to their clients 
  9. ;    or customers without written permission of the Office of Kermit 
  10. ;    Development and Distribution, Columbia University.  This copyright 
  11. ;    notice must not be removed, altered, or obscured.
  12. ;
  13. ; Edit history
  14. ; 12 Jan 1995 version 3.14
  15. ; Last edit
  16. ; 12 Jan 1995
  17.  
  18.     public    clscpt, defkey, clscpi, ploghnd, sloghnd, tloghnd
  19.     public  dopar, shokey, cptchr, pktcpt, targ, replay, repflg
  20.     public    kbdflg, shkadr, telnet, ttyact, write, dec2di, caplft
  21.     public    cnvlin,  decout, valout, cnvstr, writeln
  22.     public    pntchr, pntflsh, pntchk, prnhand, prnopen
  23.     public    vfopen, vfread, ldiv, lmul, lgcd, atoi, atoibyte
  24.     public  domath, domath_ptr, domath_cnt, domath_msg
  25.     public    atoi_cnt, atoi_err, tod2secs
  26.  
  27. braceop    equ    7bh            ; opening curly brace
  28. bracecl    equ    7dh            ; closing curly brace
  29.  
  30. data     segment
  31.     extrn    flags:byte, trans:byte, diskio:byte, portval:word
  32.     extrn    rdbuf:byte, dosnum:word, filtst:byte, prnname:byte
  33.     extrn    comand:byte, kstatus:word, flowon:byte, flowoff:byte
  34.     extrn    cardet:byte
  35. ifndef    no_terminal
  36.     extrn    anspflg:byte
  37. endif    ; no_terminal
  38.  
  39. targ    termarg    <0,1,cptchr,0,parnon>
  40. crlf    db      cr,lf,'$'
  41. tmsg1    db    cr,lf,'(Connecting to host, type $' 
  42. tmsg3    db    ' C to return to PC)',cr,lf,cr,lf,cr,lf,'$'
  43. erms21    db    cr,lf,'?Cannot start the connection.$'
  44. erms25    db    cr,lf,'?Input must be numeric$' 
  45. erms22    db    cr,lf,'?No open logging file$'
  46. erms23    db    '*** Error writing session log, suspending capture ***$'
  47. erms24    db    cr,lf,'?Error writing Packet log$'
  48. erms26    db    ' *** PRINTER IS NOT READY ***  press R to retry'
  49.     db    ' or D to discard printing:  $'
  50. erms27    db    cr,lf
  51.     db    '? Carrier signal not detected on this serial port.'
  52.     db    cr,lf
  53.     db    '  Use the DIAL command, SET CARRIER OFF, or check your modem.$'
  54.  
  55. esctl    db    'Control-$'
  56. repflg    db    0        ; REPLAY or SET TERM REPLAY filespec flag
  57. reperr    db    cr,lf,'?File not found$'    ; for REPLAY command
  58. noterm    db    cr,lf,'Connect mode is not built into this Kermit$'
  59. vfopbad    db    cr,lf,'?Cannot open file $'    ; filename follows
  60. vfclbad    db    cr,lf,'?Cannot close file$'
  61. vfoptwice db    cr,lf,'?File is already open$'
  62. vfnofile db    cr,lf,'?File is not open$'
  63. vfrbad    db    cr,lf,'?Error while reading file$'
  64. vfwbad    db    cr,lf,'?Error while writing file$'
  65. vfrdbad    db    cr,lf,'?more parameters are needed$'
  66. vfrhandle dw    -1            ; READ FILE handle (-1 = invalid)
  67. vfwhandle dw    -1            ; WRITE FILE handle
  68.  
  69. opntab    db    3            ; OPEN FILE table
  70.     mkeyw    'Read',1
  71.     mkeyw    'Write',2
  72.     mkeyw    'Append',3
  73.  
  74. inthlp db cr,lf,' ', 22 dup ('-'),' Special keys within Connect mode '
  75.        db    22 dup ('-')
  76.        db cr,lf,'                           numeric keypad keys:'
  77.        db cr,lf,'  Pg Up/Dn  roll screen vertically   Ctrl Pg Up/Dn  roll'
  78.        db    ' screen one line '
  79.        db cr,lf,'  Home/End  roll to start/end screen Ctrl End screen dump'
  80.        db cr,lf,'  - (minus) toggle status/mode line'
  81.        db cr,lf,'                           other key combinations:'
  82.        db cr,lf,'  Alt-b  send a BREAK                Alt-n  next active'
  83.        db    ' Telnet session'
  84.        db cr,lf,'  Alt-c  start Compose sequence      Alt-x  exit emulator'
  85.        db cr,lf,'  Alt-h  show this menu              Alt-z  network session'
  86.        db    ' hold'
  87.        db cr,lf,'  Alt-= or Alt-r  reset emulator     Alt--  toggle terminal'
  88.        db    ' type'
  89.        db cr,lf,'  Ctrl Prtscrn  toggle printing'
  90.        db cr,lf,'  Additional commands are escape character '
  91. inthlpc db '  '
  92.        db    ' followed by special characters.'
  93.        db cr,lf,' ',78 dup ('-')
  94.        db cr,lf,'  7n1 = SET TERM BYTE 7, SET PARITY NONE, 1 stop bit'
  95.        db cr,lf,'  8n1 = SET TERM BYTE 8, SET PARITY NONE, 1 stop bit'
  96.        db cr,lf,'  7e1 = SET PARITY EVEN, 1 stop bit   7s1 = SET PARITY SPACE'
  97.        db    ', 1 stop bit'
  98.        db cr,lf,'  7o1 = SET PARITY ODD,  1 stop bit   7m1 = SET PARITY MARK'
  99.        db    ',  1 stop bit'
  100.        db cr,lf,'  press a key to exit this menu'
  101.        db    0
  102.  
  103. intqry db cr,lf,' ',20 dup ('-'),' Single character commands active now ' 
  104.        db    20 dup ('-')
  105.        db cr,lf,'  ?  Show this menu                  F  Dump screen to file'
  106.        db cr,lf,'  C  Close the emulator              P  Push to DOS'
  107.        db cr,lf,'  S  Status of the connection        Q  Quit logging'
  108.        db cr,lf,'  M  Toggle mode line                R  Resume logging'
  109.        db cr,lf,'  B  Send a Break                    0  Send a null'
  110.        db cr,lf,'  L  Send a long 1.8 s Break         H  Hangup phone'
  111.        db cr,lf,'  A  Send Telnet "Are You There"     I  Send Telnet' 
  112.        db    ' "Interrupt Process"' 
  113.        db cr,lf,'  Typing the escape character '
  114. intqryc db '  '                    ; where escape char glyphs go
  115.        db    ' will send it to the host'
  116.        db cr,lf,'  press space bar to exit this menu'
  117.        db 0
  118.  
  119. intprm    db    'Command> $'
  120. intclet    db    'B','C','F','H','L'    ; single letter commands
  121.     db    'M','P','Q','R','S'    ; must parallel dispatch table intcjmp
  122.     db    '?','0','A','I'
  123. numlet    equ    $ - intclet        ; number of entries
  124.     even
  125. ifndef    no_terminal
  126. intcjmp    dw    intchb,intchc,intchf,intchh,intchl
  127.     dw    intchm,intchp,intchq,intchr,intchs
  128.     dw    intchu,intchn,intayt,inttip
  129. endif    ; no_terminal
  130.  
  131. prnhand    dw    4        ; printer file handle (4 = DOS default)
  132.  
  133.     even
  134. ploghnd    dw    -1        ; packet logging handle
  135. sloghnd    dw    -1        ; session logging handle
  136. tloghnd    dw    -1        ; transaction logging handle
  137.  
  138. clotab    db    6
  139.     mkeyw    'READ-FILE',4001h
  140.     mkeyw    'WRITE-FILE',4002h
  141.     mkeyw    'All-logs',logpkt+logses+logtrn
  142.     mkeyw    'Packets',logpkt
  143.     mkeyw    'Session',logses
  144.     mkeyw    'Transactions',logtrn
  145.  
  146. clseslog db    cr,lf,' Closing Session log$'
  147. clpktlog db    cr,lf,' Closing Packet log$'
  148. cltrnlog db    cr,lf,' Closing Transaction log$'
  149.  
  150. writetab db    5            ; Write command log file types
  151.     mkeyw    'FILE',4002h        ; FILE
  152.     mkeyw    'Packet',logpkt
  153.     mkeyw    'Screen',80h        ; unused value, to say screen
  154.     mkeyw    'Session',logses
  155.     mkeyw    'Transaction',logtrn
  156.  
  157. sttmsg    db    cr,lf,'Press space to continue ...$'
  158. kbdflg    db    0            ; non-zero means char here from Term
  159. ttyact    db    1            ; Connect mode active, if non-zero
  160. shkadr    dw    0            ; offset of replacement Show Key cmd
  161. nbase    dw    10            ; currently active number base
  162. temp    dw    0
  163. temp1    dw    0
  164. tmp    db    0
  165. tmp1    db    0
  166. tmpstring db    6 dup (0)        ; local string work buffer
  167. pktlft    dw    cptsiz        ; number free bytes left
  168. caplft    dw    cptsiz        ; number free bytes left
  169.  
  170. maxdepth equ    8            ; domath, parenthesis nesting depth
  171. listlen equ    6            ; domath, outstanding numbers and ops
  172. parendepth db    0            ; domath, depth of ()'s
  173. mathkind db    0            ; domath, math operator symbol, temp
  174. operators db    '()!~^*/%&+-|#@'    ; domath, math operator list
  175. operator_len equ $ - operators        ; domath, length of the list
  176. precedence db    6,6,5,4,3, 2,2,2,2,1, 1,1,1,1 ; domath, precedence of ops
  177. fevalst    struc        ; structure of demath work stacks, all on the stack
  178.   savebp    dw    0        ; where bp is pushed
  179.   numcnt    dw    0        ; count of values in numlist
  180.   numlist    dw listlen dup (0,0)    ; list of dword values
  181.   opcnt        dw    0        ; count of operators in oplist
  182.   oplist    dw  listlen dup (0)    ; list of pending operators
  183. fevalst    ends
  184. domath_ptr dw    0            ; ds:offset of domath input text
  185. domath_cnt dw    0            ; count of bytes in input text
  186. domath_msg dw    0            ; non-zero to allow error msgs
  187. matherr dw    0            ; non-zero = offset of error msg
  188. opmsg    db    '?too many math operators or too few values $'
  189. opmsg1    db    '?math operator missing or invalid $'
  190. opmsg2    db    '?unknown math symbol: $'
  191. opmsg3 db    '?math expression error $'
  192. opmsg4    db    '?parentheses nested too deeply $'
  193. atoibyte db    0            ; non-zero to say convert one char
  194. atoi_err db    0            ; atoi return error codes
  195. atoi_cnt dw    0            ; atoi, bytes supplied to/remaining
  196. data    ends
  197.  
  198. data1    segment
  199. rephlp    db    'name of file to playback$'
  200. clohlp    db    cr,lf,' READ-FILE or WRITE-FILE, or the following log files:'
  201.     db    cr,lf,' All-logs, Packets, Session, Transaction$'
  202. msgtxt    db    'text to be written$'
  203. vfophlp    db    'Filename$'
  204. vfrdmsg    db    'name of variable  into which to read a line from file$'
  205. pktbuf    db    cptsiz dup (0)    ; packet logging buffer
  206. pktbp    dw    pktbuf        ; buffer pointer to next free byte
  207. capbuf    db    cptsiz dup (0)    ; session logging buffer
  208. capbp    dw    capbuf        ; buffer pointer to next free byte
  209. prnbuf    db    cptsiz dup (0)    ; printer buffer
  210. pntptr    dw    prnbuf        ; pointer to next free byte
  211. data1    ends
  212.  
  213. code1    segment
  214.     extrn    iseof:far, strlen:far, prtasz:far, isfile:far
  215.     assume    cs:code1
  216. code1    ends
  217.  
  218. code    segment
  219.     extrn     comnd:near, outchr:near, stat0:near, pcwait:far
  220.     extrn    beep:near, puthlp:near, serhng:near, lnout:near
  221.     extrn    serini:near, serrst:near, sendbr:near, putmod:near
  222.     extrn    fpush:near,  sendbl:near, trnmod:near, dodecom:near
  223. ifndef    no_terminal
  224.     extrn    dumpscr:near,term:near
  225. endif    ; no_terminal
  226. flnout    proc    far
  227.     call    lnout
  228.     ret
  229. flnout    endp
  230.     assume    cs:code, ds:data, es:nothing
  231.  
  232. ; the show key command
  233. shokey    proc    near
  234.     cmp    shkadr,0        ; keyboard translator present?
  235.     je    shokey1            ; e = no, use regular routines
  236.     mov    bx,shkadr        ; get offset of replacement routine
  237.     jmp    bx            ; and execute it rather than us
  238. shokey1:clc
  239.     ret
  240. shokey    endp
  241. ; enter with ax/scan code to define, si/ pointer to definition, cx/ length
  242. ; of definition.  Defines it in definition table. Obsolete.
  243. defkey    proc    near
  244.     ret
  245. defkey    endp
  246.  
  247.  
  248. ; This is the CONNECT command
  249. ifdef    no_terminal
  250. TELNET     PROC    NEAR
  251.     mov    ah,cmeol
  252.     call    comnd            ; get a confirm
  253.     jnc    teln1            ; nc = success
  254.     ret
  255. teln1:    mov    ah,prstr
  256.     mov    dx,offset noterm
  257.     int    dos
  258.     clc
  259.     ret
  260. TELNET    ENDP
  261. endif    ; no_terminal
  262.  
  263. ifndef    no_terminal
  264. TELNET     PROC    NEAR
  265.     mov    ah,cmeol
  266.     call    comnd            ; get a confirm
  267.     jnc    teln1            ; nc = success
  268.     ret
  269. teln1:    cmp    repflg,0        ; REPLAY?
  270.     jne    teln1d            ; ne = yes
  271.     call    serini            ; ensure port is inited now
  272.     jnc    teln1a            ; nc = success
  273.     test    flags.remflg,dquiet    ; quiet display mode?
  274.     jnz    teln1b            ; nz = yes. Don't write to screen
  275.     mov    dx,offset erms21    ; say cannot start connection
  276.     mov    ah,prstr
  277.     int    dos
  278. teln1b:    or    kstatus,ksgen        ; general command failure
  279.     ret
  280. teln1a:    cmp    flags.comflg,'F'    ; Fossil port?
  281.     je    teln1c            ; e = yes
  282.     cmp    flags.comflg,'4'    ; using real or Bios serial ports?
  283.     ja    teln1d            ; a = no
  284. teln1c:    cmp    flags.carrier,0        ; want CD on now?
  285.     je    teln1d            ; e = no
  286.     test    cardet,80h        ; CD on?
  287.     jnz    teln1d            ; nz = yes
  288.     mov    ah,prstr        ; complain on screen
  289.     mov    dx,offset erms27
  290.     int    dos
  291.     stc                ; fail
  292.     ret
  293. teln1d:    cmp    flags.vtflg,0        ; emulating a terminal?
  294.     jne    teln2            ; ne= yes, no wait necessary
  295.     mov    ah,prstr
  296.     mov    dx,offset crlf        ; output a crlf
  297.     int    dos
  298.     call    domsg            ; reassure user
  299.     mov    ax,2000            ; two seconds
  300.     call    pcwait            ; pause
  301. teln2:    xor    al,al            ; initial flags
  302.     mov    ttyact,1        ; say telnet is active
  303.     cmp    flags.vtflg,0        ; emulating a terminal?
  304.     je    teln3            ; e = no, say mode line is to be off
  305.     cmp    flags.modflg,0        ; mode line enabled?
  306.     jne    tel010            ; ne = yes
  307. teln3:    or    al,modoff        ; no, make sure it stays off
  308.  
  309. tel010:    test    flags.debug,logses    ; debug mode?
  310.     jz    tel0            ; z = no, keep going
  311.     or    al,trnctl        ; yes, show control chars
  312. tel0:    cmp    flags.vtflg,0        ; emulating a terminal?
  313.     je    tel1            ; e = no
  314.     or    al,emheath        ; say emulating some kind of terminal
  315. tel1:    mov    bx,portval
  316.     cmp    [bx].ecoflg,0        ; echoing?
  317.     jz    tel2            ; z = no
  318.     or    al,lclecho        ; turn on local echo
  319. tel2:    mov    targ.flgs,al        ; store flags
  320.     mov    ah,flags.comflg        ; COMs port identifier
  321.     mov    targ.prt,ah        ; Port 1 or 2, etc
  322.     mov    ah,[bx].parflg        ; parity flag
  323.     mov    targ.parity,ah
  324.     mov    ax,[bx].baud        ; baud rate identifier
  325.     mov    targ.baudb,al
  326.     xor    ah,ah
  327.     test    flags.capflg,logses    ; select session logging flag bit
  328.     jz    tel3            ; z = no logging
  329.     mov    ah,capt            ; set capture flag
  330. tel3:    or    targ.flgs,ah
  331.     jmp    short tem1
  332.  
  333. TEM:    call    serini            ; init serial port
  334.     jnc    tem1            ; nc = success
  335.     clc
  336.     ret                ; and exit Connect mode
  337.  
  338. tem1:    mov    dx,offset crlf        ; give user an indication that we are
  339.     mov    ah,prstr        ; entering terminal mode
  340.     int    dos
  341.     mov    ttyact,1        ; say telnet is active
  342.     mov    ax,offset targ        ; point to terminal arguments
  343.     call    term            ; call the main Terminal procedure
  344.     mov    al,kbdflg        ; get the char from Term, if any
  345.     mov    kbdflg,0        ; clear    the flag
  346.     or    al,al            ; was there a char from Term?
  347.     jnz    intch2            ; nz = yes, else ask for one from kbd
  348.  
  349. intchar:call    iseof            ; stdin at eof?
  350.     jnc    intch1            ; nc = not eof, get more
  351.     mov    al,'C'            ; use C when file is empty
  352.     jmp    intchc            ;  to provide an exit
  353. intch1:    cmp    al,0            ; asking for help?
  354.     jne    intch1b            ; ne = no
  355.     mov    al,' '
  356.     mov    ah,trans.escchr
  357.     cmp    ah,' '            ; printable now?
  358.     jae    intch1a            ; ae = yes
  359.     mov    al,'^'
  360.     add    ah,40h            ; make control visible
  361. intch1a:mov    word ptr intqryc,ax    ; store escape char code
  362.     mov    ax,offset intqry    ; '?' get help message
  363.     call    puthlp            ; write help msg
  364.     mov    dx,offset intprm
  365.     mov    ah,prstr        ; show prompt
  366.     int    dos
  367. intch1b:mov    ah,0ch            ; clear Bios keyboard buffer and do
  368.     mov    al,coninq        ;  read keyboard, no echo
  369.     int    dos            ; get a char
  370.     or    al,al            ; scan code indicator?
  371.     jnz    intch1c            ; nz = no, ascii
  372.     mov    ah,coninq        ; read and discard scan code
  373.     int    dos
  374.     jmp    short intch1        ; try again
  375. intch1c:cmp    al,'?'            ; want to see menu again?
  376.     jne    intch2            ; ne = no
  377.     xor    al,al            ; prep for menu display
  378.     jmp    short intchar
  379.  
  380. intch2:    mov    flags.cxzflg,0        ; prevent Control-C carryover
  381.     cmp    al,' '            ; space?
  382.     je    tem            ; e = yes, ignore it
  383.     cmp    al,cr            ; check ^M (cr) against plain ascii M
  384.     je    tem            ; exit on cr
  385.     cmp    al,trans.escchr        ; is it the escape char?
  386.     jne    intch3            ; ne = no
  387.     mov    ah,al
  388.     call    outchr
  389.     jmp    tem            ; return, we are done here
  390. intch3:    push    es
  391.     push    ds
  392.     pop    es
  393.     mov    di,offset intclet    ; command letters
  394.     mov    cx,numlet        ; quantity of them
  395.     cmp    al,' '            ; control code?
  396.     jae    intch3a            ; ae = no
  397.     or    al,40H            ; convert control chars to printable
  398. intch3a:cmp    al,96            ; lower case?
  399.     jb    intch3b            ; b = no
  400.     and    al,not (20h)        ; move to upper case
  401. intch3b:cld
  402.     repne    scasb            ; find the matching letter
  403.     pop    es
  404.     jne    intch4            ; ne = not found, beep and get another
  405.     dec    di            ; back up to letter
  406.     sub    di,offset intclet    ; get letter number
  407.     shl    di,1            ; make it a word index
  408.     jmp    intcjmp[di]        ; dispatch to it
  409. intch4:    call    beep            ; say illegal character
  410.     jmp    intchar
  411.  
  412. intayt:    mov    ah,255            ; 'I' Telnet Are You There
  413.     call    outchr            ; send IAC (255) AYT (246)
  414.     mov    ah,246
  415.     call    outchr
  416.     jmp    tem
  417.  
  418. intchb:    call    sendbr            ; 'B' send a break
  419.     jmp    tem            ; And return
  420.  
  421. intchc:    clc                ; exit Connect mode
  422.     ret
  423.  
  424. intchf:    call    dumpscr            ; 'F' dump screen, use msy routine
  425.     jmp    tem            ; and return
  426.  
  427. intchh:    call    serhng            ; 'H' hangup phone
  428.     call    serrst            ; turn off port
  429.     jmp    tem
  430.  
  431. intchl:    call    sendbl            ; 'L' send a long break
  432.     jmp    tem
  433.  
  434. inttip:    mov    ah,255            ; 'I' Telnet Interrrupt Process
  435.     call    outchr            ; send IAC (255) IP (244)
  436.     mov    ah,244
  437.     call    outchr
  438.     jmp    tem
  439.  
  440. intchm:    cmp    flags.modflg,1        ; 'M' toggle mode line, enabled?
  441.     jne    intchma            ; ne = no, leave it alone
  442.     xor    targ.flgs,modoff    ; enabled, toggle its state
  443. intchma:jmp    tem            ; and reconnect
  444.  
  445. intchp:    call    fpush            ; 'P' push to DOS
  446.     mov    dx,offset sttmsg    ; say we have returned
  447.     mov    ah,prstr
  448.     int    dos
  449.     jmp    short intchsb        ; wait for a space
  450.  
  451. intchq:    and    targ.flgs,not capt    ; 'Q' suspend session logging
  452.     jmp    tem            ; and resume
  453.  
  454. intchr:    test    flags.capflg,logses    ; 'R' resume logging. Can we capture?
  455.     jz    intchr1            ; z = no
  456.     or    targ.flgs,capt        ; turn on session logging flag
  457. intchr1:jmp    tem            ; and resume
  458.  
  459. intchs:    call    stat0            ; 'S' status, call stat0
  460.     mov    dx,offset sttmsg
  461.     mov    ah,prstr
  462.     int    dos
  463. intchsa:call    iseof            ; is stdin at eof?
  464.     jnc    intchsb            ; nc = not eof, get more
  465.     jmp    tem            ; resume if EOF
  466. intchsb:mov    ah,coninq        ; console input, no echo
  467.     int    dos
  468.     cmp    al,' '            ; space?
  469.     jne    intchsa
  470.     jmp    tem
  471.  
  472. intchu:    mov    ah,trans.escchr
  473.     cmp    ah,' '            ; printable now?
  474.     jae    intchu1            ; ae = yes
  475.     mov    al,'^'
  476.     add    ah,40h            ; make control visible
  477. intchu1:mov    word ptr inthlpc,ax    ; store escape char code
  478.     mov    ax,offset inthlp    ; help message
  479.     call    puthlp            ; write help msg
  480.     mov    ah,0ch            ; clear Bios keyboard buffer and do
  481.     mov    al,coninq        ;  read keyboard, no echo
  482.     int    dos            ; get a char
  483.     or    al,al            ; scan code indicator?
  484.     jnz    intchu2            ; nz = no, ascii
  485.     mov    ah,coninq        ; read and discard scan code
  486.     int    dos
  487. intchu2:jmp    tem            ; try again
  488.  
  489. intchn:    xor    ah,ah            ; '0' send a null
  490.     call    outchr
  491.     jmp    tem
  492. TELNET  ENDP
  493. endif    ; no_terminal
  494. code    ends
  495.  
  496. code1    segment
  497.     assume cs:code1
  498. ; Reassure user    about connection to the host. Tell him what escape sequence
  499. ; to use to return
  500.  
  501. DOMSG    PROC    FAR
  502.     mov    ah,prstr
  503.     mov    dx,offset tmsg1
  504.     int    dos
  505.     call    escprt
  506.     mov    ah,prstr
  507.     mov    dx,offset tmsg3
  508.     int    dos
  509.     ret
  510. DOMSG    ENDP
  511.  
  512. ; print    the escape character in readable format.  
  513.  
  514. ESCPRT    PROC    NEAR
  515.     mov    dl,trans.escchr
  516.     cmp    dl,' '
  517.     jge    escpr2
  518.     push    dx
  519.     mov    ah,prstr
  520.     mov    dx,offset esctl
  521.     int    dos
  522.     pop    dx
  523.     add    dl,040H        ; Make it printable
  524. escpr2:    mov    ah,conout
  525.     int    dos
  526.     ret
  527. ESCPRT    ENDP
  528. code1    ends
  529.  
  530. code    segment
  531.     assume    cs:code 
  532.  
  533. ; Set parity for character in Register AL
  534.  
  535. dopar:    push    bx
  536.     mov    bx,portval
  537.     mov    bl,[bx].parflg        ; get parity flag byte
  538.     test    bl,PARHARDWARE        ; hardware?
  539.     jnz    parret            ; nz = yes
  540.     cmp    bl,parnon        ; No parity?
  541.     je    parret            ; Just return
  542.     and    al,07FH            ; Strip parity. Same as Space parity
  543.     cmp    bl,parspc        ; Space parity?
  544.     je    parret            ; e = yes, then we are done here
  545.     cmp    bl,parevn        ; Even parity?
  546.     jne    dopar0            ; ne = no
  547.     or    al,al
  548.     jpe    parret            ; pe = even parity now
  549.     xor    al,080H            ; Make it even parity
  550.     jmp    short parret
  551. dopar0:    cmp    bl,parmrk        ; Mark parity?
  552.     jne    dopar1            ; ne = no
  553.     or    al,080H            ; Turn on the parity bit
  554.     jmp    short parret
  555. dopar1:    cmp    bl,parodd        ; Odd parity?    
  556.     or    al,al
  557.     jpo    parret            ; Already odd, leave it
  558.     xor    al,080H            ; Make it odd parity
  559. parret:    pop    bx
  560.     ret
  561.  
  562. ; REPLAY filespec  through terminal emulator
  563. replay    proc    near
  564.     mov    bx,offset rdbuf        ; place for filename
  565.     mov    dx,offset rephlp    ; help
  566.     mov    repflg,0        ; clear the replay active flag
  567.     mov    ah,cmword        ; get filename
  568.     call    comnd
  569.     jc    replay2            ; c = failure
  570.     mov    ah,cmeol        ; get an EOL confirm
  571.     call    comnd
  572.     jc    replay2            ; c = failure
  573. ifndef    no_terminal
  574.     mov    ah,open2        ; open file
  575.     xor    al,al            ; open readonly
  576.     cmp    byte ptr dosnum+1,2    ; above DOS 2?
  577.     jna    replay1            ; na = no, so no shared access
  578.     mov    al,0+40h        ; open readonly, deny none
  579. replay1:mov    dx,offset rdbuf        ; asciiz filename
  580.     int    dos
  581.     jnc    replay3            ; nc = success
  582.     mov    ah,prstr
  583.     mov    dx,offset reperr    ; Cannot open that file
  584.     int    dos
  585.     clc
  586.     ret
  587. replay3:mov    diskio.handle,ax    ; file handle
  588.     mov    repflg,1        ; set replay flag
  589.     call    telnet            ; enter Connect mode
  590.     mov    bx,diskio.handle
  591.     mov    ah,close2        ; close the file
  592.     int    dos
  593. endif    ; no_terminal
  594.     mov    repflg,0        ; clear the flag
  595.     clc
  596. replay2:ret
  597. replay    endp
  598.  
  599. cptchr    proc    near            ; session capture routine, char in al
  600.     test    flags.capflg,logses    ; session logging active now?
  601.     jz    cptch1            ; z = no
  602.     push    di
  603.     push    es
  604.     mov    di,data1        ; seg of capbp and capbuf
  605.     mov    es,di
  606.     cld
  607.     mov    di,es:capbp        ; buffer pointer
  608.     stosb
  609.     inc    es:capbp
  610.     pop    es
  611.     pop    di
  612.     dec    caplft            ; decrement chars remaining
  613.     jg    cptch1            ; more room, forget this part
  614.     call    cptdmp            ; dump the info
  615. cptch1:    ret
  616. cptchr    endp
  617.  
  618. cptdmp    proc    near            ; empty the capture buffer
  619.     push    ax
  620.     push    bx
  621.     push    cx
  622.     push    dx
  623.     mov    bx,sloghnd        ; get file handle
  624.     or    bx,bx            ; is file open?
  625.     jle    cptdm1            ; le = no, skip it
  626.     mov    cx,cptsiz        ; original buffer size
  627.     sub    cx,caplft        ; minus number remaining
  628.     jl    cptdm2            ; means error
  629.     jcxz    cptdm1            ; z = nothing to do
  630.     push    ds
  631.     mov    dx,data1        ; seg of capbuf
  632.     mov    ds,dx
  633.     mov    dx,offset capbuf    ; the capture routine buffer
  634.     mov    ah,write2        ; write with filehandle
  635.     int    dos            ; write out the block
  636.     pop    ds
  637.     jc    cptdm2            ; carry set means error
  638.     cmp    ax,cx            ; wrote all?
  639.     jne    cptdm2            ; no, an error
  640.     push    es
  641.     mov    dx,data1        ; seg of capbuf and capbp
  642.     mov    es,dx
  643.     mov    es:capbp,offset capbuf
  644.     pop    es
  645.     mov    caplft,cptsiz        ; init buffer ptr & chrs left
  646.     clc
  647.     jmp    short cptdm1
  648. cptdm2:    and    targ.flgs,not capt    ; so please stop capturing
  649.     and    flags.capflg,not logses    ; deselect session logging flag bit
  650.     mov    dx,offset erms23    ; tell user the bad news
  651.     call    putmod            ; write on mode line
  652.     stc
  653. cptdm1:    pop    dx
  654.     pop    cx
  655.     pop    bx
  656.     pop    ax
  657.     ret
  658. cptdmp    endp
  659.  
  660. pktcpt    proc    near            ; packet log routine, char in al
  661.     test    flags.capflg,logpkt    ; logging packets now?
  662.     jz    pktcp1            ; z = no
  663.     push    di
  664.     push    es
  665.     mov    di,data1        ; seg of pktbuf and pktbp
  666.     mov    es,di
  667.     mov    di,es:pktbp        ; buffer pointer
  668.     cld
  669.     stosb                ; store char in buffer
  670.     inc    es:pktbp        ; move pointer to next free byte
  671.     pop    es
  672.     pop    di
  673.     dec    pktlft            ; decrement chars remaining
  674.     jg    pktcp1            ; g = more room, forget this part
  675.     call    pktdmp            ; dump the info
  676. pktcp1:    ret
  677. pktcpt    endp
  678.  
  679. pktdmp    proc    near            ; empty the capture buffer
  680.     push    ax
  681.     push    bx
  682.     push    cx
  683.     push    dx
  684.     mov    bx,ploghnd        ; get file handle
  685.     or    bx,bx            ; is file open?
  686.     jle    cptdm1            ; le = no, skip it
  687.     mov    cx,cptsiz        ; original buffer size
  688.     sub    cx,pktlft        ; minus number remaining
  689.     jl    pktdm2            ; l means error
  690.     jcxz    pktdm1            ; z = nothing to do
  691.     push    ds
  692.     mov    dx,data1        ; seg of pktbuf
  693.     mov    ds,dx
  694.     mov    dx,offset pktbuf    ; the capture routine buffer
  695.     mov    ah,write2        ; write with filehandle
  696.     int    dos            ; write out the block
  697.     pop    ds
  698.     jc    pktdm2            ; carry set means error
  699.     cmp    ax,cx            ; wrote all?
  700.     jne    pktdm2            ; ne = no, error
  701.     push    es
  702.     mov    dx,data1        ; seg of pktbuf
  703.     mov    es,dx
  704.     mov    es:pktbp,offset pktbuf
  705.     pop    es
  706.     mov    pktlft,cptsiz        ; init buffer ptr & chrs left
  707.     jmp    short pktdm1
  708. pktdm2:    and    flags.capflg,not logpkt    ; so please stop capturing
  709.     mov    dx,offset erms24    ; tell user the bad news
  710.     mov    ah,prstr
  711.     int    dos
  712.     call    clscp4            ; close the packet log
  713. pktdm1:    pop    dx
  714.     pop    cx
  715.     pop    bx
  716.     pop    ax
  717.     ret
  718. pktdmp    endp
  719.  
  720. ; CLOSE command
  721.  
  722. clscpt    proc    near
  723.     mov    ah,cmkey        ; get kind of file to close
  724.     mov    dx,offset clotab    ; close table
  725.     mov    bx,offset clohlp    ; help
  726.     call    comnd
  727.            jc    clscp2            ; c = failure
  728.     mov    temp,bx
  729.     mov    ah,cmeol
  730.     call    comnd
  731.            jc    clscp2            ; c = failure
  732.     mov    kstatus,kssuc        ; success status thus far
  733.     mov    bx,temp
  734.     cmp    bh,40h            ; READ-FILE or WRITE-FILE?
  735.     jne    clscp0            ; ne = no
  736.     mov    ax,bx
  737.     jmp    vfclose            ; close FILE, pass kind in AX
  738. clscp0:    cmp    bx,logpkt+logses+logtrn    ; close all?
  739.     je    clscpi            ; e = yes
  740.     cmp    bx,logpkt        ; just packet?
  741.     je    clscp4
  742.     cmp    bx,logses        ; just session?
  743.     je    clscp6
  744.     cmp    bx,logtrn        ; just session?
  745.     jne    clscp1            ; ne = no
  746.     jmp    clscp8
  747. clscp1:    mov    dx,offset erms22    ; say none active
  748.     mov    ah,prstr
  749.     int    dos
  750.     clc
  751.     ret
  752. clscp2:    mov    kstatus,ksgen        ; general cmd failure status
  753.     stc
  754.     ret
  755.                     ; CLSCPI called at Kermit exit
  756. CLSCPI:    mov    bx,portval
  757.     mov    [bx].flowc,0        ; set no flow control so no sending it
  758.     call    pntflsh            ; flush PRN buffer
  759.     call    clscp4            ; close packet log
  760.     call    clscp6            ; close session log
  761.     call    clscp8            ; close transaction log
  762.     mov    al,2            ; close WRITE FILE log
  763.     call    vfclose
  764.     clc                ; return success
  765.     ret
  766.  
  767. clscp4:    push    bx            ; PACKET LOG
  768.     mov    bx,ploghnd        ; packet log handle
  769.     or    bx,bx            ; is it open?
  770.     jle    clscp5            ; e = no
  771.     call    pktdmp            ; dump buffer
  772.     mov    ah,close2
  773.     int    dos
  774.     cmp    flags.takflg,0        ; ok to echo?
  775.     je    clscp5            ; e = no
  776.     mov    ah,prstr
  777.     mov    dx,offset clpktlog    ; tell what we are doing
  778.     int    dos
  779. clscp5:    mov    ploghnd,-1        ; say handle is invalid
  780.     pop    bx
  781.     and    flags.capflg,not logpkt    ; say this log is closed
  782.     ret
  783.  
  784. clscp6:    push    bx            ; SESSION LOG
  785.     mov    bx,sloghnd        ; session log handle
  786.     or    bx,bx            ; is it open?
  787.     jle    clscp7            ; e = no
  788.     call    cptdmp            ; dump buffer
  789.     mov    ah,close2
  790.     int    dos
  791.     cmp    flags.takflg,0        ; ok to echo?
  792.     je    clscp7            ; e = no
  793.     mov    ah,prstr
  794.     mov    dx,offset clseslog    ; tell what we are doing
  795.     int    dos
  796. clscp7:    mov    sloghnd,-1        ; say handle is invalid
  797.     pop    bx
  798.     and    flags.capflg,not logses    ; say this log is closed
  799.     ret
  800.  
  801. clscp8:    push    bx            ; TRANSACTION LOG
  802.     mov    bx,tloghnd        ; transaction log handle
  803.     or    bx,bx            ; is it open?
  804.     jle    clscp9            ; e = no
  805.     mov    ah,close2
  806.     int    dos
  807.     cmp    flags.takflg,0        ; ok to echo?
  808.     je    clscp9            ; e = no
  809.     mov    ah,prstr
  810.     mov    dx,offset cltrnlog    ; tell what we are doing
  811.     int    dos
  812. clscp9:    mov    tloghnd,-1        ; say handle is invalid
  813.     pop    bx
  814.     and    flags.capflg,not logtrn    ; say this log is closed
  815.     ret
  816. clscpt    endp
  817.  
  818. ; Print on PRN the char in register al. On success return with C bit clear.
  819. ; On failure do procedure pntchk and return its C bit (typically C set).
  820. ; Uses buffer dumpbuf (screen dump).
  821. pntchr    proc    near
  822.     push    es
  823.     push    ax
  824.     mov    ax,data1        ; segment of pntptr and prnbuf
  825.     mov    es,ax
  826.     cmp    es:pntptr,offset prnbuf+cptsiz ; buffer full yet?
  827.     pop    ax
  828.     pop    es
  829.     jb    pntchr1            ; b = no
  830.     call    pntflsh            ; flush buffer now
  831.     jnc    pntchr1            ; nc = success
  832.     ret                ; c = fail, discard char
  833. pntchr1:push    es
  834.     push    bx
  835.     mov    bx,data1        ; segment of pntptr and prnbuf
  836.     mov    es,bx
  837.     mov    bx,es:pntptr        ; pointer to next open slot
  838.     mov    es:[bx],al        ; store the character
  839.     inc    bx            ; update pointer
  840.     mov    es:pntptr,bx        ; save pointer
  841.     pop    bx
  842.     pop    es
  843.     clc                ; clear carry bit
  844.     ret
  845. pntchr    endp
  846.  
  847. ; Flush printer buffer. Return carry clear if success.
  848. ; On failure do procedure pntchk and return its C bit (typically C set).
  849. ; Uses buffer dumpbuf (screen dump).
  850. pntflsh    proc    near
  851.     push    es
  852.     push    ax
  853.     mov    ax,data1        ; segment of pntptr and prnbuf
  854.     mov    es,ax
  855.     cmp    es:pntptr,offset prnbuf    ; any text in buffer?
  856.     pop    ax
  857.     pop    es
  858.     ja    pntfls1            ; a = yes
  859.     clc
  860.     ret                ; else nothing to do
  861. pntfls1:cmp    prnhand,0        ; is printer handle valid?
  862.     jg    pntfls2            ; g = yes
  863.     push    es
  864.     push    ax
  865.     mov    ax,data1        ; segment of pntptr and prnbuf
  866.     mov    es,ax
  867.     mov    es:pntptr,offset prnbuf
  868.     pop    ax
  869.     pop    es
  870.     clc                ; omit printing, quietly
  871.     ret
  872. pntfls2:push    ax
  873.     push    bx
  874.     push    cx
  875.     push    dx
  876.     push    si
  877.     push    di
  878.     push    es
  879.     mov    ah,flowoff        ; get flow control char
  880.     or    ah,ah            ; flow control active?
  881.     jz    pntfls3            ; z = no, not using xoff
  882.     call    outchr            ; output xoff (ah), no echo
  883. pntfls3:mov    bx,prnhand        ; file handle for DOS printer PRN
  884.     push    DS            ; about to change DS
  885.     mov    dx,data1        ; segment of prnbuf
  886.     mov    ds,dx            ; set DS
  887.     mov    dx,offset prnbuf    ; start of buffer
  888.     mov    cx,ds:pntptr
  889.     sub    cx,dx            ; cx = current byte count
  890. pntfls4:push    cx
  891.     push    dx
  892.     mov    cx,1
  893.     mov    ah,write2
  894.     int    dos            ; write buffer to printer
  895.     pop    dx
  896.     pop    cx
  897.     jc    pntfls5            ; c = call failed
  898.     cmp    ax,1            ; did we write it?
  899.     jne    pntfls5            ; ne = no, dos critical error
  900.     inc    dx            ; point to next char
  901.     loop    pntfls4
  902.     mov    ds:pntptr,offset prnbuf    ; reset buffer pointer
  903.     pop    DS            ; restore DS
  904.     clc                ; declare success
  905.     jmp    pntfls11
  906. pntfls5:mov    si,dx            ; address of next char to be printed
  907.     mov    di,offset prnbuf    ; start of buffer
  908.     sub    dx,di            ; dx now = number successful prints
  909.     mov    cx,ds:pntptr
  910.     sub    cx,si            ; count of chars to be printed
  911.     jle    pntfls6
  912.     mov    ax,ds
  913.     mov    es,ax
  914.     cld
  915.     rep    movsb            ; copy unwritten to start of buffer
  916. pntfls6:sub    ds:pntptr,dx        ; move back printer pointer by ok's
  917.     pop    DS            ; restore DS
  918.  
  919. pntfls7:mov    dx,offset erms26    ; printer not ready, get user action
  920.     call    putmod            ; write new mode line
  921.     call    beep            ; make a noise
  922.     mov    ah,0ch            ; clear DOS typeahead buffer
  923.     mov    al,1            ; read from DOS buffer
  924.     int    dos
  925.     or    al,al            ; Special key?
  926.     jnz    pntfls8            ; nz = no, consume
  927.     mov    al,1            ; consume scan code
  928.     int    dos
  929.     jmp    short pntfls7        ; try again
  930.  
  931. pntfls8:and    al,not 20h        ; lower to upper case quicky
  932.     cmp    al,'R'            ; Retry?
  933.     jne    pntfls8a        ; ne = no
  934.     call    trnmod            ; toggle mode line
  935.     call    trnmod            ; back to same state as before
  936.     jmp    pntfls3            ; go retry
  937. pntfls8a:cmp    al,'D'            ; Discard printing?
  938.     jne    pntfls7            ; ne = no, try again
  939.     mov    bx,prnhand
  940.     cmp    bx,4            ; stdin/stdout/stderr/stdaux/stdprn?
  941.     jbe    pntfls9            ; be = yes, always available
  942.     mov    ah,close2        ; close this file
  943.     int    dos
  944. pntfls9:mov    bx,offset prnname    ; name of printer file
  945.     mov    word ptr [bx],'UN'    ; set to NUL<0>
  946.     mov    word ptr [bx+2],'L'+0
  947.     push    es
  948.     mov    ax,data1        ; seg for pntptr
  949.     mov    es,ax
  950.     mov    es:pntptr,offset prnbuf    ; reset pointer
  951.     pop    es
  952.     mov    prnhand,-1        ; declare handle invalid
  953. ifndef    no_terminal
  954.     mov    anspflg,0        ; mszibm/msyibm print status flag off
  955. endif    ; no_terminal
  956. pntfls10:call    trnmod            ; toggle mode line
  957.     call    trnmod            ; back to same state as before
  958.     stc                ; declare failure
  959. pntfls11:pushf
  960.     mov    ah,flowon
  961.     or    ah,ah            ; flow control active?
  962.     jz    pntfls12        ; z = no, not using xon
  963.     call    outchr            ; output xon (al), no echo
  964. pntfls12:popf
  965.     pop    es
  966.     pop    di
  967.     pop    si
  968.     pop    dx
  969.     pop    cx
  970.     pop    bx
  971.     pop    ax
  972.     ret                ; nc = success
  973. pntflsh    endp
  974.  
  975. ; Check for PRN (DOS's printer) being ready. If ready, return with C clear
  976. ; Otherwise, write Not Ready msg on mode line and return with C bit set.
  977. ; N.B. DOS Critical Error will occur here if PRN is not ready.  [jrd]
  978. pntchk    proc    near
  979.     push    dx
  980.     push    cx
  981.     push    ax
  982.     mov    cx,10            ; ten retries before declaring error
  983.     cmp    prnhand,0        ; printer handle valid?
  984.     jle    pntchk2            ; le = no, invalid
  985. pntchk0:push    bx
  986.     mov    bx,prnhand        ; file handle
  987.     mov    ah,ioctl        ; get printer status, via DOS
  988.     mov    al,7            ; status for output
  989.     int    dos
  990.     pop    bx
  991.     jc    pntchk1            ; c = call failed
  992.     cmp    al,0ffh            ; code for Ready?
  993.     je    pntchk3            ; e = yes, assume printer is ready
  994. pntchk1:push    cx            ; save counter, just in case
  995.     mov    ax,100            ; wait 100 millisec
  996.     call    pcwait
  997.     pop    cx
  998.     loop    pntchk0            ; and try a few more times
  999.                     ; get here when printer is not ready
  1000. pntchk2:pop    ax
  1001.     pop    cx
  1002.     pop    dx
  1003.     stc                ; say printer not ready
  1004.     ret
  1005. pntchk3:pop    ax
  1006.     pop    cx
  1007.     pop    dx
  1008.     clc                ; say printer is ready
  1009.     ret
  1010. pntchk    endp
  1011.  
  1012.  
  1013. prnopen    proc    near
  1014.     push    ax
  1015.     push    bx
  1016.     push    cx
  1017.     push    dx
  1018.     mov    prnhand,4        ; preset default handle
  1019.     mov    dx,offset prnname    ; name of disk file, from msssho
  1020.     mov    ax,dx            ; where isfile wants name ptr
  1021.     call    isfile            ; what kind of file is this?
  1022.     jc    prnop3            ; c = no such file, create it
  1023.     test    byte ptr filtst.dta+21,1fh ; file attributes, ok to write?
  1024.     jnz    prnop2            ; nz = no
  1025.     mov    al,1            ; writing
  1026.     mov    ah,open2        ; open existing file
  1027.     int    dos
  1028.     jc    prnop2            ; c = failure
  1029.     mov    prnhand,ax        ; save file handle
  1030.     mov    bx,ax            ; handle for DOS
  1031.     mov    ah,ioctl
  1032.     mov    al,0            ; get info
  1033.     int    dos
  1034.     or    dl,20h            ; turn on binary mode
  1035.     xor    dh,dh
  1036.     mov    ah,ioctl
  1037.     mov    al,1            ; set info
  1038.     int    dos
  1039.     mov    cx,0ffffh        ; setup file pointer
  1040.     mov    dx,-1            ; and offset
  1041.     mov    al,2            ; move to eof minus one byte
  1042.     mov    ah,lseek        ; seek the end
  1043.     int    dos
  1044.     pop    dx
  1045.     pop    cx
  1046.     pop    bx
  1047.     pop    ax
  1048.     clc
  1049.     ret
  1050. prnop2:    pop    dx
  1051.     pop    cx
  1052.     pop    bx
  1053.     pop    ax
  1054.     stc
  1055.     ret
  1056. prnop3:    test    filtst.fstat,80h    ; access problem?
  1057.     jnz    prnop2            ; nz = yes
  1058.     mov    ah,creat2        ; file did not exist
  1059.     mov    cx,20h            ; attributes, archive bit
  1060.     int    dos
  1061.     mov    prnhand,ax        ; save file handle
  1062.     pop    dx
  1063.     pop    cx
  1064.     pop    bx
  1065.     pop    ax
  1066.     ret                ; may have carry set
  1067. prnopen    endp
  1068.  
  1069. ; worker: copy line from si to di, first removing trailing spaces, second
  1070. ; parsing out curly braced strings, then third converting \{b##} in strings
  1071. ; to binary numbers. Returns carry set if error; else carry clear, with byte
  1072. ; count in cx. Braces are optional but must occur in pairs.
  1073. ; Items which cannot be converted to legal numbers are copied verbatium
  1074. ; to the output string (ex: \{c}  is copied as \{c}  but \{x0d} is hex 0dh).
  1075. ; '\\' is written as '\'
  1076. ; Requires byte count in CX to handle embedded \0 bytes.
  1077. cnvlin    proc    near
  1078.     push    ax
  1079.     push    si            ; source ptr
  1080.     push    di            ; destination ptr
  1081.     push    bp            ; end of string marker
  1082.     push    temp            ; output length counter
  1083.     push    es            ; end of save regs
  1084.     push    ds            ; move ds into es
  1085.     pop    es            ; use data segment for es:di
  1086.     mov    temp,di            ; initial output position
  1087.     call    cnvstr            ; parse curly braces
  1088.     xor    dx,dx            ; initialize returned byte count
  1089.     cld
  1090.     mov    bp,si
  1091.     add    bp,cx            ; point to last byte + 1 of string
  1092. cnvln1:    cmp    si,bp            ; at end of string?
  1093.     jae    cnvlnx            ; ae = yes, exit
  1094.     mov    al,[si]            ; look at starting byte
  1095.     cmp    al,'\'            ; numeric intro?
  1096.     jne    cnvln3            ; ne = no
  1097.     mov    atoi_cnt,cx        ; length for atoi
  1098.     mov    atoibyte,1        ; convert only one character
  1099.     call    atoi            ; deal with \numbers
  1100.     jnc    cnvln4            ; nc = success, converted number
  1101. cnvln3:    lodsb                ; reread from string literally
  1102.     xor    ah,ah            ; only one byte of output
  1103. cnvln4:    cld
  1104.     stosb                ; save the char
  1105.     or    ah,ah            ; is returned number > 255?
  1106.     jz    cnvln1            ; z = no, do more chars
  1107. cnvln5:    stosb                ; save high order byte next
  1108.     jmp    short cnvln1        ; do more chars
  1109. cnvlnx:    mov    byte ptr [di],0        ; plant terminator
  1110.     clc                ; clear c bit, success
  1111.     sub    di,temp            ; current - inital output position
  1112.     mov    cx,di            ; returned byte count to CX
  1113.     pop    es            ; restore regs
  1114.     pop    temp
  1115.     pop    bp
  1116.     pop    di            ; destination ptr
  1117.     pop    si            ; source ptr
  1118.     pop    ax
  1119.     ret
  1120. cnvlin    endp
  1121.  
  1122. ; Convert string by removing surrounding curly brace delimiter pair. 
  1123. ; Converts text in place.
  1124. ; Enter with source ptr in si.
  1125. ; Preserves all registers, uses byte tmp. 9 Oct 1987 [jrd]
  1126. ; 
  1127. cnvstr    proc    near
  1128.     push    ax
  1129.     push    bx
  1130.     push    dx
  1131.     push    si            ; save start of source string
  1132.     push    di
  1133.     push    es
  1134.     xor    bx,bx             ; output count, assume none
  1135.     mov    dx,si            ; source address
  1136.     jcxz    cnvst4            ; z = nothing there
  1137.     push    ds
  1138.     pop    es            ; set es to data segment
  1139.     cld
  1140.     mov    di,si            ; set destination address to source
  1141.                     ; 2. Parse off curly brace delimiters
  1142.     mov    bx,cx            ; assume no changes to byte count
  1143.     cmp    byte ptr [si],braceop    ; opening brace?
  1144.     jne    cnvst4            ; ne = no, ignore brace-matching code
  1145.     xor    bx,bx            ; count up output bytes
  1146.     inc    si            ; skip opening brace
  1147.     mov    dl,braceop        ; opening brace (we count them up)
  1148.     mov    dh,bracecl        ; closing brace (we count them down)
  1149.     mov    tmp,1            ; we are at brace level 1
  1150. cnvst1:    cld                ; search forward
  1151.     lodsb                ; read a string char
  1152.     stosb                ; store char (skips opening brace)
  1153.     dec    cx
  1154.     inc    bx            ; count bytes read and written
  1155.     or    cx,cx            ; at end of string?
  1156.     jle    cnvst4            ; le = yes, we are done
  1157.     cmp    al,dl            ; an opening brace?
  1158.     jne    cnvst2            ; ne = no
  1159.     inc    tmp            ; yes, increment brace level
  1160.     jmp    short cnvst1        ;  and continue scanning
  1161.  
  1162. cnvst2:    cmp    al,dh            ; closing brace?
  1163.     jne    cnvst1            ; ne = no, continue scanning
  1164.     dec    tmp            ; yes, decrement brace level
  1165.     or    cx,cx            ; have we just read the last char?
  1166.     jnz    cnvst3            ; nz = no, continue scanning
  1167.     mov    tmp,0            ; yes, this is the closing brace
  1168. cnvst3:    cmp    tmp,0            ; at level 0?
  1169.     jne    cnvst1            ; ne = no, #opening > #closing braces
  1170.     dec    bx            ; don't count terminating brace
  1171.     mov    byte ptr [di-1],0    ; plant terminator on closing brace
  1172.  
  1173. cnvst4:    pop    es            ; recover original registers
  1174.     pop    di
  1175.     pop    si
  1176.     pop    dx
  1177.     mov    cx,bx            ; return count in cx
  1178.     pop    bx
  1179.     pop    ax
  1180.     ret
  1181. cnvstr    endp
  1182.  
  1183. ; OPEN { READ | WRITE | APPEND } filespec
  1184. vfopen    proc    near
  1185.     mov    ah,cmkey        ; get READ/WRITE/APPEND keyword
  1186.     mov    dx,offset opntab    ; keyword table
  1187.     xor    bx,bx            ; help
  1188.     call    comnd
  1189.     jc    vfopen1            ; c = failed
  1190.     mov    temp,bx
  1191.     mov    ah,cmword        ; read filespec
  1192.     mov    bx,offset rdbuf        ; buffer for filename
  1193.     mov    dx,offset vfophlp    ; help
  1194.     call    comnd
  1195.     jc    vfopen1            ; c = failed
  1196.     mov    ah,cmeol        ; get end of line confirmation
  1197.     call    comnd
  1198.     jnc    vfopen2
  1199.     mov    kstatus,ksgen        ; general cmd failure status
  1200. vfopen1:ret                ; error return, carry set
  1201.  
  1202. vfopen2:mov    kstatus,kssuc        ; assume success status
  1203.     mov    dx,offset rdbuf        ; filename, asiiz
  1204.     mov    bx,temp            ; kind of open
  1205.     cmp    bx,1            ; open for reading?
  1206.     jne    vfopen4            ; ne = no
  1207.                     ; OPEN READ
  1208.     cmp    vfrhandle,0        ; is it open now?
  1209.     jge    vfopen8            ; ge = yes, complain
  1210.     mov    ah,open2        ; file open
  1211.     xor    al,al            ; 0 = open readonly
  1212.     cmp    dosnum,300h        ; at or above DOS 3?
  1213.     jb    vfopen3            ; b = no, so no shared access
  1214.     or    al,40h            ; open readonly, deny none
  1215. vfopen3:int    dos
  1216.     jc    vfopen9            ; c = failed to open the file
  1217.     mov    vfrhandle,ax        ; save file handle
  1218.     clc
  1219.     ret
  1220.                     ; OPEN WRITE or APPEND
  1221. vfopen4:cmp    vfwhandle,0        ; is it open now?
  1222.     jge    vfopen8            ; ge = yes, complain
  1223.     mov    ax,dx            ; filename for isfile
  1224.     call    isfile        ; check for read-only/system/vol-label/dir
  1225.     jc    vfopen7            ; c = file does not exist
  1226.     test    byte ptr filtst.dta+21,1fh    ; the no-no file attributes
  1227.     jnz    vfopen9            ; nz = do not write over one of these
  1228. vfopen5:test    filtst.fstat,80h    ; access problem?
  1229.     jnz    vfopen9            ; nz = yes, quit here
  1230.     test    byte ptr filtst.dta+21,1bh    ; r/o, hidden, volume label?
  1231.     jnz    vfopen9            ; we won't touch these
  1232.     mov    ah,open2           ; open existing file (usually a device)
  1233.     mov    al,1+1            ; open for writing
  1234.     int    dos
  1235.     jc    vfopen9            ; carry set means can't open
  1236.     mov    vfwhandle,ax        ; remember file handle
  1237.     mov    bx,ax            ; file handle for lseek
  1238.     xor    cx,cx
  1239.     xor    dx,dx            ; cx:dx = displacment
  1240.     xor    al,al            ; 0 means from start of file
  1241.     cmp    temp,2            ; WRITE? means from start of file
  1242.     je    vfopen6            ; e = yes, else APPEND
  1243.     mov    al,2            ; move to eof
  1244. vfopen6:mov    ah,lseek        ; seek the place
  1245.     int    dos
  1246.     clc
  1247.     ret
  1248.  
  1249. vfopen7:cmp    temp,1            ; READ?
  1250.     je    vfopen9            ; e = yes, should not be here
  1251.     mov    ah,creat2        ; create file
  1252.     xor    cx,cx            ; 0 = attributes bits
  1253.     int    dos
  1254.     jc    vfopen9            ; c = failed
  1255.     mov    vfwhandle,ax        ; save file handle
  1256.     clc                ; carry clear for success
  1257.     ret
  1258.  
  1259. vfopen8:mov    dx,offset vfoptwice    ; trying to reopen a file
  1260.     mov    ah,prstr
  1261.     int    dos
  1262.     mov    kstatus,kstake        ; Take file failure status
  1263.     stc
  1264.     ret
  1265. vfopen9:mov    dx,offset vfopbad    ; can't open, complain
  1266.     mov    ah,prstr
  1267.     int    dos
  1268.     mov    dx,offset rdbuf        ; filename
  1269.     call    prtasz
  1270.     mov    kstatus,kstake        ; Take file failure status
  1271.     stc
  1272.     ret
  1273. vfopen    endp
  1274.  
  1275. ; CLOSE {READ-FILE | WRITE-FILE}
  1276. vfclose    proc    near
  1277.     mov    tmp,al            ; remember kind (1=READ, 2=WRITE)
  1278.     mov    bx,vfrhandle        ; READ FILE handle
  1279.     cmp    al,1            ; READ-FILE?
  1280.     je    vfclos1            ; e = yes
  1281.     cmp    al,2            ; WRITE-FILE?
  1282.     jne    vfclos3            ; ne = no, a mistake
  1283.     mov    bx,vfwhandle        ; write handle
  1284.     or    bx,bx
  1285.     jl    vfclos3            ; l = invalid handle
  1286.     mov    dx,offset rdbuf
  1287.     xor    cx,cx            ; zero length
  1288.     push    bx            ; save handle
  1289.     mov    ah,write2        ; set file high water mark
  1290.     int    dos
  1291.     pop    bx
  1292. vfclos1:or    bx,bx
  1293.     jl    vfclos3            ; l = invalid handle
  1294.     mov    kstatus,kssuc        ; success status thus far
  1295.     mov    ah,close2        ; close file
  1296.     int    dos
  1297.     jc    vfclos4            ; c = error
  1298.     cmp    tmp,1            ; READ?
  1299.     jne    vfclos2            ; ne = no, WRITE
  1300.     mov    vfrhandle,-1        ; declare READ handle to be invalid
  1301.     clc
  1302.     ret
  1303. vfclos2:mov    vfwhandle,-1        ; declare WRITE handle to be invalid
  1304.     clc
  1305.     ret
  1306. vfclos4:mov    ah,prstr
  1307.     mov    dx,offset vfclbad    ; complain
  1308.     int    dos
  1309. vfclos3:mov    kstatus,ksgen        ; general cmd failure status
  1310.     stc
  1311.     ret
  1312. vfclose    endp
  1313.  
  1314. ; READ-FILE variable name
  1315. vfread    proc    near
  1316.     mov    comand.cmper,1        ; do not react to '\%' in macro name
  1317.     mov    comand.cmarray,1    ; allow sub in [..] of \&<char> arrays
  1318.     mov    ah,cmword
  1319.     mov    bx,offset rdbuf+2    ; buffer for macro name
  1320.     mov    word ptr rdbuf,0
  1321.     mov    dx,offset vfrdmsg
  1322.     call    comnd            ; get macro name
  1323.     jnc    vfread1            ; nc = success
  1324.     mov    kstatus,ksgen        ; general cmd failure status
  1325.     ret                ; failure
  1326. vfread1:or    ax,ax            ; null entry?
  1327.     jnz    vfread2            ; nz = no
  1328.     mov    dx,offset vfrdbad    ; more parameters needed
  1329.     mov    ah,prstr
  1330.     int    dos
  1331.     mov    kstatus,ksgen        ; general cmd failure status
  1332.     stc
  1333.     ret
  1334.  
  1335. vfread2:push    ax
  1336.     mov    ah,cmeol        ; get command confirmation
  1337.     call    comnd
  1338.     pop    ax            ; ax is variable length
  1339.     jc    vfreadx            ; c = failed
  1340.     mov    cx,cmdblen        ; length of rdbuf
  1341.     sub    cx,ax            ; minus macro name
  1342.     dec    cx            ; minus space separator
  1343.     mov    temp,0            ; leading whitespace and comment flgs
  1344.     mov    di,offset rdbuf+2    ; destination buffer
  1345.     add    di,ax            ; plus variable name
  1346.     mov    byte ptr [di],' '    ; space separator
  1347.     inc    di            ; put definition here
  1348.     mov    bx,vfrhandle        ; READ FILE handle
  1349.     or    bx,bx            ; check for valid handle
  1350.     jge    vfread3            ; ge = valid
  1351.     mov    ah,prstr
  1352.     mov    dx,offset vfnofile    ; say no file
  1353.     int    dos
  1354. vfreadx:mov    kstatus,ksgen        ; general cmd failure status
  1355.     stc                ; failure return
  1356.     ret
  1357. vfread3:push    cx            ; read from file
  1358.     mov    kstatus,kssuc        ; assume success status
  1359.     mov    cx,1            ; read 1 char
  1360.     mov    dx,di            ; place here
  1361.     mov    byte ptr [di],0        ; insert terminator
  1362.     mov    ah,readf2
  1363.     int    dos
  1364.     pop    cx
  1365.     jc    vfreadx            ; c = read failure
  1366.     or    ax,ax            ; count of bytes read
  1367.     jz    vfread9            ; z means end of file
  1368.     mov    al,[di]            ; get the character
  1369.     cmp    flags.takflg,0        ; echo Take files?
  1370.     je    vfread3a        ; e = no
  1371.     push    ax
  1372.     mov    ah,conout
  1373.     mov    dl,al            ; echo character
  1374.     int    dos
  1375.     pop    ax
  1376. vfread3a:cmp    al,CR            ; CR?
  1377.     je    vfread7            ; e = yes, ignore it
  1378.     cmp    al,LF            ; LF?
  1379.     je    vfread8            ; e = yes, exit
  1380.     cmp    byte ptr temp,0        ; seen non-spacing char yet?
  1381.     jne    vfread6            ; ne = yes
  1382.     cmp    al,' '            ; is this a space?
  1383.     je    vfread7            ; e = yes, skip it
  1384.     cmp    al,TAB            ; or a tab?
  1385.     je    vfread7            ; e = yes, skip it
  1386.     mov    byte ptr temp,1        ; say have seen non-spacing char
  1387.  
  1388. vfread6:inc    di            ; next storage cell
  1389. vfread7:loop    vfread3            ; loop til end of line
  1390.  
  1391. vfread8:cmp    byte ptr [di-1],'-'    ; last printable is line-continuation?
  1392.     jne    vfread10        ; ne = no, use this line as-is
  1393.     dec    di            ; point to hyphen
  1394.     mov    cx,offset rdbuf+cmdblen    ; end of rdbuf
  1395.     sub    cx,di            ; minus where we are now
  1396.     jle    vfread10        ; le = no space remaining
  1397.     mov    temp,0            ; leading whitespace and comment flgs
  1398.     jmp    vfread3            ; read another line
  1399.  
  1400. vfread9:mov    kstatus,ksgen        ; EOF, general command failure status
  1401.  
  1402. vfread10:cmp    flags.takflg,0        ; echo Take files?
  1403.     je    vfread11        ; e = no
  1404.     mov    ah,prstr
  1405.     mov    dx,offset crlf        ; for last displayed line
  1406.     int    dos
  1407.  
  1408. vfread11:mov    byte ptr [di],0        ; insert final terminator
  1409.     mov    dx,offset rdbuf+2    ; start counting from here
  1410.     push    kstatus            ; preserve status from above work
  1411.     call    strlen            ; cx becomes length
  1412.     call    dodecom            ; create the variable
  1413.     pop    kstatus            ; recover reading status
  1414.     jc    vfread12        ; c = failure
  1415.     ret
  1416. vfread12:mov    kstatus,ksgen        ; general command failure status
  1417.     mov    ah,prstr
  1418.     mov    dx,offset vfrbad    ; say error while reading
  1419.     int    dos
  1420.     stc
  1421.     ret
  1422. vfread    endp
  1423.  
  1424. ; WRITELN {FILE or log} text   (adds trailing CR/LF)
  1425. writeln    proc    near
  1426.     mov    tmp,1            ; flag for trailing CR/LF
  1427.     jmp    short write0        ; common code
  1428. writeln    endp
  1429.  
  1430. ; WRITE {FILE or log} text
  1431. Write    proc    near
  1432.     mov    tmp,0            ; flag for no trailing CR/LF
  1433. write0:    mov    ah,cmkey        ; get kind of log file
  1434.     mov    dx,offset writetab    ; table of possibilities
  1435.     xor    bx,bx            ; help, when we get there
  1436.     call    comnd
  1437.     jnc    write1            ; nc = success
  1438.     mov    kstatus,ksgen        ; general cmd failure status
  1439.     ret
  1440. write1:    mov    temp,bx            ; save log file kind
  1441.     mov    comand.cmdonum,1    ; \number conversion allowed
  1442.     mov    comand.cmblen,cmdblen    ; use full length
  1443.     mov    ah,cmline        ; get string to be written
  1444.     mov    bx,offset rdbuf        ; where to put text
  1445.     mov    dx,offset msgtxt    ; help
  1446.     call    comnd
  1447.     jnc    wpkt0
  1448.     mov    kstatus,ksgen        ; general cmd failure status
  1449.     ret                ; c = failure
  1450. wpkt0:    mov    kstatus,kssuc        ; success status thus far
  1451.     mov    si,offset rdbuf        ; start of text in buffer
  1452.     cmp    tmp,0            ; add trailing CR/LF?
  1453.     je    wpkt0a            ; e = no
  1454.     mov    bx,ax            ; current length
  1455.     mov    word ptr rdbuf[bx],LF*256+CR ; add CR LF
  1456.     mov    word ptr rdbuf[bx+2],0    ; and terminator
  1457.     add    ax,2
  1458. wpkt0a:    mov    bx,temp            ; log file kind
  1459.     mov    cx,ax            ; length 
  1460.     jcxz    wpkt2            ; z = no chars to write
  1461.     cmp    bx,logpkt        ; Packet log?
  1462.     jne    wses1            ; ne = no
  1463. wpkt1:    lodsb                ; get byte to al
  1464.     call    pktcpt            ; write to packet log
  1465.     loop    wpkt1
  1466. wpkt2:     clc                ; say success
  1467.     ret
  1468.  
  1469. wses1:    cmp    bx,logses        ; Session log?
  1470.     jne    wtrn1            ; ne = no
  1471. wses2:    lodsb                ; get byte to al
  1472.     call    cptchr            ; write to log
  1473.     loop    wses2            ; do cx chars
  1474.     clc                ; say success
  1475.     ret
  1476.  
  1477. wtrn1:    cmp    bx,logtrn        ; Transaction log?
  1478.     jne    wtrn2            ; ne = no
  1479.     mov    bx,tloghnd        ; file handle
  1480.     jmp    short wtrn4
  1481.  
  1482. wtrn2:    cmp    bx,80h            ; WRITE SCREEN?
  1483.     jne    wtrn3            ; ne = no
  1484.     xor    bx,bx            ; handle is stdout
  1485.     jmp    short wtrn4
  1486.  
  1487. wtrn3:    cmp    bx,4002h        ; WRITE FILE?
  1488.     jne    wtrn5            ; ne = no, forget this
  1489.     mov    bx,vfwhandle        ; handle
  1490.  
  1491. wtrn4:    or    bx,bx            ; is handle valid?
  1492.     jl    wtrn5            ; l = no
  1493.     mov    dx,offset rdbuf
  1494.     mov    ah,write2        ; write to file handle in bx
  1495.     int    dos
  1496.     jc    wtrn4a            ; c = failure
  1497.     clc
  1498.     ret
  1499. wtrn4a:    mov    ah,prstr
  1500.     mov    dx,offset vfwbad    ; say error while writing
  1501.     int    dos
  1502.     mov    kstatus,ksgen
  1503.     stc
  1504.     ret
  1505. wtrn5:    mov    kstatus,ksgen        ; general cmd failure status
  1506.     mov    ah,prstr
  1507.     mov    dx,offset vfnofile    ; say no file
  1508.     int    dos
  1509.     stc
  1510.     ret
  1511. write    endp
  1512. code    ends
  1513.  
  1514. code1    segment
  1515.     assume    cs:code1
  1516.  
  1517. ; Convert ascii strings of the form "\{bnnn}" to a binary dword in dx:ax.
  1518. ; The braces are optional but must occur in pairs. Numeric base indicator "b"
  1519. ; is O or o or X or x or D or d or missing, for octal, hex, or decimal (def).
  1520. ; Enter with si pointing at "\".
  1521. ; Returns binary value in ax with carry clear and si to right of "}" or at
  1522. ; terminating non-numeric char if successful; otherwise, a failure,
  1523. ; return carry set with si = entry value and first read char in al.
  1524. ; Public byte  atoibyte  is used to control conversion of one character, if
  1525. ;  non-zero, or as many as can be parsed if zero. This routine always clears
  1526. ;  atoibyte upon exiting.
  1527. ; atoi_err byte values, carry bit state, meaning
  1528. ; 0 nc    successfully converted, can accept more data
  1529. ; 1 nc    successfully converted and string is terminated
  1530. ; 2 nc    successfully converted with break char pointed to by SI
  1531. ; 4 c    insufficient bytes to resolve
  1532. ; 8 c    syntax error in expression, cannot convert
  1533. atoi    proc    far
  1534.     push    temp
  1535.     push    temp1
  1536.     push    cx            ; save working reg
  1537.     push    si            ; save entry si
  1538.     push    bx
  1539.     push    ax            ; save read char
  1540.     xor    ax,ax
  1541.     mov    temp,ax
  1542.     mov    temp1,ax
  1543.     mov    atoi_err,al        ; assume success and can read more
  1544.     xor    bx,bx            ; assume no opening brace
  1545.     cld
  1546.     mov    cx,atoi_cnt        ; bytes available to examine
  1547.     or    cx,cx
  1548.     jnz    atoi1
  1549.     mov    atoi_cnt,16        ; safety
  1550. atoi1:    call    atoi_read        ; read a byte or fail
  1551.     jnc    atoi1a
  1552.     jmp    atoix            ; fail
  1553.  
  1554. atoi1a:    cmp    al,' '            ; leading space?
  1555.     je    atoi1            ; e = yes, read again, for do_math
  1556.     cmp    al,'\'            ; number introducer?
  1557.     jne    atoi1b            ; ne = no
  1558.     call    atoi_read        ; get next byte
  1559.     jnc    atoi1b
  1560.     jmp    atoix
  1561.  
  1562. atoi1b:    cmp    al,braceop        ; opening brace?
  1563.     jne    atoi1c            ; ne = no
  1564.     mov    bl,bracecl        ; remember a closing brace is needed
  1565.     call    atoi_read        ; get next byte
  1566.     jnc    atoi1c
  1567.     jmp    atoix
  1568.  
  1569. atoi1c:    call    isnumbase        ; number base introducer?
  1570.     jc    atoi1d            ; c = no
  1571.     call    atoi_read        ; get next byte
  1572.     jnc    atoi2            ; nc = got a byte
  1573.     jmp    atoix
  1574. atoi1d:    mov    nbase,10        ; assume base 10
  1575.     mov    cx,3            ; and three digits per char
  1576.  
  1577. atoi2:    call    cnvdig            ; do we have a digit now?
  1578.     jnc    atoi2a            ; nc = yes
  1579.     mov    atoi_err,8        ; syntax error, digit required
  1580.     jmp    atoix
  1581. atoi2a:    dec    si            ; back over it for read below
  1582.     inc    atoi_cnt
  1583.     mov    ax,cx            ; number base byte count
  1584.     mov    cx,atoi_cnt        ; available bytes
  1585.     cmp    atoibyte,0        ; read as many bytes as possible?
  1586.     je    atoi3            ; e = yes
  1587.     cmp    ax,cx            ; number base wants more than we have?
  1588.     ja    atoi3            ; a = yes, use available bytes
  1589.     mov    cx,ax            ; limit loop to num base requirements
  1590.     mov    atoi_err,1        ; presume successful and terminated
  1591.  
  1592. atoi3:    call    atoi_read        ; get a byte
  1593.     jc    atoix            ; c = failed
  1594.     call    cnvdig            ; convert ascii to binary digit
  1595.     jc    atoi4            ; c = cannot convert, SI-1 is break
  1596.     xor    ah,ah            ; clear high order value
  1597.     cmp    atoibyte,0        ; read as many bytes as possible?
  1598.     je    atoi3b            ; e = yes
  1599.     push    ax            ; test for fitting into byte result
  1600.     mov    ax,temp            ; current low order value
  1601.     mul    nbase            ; times number base
  1602.     add    dx,ax            ; to dx, plus any overflow
  1603.     pop    ax
  1604.     add    dx,ax            ; next result would be in dx
  1605.     or    dh,dh            ; overflow beyond one byte
  1606.     jnz    atoi4            ; nz = cannot accept this byte
  1607.     cmp    cx,1            ; reading last byte?
  1608.     ja    atoi3b            ; a = no
  1609.     
  1610. atoi3b:    inc    bh            ; say we did a successful conversion
  1611.     push    ax            ; save this byte's value
  1612.     mov    ax,temp1
  1613.     mul    nbase            ; high order
  1614.     mov    temp1,ax        ; keep low order part of product
  1615.     mov    ax,temp
  1616.     mul    nbase            ; low order
  1617.     add    temp1,dx        ; high order carry
  1618.     mov    temp,ax            ; low order
  1619.     pop    ax            ; recover binary digit
  1620.     add    temp,ax
  1621.     adc    temp1,0
  1622.     loop    atoi3            ; get more
  1623.     jmp    short atoi4a        ; out of data, don't backup
  1624.                     ; here on break char in al
  1625.  
  1626. atoi4:    dec    si            ; backup to reread terminator
  1627.     inc    atoi_cnt
  1628.     mov    atoi_err,2        ; terminated on break char
  1629. atoi4a:    or    bl,bl            ; closing brace needed?
  1630.     jz    atoi6            ; z = no, success so far
  1631. atoi5:    call    atoi_read        ; get a byte for brace
  1632.     jnc    atoi5a
  1633.     cmp    atoi_cnt,0        ; out of counts?
  1634.     je    atoix            ; e = yes
  1635. atoi5a:    cmp    al,bl            ; the closing brace?
  1636.     jne    atoi5b            ; ne = no
  1637.     mov    atoi_err,1        ; success, terminator seen (brace)
  1638.     jmp    atoi6
  1639. atoi5b:    cmp    al,' '            ; space padding?
  1640.     je    atoi5            ; e = yes, skip it
  1641. atoi5c:    mov    atoi_err,8        ; syntax error (failed to get brace)
  1642.     jmp    atoix
  1643.  
  1644. atoi6:    or    bh,bh            ; did we do any conversion?
  1645.     jz    atoix            ; z = no
  1646.     pop    ax            ; throw away old saved ax
  1647.     pop    bx            ; restore bx
  1648.     pop    ax            ; throw away starting si, keep current
  1649.     pop    cx            ; restore old cx
  1650.     mov    dx,temp1
  1651.     mov    ax,temp
  1652.     pop    temp1
  1653.     pop    temp
  1654.     mov    atoibyte,0
  1655.     mov    atoi_cnt,0
  1656.     clc                ; clear carry for success
  1657.     ret
  1658. atoix:    pop    ax            ; restore first read al
  1659.     pop    bx
  1660.     pop    si            ; restore start value
  1661.     pop    cx            ; restore old cx
  1662.     pop    temp1
  1663.     pop    temp
  1664.     xor    dx,dx
  1665.     mov    atoibyte,0
  1666.     mov    atoi_cnt,0
  1667.     stc                ; set carry for failure
  1668.     ret
  1669. atoi    endp
  1670.  
  1671. ; Examine char in AL for being a number base indicator, O, X, D, in
  1672. ; either case.
  1673. ; If matched return carry clear, number base nbase set, and cx holding
  1674. ; the qty of bytes in a single character result value.
  1675. ; If not matched return carry set.
  1676. ; AL is preserved.
  1677. isnumbase proc    near
  1678.     push    ax            ; try for number bases
  1679.     cmp    al,'a'            ; lower case?
  1680.     jb    isnum1            ; b = no
  1681.     cmp    al,'z'            ; in range of lower case?
  1682.     ja    isnum1            ; a = no
  1683.     and    al,5fh            ; map to upper case
  1684. isnum1:    cmp    al,'O'            ; octal?
  1685.     jne    isnum2            ; ne = no
  1686.     mov    nbase,8            ; set number base
  1687.     cmp    atoibyte,0        ; all bytes?
  1688.     je    isnum4            ; e = yes
  1689.     mov    cx,3            ; three octal chars per final char
  1690.     jmp    short isnum4
  1691. isnum2:    cmp    al,'X'            ; hex?
  1692.     jne    isnum3            ; ne = no
  1693.     mov    nbase,16
  1694.     cmp    atoibyte,0        ; all bytes?
  1695.     je    isnum4            ; e = yes
  1696.     mov    cx,2            ; two hex chars per final char
  1697.     jmp    short isnum4
  1698. isnum3:    cmp    al,'D'            ; decimal?
  1699.     jne    isnum5            ; ne = no, syntax error
  1700.     mov    nbase,10
  1701.     cmp    atoibyte,0        ; all bytes?
  1702.     je    isnum4            ; e = yes
  1703.     mov    cx,3
  1704. isnum4:    pop    ax            ; successful result
  1705.     clc
  1706.     ret
  1707. isnum5:    pop    ax
  1708.     stc                ; carry set for failure
  1709.     ret
  1710. isnumbase endp
  1711.  
  1712. ; Read a byte from ds:si.
  1713. ; If success decrement byte atoi_cnt, inc si, return byte in AL, carry clear.
  1714. ; If failure return carry set, no change to atoi_cnt, AL unchanged.
  1715. atoi_read proc    near
  1716.     cmp    atoi_cnt,0        ; any bytes left?
  1717.     jg    atoi_read1        ; g = yes
  1718.     mov    atoi_err,4        ; c = insufficient bytes to resolve
  1719.     stc                ; return failure
  1720.     ret
  1721. atoi_read1:
  1722.     cld
  1723.     lodsb                ; get first char
  1724.     dec    atoi_cnt        ; one less byte availble
  1725.     clc
  1726.     ret
  1727. atoi_read endp
  1728.  
  1729.                     ; worker for atoi
  1730. cnvdig    proc    near            ; convert ascii code in al to binary
  1731.     push    ax            ; return carry set if cannot
  1732.     cmp    al,'a'            ; lower case hexadecimal candidate?
  1733.     jb    cnvdig1            ; b = no
  1734.     sub    al,20h            ; lower case hex to upper
  1735. cnvdig1:cmp    al,'A'            ; uppercase hex
  1736.     jb    cnvdig2
  1737.     sub    al,'A'-10-'0'        ; 'A' becomes '10'
  1738. cnvdig2:sub    al,'0'            ; remove ASCII bias
  1739.     jc    cnvdigx            ; c = out of range
  1740.     cmp    al,byte ptr nbase    ; out of range?
  1741.     jae    cnvdigx            ; ae = yes, out of range
  1742.     add    sp,2            ; pop saved ax
  1743.     clc                ; success, binary value is in al
  1744.     ret
  1745. cnvdigx:pop    ax            ; return ax unchanged
  1746.     stc                ; c set for failure
  1747.     ret
  1748. cnvdig    endp    
  1749.  
  1750. decout    proc    far        ; display decimal number in ax
  1751.     push    ax
  1752.     push    cx
  1753.     push    dx
  1754.     mov    cx,10        ; set the numeric base
  1755.     call    mvalout        ; convert and output value
  1756.     pop    dx
  1757.     pop    cx
  1758.     pop    ax
  1759.     ret
  1760. decout    endp
  1761.  
  1762. mvalout    proc    near        ; output number in ax using base in cx
  1763.                 ; corrupts ax and dx
  1764.     xor    dx,dx        ; clear high word of numerator
  1765.     div    cx        ; (ax / cx), remainder = dx, quotient = ax
  1766.     push    dx        ; save remainder for outputting later
  1767.     or    ax,ax        ; any quotient left?
  1768.     jz    mvalout1    ; z = no
  1769.     call    mvalout        ; yes, recurse
  1770. mvalout1:pop    dx        ; get remainder
  1771.     add    dl,'0'        ; make digit printable
  1772.     cmp    dl,'9'        ; above 9?
  1773.     jbe    mvalout2    ; be = no
  1774.     add    dl,'A'-1-'9'    ; use 'A'--'F' for values above 9
  1775. mvalout2:mov    ah,conout
  1776.     int    dos
  1777.     ret
  1778. mvalout    endp
  1779.  
  1780.  
  1781. valout    proc    far        ; output number in ax using base in cx
  1782.                 ; corrupts ax and dx
  1783.     xor    dx,dx        ; clear high word of numerator
  1784.     div    cx        ; (ax / cx), remainder = dx, quotient = ax
  1785.     push    dx        ; save remainder for outputting later
  1786.     or    ax,ax        ; any quotient left?
  1787.     jz    valout1        ; z = no
  1788.     call    valout        ; yes, recurse
  1789. valout1:pop    dx        ; get remainder
  1790.     add    dl,'0'        ; make digit printable
  1791.     cmp    dl,'9'        ; above 9?
  1792.     jbe    valout2        ; be = no
  1793.     add    dl,'A'-1-'9'    ; use 'A'--'F' for values above 9
  1794. valout2:mov    ah,conout
  1795.     int    dos
  1796.     ret
  1797. valout    endp
  1798.  
  1799. ; Write binary number in AX as decimal asciiz to buffer pointer DS:DI.
  1800. dec2di    proc    far        ; output number in ax using base in cx
  1801.     push    ax
  1802.     push    cx
  1803.     push    dx
  1804.     mov    cx,10
  1805.     call    dec2di1        ; recursive worker
  1806.     pop    dx
  1807.     pop    cx
  1808.     pop    ax
  1809.     ret
  1810.  
  1811. dec2di1    proc    near        ; worker of dec2di
  1812.     xor    dx,dx        ; clear high word of numerator
  1813.     div    cx        ; (ax / cx), remainder = dx, quotient = ax
  1814.     push    dx        ; save remainder for outputting later
  1815.     or    ax,ax        ; any quotient left?
  1816.     jz    dec2di2        ; z = no
  1817.     call    dec2di1        ; yes, recurse
  1818. dec2di2:pop    dx        ; get remainder
  1819.     add    dl,'0'        ; make digit printable
  1820.     mov    [di],dl        ; store char in buffer
  1821.     inc    di
  1822.     mov    byte ptr[di],0    ; add terminator
  1823.     ret
  1824. dec2di1    endp
  1825. dec2di    endp
  1826.  
  1827. ; Perform math. Reads argptr string, returns binary value in DX:AX.
  1828. ; Expects pointer to string to be in domath_ptr and its length in domath_cnt.
  1829. ; Note that value and operator lists are stored on the stack in positive
  1830. ; order (increasing array values are at increasing addresses, not in push
  1831. ; order).
  1832. ; Returns carry set if error.
  1833. domath    proc    far
  1834.     push    bx
  1835.     push    cx
  1836.     push    si
  1837.     push    di
  1838.     mov    si,domath_ptr
  1839.     mov    di,domath_cnt
  1840.     mov    parendepth,0        ; parenthesis nesting depth
  1841.     call    domath_main
  1842.     mov    domath_msg,0        ; re-enable domath error messages
  1843.     jnc    domathx1
  1844.     mov    domath_ptr,si
  1845.     mov    domath_cnt,di
  1846. domathx1:    
  1847.     pop    di
  1848.     pop    si
  1849.     pop    cx
  1850.     pop    bx
  1851.     ret
  1852. domath    endp
  1853.  
  1854. domath_main proc near
  1855.     push    si
  1856.     push    bp
  1857.     sub    sp,size fevalst        ; counters and lists
  1858.     mov    bp,sp            ; remember base of lists
  1859.     mov    [bp].numcnt,0        ; no numbers in list
  1860.     mov    [bp].opcnt,0        ; no operators in list
  1861.     mov    [bp].numlist,0        ; returned value
  1862.     mov    [bp].numlist[2],0    ; high order returned value
  1863.     inc    parendepth        ; recursion limit counter
  1864.     cmp    parendepth,maxdepth    ; called too many times?
  1865.     jbe    domath0            ; be = no
  1866.     mov    matherr,offset opmsg4
  1867.     jmp    domath_error        ; a = too many parentheses
  1868.  
  1869. domath0:call    gettoken        ; read a token from string
  1870.     jc    domath_exit        ; c = nothing present
  1871.     cmp    bl,'O'            ; operator?
  1872.     je    domath1            ; e = yes
  1873.     cmp    [bp].numcnt,2        ; have two numbers (num num)?
  1874.     jb    domath0            ; b = no, get an operator
  1875.     mov    matherr,offset opmsg1    ; missing operator
  1876.     jmp    domath_error        ; exit with grammar error
  1877.  
  1878.     ; have initial operator in AX, decide in/pre/post-fix style
  1879. domath1:cmp    al,'!'            ; postfix? (number is on stack)
  1880.     jne    domath2            ; ne = no
  1881.     call    domath_calc1        ; do math on one arg, result on stack
  1882.     jc    domath_error        ; failure, exit
  1883.     jmp    short domath0        ; done here, get next tokens
  1884.  
  1885.                     ; prefix or infix?
  1886. domath2:call    gettoken        ; get expected following number
  1887.     jc    domath_error        ; c = eof, unexpected, error
  1888.     cmp    bl,'N'            ; got the number?
  1889.     jne    domath4            ; ne = no, operator
  1890. domath3:call    domath_la        ; call lookahead proc
  1891.     ; c clear, bl = N for use current number on stack
  1892.     ; c clear, bl = O for have higher prec operator on stack & ax, delay
  1893.     ; c clear, bl = F for read end of file, no next operator
  1894.     ; c set,   bl = F for math failure, best to exit
  1895.     jc    domath_error        ; failure on math
  1896.     cmp    bl,'F'            ; end of file?
  1897.     je    domath_end        ; e = eof, do remaining math
  1898.     cmp    bl,'O'            ; found higher prec op (delay)?
  1899.     je    domath1            ; e = yes, do newest operator
  1900.     call    domath_calc2        ; bl = 'N', number ready, do math
  1901.     jc    domath_error        ; c = failure
  1902.     cmp    [bp].opcnt,0        ; any ops backlogged?
  1903.     jne    short domath3        ; be = try again to reduce back math
  1904.     jmp    domath0            ; start over
  1905.  
  1906.             ; Have op op. Is second op a prefix operator?
  1907. domath4:cmp    al,'~'            ; prefix?
  1908.     je    domath5            ; e = yes
  1909.     cmp    al,'-'            ; prefix, overload?
  1910.     je    domath5            ; e = yes
  1911.     cmp    al,'+'            ; prefix, overload?
  1912.     jne    domath_error        ; ne = no, inconsistent syntax
  1913.         ; could be  op number postfix  so look at next token to see
  1914.         ; and if so reduce <number postfix> before applying prefix.
  1915. domath5:call    gettoken        ; get expected number following prefix
  1916.     jc    domath_end        ; c = eof, do remaining math
  1917.     cmp    bl,'O'            ; operator?
  1918.     je    domath_error        ; e = yes, that makes op op op
  1919.     call    domath_la        ; do lookahead for postfix
  1920.     jc    domath_error        ; c = failure on math
  1921.     call    domath_calc1        ; do prefix calculation now
  1922.     jc    domath_error        ; c = failure
  1923.     call    popop            ; get first operator to ax
  1924.     call    pushop            ; put it back as if just read
  1925.     mov    bl,'O'            ; mark as operator
  1926.     jmp    short domath3        ; reanalyze from new operator
  1927.  
  1928.                     ; end of data, finish up math & exit
  1929. domath_end:                ; do calcs remaining on stack
  1930.     cmp    [bp].opcnt,0        ; operators remaining to be done?
  1931.     je    domath_exit        ; e = no
  1932.     call    domath_calc2        ; finish math
  1933.     jc    domath_error        ; c = failure
  1934.     jmp    short domath_end    ; keep trying til no more operators
  1935.  
  1936. domath_error:                ; math errors seen, exit in error
  1937.     mov    cx,1            ; set carry for error
  1938.     jmp    short domath_exit1
  1939.  
  1940. domath_exit:                ; only way out, restore stack
  1941.     xor    cx,cx            ; assume success, cx = error counter
  1942. domath_exit1:
  1943.     dec    parendepth        ; nesting depth
  1944.     cmp    [bp].numcnt,1        ; only one value remaning?
  1945.     je    domath_exit2        ; e = yes, that's good
  1946.     jb    domath_exit2a        ; b = no numbers, empty arg
  1947.     jcxz    domath_exit2        ; z = no error
  1948.  
  1949.     cmp    domath_msg,0        ; msgs permitted?
  1950.     jnz    domath_exit2a        ; nz = no
  1951.     mov    matherr,offset opmsg1    ; missing operator
  1952. domath_exit2a:
  1953.     inc    cx            ; say error
  1954. domath_exit2:
  1955.     cmp    [bp].opcnt,0        ; used all operators?
  1956.     je    domath_exit3        ; e = yes
  1957.     mov    matherr,offset opmsg    ; too many operators
  1958.     inc    cx            ; say error
  1959.  
  1960. domath_exit3:                ; all returns
  1961.     mov    ax,[bp].numlist        ; returned value
  1962.     mov    dx,[bp].numlist[2]    ; high order part
  1963.     mov    sp,bp            ; base of lists
  1964.     add    sp,size fevalst        ; counters and lists
  1965.     or    cx,cx            ; any errors?
  1966.     jz    domath_exit4        ; z = no (clears carry bit)
  1967.     cmp    domath_msg,0        ; ok to complain?
  1968.     jne    domath_exit3a        ; ne = no, keep quiet
  1969.     mov    ah,prstr
  1970.     mov    dx,matherr        ; math error pointer
  1971.     or    dx,dx            ; if any
  1972.     jz    domath_exit3a        ; z = none
  1973.     push    dx
  1974.     mov    dx,offset crlf
  1975.     int    dos
  1976.     pop    dx
  1977.     int    dos            ; display error message
  1978. domath_exit3a:
  1979.     xor    ax,ax            ; return zero on errors
  1980.     xor    dx,dx
  1981.     stc                ; set carry for fail
  1982. domath_exit4:
  1983.     mov    matherr,0
  1984.     pop    bp
  1985.     pop    si
  1986.     ret                ; all done. Result in DX:AX
  1987. domath_main endp
  1988.  
  1989. ; Worker for domath. Reads argptr, inc's it, dec's arglen. Recognizes
  1990. ; numbers (with or without leading \), recognizes math operators and ().
  1991. ; Returns numbers as binary in DX:AX and BL = 'N',
  1992. ; returns operator and precedence in AL and AH with BL = 'O'. 
  1993. ; Returns Carry set and BL = 'F' if neither kind of token.
  1994. ; Tolerates leading whitespace.
  1995. ; Uses domath_ptr as source pointer, domath_cnt as source count.
  1996. ; Array domath_tmp is owned by this routine as private space.
  1997. gettoken proc    near
  1998.     xor    ax,ax            ; no operator, lowest precedence
  1999.     xor    dx,dx
  2000.  
  2001. gettok0:cmp    domath_cnt,0        ; anything to read?
  2002.     jg    gettok1            ; g = yes
  2003.     mov    bl,'F'            ; F for end of file, failure
  2004.     stc
  2005.     ret
  2006.  
  2007. gettok1:mov    si,domath_ptr
  2008.     mov    al,byte ptr [si]
  2009.     cmp    al,' '            ; leading whitepace?
  2010.     jne    gettok1a        ; ne = no
  2011.     inc    domath_ptr
  2012.     dec    domath_cnt
  2013.     jmp    short gettok0
  2014.  
  2015. gettok1a:jb    gettok1b        ; b = non-printable
  2016.     cmp    al,127
  2017.     jb    gettok2            ; b = printable
  2018. gettok1b:mov    bl,'F'            ; declare F for end of file, failure
  2019.     mov    domath_cnt,0        ; truncate string
  2020.     clc
  2021.     ret
  2022.  
  2023. gettok2:mov    cx,domath_cnt
  2024.     mov    atoi_cnt,cx
  2025.     call    atoi            ; convert DS:SI to number in DX:AX
  2026.     jc    gettok5            ; c = failed to convert number
  2027.     mov    cx,si
  2028.     sub    cx,domath_ptr        ; amount read
  2029.     sub    domath_cnt,cx        ; deduct that read
  2030.     mov    domath_ptr,si        ; break char
  2031.     call    pushval            ; push onto number stack
  2032.     mov    bl,'N'            ; say returning number
  2033.     ret                ; may have carry bit set
  2034.  
  2035. gettok5:mov    si,domath_ptr
  2036.     lodsb                ; reread non-numeric
  2037.     inc    domath_ptr
  2038.     dec    domath_cnt
  2039.     push    di            ; look for operators
  2040.     push    es
  2041.     mov    di,seg operators    ; list of math operators
  2042.     mov    es,di
  2043.     mov    di,offset operators
  2044.     mov    cx,operator_len        ; length of list
  2045.     cld
  2046.     repne    scasb            ; look for match
  2047.     pop    es
  2048.     je    gettok6            ; e = found a match
  2049.     pop    di
  2050.     cmp    domath_msg,0        ; allowed to display messages?
  2051.     jne    gettok5a        ; ne = no
  2052.     push    ax
  2053.     mov    ah,prstr
  2054.     mov    dx,offset crlf
  2055.     int    dos
  2056.     mov    dx,offset opmsg2    ; unknown symbol
  2057.     int    dos
  2058.     pop    ax
  2059.     mov    dl,al            ; unknown op
  2060.     mov    ah,conout
  2061.     int    dos
  2062.     mov    ah,prstr
  2063.     mov    dx,offset crlf
  2064.     int    dos
  2065. gettok5a:
  2066.     dec    domath_ptr        ; set to read on this symbol
  2067.     inc    domath_cnt
  2068.     mov    bl,'F'            ; say returning parse failure
  2069.     stc                ; fail
  2070.     ret
  2071. gettok6:sub    di,offset operators + 1    ; index into list
  2072.     mov    ah,precedence[di]    ; precedence to return
  2073.     pop    di
  2074.     mov    bl,'O'            ; say returning operator
  2075.     cmp    al,'('            ; start recursion?
  2076.     je    gettok7
  2077.     cmp    al,')'            ; closure?
  2078.     je    gettok9            ; e = yes, it's an EOF here
  2079.     call    pushop            ; push operator on op stack
  2080.     clc
  2081.     ret
  2082.  
  2083. gettok7:call    domath_main        ; '(', invoke new scan
  2084.     jnc    gettok8            ; nc = succeeded
  2085.     ret                ; c = return failure
  2086. gettok8:call    pushval            ; push returned DX:AX
  2087.     mov    bl,'N'            ; report number
  2088.     ret                ; may have carry bit set
  2089.  
  2090. gettok9:mov    bl,'O'
  2091.     stc                ; ')' returns EOF
  2092.     ret
  2093. gettoken endp
  2094.  
  2095. ; Lookahead processor. Have ...<op><number> on stack
  2096. ; Return bl = N for return number present on stack, carry clear
  2097. ; Return bl = O for return higher prec operator on stack, carry clear
  2098. ; Return bl = F and carry clear for end of file
  2099. ; Return bl = F and carry set for math failure (errors)
  2100.  
  2101. domath_la proc near
  2102.     call    gettoken        ; expect operator or end of file
  2103.     jnc    domath_la1        ; nc = success
  2104.     mov    bl,'F'            ; say eof
  2105.     clc                ; carry clear for eof
  2106.     ret
  2107.  
  2108. domath_la1:
  2109.     cmp    bl,'O'            ; lookahead operator?
  2110.     je    domath_la2        ; e = yes
  2111.     mov    bl,'F'            ; fail, case of number number
  2112.     stc                ; syntax error, signal quit
  2113.     ret
  2114.  
  2115. domath_la2:
  2116.     mov    si,[bp].opcnt        ; get size of op list
  2117.     dec    si            ; zero based index
  2118.     or    si,si            ; sanity check, should be > 0
  2119.     jnz    domath_la2a        ; nz = have current op available
  2120.     mov    bl,'F'            ; signal total failure
  2121.     stc
  2122.     ret
  2123. domath_la2a:
  2124.     shl    si,1            ; index words
  2125.     mov    ax,[bp].oplist[si]    ; lookahead operator
  2126.     mov    cx,[bp].oplist[si-2]    ; currently active operator
  2127.     cmp    ah,ch            ; lookahead versus current op
  2128.     ja    domath_la3        ; a = lookahead is higher, delay
  2129.     call    popop            ; remove lookahead operator from stack
  2130.     dec    domath_ptr        ; set to reread operator
  2131.     inc    domath_cnt
  2132.     mov    bl,'N'            ; signal number ready on stack
  2133.     clc
  2134.     ret
  2135.  
  2136. domath_la3:                ; delay
  2137.     cmp    al,'!'            ; postfix on number?
  2138.     jne    domath_la5        ; ne = no, another operator, delay
  2139.     call    domath_calc1        ; combine number!, report number
  2140.     jnc    domath_la4        ; nc = success, use number on stack
  2141.     mov    bl,'F'            ; report failed
  2142.     ret                ; carry set
  2143.  
  2144. domath_la4:mov    bl,'N'            ; report number is on stack
  2145.     clc                ; say success
  2146.     ret
  2147.  
  2148. domath_la5:mov    bl,'O'        ; lookahead (delayed op) is on stack and ax
  2149.     clc            ; bl = 'O', signal delay and lookahead op
  2150.     ret            ; is on the stack
  2151. domath_la endp
  2152.  
  2153. ; Calculate results of top operator and one top value.
  2154. ; Return value on top of the value stack.
  2155. ; Returns carry set if failure
  2156. ; Pops one operator, and zero (failure) or one value from stack before
  2157. ; starting.
  2158. domath_calc1    proc    near
  2159.     mov    si,[bp].opcnt        ; count of operators
  2160.     cmp    si,0            ; any?
  2161.     jg    dom_c1_1a        ; g = yes
  2162.     mov    matherr,offset opmsg3
  2163.     stc                ; fail
  2164.     ret
  2165. dom_c1_1a:
  2166.     cmp    [bp].numcnt,0        ; one or more values?
  2167.     jne    dom_c1_1b        ; ne = yes
  2168.     mov    matherr,offset opmsg    ; too few values
  2169.     stc
  2170.     ret
  2171. dom_c1_1b:
  2172.     call    popop            ; get top operator from list to AX
  2173.     mov    mathkind,al        ; operation to do
  2174.     call    popval            ; get first value from list to DX:AX
  2175.  
  2176.     cmp    mathkind,'!'        ; factorial?
  2177.     jne    dom_c1c            ; ne = no
  2178.     mov    bx,ax            ; save argument
  2179.     mov    cx,ax
  2180.     mov    ax,-1            ; default for too large an arg
  2181.     mov    dx,ax
  2182.     cmp    cx,10            ; largest within 32 bits?
  2183.     ja    dom_c1b            ; a = too large, report -1
  2184.     mov    ax,1            ; default for 0! and 1!
  2185.     xor    dx,dx
  2186.     sub    cx,ax
  2187.     jle    dom_c1b            ; le = special cases of 0 and 1
  2188.     mov    ax,bx            ; recover argument
  2189. dom_c1a:mul    cx
  2190.     loop    dom_c1a
  2191. dom_c1b:jmp    dom_c1_1x
  2192.  
  2193. dom_c1c:cmp    mathkind,'~'        ; logical not?
  2194.     jne    dom_c1d            ; ne = no
  2195.     not    ax            ; 1's complement
  2196.     not    dx
  2197.     jmp    dom_c1_1x
  2198.  
  2199. dom_c1d:cmp    mathkind,'-'        ; negate?
  2200.     jne    dom_c1e            ; ne = no
  2201.     neg    dx
  2202.     neg    ax            ; change sign
  2203.     sbb    dx,0
  2204.     jmp    dom_c1_1x
  2205.  
  2206. dom_c1e:cmp    mathkind,'+'        ; unary '+'?
  2207.     je    dom_c1_1x        ; e = yes
  2208.  
  2209. dom_c1f:stc                ; unknown operator
  2210.     mov    matherr,offset opmsg2
  2211.     ret
  2212. dom_c1_1x:
  2213.     call    pushval
  2214.     ret                ; may have carry bit set
  2215. domath_calc1 endp
  2216.  
  2217. ; Calculate results of top operator and two top values.
  2218. ; Return value on top of the value stack.
  2219. ; Returns carry set if failure
  2220. ; Pops one operator, and one (failure) or two values from stack before
  2221. ; starting.
  2222. domath_calc2 proc near
  2223.     cmp    [bp].numcnt,2        ; two or more args?
  2224.     jb    domath_calc1        ; b = no, do 1 arg math
  2225.  
  2226.     call    popop            ; get top operator from list to AX
  2227.     jnc    dom_c2_2a        ; nc = success
  2228.     mov    matherr,offset opmsg3
  2229.     ret                ; fail
  2230. dom_c2_2a:
  2231.     mov    mathkind,al        ; operation to do
  2232.     call    popval            ; get first value from list to DX:AX
  2233.     mov    bx,ax            ; right side, low order
  2234.     mov    cx,dx            ; right side, high order
  2235.     call    popval            ; first (left side) to dx:ax
  2236.     cmp    mathkind,'^'        ; raise arg1 to power of arg2?
  2237.     jne    dom_c2_6        ; ne = no
  2238.     mov    cx,bx            ; use low order of exponent
  2239.     dec    cx            ;
  2240.     cmp    cx,31            ; largest exponent we allow
  2241.     jbe    dom_c2_1        ; be = ok
  2242.     mov    ax,-1            ; report -1 as overflow result
  2243.     cwd
  2244.     jc    dom_c2_2y        ; c = overflow error
  2245. dom_c2_1:or    cl,cl            ; zero power?
  2246.     jne    dom_c2_2        ; ne = no
  2247.     mov    ax,1            ; report 1
  2248.     xor    dx,dx
  2249.     jmp    dom_c2_2x
  2250. dom_c2_2:push    si
  2251.     push    di
  2252.     mov    si,ax            ; original number
  2253.     mov    di,dx
  2254. dom_c2_3:push    cx            ; save loop counter
  2255.     mov    cx,di
  2256.     mov    bx,si            ; original number
  2257.     call    lmul            ; use long multiply
  2258.     pop    cx
  2259.     jc    dom_c2_4        ; c = overflow
  2260.     loop    dom_c2_3
  2261.     pop    di
  2262.     pop    si
  2263.     jmp    dom_c2_2x
  2264. dom_c2_4:pop    di
  2265.     pop    si
  2266.     stc
  2267.     jmp    dom_c2_2y        ; failure from overflow
  2268.  
  2269. dom_c2_6:cmp    mathkind,'*'        ; times?
  2270.     jne    dom_c2_7        ; ne = no
  2271.     call    lmul            ; do 32 bit signed multiply
  2272.     jc    dom_c2_2y        ; c = overflow error
  2273.     jmp    dom_c2_2x
  2274.  
  2275. dom_c2_7:cmp    mathkind,'/'        ; divide?
  2276.     jne    dom_c2_8        ; ne = no
  2277.     call    ldiv
  2278.     jc    dom_c2_2y        ; c = overflow error
  2279.     jmp    dom_c2_2x
  2280.  
  2281. dom_c2_8:cmp    mathkind,'%'        ; modulo?
  2282.     jne    dom_c2_9        ; ne = no
  2283.     call    ldiv            ; divide
  2284.     jc    dom_c2_2y        ; c = overflow error
  2285.     xchg    cx,dx            ; get remainder to dx:ax
  2286.     xchg    bx,ax
  2287.     jmp    dom_c2_2x
  2288.  
  2289. dom_c2_9:cmp    mathkind,'&'        ; logical AND?
  2290.     jne    dom_c2_11        ; ne = no
  2291.     and    ax,bx
  2292.     and    dx,cx
  2293.     jmp    dom_c2_2x
  2294.  
  2295. dom_c2_11:cmp    mathkind,'+'        ; addition?
  2296.     jne    dom_c2_12        ; ne = no
  2297. dom_c2_11a:
  2298.     push    si
  2299.     mov    si,dx            ; get sign bit
  2300.     xor    si,cx            ; different? if so then 1
  2301.     add    ax,bx
  2302.     adc    dx,cx
  2303.     test    si,8000h        ; check for case of same start signs
  2304.     jnz    dom_c2_11b        ; nz = different signs, no overflow
  2305.     mov    si,dx
  2306.     xor    si,cx            ; different
  2307.     test    si,8000h        ; different signs now?
  2308.     pop    si
  2309.     jnz    dom_c2_2y        ; nz = yes, overflow
  2310.     jmp    dom_c2_2x
  2311. dom_c2_11b:pop    si
  2312.     jmp    dom_c2_2x
  2313.  
  2314. dom_c2_12:cmp    mathkind,'-'        ; subtraction?
  2315.     jne    dom_c2_13        ; ne = no
  2316.     neg    cx
  2317.     neg    bx            ; change sign of right side number
  2318.     sbb    cx,0
  2319.     jmp    short dom_c2_11a    ; now do addition with bounds check
  2320.  
  2321. dom_c2_13:cmp    mathkind,'|'        ; logical OR?
  2322.     jne    dom_c2_14        ; ne = no
  2323.     or    ax,bx
  2324.     or    dx,cx
  2325.     jmp    dom_c2_2x
  2326.  
  2327. dom_c2_14:cmp    mathkind,'#'        ; exclusive OR?
  2328.     jne    dom_c2_15        ; ne = no
  2329.     xor    ax,bx
  2330.     xor    dx,cx
  2331.     jmp    dom_c2_2x
  2332.  
  2333. dom_c2_15:cmp    mathkind,'@'        ; GCD?
  2334.     jne    dom_c2_16        ; ne = no
  2335.     call    lgcd            ; call the gcd routine
  2336.     jc    dom_c2_2y        ; c = overflow error
  2337.     jmp    dom_c2_2x
  2338. dom_c2_16:stc
  2339.     ret                ; unknown operator
  2340.  
  2341. dom_c2_2x:
  2342.     call    pushval            ; store result
  2343.     ret
  2344. dom_c2_2y:
  2345.     call    pushval            ; store result (typically -1)
  2346.     mov    matherr,offset opmsg3
  2347.     stc                ; say failure of math
  2348.     ret
  2349. domath_calc2 endp
  2350.  
  2351. ; Push operator (AL) and precedence (AH) onto the operator stack.
  2352. ; Increments [bp].opcnt.
  2353. ; Return carry set if no room.
  2354. pushop    proc    near
  2355.     mov    si,[bp].opcnt        ; count of operators
  2356.     cmp    si,listlen        ; list full?
  2357.     jae    pushop1            ; ae = yes, fail
  2358.     shl    si,1            ; words
  2359.     mov    [bp].oplist[si],ax    ; save operator (AL) and preced (AH)
  2360.     inc    [bp].opcnt        ; one more operator in the list
  2361.     clc                ; success
  2362.     ret
  2363. pushop1:mov    matherr,offset opmsg1
  2364.     stc                ; fail
  2365.     ret
  2366. pushop    endp
  2367.  
  2368. ; Pop current opcode from op stack to AX. Decrements [bp].opcnt.
  2369. ; Returns carry set if no operators are available
  2370. popop    proc    near
  2371.     mov    si,[bp].opcnt        ; count of operators in list
  2372.     or    si,si            ; any?
  2373.     jz    popop1            ; z = no, exit
  2374.     dec    si            ; index from zero
  2375.     shl    si,1            ; words
  2376.     mov    ax,[bp].oplist[si]    ; get lookahead (last) operator
  2377.     dec    [bp].opcnt
  2378.     clc                ; success
  2379.     ret
  2380. popop1:    mov    matherr,offset opmsg1
  2381.     stc                ; failed to op (empty list)
  2382.     ret
  2383. popop    endp
  2384.  
  2385. ; Push value in DX:AX onto value stack. Increments [bp].numcnt.
  2386. ; Returns carry set if not enough space.
  2387. pushval    proc    near
  2388.     mov    si,[bp].numcnt
  2389.     cmp    si,listlen        ; at limit of list?
  2390.     ja    pushval1        ; a = exceeded list length, fail
  2391.     shl    si,1            ; address dwords
  2392.     shl    si,1
  2393.     mov    [bp].numlist[si],ax    ; push dx:ax onto value stack
  2394.     mov    [bp].numlist[si+2],dx    ; high order part
  2395.     inc    [bp].numcnt        ; occupancy is one greater
  2396.     clc                ; succeed
  2397.     ret
  2398. pushval1:stc                ; fail
  2399.     ret
  2400. pushval    endp
  2401.  
  2402. ; Pop top value from value stack into DX:AX. Decrements [bp].numcnt.
  2403. ; Returns carry set if no value were available.
  2404. popval    proc    near
  2405.     mov    si,[bp].numcnt        ; count of values in list
  2406.     or    si,si            ; count
  2407.     jz    popval1            ; z = none
  2408.     dec    si            ; index from 0
  2409.     shl    si,1            ; address dwords
  2410.     shl    si,1
  2411.     mov    ax,[bp].numlist[si]    ; pop top value to dx:ax
  2412.     mov    dx,[bp].numlist[si+2]    ; high order part
  2413.     dec    [bp].numcnt        ; occupancy is one less
  2414.     clc                ; success
  2415.     ret
  2416. popval1:stc                ; fail
  2417.     ret
  2418. popval    endp
  2419.                     ; end of domath procedures
  2420.  
  2421. ; Perform 32 bit division. Numerator is in DX:AX, denominator in CX:BX.
  2422. ; Returns quotient in DX:AX, remainder in CX:BX. Carry set and -1 on
  2423. ; divide by zero.
  2424. ldiv    proc    far
  2425.     push    temp
  2426.     push    temp1
  2427.     push    si
  2428.     push    di
  2429.     mov    tmp,0            ; holds final sign (0=positive)
  2430.     or    dx,dx            ; numerator is negative?
  2431.     jge    ldiv1            ; ge = no
  2432.     neg    dx
  2433.     neg    ax
  2434.     sbb    dx,0            ; change sign
  2435.     xor    tmp,1            ; remember to change sign later
  2436. ldiv1:    or    cx,cx            ; denominator is negative?
  2437.     jge    ldiv2            ; ge = no
  2438.     neg    cx
  2439.     neg    bx
  2440.     sbb    cx,0            ; change sign
  2441.     xor    tmp,1            ; remember to change sign later
  2442. ldiv2:    mov    di,cx            ; denominator, hold here
  2443.     mov    si,bx
  2444.     cmp    dx,cx            ; is numerator larger than denom?
  2445.     jne    ldiv10            ; ne = yes, and 32 bits too
  2446.     or    dx,dx            ; 32 bit number?
  2447.     jnz    ldiv10            ; nz = yes
  2448.                 ; only 16 bit numbers here
  2449.     or    bx,bx            ; denominator zero?
  2450.     jnz    ldiv3            ; nz = no
  2451.     jmp    ldivf            ; overflow, report failure
  2452.  
  2453. ldiv3:    div    bx            ; regular signed division
  2454.     mov    bx,dx            ; remainder
  2455.     xor    dx,dx            ; high quotient
  2456.     xor    cx,cx            ; high remainder
  2457.     jmp    ldivx            ; exit success
  2458.  
  2459.                 ; 32 bit numbers here
  2460. ldiv10:    mov    tmp1,0            ; shift counter
  2461.     mov    temp,0            ; shift accumulator, low part
  2462.     mov    temp1,0            ; shift accumulator, high part
  2463.     or    cx,cx            ; check for zero denominator
  2464.     jnz    ldiv11            ; nz = not zero
  2465.     or    bx,bx
  2466.     jz    ldivf            ; zero, exit failure
  2467.  
  2468. ldiv11:    cmp    dx,di            ; top vs bottom high order words
  2469.     jb    ldiv13            ; b = top smaller than bottom
  2470.     ja    ldiv12            ; a = top larger than bottom
  2471.                     ; high order words are the same
  2472.     cmp    ax,si            ; top vs bottom low order words
  2473.     jb    ldiv13            ; b = top eq or larger than bottom
  2474.     je    ldiv15            ; e = top equals bottom
  2475.                 ; top is larger than bottom
  2476. ldiv12:    or    di,di            ; can shift left further?
  2477.     js    ldiv14            ; s = no, accumulate and back down
  2478.     inc    tmp1            ; remember doing left shift
  2479.     shl    si,1            ; shift denominator left one bit
  2480.     rcl    di,1            ; include carry-out from low half
  2481.     jmp    short ldiv11        ; compare again til top < bot
  2482.  
  2483. ; either we start with top < bottom (tmp1 = 0), or we have left shifted
  2484. ; the bottom enough (tmp1 > 0) to create that condition.
  2485.  
  2486.                        ; top is smaller than or equal to bottom
  2487. ldiv13:    cmp    tmp1,0            ; any shifts remaining?
  2488.     je    ldiv16            ; e = no
  2489. ; If tmp1 is 0 then we are done, no further adjustments can be made.
  2490. ; Else back off tmp1 by one position
  2491.     dec    tmp1            ; shift right by 1 to get top >= bot
  2492.     shr    di,1
  2493.     rcr    si,1
  2494.  
  2495. ldiv14:    cmp    dx,di            ; is top less than bottom?
  2496.     jb    ldiv13            ; b = yes, shift again
  2497.     ja    ldiv15            ; a = no, greater than
  2498.     cmp    ax,si            ; low order part
  2499.     jb    ldiv13            ; b = top is less than bottom
  2500. ldiv15:    sub    ax,si            ; (top - bottom) to get remainder
  2501.     sbb    dx,di
  2502.     call    ldiv_acc        ; accumulate shifted success
  2503.     jmp    short ldiv14        ; try again til top < bot
  2504.  
  2505. ldiv16:    mov    bx,ax            ; remainder to cx:bx
  2506.     mov    cx,dx            ; quotient to dx:ax
  2507.     mov    ax,temp            ; extract accumlated shifts
  2508.     mov    dx,temp1        ; and exit success
  2509.  
  2510.                     ; successful exit, update signs
  2511. ldivx:    cmp    tmp,0            ; need to adjust signs?
  2512.     je    ldivx1            ; e = no
  2513.     neg    dx
  2514.     neg    ax            ; change sign of quotient
  2515.     sbb    dx,0
  2516.     neg    cx
  2517.     neg    bx            ; change sign of remainder
  2518.     sbb    cx,0
  2519. ldivx1:    pop    di
  2520.     pop    si
  2521.     pop    temp1
  2522.     pop    temp
  2523.     clc                ; success
  2524.     ret
  2525.  
  2526. ldivf:    mov    ax,-1            ; failure
  2527.     cwd                ; report -1
  2528.     mov    bx,ax
  2529.     mov    cx,ax
  2530.     pop    di            ; failure exit
  2531.     pop    si
  2532.     pop    temp1
  2533.     pop    temp
  2534.     stc                ; say failure
  2535.     ret
  2536.  
  2537. ldiv_acc proc    near            ; add current shift to accumulator
  2538.     push    cx
  2539.     push    ax
  2540.     push    dx
  2541.     mov    cl,tmp1            ; shift bit count
  2542.     xor    ch,ch
  2543.     mov    ax,1            ; value = 2 ** temp1
  2544.     xor    dx,dx
  2545.     jcxz    ldiv_acc2        ; z = nothing to do
  2546. ldiv_acc1:shl    ax,1
  2547.     rcl    dx,1
  2548.     loop    ldiv_acc1
  2549. ldiv_acc2:add    temp,ax            ; accumulate shifts
  2550.     adc    temp1,dx
  2551.     pop    dx
  2552.     pop    ax
  2553.     pop    cx
  2554.     ret
  2555. ldiv_acc endp
  2556. ldiv    endp
  2557.  
  2558. ; Multiplies 32 bit values in DX:AX by CX:BX and returns the result in
  2559. ; DX:AX. Overflows result in carry set and -1 as the answer. Signed
  2560. ; arithmetic is used here, beware.
  2561. lmul    proc    far
  2562.     push    si
  2563.     push    di
  2564.     push    bx
  2565.     push    cx
  2566.     push    temp
  2567.     mov    temp,0            ; zero means no sign change at end
  2568.     or    dx,dx            ; negative?
  2569.     jns    lmul1            ; ns = no
  2570.     neg    ax            ; make positive
  2571.     neg    dx
  2572.     sbb    dx,0
  2573.     xor    temp,1            ; sign change needed
  2574. lmul1:    or    cx,cx            ; ditto for cx:bx
  2575.     jns    lmul2
  2576.     neg    bx
  2577.     neg    cx
  2578.     sbb    cx,0
  2579.     xor    temp,1
  2580. lmul2:    or    cx,cx            ; check for high word in both numbers
  2581.     jz    lmul3            ; z = bottom does not have it
  2582.     or    dx,dx
  2583.     jnz    lmul4            ; nz = both have parts too large
  2584.  
  2585. lmul3:    push    dx
  2586.     push    ax
  2587.     mul    bx            ; low bottom time whole top
  2588.     mov    di,dx
  2589.     mov    si,ax            ; regular product to di:si
  2590.     pop    ax
  2591.     pop    dx            ; recover normal top
  2592.     push    dx
  2593.     push    ax
  2594.     mov    ax,dx
  2595.     mul    bx
  2596.     add    di,ax
  2597.     pop    ax
  2598.     pop    dx            ; recover normal top
  2599.     js    lmul4            ; s = overflow in high accumlator
  2600.     mul    cx            ; high bottom times regular top
  2601.     add    di,ax            ; high reg product plus new product
  2602.     jns    lmul5            ; ns = no overflow in high accumulator
  2603.  
  2604. lmul4:    mov    ax,-1            ; overflow, yield minus one as answer
  2605.     cwd                ; extend sign to dx
  2606.     mov    temp,0            ; no sign change
  2607.     stc                ; carry set for problem
  2608.     jmp    short lmul6
  2609. lmul5:    mov    dx,di            ; results to dx:ax
  2610.     mov    ax,si
  2611.     cmp    temp,0            ; sign change needed?
  2612.     je    lmul6            ; e = no
  2613.     neg    dx            ; flip output sign
  2614.     neg    ax
  2615.     sbb    dx,0
  2616.     clc                ; carry clear for no problem
  2617. lmul6:    pop    temp
  2618.     pop    cx
  2619.     pop    bx
  2620.     pop    di
  2621.     pop    si
  2622.     ret
  2623. lmul    endp
  2624.  
  2625. ; Greatest common divisor, 32 bit (removes signs). Inputs are DX:AX and
  2626. ; CX:BX. Results are in DX:AX. Carry bit set and -1 returned if error.
  2627. lgcd    proc    far
  2628.     push    bx
  2629.     push    cx
  2630.     or    dx,dx            ; negative?
  2631.     jns    lgcd1            ; ns = no
  2632.     neg    ax            ; make positive
  2633.     neg    dx
  2634.     sbb    dx,0
  2635. lgcd1:    or    cx,cx            ; negative?
  2636.     jns    lgcd2            ; ns = no
  2637.     neg    bx
  2638.     neg    cx            ; make positive
  2639.     sbb    cx,0
  2640. lgcd2:    cmp    dx,cx            ; first arg same/larger than second?
  2641.     ja    lgcd4            ; a = yes
  2642.     jb    lgcd3            ; b = smaller
  2643.     cmp    ax,bx            ; low order parts
  2644.     jae    lgcd4            ; ae = larger
  2645. lgcd3:    xchg    dx,cx            ; make largest the top number dx:ax
  2646.     xchg    ax,bx
  2647. lgcd4:    push    bx            ; preserve smaller number
  2648.     push    cx
  2649.     call    ldiv            ; large / small
  2650.     jc    lgcd6            ; c = divide by zero
  2651.     mov    dx,cx            ; temp spot
  2652.     or    dx,bx            ; remainder?
  2653.     jz    lgcd5            ; z = no, small is the answer
  2654.     pop    dx            ; new values, new top is old bot
  2655.     pop    ax            ; bottom is new remainder
  2656.     jmp    short lgcd2        ; repeat calculation
  2657. lgcd5:    pop    dx            ; recover smaller number from stack
  2658.     pop    ax            ; result in dx:ax
  2659.     pop    dx
  2660.     pop    cx
  2661.     clc
  2662.     ret                ; success
  2663. lgcd6:    pop    ax
  2664.     pop    ax            ; clean stack
  2665.     pop    dx
  2666.     pop    cx
  2667.     mov    ax,-1            ; dx:ax = -1 on error
  2668.     cwd
  2669.     stc
  2670.     ret
  2671. lgcd    endp
  2672.  
  2673. ; Convert ASCIIZ string in DS:SI of form hh:mm:ss to ASCIIZ string seconds
  2674. ; in ES:DI.
  2675. tod2secs proc    far
  2676.     mov    temp,0
  2677.     mov    temp1,0
  2678.     xor    dx,dx            ; dh=field counter, dl=read byte
  2679.     xor    bx,bx            ; three groups possible
  2680. tod2s1:    mov    dl,[si]            ; get a char
  2681.     inc    si            ; next char
  2682.     inc    dh            ; count char in field
  2683.     or    dl,dl            ; null terminator?
  2684.     jz    tod2s3            ; z = yes, wrap calculations and quit
  2685.     cmp    dl,':'            ; field separator?
  2686.     je    tod2s3            ; e = a separator, step fields
  2687.     sub    dl,'0'            ; remove ascii bias
  2688.     cmp    dl,9
  2689.     ja    short tod2s6        ; a = failure to get expected digit
  2690.     cmp    dh,2            ; more than two bytes in this field
  2691.     ja    tod2s6            ; a = yes, fail translation
  2692.     mov    al,bh            ; get sum to al
  2693.     mov    ah,10
  2694.     mul    ah            ; sum times ten
  2695.     add    al,dl            ; sum = 10 * previous + current
  2696.     mov    bh,al            ; current sum
  2697.     mov    ah,60
  2698.     or    bl,bl            ; doing hours?
  2699.     jne    tod2s2            ; ne = no, min, sec
  2700.     mov    ah,24            ; max for hours field
  2701. tod2s2:    cmp    bh,ah            ; more than legal?
  2702.     jae    tod2s6            ; ae = illegal
  2703.     jmp    short tod2s1        ; continue analysis
  2704.  
  2705. tod2s3:    mov    al,bh            ; current sum
  2706.     xor    ah,ah
  2707.     mov    cx,1
  2708.     cmp    bl,2            ; seconds?
  2709.     je    tod2s4            ; e = yes
  2710.     mov    cx,60
  2711.     or    bl,bl            ; hours?
  2712.     jne    tod2s4            ; ne = no
  2713.     mov    cx,60*60        ; seconds per hour
  2714. tod2s4:    mul    cx
  2715.     add    temp,ax
  2716.     adc    temp1,dx
  2717.     xor    bh,bh            ; bh = current field sum
  2718.     xor    dh,dh            ; dh = counter of bytes in field
  2719.     cmp    byte ptr [si-1],0    ; ended on null?
  2720.     je    tod2s5            ; e = yes, end of conversion
  2721.     inc    bl            ; point to next field
  2722.     cmp    bl,2            ; last field to use (secs)
  2723.     jbe    tod2s1            ; be = get more text
  2724. tod2s5:    mov    ax,temp
  2725.     mov    dx,temp1
  2726.     push    di
  2727.     mov    di,offset tmpstring    ; build ASCII in this buffer
  2728.     call    flnout
  2729.     pop    di
  2730.     mov    dx,offset tmpstring
  2731.     mov    si,dx
  2732.     call    strlen
  2733.     cld
  2734.     rep    movsb            ; copy string to es:di area
  2735.     mov    byte ptr es:[di],0    ; and null terminator
  2736.     clc                ; carry clear for success
  2737.     ret
  2738. tod2s6:    mov    byte ptr es:[di],0
  2739.     stc                ; carry set for illegal value    
  2740.     ret
  2741. tod2secs endp
  2742. code1    ends 
  2743.     end
  2744.