home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-387-Vol-3of3.iso / h / house_ii.zip / FOR / SOLR.FOR < prev    next >
Text File  |  1992-04-10  |  12KB  |  347 lines
  1.       SUBROUTINE SOLR(TIME,NDYRI,IDAY,KM,STM,DNLAT,DLONG, 
  2.      +                DST,ICC,CLEAR,
  3.      +                ISUN,ITH,IDHC,SAZM,SALT,
  4.      +                IDC,IDFC,DIRECT,DIFFUS,SFST,SFTT)
  5. C 
  6. C  CALCULATE SOLAR FACTORS FOR TIME=TIME AND DAY = NDYRI
  7. C 
  8. C  INPUTS FROM FORMAL PARAMETERS IN CALL STMT 
  9. C   TIME     TIME OF DAY,(0-24 HRS) 
  10. C   NDYRI    DAY OF YEAR
  11. C   IDAY     NO. OF DAYS RUN AT THIS TIME
  12. C             (IDAY IS ONLY USED TO IDENTIFY DEBUG OUTPUT)
  13. C   KM       MONTH OF YEAR (1 TO 12)
  14. C  STM       TIME ZONE (SEE ETIME SUBPROGRAM) 
  15. C  ICC     =1  CLOUD COVER DATA USED TO COMPUTE SOLAR 
  16. C          =0  TOTAL SOLAR RADIATION SUPPLIED IN  CC  ARRAY 
  17. C DNLAT      DEG N. LATTITUDE 
  18. C DLONG      DEG LONGITUDE
  19. C   DST    =0 FOR STANDARD TIME 
  20. C          =1 FOR DAYLIGHT SAVINGS TIME 
  21. C  CLEAR   CLEARNESS NO. FOR USE WITH CLOUD COVER DATA
  22. C 
  23. C  INPUTS FROM COMMON BLOCK ROOF - - - -
  24. C   IDEXPR  INTEGER 1-4 COMPASS DIRECTION THAT ROOF FACES 
  25. C     PAA   PITCH ANGLE BETWEEN VERTICAL AND ROOF LINE 
  26. C 
  27. C INPUTS FROM COMMON BLOCK NCR - - - - -
  28. C   IFXDS  INTEGER 1-4 COMPASS DIRECTIONS OF STRUCTURE THAT ARE ALWAYS
  29. C          SHADED.
  30. C   WROTA  ANGLE THAT STRUCTURE IS ROTATED FROM THE CARDINAL COMPASS
  31. C          DIRECTIONS (+CLOCKWISE, -COUNTERCLOCKWISE) 
  32. C 
  33. C INPUTS FROM COMMON BLOCK SIMA - - - - - - 
  34. C REFLG    GROUND REFLECTANCE FOR EA. MONTH OF YR.
  35. C
  36. C SOLARH   CLOUD COVER(0-10), IF ICC> 0 
  37. C            OR TOTAL HORIZ RADIATION, IF ICC=0, BTU/HR-SQ FT
  38. C  OUTPUTS - - - - - - - -
  39. C   ISUN  =1,NO SUN;  =0, SUN SUFFICIENTLY ABOVE HORIZON
  40. C   ITH  TOTAL HORIZONTAL SOLAR RADIATION, BTU/HR-SQ FT 
  41. C        IF ICC=1, ITH IS CLOUDLESS VALUE 
  42. C        IF ICC=0, ITH IS MEASURED VALUE FROM CC ARRAY
  43. C  IDHC  DIRECT SOLAR RADIATION ON HORIZONTAL SURFACE WITH
  44. C        CLOUDY SKY, BTU/HR-SQ FT 
  45. C  SAZM  SOLAR AZIMUTH ANGLE, RADIANS 
  46. C  SALT  SOALR ALTITUDE, RADIANS
  47. C 
  48. C  VALUES FOR EACH COMPASS DIRECTION ARE GIVEN BELOW  - - - - - - - 
  49. C  IDC  DIRECT SOLAR RADIATION ONTO VERTICAL SURFACE FOR CLOUDY SKY,
  50. C       BTU/HR-SQ FT
  51. C  IDFC  DIFFUSE SOLAR RADIATION ONTO VERTICAL SURFACE FOR
  52. C        CLOUDY SKY, BTU/HR-SQ FT 
  53. C  DIRECT  DIRECT SOLAR TRANSMITTED THROUGH WINDOWS / RATIO OF
  54. C          UNSHADED(BY OVERHANG AND REVEAL) WINDOW AREA TO TOTAL
  55. C          WINDOW AREA ,BTU/HR-SQ FT
  56. C  DIFFUS  DIFFUSE SOLAR RADIATION TRANSMITTED THROUGH WINDOWS
  57. C          (INCLUDES GROUND REFLECTANCE), BTU/HR-SQ FT
  58. C 
  59. C  SFST  SHADING-FROM-SIDE FACTOR (SHADING FROM REVEAL) 
  60. C  SFTT  SHADING FROM TOP FACTOR (SHADING FROM OVERHANG AND REVEAL) 
  61. C 
  62. C 
  63. CMDK NRF
  64. CMDK ROOF
  65. CMDK NCR
  66. CMDK SIMA
  67. C 
  68.       REAL IDN,IDH,IDFH,ITH,IDHC,IDC,IDFHC,IDFC 
  69.      + ,IZERO,IDHBS 
  70.       CHARACTER *4 STM
  71.       DIMENSION AJ(6),DIFFUS(4),DIRECT(4),IDC(4),IDFC(4),NDY21(12),
  72.      + PS(12), QS(12),RS(12),SFST(4),SFTT(4),TJ(6)
  73. C 
  74.       DATA  RAD/57.29577/ 
  75.       DATA  TJ/-0.00885, 2.71235,-0.62062,-7.07329, 9.75995,-3.89922/ 
  76.       DATA  AJ/ 0.01154, 0.77674,-3.94657, 8.57881,-8.38135, 3.01188/ 
  77.       DATA  PS/1.14,1.06,1.06,1.06,.96,.96,.96,.95,.95,.95,1.14,1.14/ 
  78.       DATA  QS/.003,.012,.012,.012,.033,.033,.033,.030,.030,
  79.      $         .030,.003,.003/
  80.       DATA  RS/-.0082,-.0084,-.0084,-.0084,-.0106,-.0106,-.0106,
  81.      $         -.0108,-.0108,-.0108,-.0082,-.0082/
  82.       DATA  PI/3.14159/ 
  83. C ***** SOLAR CONSTANT, BTU/FT2-HR
  84.       DATA SC/428./ 
  85. C  NDY21 IS DAY OF YR AT 21ST OF EACH MONTH 
  86.       DATA NDY21/21,52,80,111,141,172,202,233,264,
  87.      +294,325,355/
  88. C 
  89.       IDBG=0
  90.       ITM=INT(TIME+1.001) 
  91. C ***** TIME = TIME OF DAY (0 - 24),HR
  92.       IF (TIME.GT.23.98) GO TO 9996 
  93. C  SET SUN INDICATOR FOR SUNSHINE 
  94.       ISUN=0
  95. C  ZERO OUTPUTS FOR NO SUN
  96.       ITH=0.
  97.       IDHC=0. 
  98.       SAZM=0. 
  99.       SALT=0. 
  100.       DO 10 I=1,4 
  101.       IDC(I)=0. 
  102.       IDFC(I)=0.
  103.       DIRECT(I)=0.
  104.       DIFFUS(I)=0.
  105.       SFST(I)=0.
  106.       SFTT(I)=0.
  107.    10 CONTINUE
  108.       DO 15 I=1,NRF 
  109.       IDR(I)=0. 
  110.       IDIFR(I)=0. 
  111.    15 CONTINUE
  112. C 
  113.       NDYR=NDYRI
  114. C  IF NDYRI <= 0, USE DAY OF YEAR AT 21ST DAY OF KM MONTH 
  115.       IF(NDYRI.EQ.-1)NDYR=NDY21(KM)
  116.       CALL ETIME (NDYR,STM,ET,TZN)
  117. C 
  118. C **** CALCULATE SOLAR FACTORS
  119. C ***** D = DECLINATION  (TRNSYS) 
  120. C ***** SEE "ALGORITHMS FOR BUILDING HEAT TRANSFER SUBROUTINES" 
  121. C *****   P.17 ASHRAE 1976
  122.       D=23.45*SIN(360.*(284.+NDYR)/(365.*RAD))/RAD
  123.       XIM=1.0 
  124.       DO 44 IXM=1,12
  125.       IF (NDYR.LE.NDY21(IXM))GO TO 46 
  126.    44 CONTINUE
  127.    46 XIM=FLOAT(KM)
  128.       ABC=COS(15.*(2.*XIM-1.)/RAD)
  129.       A=367.5+22.5*ABC
  130.       B=0.174-.032*ABC
  131.       C=.0965-.0385*ABC 
  132. C 
  133.       DNL=DNLAT/RAD 
  134. C ***** SUNRISE HOUR ANGLE (HPRM), DEGREES FROM SOLAR NOON
  135.       HPRM=ACOS(-TAN(DNL)*TAN(D)) 
  136.       HLIM=ABS(HPRM)-15./RAD
  137.       H=15.*(TIME-12.+TZN+ET-DST)-DLONG 
  138.       HRAD=H/RAD
  139.       IF(IDBG.NE.0)WRITE(60,500)ITM,TIME,HPRM,HLIM,H,HRAD
  140.       IF (ABS(HRAD).LT.ABS(HLIM)) GO TO 50
  141.       ISUN=1
  142.       GO TO 9996
  143. C *** CALCULATE DIRECTION COSINES OF SOLAR BEAM 
  144. C ***** Z = ZENITH ANGLE, ANGLE BETWEEN BEAM FROM SUN AND VERTICAL
  145. 50    COSZ=SIN(DNL)*SIN(D)+COS(DNL)*COS(D)*COS(HRAD)
  146.       COSW=COS(D)*SIN(HRAD) 
  147.       COSS=(1-COSZ**2-COSW**2)**.5
  148.       COSH=COS(HRAD)
  149.       TANDL=TAN(D)/TAN(DNL) 
  150.       ISGN=1
  151.       IF (COSH.LT.TANDL) ISGN=-1
  152.       COSS=ISGN*COSS
  153. C 
  154. C *** CALCULATE SOLAR ALTITUDE ANGLE
  155.       SALT=ASIN(COSZ) 
  156. C *** CALCULATE SOLAR AZIMUTH ANGLE 
  157.       IF (COSS.LT.0.) GO TO 52
  158.       SAZM=ASIN(COSW/COS(SALT)) 
  159.       GO TO 54
  160. 52    SAZM=PI-ASIN(COSW/COS(SALT))
  161. C 
  162. C *** CALCULATE DIRECT NORMAL,SKY DIFFUSE AND GROUND REFLECTED RADIATION
  163. C *** IDN IS DIRECT NORMAL SOLAR RADIATION ON HORIZONTAL
  164. C *** BS IS DIFFUSE SOLAR RADIATION ON HORIZONTAL SURFACE 
  165. C *** BG IS PORTION OF TOTAL SOLAR RADIATION REFLECTED TO 
  166. C ***              VERTICAL WALL
  167.    54 IF(ICC.GT.0)GO TO 56
  168. C ***** TRNSYS MANUAL (TYPE 16 UNIT)
  169.       ITH=SOLARH(ITM)
  170.       IF(ITH.EQ.1.1E10)THEN 
  171.          WRITE(60,504) 
  172.          STOP 'SOLR:SOLAR BAD, SEE NOTE ON OUTPUT'
  173.          ENDIF
  174.       IF(IDBG.NE.0)WRITE(60,503)IDAY,ITM,KM,ITH
  175.       IZERO=SC*COSZ*(1.+.033*COS(360.*NDYR/(365.*RAD))) 
  176.       XKT=ITH/IZERO 
  177.       RAT=1.0045+XKT*(0.04349+XKT*((-3.5227)+2.6313*XKT)) 
  178.       IF(XKT.LT.0.0) RAT=1.0
  179.       IF(XKT.GT.0.8) RAT=0.165
  180.       IDHC=ITH*(1.0-RAT)
  181.       GO TO 60
  182. 56    CLOUDC=SOLARH(ITM)
  183.       IDN=A*CLEAR*EXP(-B/COSZ)
  184.       BS=C*IDN/(CLEAR)**2 
  185. C      BG=REFLG(KM)*(BS+IDN*COSZ)
  186. C 
  187. C *** CALCULATE CLOUDY SKY RADIATION
  188.       X=SIN(SALT) 
  189.       Y1=.309-.137*X+.394*X**2
  190.       XKSOL=X/(C+X)+(PS(KM)-1.)/(1.-Y1) 
  191.       IDH=IDN*COSZ
  192.       IDFH=BS 
  193.       ITH=IDH+IDFH
  194.       IDHC=ITH*XKSOL*(1.-CLOUDC/10.)
  195. C 
  196. C 
  197. C    M= COMPASS DIRECTION NO. 
  198.    60 DO 220 M=1,4
  199. C 
  200. C 
  201. C *** CALCULATE CLOUDY SKY RADIATION FOR WALL 
  202.       CALL SHADE (M,SAZM,SALT,WROTA,SFS,SFT,WAZ)
  203.       SFST(M)=SFS 
  204.       SFTT(M)=SFT 
  205. C 
  206. C---- WAZ IS WALL AZIMUTH ANGLE FROM SUN POSITION TO HORIZ. PLANE 
  207. C     COSINC IS SAME AS THAT IN EQ.5B IN ASHRAE F27.3 1981
  208.       COSINC=COS(SALT)*COS(WAZ/RAD) 
  209.       CT=COSINC 
  210.       VAL = 1.
  211.       IF (CT.LE.0.) VAL=0.
  212.       IDC(M)=VAL*IDHC*CT/COSZ 
  213.          Y2=0.55+CT*(0.437+CT*0.313)
  214.          IF (CT.LE. -0.2) Y2=.45
  215.       IF (ICC.GT.0)GO TO 92 
  216.       IDFHC=ITH-IDHC
  217.       IDFC(M)= Y2*IDFHC+0.5*REFLG(KM)*ITH 
  218.       GO TO 94
  219.    92 CONTINUE
  220. C *** IDF = DIFFUSE RADIATION FOR CLOUDLESS SKY ON VERTICAL SURFACE 
  221. C      IDF=BS*Y2+BG/2. 
  222.       CCF=PS(KM)+QS(KM)*CLOUDC+RS(KM)*CLOUDC**2 
  223.       IDFHC=ITH*CCF-IDHC
  224.       IDHBS=COSZ*CLEAR**2/C 
  225.       IDFC(M)=(Y2+0.5*REFLG(KM)*(1.+IDHBS))*IDFHC 
  226. C *** IDC=DIRECT
  227. C *** IDFC=DIFFUSE
  228.    94 CONTINUE
  229. C 
  230. C     CALC INSTANTANEOUS HEAT TRANSMISSION THRU WINDOWS 
  231.       TDIR=0. 
  232.       TDIF=0. 
  233.       ADIR=0. 
  234.       ADIF=0. 
  235.       DO 219 K=1,6
  236.       J=K-1 
  237.       TDIR=TDIR+TJ(K)*CT**J 
  238.       TDIF=TDIF+2.*TJ(K)/(J+2)
  239.       ADIR=ADIR+AJ(K)*CT**J 
  240. 219   ADIF=ADIF+ 2.0*AJ(K)/(J+2)
  241.       DIRECT(M)=IDC(M)*(TDIR+.267*ADIR) 
  242.       IF(ICC.LE.0) THEN 
  243.           DIFFUS(M)=0.5*(IDFHC+REFLG(KM)*ITH)*(TDIF+0.267*ADIF) 
  244.       ELSE
  245.           DIFFUS(M)=0.5*(1.+REFLG(KM)*(1.+IDHBS))*(TDIF+.267*ADIF)*IDFHC
  246.       ENDIF 
  247.   220 CONTINUE
  248. C 
  249. C---- CALCULATE SOLAR LOADING ON ROOF 
  250. C 
  251.       DO 360 I=1,NSECTA 
  252.       M=IDEXPR(I) 
  253.       PA   =PAA   (I) 
  254. C 
  255. C *** DETERMINE SOLAR AZIMUTH FOR EACH ROOF SURFACE 
  256.       IF (M.EQ.1) RAZ=ABS(180.+SAZM*RAD-WROTA)
  257.       IF (M.EQ.2) RAZ=ABS( 90.+SAZM*RAD-WROTA)
  258.       IF (M.EQ.3) RAZ=ABS(     SAZM*RAD-WROTA)
  259.       IF (M.EQ.4) RAZ=ABS( 90.+WROTA-SAZM*RAD)
  260.       PARAD=PA/RAD
  261.       CSINC=COS(SALT)*COS(RAZ/RAD)*COS(PARAD)+
  262.      $       SIN(SALT)*SIN(PARAD) 
  263.       IF (CSINC.LE.0.) GO TO 346
  264.       IDR(I)=IDHC*CSINC/COSZ
  265.       GO TO 347 
  266. 346   IDR(I)=0. 
  267. 347   IDIFR(I)=IDFHC*((1.+SIN(PARAD))/2.) 
  268.       IF(IDBG.NE.0)THEN 
  269.       WRITE(60,502)I,M,PA,RAZ,CSINC,IDR(I),IDHC,IDIFR(I),IDFHC 
  270.           ENDIF 
  271. 360   CONTINUE
  272. 9996  CONTINUE
  273.           IF(IDBG.NE.0)THEN 
  274.       WRITE(60,501)ITH,IDHC,SAZM,SALT,IDC,IDFC,DIRECT,DIFFUS,SFST,SFTT 
  275.           ENDIF 
  276.       RETURN
  277.   500 FORMAT(1X,'SOLR: ITM,TIME,HPRM,HLIM,H,HRAD= ',I5,5G13.5)
  278.   501 FORMAT(1X,'SOLR OUTPUTS:ITH,IDHC,SAZM,SALT= ',4G13.5/ 
  279.      +' IDC= ',4G13.5/' IDFC= ',4G13.5/ 
  280.      +' DIRECT= ',4G13.5/' DIFFUS= ',4G13.5/
  281.      +' SFST= ',4G13.5/' SFTT= ',4G13.5)
  282.   502 FORMAT(1X,'I,M,PA,RAZ,CSINC= ',2I3,3G13.5/
  283.      +3X,'IDR,IDHC,IDIFR,IDFHC= ',4G13.5) 
  284.   503 FORMAT(1X,'SOLR:IDAY,ITM,KM,ITH= ',3I5,G13.5) 
  285.   504 FORMAT(1X,'SOLR:SOLAR BAD, CHECK WETHER DATA OR VALUE OF MONTH',
  286.      +' READ IN STRRUN')
  287.       END 
  288.       SUBROUTINE ETIME(NDYR,STM,ET,TZN) 
  289. C  CALC EQUATION OF TIME
  290. C      REAL LSTM(6)
  291.       CHARACTER *4 TMER,STM 
  292.       DIMENSION E(10),TMER(6),TZNS(6) 
  293.       DATA E/-4.319780295E+00 , -6.560560432E-03 , -1.768353820E-05 , 
  294.      +        1.880630945E-08 , -3.612378625E-12 , -1.243267535E-15 , 
  295.      +        6.119539396E-19 , -9.877736221E-23 ,  7.200722198E-27 , 
  296.      +       -2.009408139E-31/
  297. C 
  298. C *** INPUTS
  299. C     NDYR  DAY OF YEAR(NON-LEAP YEAR), 1-365 
  300. C     STM  TIME ZONE (EST,CST,MST,PST,YST,ANST) 
  301. C 
  302. C *** OUTPUTS 
  303. C     ET  EQN OF TIME, HR (SEE SOLAR ENERGY BY DUFFIE AND BECKMAN)
  304. C     TZN  TIME ZONE NO., 1-6 
  305.   
  306. C    EQN OF TIME VALUES ARE FOR THE 21ST DAY OF MONTH 
  307.       DATA TMER/'EST','CST','MST','PST','YST','AHST'/ 
  308. C      DATA LSTM/75.,90.,105.,120.,135.,150./
  309.       DATA TZNS/5.,6.,7.,8.,9.,10./ 
  310.       DO 10 I=1,6 
  311.         IF (STM.EQ.TMER(I)) GO TO 20
  312. 10      CONTINUE
  313.       WRITE(60,15)
  314. 15    FORMAT ('0ERROR IN INPUT FOR STANDARD TIME MERIDIAN') 
  315.       STOP 'ETIME:ERROR IN STM FOR STD TIME ZONE' 
  316. 20    CONTINUE
  317. C      LONGM=LSTM(I) 
  318. C  EQUA OF TIME IS ON P. 19 OF DUFFIE AND BECKMAN 
  319.       T=(NDYR-0.5)*24.
  320.       ET=E(1)+T*(E(2)+T*(E(3)+T*(E(4)+T*(E(5)+T*(E(6)+
  321.      +T*(E(7)+T*(E(8)+T*(E(9)+T*E(10))))))))) 
  322. C  ET IS IN MINUTES SO CONVERT TO HRS 
  323.       ET=ET/60. 
  324.       TZN=TZNS(I) 
  325.       RETURN
  326.       END 
  327.       SUBROUTINE SHADE (M,SAZM,SALT,WA,SFS,SFT,WAZ) 
  328. C  CALCULATE WINDOW SHADING FACTORS 
  329.       DATA RAD/57.29577/
  330.   
  331. C 
  332.       SAZ=SAZM*RAD
  333.       IF (M.EQ.1) WAZ=ABS(180.+SAZ-WA)
  334.       IF (M.EQ.2) WAZ=ABS( 90.+SAZ-WA)
  335.       IF (M.EQ.3) WAZ=ABS(     SAZ-WA)
  336.       IF (M.EQ.4) WAZ=ABS( 90.+WA-SAZ)
  337.       IF ((SALT.EQ. 0.0 .AND. (SAZM.EQ. 0.0)))GO TO 20
  338.       IF (WAZ.GE.90.) GO TO 10
  339.       WAZRAD=WAZ/RAD
  340.       SFS=TAN(WAZRAD) 
  341.       SFT=TAN(SALT)/COS(WAZRAD) 
  342.       GO TO 20
  343. 10    SFS=0.0 
  344.       SFT=0.0 
  345. 20    RETURN
  346.       END 
  347.