home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-387-Vol-3of3.iso / s / sutl.zip / SOUNDER.BAS < prev    next >
BASIC Source File  |  1993-03-01  |  2KB  |  54 lines
  1. 100 ' SOUNDER.BAS -- Paul Somerson
  2. 110 ' Creates sample odd sounds
  3. 120 ' (c) 1987 Ziff Communications Co.
  4. 130 DEFINT A-Z
  5. 140 CLS:PRINT "Enter a number (0-9) or Esc to quit:"
  6. 150 I$=INKEY$:IF I$="" THEN 150
  7. 160 IF I$=CHR$(27) THEN END
  8. 170 IF INSTR("0123456789",I$)=0 THEN 150
  9. 180 ON VAL(I$)+1 GOSUB 210,250,290,330,370,410,450,490,530,570
  10. 190 GOTO 150
  11. 200 ' --- SOUND0 ---
  12. 210 FOR A=1 TO 10:FOR B=1 TO 1900 STEP 600
  13. 220 SOUND 3000-B, .33
  14. 230 NEXT:NEXT:RETURN
  15. 240 ' --- SOUND1 ---
  16. 250 FOR A=1 TO 10:FOR B=45 TO 900 STEP 300
  17. 260 SOUND 99+B, .33
  18. 270 NEXT:NEXT:RETURN
  19. 280 ' --- SOUND2 ---
  20. 290 FOR A=1 TO 5:FOR B=450 TO 1 STEP -80
  21. 300 SOUND 99+B, .3
  22. 310 NEXT:NEXT:RETURN
  23. 320 ' --- SOUND3 ---
  24. 330 FOR A=1 TO 10:FOR B=1 TO 300 STEP 50
  25. 340 SOUND  200+B, .34
  26. 350 NEXT:NEXT:RETURN
  27. 360 ' --- SOUND4 ---
  28. 370 FOR A=1 TO 15:FOR B=1 TO 200 STEP 80
  29. 380 SOUND  800+B, .1
  30. 390 NEXT:NEXT:RETURN
  31. 400 ' --- SOUND5 ---
  32. 410 FOR A=1 TO 15:FOR B=1 TO 450 STEP 200
  33. 420 SOUND  400+B, .3
  34. 430 NEXT:NEXT:RETURN
  35. 440 ' --- SOUND6 ---
  36. 450 FOR A=1 TO 200:OUT 66,0:OUT 66,0
  37. 460 OUT 97,(INP(97) OR 3)
  38. 470 NEXT:SOUND 37,0:RETURN
  39. 480 ' --- SOUND7 ---
  40. 490 FOR A=0 TO 250:OUT 66,A:OUT 66,A
  41. 500 OUT 97,(INP(97) OR 3)
  42. 510 NEXT A:SOUND 37,0:RETURN
  43. 520 ' --- SOUND8 ---
  44. 530 FOR A=250 TO 0 STEP -1:
  45. 540 OUT 66,A:OUT 66,A:OUT 97,(INP(97) OR 3)
  46. 550 NEXT A:SOUND 37,0:RETURN
  47. 560 ' --- SOUND9 ---
  48. 570 FOR B=1 TO 10:FOR A=40 TO 0 STEP -1
  49. 580 OUT 66,A:OUT 66,A:OUT 97,(INP(97) OR 3)
  50. 590 NEXT A:SOUND 37,0:NEXT
  51. 600 FOR B=1 TO 15:FOR A=0 TO 26
  52. 610 OUT 66,A:OUT 66,A:OUT 97,(INP(97) OR 3)
  53. 620 NEXT A:SOUND 37,0:NEXT:RETURN
  54.