home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
bombers.k12.ar.us
/
bombers.k12.ar.us.tar
/
bombers.k12.ar.us
/
survey_unconfigured
/
RemovePageBreak.asp
< prev
next >
Wrap
Text File
|
2006-10-25
|
3KB
|
78 lines
<!--#Include File="Include/Top_inc.asp"-->
<%
'***********************************************************************
' Application: SelectSurveyASP Advanced v8.1.11
' Author: Aaron Baril for ClassApps.com
' Page Description: This page removes an existing page break in a survey.
'
' COPYRIGHT NOTICE
'
' See attached Software License Agreement
'
' (c) Copyright 2002 - 2006 by ClassApps.com. All rights reserved.
'***********************************************************************
%>
<!--#Include File="Include/Config_inc.asp"-->
<!--#Include File="Include/Utility_inc.asp"-->
<!--#Include File="Include/adovbs_inc.asp"-->
<!--#Include File="Include/CurrentUser_inc.asp"-->
<!--#Include File="Include/SurveySecurity_inc.asp"-->
<!--#Include File="Include/Constants_inc.asp"-->
<%
'In order to remove a page break, the user must be the survey owner or an admin.
If IsUserOwnerOrAdmin(Request.QueryString("SurveyID")) = False Then
Response.Redirect "AccessDenied.asp?SurveyID=" & Request.QueryString("SurveyID") & "&Reason=" & SUR_ACCESS_DENIED_NOT_OWNER
End If
Dim strSQL
Dim conRemove
Dim lngPageNumber
Dim lngSurveyID
'Initialization
Set conRemove = Server.CreateObject("ADODB.Connection")
conRemove.Open SURVEY_APP_CONNECTION
lngPageNumber = Request.QueryString("PageNumber")
lngSurveyID = Request.QueryString("SurveyID")
'Move all the pages starting with the page specified up (decrease the page number) one page. Doing this removes
'the page break before the page specified.
strSQL = "UPDATE sur_survey_to_item_mapping " & _
"SET page_number = page_number - 1 " & _
"WHERE survey_id = " & lngSurveyID & _
" AND page_number >= " & lngPageNumber
conRemove.Execute ConvertSQL(strSQL), , adCmdText
'Delete the page condition for the page that was just removed
strSQL = "DELETE FROM sur_page_condition " & _
"WHERE survey_id = " & lngSurveyID & _
" AND page_number = " & lngPageNumber
conRemove.Execute ConvertSQL(strSQL), , adCmdText
'Drop the page number for all page conditions for this survey that are greater than the page just deleted
strSQL = "UPDATE sur_page_condition " & _
"SET page_number = page_number - 1 " & _
"WHERE survey_id = " & lngSurveyID & _
" AND page_number > " & lngPageNumber
conRemove.Execute ConvertSQL(strSQL), , adCmdText
'Delete the page properties for the page that was just removed
strSQL = "DELETE FROM sur_page " & _
"WHERE survey_id = " & lngSurveyID & _
" AND page_number = " & lngPageNumber
conRemove.Execute ConvertSQL(strSQL), , adCmdText
'Drop the page number for all page properties for this survey that are greater than the page just deleted
strSQL = "UPDATE sur_page " & _
"SET page_number = page_number - 1 " & _
"WHERE survey_id = " & lngSurveyID & _
" AND page_number > " & lngPageNumber
conRemove.Execute ConvertSQL(strSQL), , adCmdText
'Clean up
conRemove.Close
Set conRemove = Nothing
'Redirect to the modify survey page for the survey.
Response.Redirect "ModifySurvey.asp?SurveyID=" & lngSurveyID
%>