home *** CD-ROM | disk | FTP | other *** search
/ Netrunner 2004 October / NETRUNNER0410.ISO / regular / ActivePerl-5.8.4.810-MSWin32-x86.msi / _3edb65ff024d4161b2a25a85c1aaba35 < prev    next >
Encoding:
Text File  |  2004-06-01  |  2.6 KB  |  91 lines
  1. package LWP::Authen::Digest;
  2. use strict;
  3.  
  4. require Digest::MD5;
  5.  
  6. sub authenticate
  7. {
  8.     my($class, $ua, $proxy, $auth_param, $response,
  9.        $request, $arg, $size) = @_;
  10.  
  11.     my($user, $pass) = $ua->get_basic_credentials($auth_param->{realm},
  12.                                                   $request->url, $proxy);
  13.     return $response unless defined $user and defined $pass;
  14.  
  15.     my $nc = sprintf "%08X", ++$ua->{authen_md5_nonce_count}{$auth_param->{nonce}};
  16.     my $cnonce = sprintf "%8x", time;
  17.  
  18.     my $uri = $request->url->path_query;
  19.     $uri = "/" unless length $uri;
  20.  
  21.     my $md5 = Digest::MD5->new;
  22.  
  23.     my(@digest);
  24.     $md5->add(join(":", $user, $auth_param->{realm}, $pass));
  25.     push(@digest, $md5->hexdigest);
  26.     $md5->reset;
  27.  
  28.     push(@digest, $auth_param->{nonce});
  29.  
  30.     if ($auth_param->{qop}) {
  31.     push(@digest, $nc, $cnonce, $auth_param->{qop});
  32.     }
  33.  
  34.     $md5->add(join(":", $request->method, $uri));
  35.     push(@digest, $md5->hexdigest);
  36.     $md5->reset;
  37.  
  38.     $md5->add(join(":", @digest));
  39.     my($digest) = $md5->hexdigest;
  40.     $md5->reset;
  41.  
  42.     my %resp = map { $_ => $auth_param->{$_} } qw(realm nonce opaque);
  43.     @resp{qw(username uri response algorithm)} = ($user, $uri, $digest, "MD5");
  44.  
  45.     if (($auth_param->{qop} || "") eq "auth") {
  46.     @resp{qw(qop cnonce nc)} = ("auth", $cnonce, $nc);
  47.     }
  48.  
  49.     my(@order) = qw(username realm qop algorithm uri nonce nc cnonce response);
  50.     if($request->method =~ /^(?:POST|PUT)$/) {
  51.     $md5->add($request->content);
  52.     my $content = $md5->hexdigest;
  53.     $md5->reset;
  54.     $md5->add(join(":", @digest[0..1], $content));
  55.     $md5->reset;
  56.     $resp{"message-digest"} = $md5->hexdigest;
  57.     push(@order, "message-digest");
  58.     }
  59.     push(@order, "opaque");
  60.     my @pairs;
  61.     for (@order) {
  62.     next unless defined $resp{$_};
  63.     push(@pairs, "$_=" . qq("$resp{$_}"));
  64.     }
  65.  
  66.     my $auth_header = $proxy ? "Proxy-Authorization" : "Authorization";
  67.     my $auth_value  = "Digest " . join(", ", @pairs);
  68.  
  69.     # Need to check this isn't a repeated fail!
  70.     my $r = $response;
  71.     while ($r) {
  72.     my $u = $r->request->{digest_user_pass};
  73.     if ($u && $u->[0] eq $user && $u->[1] eq $pass) {
  74.         # here we know this failed before
  75.         $response->header("Client-Warning" =>
  76.                   "Credentials for '$user' failed before");
  77.         return $response;
  78.     }
  79.     $r = $r->previous;
  80.     }
  81.  
  82.     my $referral = $request->clone;
  83.     $referral->header($auth_header => $auth_value);
  84.     # we shouldn't really do this, but...
  85.     $referral->{digest_user_pass} = [$user, $pass];
  86.  
  87.     return $ua->request($referral, $arg, $size, $response);
  88. }
  89.  
  90. 1;
  91.