home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-387-Vol-3of3.iso / b / butl.zip / BOXMAKER.BAS < prev    next >
BASIC Source File  |  1993-03-01  |  1KB  |  25 lines
  1. 100 ' BOXMAKER.BAS - Paul Somerson 
  2. 110 ' Creates BOX.BAT batch file with custom boxes
  3. 120 ' (c) 1987 Ziff Communications Co.
  4. 130 DEF FNST$(Y)=RIGHT$(STR$(Y),LEN(STR$(Y))-SGN(Y))
  5. 140 KEY OFF:COLOR 2,0:CLS:OPEN "BOX.BAT" FOR OUTPUT AS #1   
  6. 150 PRINT "Single or Double line box (S/D)? "
  7. 160 L$=INKEY$:IF L$="" THEN 160
  8. 170 B=INSTR("SsDd",L$):IF B=0 THEN BEEP:GOTO 150            
  9. 180 IF B<3 THEN P=218:Q=191:R=192:S=217:T=196:U=179:GOTO 200
  10. 190 P=201:Q=187:R=200:S=188:T=205:U=186                     
  11. 200 INPUT "How many rows high (3-23):       ",H$            
  12. 210 H=VAL(H$):IF H<3 OR H>23 THEN BEEP:GOTO 200             
  13. 220 INPUT "How many columns wide (3-79):    ",W$            
  14. 230 W=VAL(W$):IF W<3 OR W>79 THEN BEEP:GOTO 220             
  15. 240 PRINT "Indented how many columns (1-";FNST$(80-W);      
  16. 250 INPUT "): ",C$                                          
  17. 260 C=VAL(C$):IF C<1 OR C>80-W THEN BEEP:GOTO 240           
  18. 270 PRINT #1,"ECHO OFF"                                     
  19. 280 PRINT #1,"ECHO";SPC(C);CHR$(P);STRING$(W-2,T);CHR$(Q)   
  20. 290 FOR A=1 TO H-2                                          
  21. 300 PRINT #1,"ECHO";SPC(C);CHR$(U);SPC(W-2);CHR$(U):NEXT    
  22. 310 PRINT #1,"ECHO";SPC(C);CHR$(R);STRING$(W-2,T);CHR$(S)   
  23. 320 CLOSE:PRINT "Now press any key, then type:  BOX"          
  24. 330 WHILE INKEY$="":WEND:SYSTEM                             
  25.