home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
bombers.k12.ar.us
/
bombers.k12.ar.us.tar
/
bombers.k12.ar.us
/
survey_unconfigured
/
ReportShareAction.asp
< prev
next >
Wrap
Text File
|
2006-05-19
|
5KB
|
113 lines
<!--#Include File="Include/Top_inc.asp"-->
<%
'***********************************************************************
' Application: SelectSurveyASP Advanced v8.1.7
' Author: Aaron Baril for ClassApps.com
' Page Description: This page works with ReportShare.asp, and processes
' the form for registering new report shares by writing a database
' record to the SUR_REPORT_SHARE table.
'
' COPYRIGHT NOTICE
'
' See attached Software License Agreement
'
' (c) Copyright 2002 - 2006 by ClassApps.com. All rights reserved.
'***********************************************************************
%>
<!--#Include File="Include/Config_inc.asp"-->
<!--#Include File="Include/Utility_inc.asp"-->
<!--#Include File="Include/adovbs_inc.asp"-->
<!--#Include File="Include/Constants_inc.asp"-->
<!--#Include File="Include/ID_inc.asp"-->
<!--#Include File="Include/CurrentUser_inc.asp"-->
<!--#Include File="Include/SurveySecurity_inc.asp"-->
<%
Dim lngSurveyID
Dim strSQL
Dim conReportShare
Dim lngReportShareID
Dim strEmailAddresses
Dim arrEmailAddresses
Dim i
'Initialization
lngSurveyID = Request.Form("SurveyID")
'If the user does not either own this survey or have admin permission, deny them access to this functionality.
If IsUserOwnerOrAdmin(lngSurveyID) = False Then
Response.Redirect "AccessDenied.asp?Reason=" & SUR_ACCESS_DENIED_NOT_OWNER_FOR_RESULTS_SHARING
End If
'Initialization
Set conReportShare = Server.CreateObject("ADODB.Connection")
conReportShare.Open SURVEY_APP_CONNECTION
'Clean up the email addresses
arrEmailAddresses = Split(Request.Form("txtEmailAddresses"), ";")
For i = 0 To UBound(arrEmailAddresses)
If Len(Trim(arrEmailAddresses(i))) > 0 And Trim(arrEmailAddresses(i)) <> ";" Then
strEmailAddresses = strEmailAddresses & Trim(arrEmailAddresses(i)) & "; "
End If
Next
strEmailAddresses = Left(strEmailAddresses, Len(strEmailAddresses) - 2)
'Create the SQL statement to either update or insert a record
If Request.Form("State") = SUR_STATE_EDIT Then
lngReportShareID = Request.Form("ReportShareID")
strSQL = "UPDATE sur_report_share " & _
"SET email_addresses = " & SQLEncode(strEmailAddresses) & ", " & _
"viewable_reports = " & SQLEncode(Request.Form("cboViewableReports")) & ", " & _
"export_data_yn = " & SQLEncode(Request.Form("cboExportDataYN")) & ", " & _
"report_filtering_yn = " & SQLEncode(Request.Form("cboReportFilteringYN")) & ", " & _
"view_open_ended_yn = " & SQLEncode(Request.Form("cboViewOpenEndedYN")) & ", " & _
"active_yn = " & SQLEncode(Request.Form("cboActiveYN")) & _
" WHERE report_share_id = " & Request.Form("ReportShareID")
Else 'INSERT mode
lngReportShareID = ID_GetNextAvailableID("SurveyGenerationReportShare")
'***5/12/2005 start: make sure you don't insert a url that is already being used
tmpRandomID = SQLEncode(GetRandomCode(15))
Dim strRandomSQL, rsRandom, tmpRandomID, tmpRandomAlreadyUsed
tmpRandomAlreadyUsed = True
Set rsRandom = Server.CreateObject("ADODB.Recordset")
Do while tmpRandomAlreadyUsed = True
strRandomSQL = "Select * from sur_report_share where report_share_url_id = " & tmpRandomID
rsRandom.Open ConvertSQL(strRandomSQL), SURVEY_APP_CONNECTION, adOpenForwardOnly, adLockReadOnly, adCmdText
If rsRandom.EOF = True Then
tmpRandomAlreadyUsed = False
Else
tmpRandomID = SQLEncode(GetRandomCode(15))
tmpRandomAlreadyUsed =True
End If
rsRandom.Close
Loop
Set rsRandom = Nothing
'***5/12/2005 end
strSQL = "INSERT INTO sur_report_share(report_share_id, survey_id, created_date, report_share_url_id, " & _
"email_addresses, last_sent_date, export_data_yn, report_filtering_yn, viewable_reports, " & _
"view_open_ended_yn, active_yn) VALUES(" & _
lngReportShareID & ", " & _
Request.Form("SurveyID") & ", " & _
"GETDATE(), " & _
tmpRandomID & ", " & _
SQLEncode(strEmailAddresses) & ", " & _
"Null, " & _
SQLEncode(Request.Form("cboExportDataYN")) & ", " & _
SQLEncode(Request.Form("cboReportFilteringYN")) & ", " & _
SQLEncode(Request.Form("cboViewableReports")) & ", " & _
SQLEncode(Request.Form("cboViewOpenEndedYN")) & ", " & _
SQLEncode(Request.Form("cboActiveYN")) & ")"
End If
'Execute the SQL
conReportShare.Execute ConvertSQL(strSQL), , adCmdText
'Clean up
conReportShare.Close
Set conReportShare = Nothing
'Redirect back to the list of report shares
Response.Redirect "ReportShareList.asp?SurveyID=" & Request.Form("SurveyID") & "&SurveyName=" & Request.Form("SurveyName")
%>