home *** CD-ROM | disk | FTP | other *** search
/ RBBS in a Box Volume 1 #3.1 / RBBSIABOX31.cdr / log2 / lease.bas < prev    next >
Encoding:
BASIC Source File  |  1984-08-21  |  2.5 KB  |  85 lines
  1. 10 CLS
  2. 20 KEY OFF
  3. 30 PRINT "LEASE/BUY DECISION"
  4. 40 DEFDBL A-Z:DEFINT Y,Z
  5. 50 REM  - FUNCTION TO ROUND TO NEAREST HUNDREDTH
  6. 60 DEF FNA(X)=INT(X*100+.5)/100
  7. 70 PRINT
  8. 80 PRINT "ENTER THE COST TO ACQUIRE ASSET ";
  9. 90 PRINT "(PRINCIPAL OF LOAN) ";
  10. 100 INPUT B1
  11. 110 PRINT "ENTER THE INTEREST RATE (%) ";
  12. 120 INPUT I1
  13. 130 REM  - CONVERT INTEREST RATE TO DECIMAL
  14. 140 I1=I1/100
  15. 150 PRINT "ENTER THE TERM IN YEARS ";
  16. 160 INPUT Y1
  17. 170 PRINT "WHAT IS THE SALVAGE VALUE ";
  18. 180 PRINT "AT THE END OF";Y1;"YEARS ";
  19. 190 INPUT S1
  20. 200 PRINT
  21. 210 PRINT "WHAT IS THE TAX RATE (%) ";
  22. 220 INPUT R1
  23. 230 REM  - CONVERT TAX RATE TO DECIMAL
  24. 240 R1=R1/100
  25. 250 PRINT "ENTER THE ANNUAL AMOUNT ";
  26. 260 PRINT "OF LOAN PAYMENTS ";
  27. 270 INPUT A1
  28. 280 PRINT "ENTER THE ANNUAL AMOUNT ";
  29. 290 PRINT "OF LEASE PAYMENTS ";
  30. 300 INPUT A2
  31. 310 REM  - RESET TOTAL AMOUNTS TO ZERO
  32. 320 T1=0
  33. 330 L1=0
  34. 340 PRINT
  35. 350 PRINT "ENTER THE DEPRECIATION AMOUNT ";
  36. 360 PRINT "FOR EACH YEAR"
  37. 370 PRINT
  38. 380 REM  - LOOP TO INPUT, CALCULATE AND ACCUMULATE
  39. 390 REM  - VALUES FOR EACH YEAR
  40. 400 FOR Z=1 TO Y1
  41. 410 IF Z>1 THEN 440
  42. 420 PRINT "YEAR NUMBER";
  43. 430 GOTO 450
  44. 440 PRINT SPC(11);
  45. 450 PRINT Z;
  46. 460 INPUT D1
  47. 470 REM  - CALCULATE INTEREST AMOUNT FOR EACH YEAR
  48. 480 B0=ABS(B1-FNA(B1*(1+I1)))
  49. 490 REM  - CONVERT D1 TO PRESENT VALUE OF COST
  50. 500 REM  - OF OWNING EACH YEAR
  51. 510 D1=FNA((A1-FNA((D1+B0)*R1))/((1+I1)^Z))
  52. 520 REM  - SUBTRACT ANNUAL PAYMENT,
  53. 530 REM  - ADD ANNUAL INTEREST TO PRINCIPAL
  54. 540 B1=B1-A1+B0
  55. 550 REM  - SUM PRESENT VALUE AMOUNTS OF EACH YEAR
  56. 560 T1=T1+D1
  57. 570 REM  - COMPUTE PRESENT VALUE OF COST TO LEASE FOR EACH YEAR
  58. 580 L1=L1+FNA((A2-(A2*R1))/(1+I1)^Z)
  59. 590 NEXT Z
  60. 600 REM  - SUBTRACT PRESENT VALUE OF SALVAGE VALUE
  61. 610 REM  - FROM TOTAL COST TO OWN
  62. 620 T1=T1-FNA(S1/(1+I1)^Y1)
  63. 630 REM  -OUTPUT RESULTS
  64. 640 PU$="$$,###,###,###.##"
  65. 650 PRINT
  66. 660 PRINT "PRESENT VALUE OF COST OF LOAN  =";
  67. 670 PRINT USING PU$; T1
  68. 680 PRINT "PRESENT VALUE OF COST OF LEASE =";
  69. 690 PRINT USING PU$; L1
  70. 700 PRINT
  71. 710 IF L1<T1 THEN 750
  72. 720 PRINT "ADVANTAGE OF BUYING =";
  73. 730 PRINT USING PU$;L1-T1
  74. 740 GOTO 770
  75. 750 PRINT "ADVANTAGE OF LEASING =";
  76. 760 PRINT USING PU$;T1-L1
  77. 770 PRINT
  78. 780 REM  - RESTART OR END PROGRAM?
  79. 790 PRINT "WOULD YOU LIKE TO RE-RUN THIS PROGRAM";
  80. 800 PRINT " WITH NEW DATA (Y/N)?"
  81. 810 Z$=INKEY$:IF Z$="" THEN 810
  82. 820 IF Z$="Y" OR Z$="y" THEN 70
  83. 830 IF Z$<>"N" AND Z$<>"n" THEN 790
  84. 840 END
  85.