The World of Computer Software/World_Of_Computer_Software-02-387-Vol-3of3.iso/o/os2_util.zip/REBUIL.ZIP/MKTOOLKT.EXE/MKTOOLKT.CMD

OS/2 REXX Batch file | 1992-09-03 | 12KB | 208 lines

/****************************************************************/
/* MKTOOLKIT.CMD                Version 1.0; September 3, 1992  */
/*                                                              */
/* Function:                                                    */
/*      Build the WPS entries for the following products:       */
/*              Toolkit                                         */
/*              C Set/2                                         */
/*              WorkFrame/2                                     */
/* Parameters:                                                  */
/*      None                                                    */
/*                                                              */
/* Programmed by:                                               */
/*      Georg Haschek (61804212 at VIEVMA)                      */
/*                                                              */
/* Change history:                                              */
/*      1.0  92/09/03 ... First release to OS2TOOLS             */
/*                                                              */
/****************************************************************/
Trace 'O'
Address CMD
'@ECHO OFF'
Signal On Halt
Signal On Syntax

/**************/
/* Initialize */
/**************/
Call rxfuncadd sysloadfuncs, rexxutil, sysloadfuncs
Call sysloadfuncs

Parse Version v
v = Translate(Word(v,5)||Right(Wordpos(Word(v,4),'Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec'),2)||Right(Word(v,3),2),'0',' ')
If v < 19920708 Then Do
  Say "The version of REXX on your system is backlevel."
  Say " "
  Say "Please get the latest version from OS2TOOLS (REXX20 PACKAGE), or from"
  Say "the OS2CSD disk. The success of MKTOOLKT is not guaranteed!"
  'PAUSE'
End

tooldrive = ''
csetrive = ''
workdrive = ''
bootdrive = Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\OS2\SYSTEM',Value('PATH',,'OS2ENVIRONMENT'))-2,2)
If Pos('\TOOLKT20',Translate(Value('PATH',,'OS2ENVIRONMENT'))) > 0 Then tooldrive = Translate(Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\TOOLKT20',Translate(Value('PATH',,'OS2ENVIRONMENT')))-2,2))
If Pos('\IBMC',Translate(Value('PATH',,'OS2ENVIRONMENT'))) > 0 Then csetdrive = Translate(Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\IBMC',Translate(Value('PATH',,'OS2ENVIRONMENT')))-2,2))
If Pos('\IBMWF',Translate(Value('PATH',,'OS2ENVIRONMENT'))) > 0 Then workdrive = Translate(Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\IBMWF',Translate(Value('PATH',,'OS2ENVIRONMENT')))-2,2))
If tooldrive = '' & csetdrive = '' & workdrive = '' Then Do
  Say "No Toolkit, WorkFrame/2, or C Set/2 found, terminating."
  Call Endit
End

iconfile = 'GROUP.ICO'
iconparm = ''
If Stream(iconfile,'C','QUERY EXISTS') = '' Then Do
  Parse Source . . myname .
  mydir = Filespec('D',myname)||Filespec('P',myname)
  If Stream(mydir||iconfile,'C','QUERY EXISTS') = '' Then Do
    If SysSearchPath('PATH',iconfile) = '' Then Do
      If SysSearchPath('DPATH',iconfile) <> '' Then Do
        iconparm = 'ICONFILE='||SysSearchPath('DPATH',iconfile)||';'
      End
    End
    Else Do
      iconparm = 'ICONFILE='||SysSearchPath('PATH',iconfile)||';'
    End
  End
  Else Do
    iconparm = 'ICONFILE='||mydir||iconfile||';'
  End
End
Else Do
  iconparm = 'ICONFILE='||Directory()||'\'||iconfile||';'
End

'CLS'
Say "Your system is installed on the" bootdrive "drive."
Say " "
Say "The following components have been found:"
Say " "
If tooldrive <> '' Then Say "     Toolkit for OS/2 2.0 on drive" tooldrive
If csetdrive <> '' Then Say "     C Set/2 on drive" csetdrive
If workdrive <> '' Then Say "     WorkFrame/2 on drive" workdrive
Say " "
Say "This program will now create a folder for each identified product on your"
Say "desktop, which will contain the default WPS entries for the listed products."
Say " "
Say "Do you want to continue (Y/N)?"
Parse Upper Pull yesno .
If Substr(yesno,1,1) <> 'Y' Then Call Endit

If tooldrive <> '' Then Do
  Call SysCreateObject 'WPFolder','Toolkit','<WP_DESKTOP>','OBJECTID=<TOOLKIT_FOLDER>;ICONFILE='||tooldrive||'\TOOLKT20\ICON\UTILS.ICO','R'
  Call SysCreateObject 'WPFolder','Toolkit Information','<TOOLKIT_FOLDER>','OBJECTID=<TOOLKIT_INFO>;ICONFILE='||tooldrive||'\TOOLKT20\ICON\ICONINFO.ICO','R'
  Call SysCreateObject 'WPProgram','REXX Reference','<TOOLKIT_INFO>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=REXXAPI.INF;STARTUPDIR='||tooldrive||'\TOOLKT20\BOOKS;','R'
  Call SysCreateObject 'WPProgram','IPF Reference','<TOOLKIT_INFO>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=IPFC20.INF;STARTUPDIR='||tooldrive||'\TOOLKT20\BOOKS;','R'
  Call SysCreateObject 'WPProgram','SOM Reference','<TOOLKIT_INFO>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=SOM.INF;STARTUPDIR='||tooldrive||'\TOOLKT20\BOOKS;','R'
  Call SysCreateObject 'WPProgram','Tools Reference','<TOOLKIT_INFO>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=TOOLINFO.INF;STARTUPDIR='||tooldrive||'\TOOLKT20\BOOKS;','R'
  Call SysCreateObject 'WPProgram','PM Reference','<TOOLKIT_INFO>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=PMREF;STARTUPDIR='||tooldrive||'\TOOLKT20\BOOKS;','R'
  Call SysCreateObject 'WPProgram','CP Reference','<TOOLKIT_INFO>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=PROGREF20;STARTUPDIR='||tooldrive||'\TOOLKT20\BOOKS;','R'
  Call SysCreateObject 'WPFolder','Sample Programs','<TOOLKIT_FOLDER>','OBJECTID=<TOOLKIT_SAMPLES>;ICONFILE='||tooldrive||'\TOOLKT20\ICON\OSTUTOR.ICO','R'
  samples.1 = tooldrive||'\TOOLKT20\C\SAMPLES\ANIMALS\ANIMALS.CMD WINDOWABLEVIO ;; SOM Inheritance Sample'
  samples.2 = tooldrive||'\TOOLKT20\C\SAMPLES\CLIPBRD\CLIPBRD.EXE PM ;; Clipboard Sample'
  samples.3 = tooldrive||'\TOOLKT20\C\SAMPLES\CLOCK\CLOCK.EXE PM ;; Clock Sample'
  samples.4 = tooldrive||'\TOOLKT20\C\SAMPLES\DIALOG\DIALOG.EXE PM ;; Introductory Dialog Box Sample'
  samples.5 = tooldrive||'\TOOLKT20\C\SAMPLES\DLLAPI\DLLAPI.EXE PM ;; Dynamic Link Library Sample'
  samples.6 = tooldrive||'\TOOLKT20\C\SAMPLES\DRAGDROP\DRAGDROP.EXE PM ;; Dragdrop Sample'
  samples.7 = tooldrive||'\TOOLKT20\C\SAMPLES\EAS\EAS.EXE PM ;; Edit Extended Attributes Sample'
  samples.8 = tooldrive||'\TOOLKT20\C\SAMPLES\GRAPHIC\GRAPHIC.EXE PM ;; Retained Graphics Sample'
  samples.9 = tooldrive||'\TOOLKT20\C\SAMPLES\HANOI\HANOI.EXE PM ;; Towers of Hanoi Sample'
  samples.10 = tooldrive||'\TOOLKT20\C\SAMPLES\HELLO\HELLO.EXE PM ;; Standard Window Sample'
  samples.11 = tooldrive||'\TOOLKT20\C\SAMPLES\IMAGE\IMAGE32.EXE PM ;; Image Sample'
  samples.12 = tooldrive||'\TOOLKT20\C\SAMPLES\JIGSAW\JIGSAW.EXE PM ;; Jigsaw Puzzle Sample'
  samples.13 = tooldrive||'\TOOLKT20\C\SAMPLES\NPIPE\SVRNPIPE.EXE PM ;CLINPIPE.EXE; Tic-Tac-Toe Sample'
  samples.14 = tooldrive||'\TOOLKT20\C\SAMPLES\PRINT\PRTSAMP.EXE PM ;; Print Sample'
  samples.15 = tooldrive||'\TOOLKT20\C\SAMPLES\QUEUES\SVRQUEUE.EXE PM ;CLIQUEUE.EXE; Queues Sample'
  samples.16 = tooldrive||'\TOOLKT20\C\SAMPLES\SEMAPH\SEMAPH.EXE PM ;; Semaphore Sample'
  samples.17 = tooldrive||'\TOOLKT20\C\SAMPLES\SORT\SORT.EXE PM ;; Sorting Algorithm Sample'
  samples.18 = tooldrive||'\TOOLKT20\C\SAMPLES\STYLE\STYLE.EXE PM ;; Style Sample'
  samples.19 = tooldrive||'\TOOLKT20\C\SAMPLES\TEMPLATE\TEMPLATE.EXE PM ;; Application Templace Sample'
  samples.20 = tooldrive||'\TOOLKT20\C\SAMPLES\TP\TP.CMD WINDOWABLEVIO ;; SOM Text Processing Sample'
  samples.21 = tooldrive||'\TOOLKT20\C\SAMPLES\VMM\VMM.EXE PM ;; Virtual Memory Management Sample'
  samples.22 = tooldrive||'\TOOLKT20\C\SAMPLES\WORMS\WORMS.EXE WINDOWABLEVIO ;-30; Mixed Mode Sample'
  samples.23 = tooldrive||'\TOOLKT20\REXX\SAMPLES\CALLREXX\CALLREXX.CMD WINDOWABLEVIO ;; REXX Interpreter Invocation Sample'
  samples.24 = tooldrive||'\TOOLKT20\REXX\SAMPLES\DEVINFO\DEVINFO.CMD WINDOWABLEVIO ;; REXX Variable Pool Interface Sample'
  samples.25 = tooldrive||'\TOOLKT20\REXX\SAMPLES\PMREXX\PMREXX.EXE PM ;REXXTRY.CMD; Presentation Manager REXX Interface Sample'
  samples.26 = tooldrive||'\TOOLKT20\REXX\SAMPLES\REXXUTIL\REXXUDEM.CMD WINDOWABLEVIO ;; REXX Utility Functions Sample'
  samples.27 = tooldrive||'\TOOLKT20\REXX\SAMPLES\RXMACDLL\RXMACDLL.CMD WINDOWABLEVIO ;; External Functions in REXX Macrospace Sample'
  samples.0 = 27
  Do i = 1 to samples.0
    Parse Var samples.i program type ';' parms ';' title
    program = Strip(program)
    type = Strip(title)
    parms = Strip(parms)
    title = Strip(title)
    If parms = '' Then Do
      Call SysCreateObject 'WPProgram',title,'<TOOLKIT_SAMPLES>','EXENAME='||program||';PROGTYPE='||type||';STARTUPDIR='||Filespec('D',program)||Substr(Filespec('P',program),1,Length(Filespec('P',program))-1)||';','R'
    End
    Else Do
      Call SysCreateObject 'WPProgram',title,'<TOOLKIT_SAMPLES>','EXENAME='||program||';PROGTYPE='||type||';PARAMETERS='||parms||';STARTUPDIR='||Filespec('D',program)||Substr(Filespec('P',program),1,Length(Filespec('P',program))-1)||';','R'
    End
  End
  Call SysCreateObject 'WPProgram','Information Presentation Facility Sample','<TOOLKIT_SAMPLES>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=IPF.INF;STARTUPDIR='||tooldrive||'\TOOLKT20\C\SAMPLES\IPF;','R'
  Call SysCreateObject 'WPFolder','PM Development Tools','<TOOLKIT_FOLDER>','OBJECTID=<TOOLKIT_TOOLS>;ICONFILE='||tooldrive||'\TOOLKT20\ICON\FXICON.ICO','R'
  Call SysCreateObject 'WPProgram','Dialog Editor','<TOOLKIT_TOOLS>','EXENAME='||tooldrive||'\TOOLKT20\OS2BIN\DLGEDIT.EXE;PROGTYPE=PM;STARTUPDIR='||tooldrive||'\TOOLKT20\OS2BIN;','R'
  Call SysCreateObject 'WPProgram','Font Editor','<TOOLKIT_TOOLS>','EXENAME='||tooldrive||'\TOOLKT20\OS2BIN\FONTEDIT.EXE;PROGTYPE=PM;STARTUPDIR='||tooldrive||'\TOOLKT20\OS2BIN;','R'
  Call SysCreateObject 'WPProgram','Icon Editor','<TOOLKIT_TOOLS>','EXENAME='||tooldrive||'\TOOLKT20\OS2BIN\ICONEDIT.EXE;PROGTYPE=PM;STARTUPDIR='||tooldrive||'\TOOLKT20\OS2BIN;','R'
  Call SysRegisterObjectClass 'WPKlist', tooldrive||'\TOOLKT20\DLL\WPCLSLST.DLL'
  Call SysCreateObject 'WPKlist', 'WP Class List','<TOOLKIT_TOOLS>'
End

If csetdrive <> '' Then Do
  Call SysCreateObject 'WPFolder','IBM C Set/2','<WP_DESKTOP>','OBJECTID=<CSET_FOLDER>;'||iconparm,'R'
  Call SysCreateObject 'WPProgram','IBM C Set/2 Online Help','<CSET_FOLDER>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=DDE4HELP.INF;STARTUPDIR='||csetdrive||'\IBMC\HELP;','R'
  Call SysCreateObject 'WPProgram','IBM C Set/2 Debugger','<CSET_FOLDER>','EXENAME='||csetdrive||'\IBMC\BIN\IPMD.EXE;PROGTYPE=PM;STARTUPDIR='||csetdrive||'\IBMC\BIN;','R'
End

If workdrive <> '' Then Do
  Call SysCreateObject 'WPFolder','IBM WorkFrame/2','<WP_DESKTOP>','OBJECTID=<WKFR_FOLDER>;'||iconparm,'R'
  Call SysCreateObject 'WPProgram','IBM WorkFrame/2 Online Help','<WKFR_FOLDER>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=DDE3WF.INF;STARTUPDIR='||workdrive||'\IBMWF\HELP;','R'
  Call SysCreateObject 'WPProgram','IBM WorkFrame/2','<WKFR_FOLDER>','EXENAME='||workdrive||'\IBMWF\BIN\WF.EXE;PROGTYPE=PM;STARTUPDIR='||workdrive||'\IBMWF;','R'
End

/****************/
/* Exit program */
/****************/
Endit:
Exit 0

/********************************/
/* Notify user in case of error */
/********************************/
Telluser: Procedure
Parse source . . tell_name .
tell_name = Filespec('name',tell_name)
Parse Upper Var tell_name tell_name '.' .
ulogfile = tell_name
If Arg(2,'e') = 0 Then Do
  Say tell_name||':' Date('U') Time() Arg(1)
End
Else Do
  If Arg(2) = 0 Then Do
    Say tell_name||':' Date('U') Time() Arg(1)
  End
  Else Do
    Say Copies(' ',15+Length(tell_name)) Arg(1)
  End
End
Return 0

/*************************/
/* Handle SIGNAL ON HALT */
/*************************/
Halt:
Call Telluser 'Halt signalled in line' SIGL'.'
Call Endit

/***************************/
/* Handle SIGNAL ON SYNTAX */
/***************************/
Syntax:
myrc = rc
errormsg ='REXX error' myrc 'in line' SIGL':' Errortext(myrc)
errormsg2 = Substr('     ',1,6-Length(SIGL))(SIGL)' *-*   'Sourceline(sigl)
Call Telluser errormsg
Call Telluser errormsg2,1
Call Endit