home *** CD-ROM | disk | FTP | other *** search
/ The World of Computer Software / World_Of_Computer_Software-02-386-Vol-2of3.iso / 7 / 7dev.zip / DEV.ASM next >
Assembly Source File  |  1986-06-19  |  6KB  |  245 lines
  1.         name    dev
  2.         page    60,132
  3.         title   'DEV --- Report installed device drivers'
  4.  
  5. ; DEV --- a utility to report device header information for
  6. ;         all installed device drivers
  7. ; 
  8. ; version 1.0   December 12, 1984
  9. ; Copyright (c) 1984 by Ray Duncan
  10. ;
  11. ; Requires PC-DOS or MS-DOS 2.0 or greater.
  12. ;
  13. ; WARNING: this utility uses an undocumented field in the
  14. ; file control block.
  15. ;
  16. ; Used in the form:
  17. ;
  18. ;     A>DEV 
  19. ;
  20. ; To assemble, link, and convert this program into 
  21. ; an EXE file, follow these steps:
  22. ;
  23. ;    C>MASM DEV;
  24. ;     C>LINK DEV;
  25. ;
  26.  
  27. cr      equ     0dh             ;ASCII carriage return
  28. lf      equ     0ah             ;ASCII line feed
  29. blank    equ    20h        ;ASCII space code
  30. eom    equ    '$'        ;end of string marker
  31.  
  32.  
  33. cseg    segment    para public 'CODE'
  34.  
  35.     assume    cs:cseg,ds:data,es:data,ss:stack
  36.  
  37.  
  38. dev     proc    far             ;entry point from PC-DOS
  39.  
  40.         push    ds              ;save DS:0000 for final
  41.         xor     ax,ax           ;return to PC-DOS
  42.         push    ax
  43.         mov     ax,data         ;make our data segment
  44.     mov    ds,ax        ;addressable via DS and ES.
  45.     mov     es,ax 
  46.         mov     ah,30h        ;check version of PC-DOS.    
  47.         int     21h
  48.         cmp     al,2
  49.         jae     dev1        ;proceed, DOS 2.0 or greater.
  50.         mov     dx,offset msg2  ;DOS 1.x --- print error message.
  51.     jmp    dev6
  52.  
  53. dev1:    mov    cx,ax        ;save DOS version number.
  54.     mov    ah,15        ;now try and open the "NUL" device.
  55.     mov    dx,offset nulfcb
  56.     int    21h
  57.     or    al,al        ;opened successfully?
  58.     jz    dev2        ;yes, jump.
  59.     mov    dx,offset msg1    ;no, print error msg and exit.
  60.     jmp    dev6
  61.  
  62. dev2:                ;Pick up double pointer to device 
  63.                 ;driver chain out of reserved
  64.                 ;area in fcb.  This area is mapped
  65.                 ;differently in DOS 2.x and DOS 3.x.
  66.     cmp    cl,2        ;is this DOS 2.x?
  67.     ja    dev3        ;no, jump.
  68.     mov    bx,word ptr nulfcb+25
  69.     mov    es,word ptr nulfcb+27
  70.     jmp    dev4
  71.  
  72. dev3:                ;come here if DOS 3.0 or greater.
  73.     mov    bx,word ptr nulfcb+26
  74.     mov    es,word ptr nulfcb+28
  75.  
  76. dev4:    call    header        ;print sign-on message and 
  77.                 ;column headings.
  78.  
  79. dev5:                ;trace through the device chain
  80.  
  81.     call    prdev        ;print device header information
  82.                 ;for driver pointed to by ES:BX.
  83.                 ;pick up addr of next header.
  84.     les    bx,dword ptr es:[bx]
  85.     cmp    bx,-1        ;found last one yet?
  86.     jne    dev5        ;no, try next.
  87.     
  88.           mov    dx,offset msg3    ;yes, print "end of device chain".
  89.  
  90. dev6:     mov    ah,9        ;print the string whose address
  91.     int    21h        ;is in DX.
  92.     ret            ;then return to DOS.
  93.  
  94. dev       endp
  95.  
  96.  
  97. header    proc    near        ;print out headings for device
  98.     mov    dx,offset hdr    ;driver information.
  99.     mov    ah,9
  100.     int    21h
  101.     ret
  102. header    endp
  103.  
  104.  
  105. prdev    proc    near        ;print out device driver info.
  106.                 ;ES:BX is pointer to device header,
  107.                 ;which must be preserved.
  108.     mov    ax,es        ;convert segment of device header
  109.     mov    di,offset inf1
  110.     call    hexasc
  111.     mov    ax,bx        ;convert offset of device header.
  112.     mov    di,offset inf2
  113.     call    hexasc
  114.     mov    ax,es:[bx+4]    ;get attribute word, save a 
  115.     push    ax        ;copy of it, then convert it.
  116.     mov    di,offset inf3
  117.     call    hexasc
  118.     mov    ax,es:[bx+6]    ;convert ptr to device strategy.
  119.     mov    di,offset inf4
  120.     call    hexasc
  121.     mov    ax,es:[bx+8]    ;convert ptr to device int handler.
  122.     mov    di,offset inf5
  123.     call    hexasc
  124.  
  125.                 ;if not char device, clear out name
  126.                 ;field and set number of units.
  127.     pop    ax        ;get back attribute word.
  128.     test    ax,08000h    ;is bit 15 = 1 ?
  129.     jnz    prdev7        ;yes, it's character dev, jump.
  130.                           ;no, it's block device.
  131.                 ;set flag to skip device name.
  132.     mov     byte ptr inf8,eom
  133.     mov    al,es:[bx+10]    ;pick up number of units.
  134.     aam            ;convert to ASCII decimal and
  135.     add    ax,'00'        ;store into output string.
  136.     mov    byte ptr inf7+1,al
  137.     mov    byte ptr inf7,ah
  138.                 ;set type = B for Block
  139.     mov    byte ptr inf6,'B'    
  140.     jmp    prdev9
  141.  
  142. prdev7:                ;if char device, move its 8-character
  143.                 ;name into the output string.
  144.     xor    si,si
  145. prdev8:    mov    al,es:[si+bx+10]
  146.     mov    [si+inf8],al
  147.     inc    si
  148.     cmp    si,8
  149.     jne    prdev8
  150.                 ;remove # of units field.
  151.     mov    word ptr inf7,'  '
  152.                 ;set type = C for Character.
  153.     mov    byte ptr inf6,'C'
  154.  
  155. prdev9: mov    dx,offset inf    ;now print device information
  156.     mov    ah,9        ;and exit.
  157.     int    21h
  158.     ret
  159. prdev    endp
  160.  
  161. hexasc    proc    near        ;convert binary word to hex ASCII.
  162.                 ;call with AX=binary value
  163.                 ;          DI=addr to store string 
  164.                 ;returns AX, CX, DI destroyed.
  165.     push    ax        ;save copy of original value.
  166.     mov    al,ah
  167.     call    btoa        ;convert upper byte.
  168.     add    di,2        ;increment output address.
  169.     pop    ax
  170.     call    btoa        ;convert lower byte.
  171.     ret            ;return to caller.
  172. hexasc    endp
  173.  
  174. btoa    proc    near        ;convert binary byte to hex ASCII.
  175.                 ;call with AL=binary value 
  176.                 ;          DI=addr to store string
  177.                 ;returns AX, CX destroyed.
  178.     mov    ah,al        ;save lower nibble.
  179.     mov    cx,4        ;shift right 4 positions
  180.     shr    al,cl        ;to get upper nibble.
  181.     call    ascii        ;convert 4 bits to ASCII equivalent
  182.     mov    [di],al        ;store into output string.
  183.     mov    al,ah        ;get back lower nibble.
  184.     and    al,0fh
  185.     call    ascii        ;convert 4 bits to ASCII
  186.     mov     [di+1],al    ;and store into output string.
  187.     ret            ;back to caller.
  188. btoa    endp
  189.  
  190. ascii    proc    near        ;convert 4 lower bits of AL
  191.     add    al,'0'        ;into the equivalent ASCII char.
  192.     cmp    al,'9'        ;in the range {0...9,A...F}
  193.     jle    ascii2        ;and return char. in AL.
  194.     add    al,'A'-'9'-1    ;"fudge factor" for range A-F.
  195. ascii2:    ret            ;return to caller.
  196. ascii    endp
  197.  
  198. cseg    ends
  199.  
  200.  
  201. data    segment para public 'DATA'
  202.  
  203. msg1    db    cr,lf
  204.     db    'Failed to open NUL device.'
  205.     db    cr,lf,eom
  206.  
  207. msg2    db      cr,lf
  208.         db      'Requires DOS version 2 or greater.'
  209.         db      cr,lf,eom
  210.  
  211. msg3    db    cr,lf
  212.     db    'End of device chain.'
  213.     db    cr,lf,eom
  214.  
  215. hdr    db    cr,lf
  216.     db    'Addr      Attr '
  217.     db    'Str  Int   Type  Units  Name   '
  218.     db    eom
  219.  
  220.  
  221. inf     db    cr,lf
  222. inf1    db    'XXXX:'        ;seg device header
  223. inf2    db    'XXXX '        ;offs device header
  224. inf3    db    'XXXX '        ;attribute
  225. inf4    db    'XXXX '        ;strategy
  226. inf5    db    'XXXX   '    ;interrupt handler
  227. inf6    db    'X     '    ;type (block or char)
  228. inf7    db    'XX    '    ;units (if block device)
  229. inf8    db    '         '    ;name  (if char device)
  230.     db    eom
  231.  
  232.                 ;fcb to open NUL device
  233. nulfcb    db    0        ;drive
  234.     db    'NUL'        ;name of NUL device
  235.     db    8 dup (' ')
  236.     db    25 dup (0)
  237. data    ends    
  238.  
  239.  
  240. stack   segment para stack 'STACK'
  241.         db      64 dup (?)
  242. stack   ends
  243.  
  244.         end     dev
  245.