home *** CD-ROM | disk | FTP | other *** search
/ World of A1200 / World_Of_A1200.iso / programs / develop / hc11dev / talkers / talkera8.asc < prev    next >
Text File  |  1995-02-27  |  8KB  |  210 lines
  1. *************************** TALKERA8.ASC 9/2/89 **************************
  2. *   Written by R.Soja, Motorola, East Kilbride                           *
  3. *   Motorola Copyright 1988                                              *
  4. *   MCU resident, Interrupt driven Communication routines for 68HC11     *
  5. *   monitor. Provides low level memory and stack read/write operations.  *
  6. *                                                                        *
  7. *   This talker DOES NOT use XIRQ
  8. *   -----------------------------
  9. *                                                                        *
  10. *   Works with Host user interface program PCBUG11.EXE.                  *
  11. * N.B. TALKERA8.ASC is designed to be downloaded through 68HC11A8 type   *
  12. *      bootloader, and communicate with host through SCI.                *
  13. *      This bootloader loads 256 bytes of user code before terminating.  *
  14. *
  15. * CONSTANTS
  16. TALKBASE  equ $0000
  17. BOOTVECT  equ $00C4       Start of bootstrap vector jump table.
  18. STACK     equ $00EB
  19. REGBASE   equ $1000
  20. *
  21. JSCI      equ $00C4
  22. JXIRQ     equ $00F1
  23. JSWI      equ $00F4
  24. JILLOP    equ $00F7
  25. JCOP      equ $00FA
  26. uS500     equ 5000/35     500uS delay with DEY/BNE loop
  27. JMPEXT    equ $7E         Mnemonic for jump extended instruction
  28. BRKCODE   equ $4A         Break point signal code to host.
  29. BRKACK    equ $B5         Break point acknowledge code from host.
  30. *
  31. * REGISTERS
  32. BAUD      equ $2B
  33. SCCR1     equ $2C
  34. SCCR2     equ $2D
  35. SCSR      equ $2E
  36. SCDR      equ $2F
  37. *
  38. RDRF      equ $20
  39. TDRE      equ $80
  40. *
  41. * PROGRAM
  42.           org TALKBASE
  43. TLKRSTART EQU *
  44.           LDS #STACK
  45.           LDX #REGBASE
  46.           CLR SCCR1,X
  47.           LDD #$302C
  48.           STAA BAUD,X   Initialise SCI to 9600 baud, no parity
  49.           STAB SCCR2,X  and enable SCI tx & rx.
  50.           LDAA #$40     Enable STOP, and I bit interrupts, disable XIRQ.
  51.           TAP
  52. *
  53. IDLE      JMP IDLE      Now hang around for SCI interrupt from host.
  54. * A RESET from host changes above jump destination to start of user code.
  55. *
  56. SCISRV    EQU *             On detecting interrupt,
  57.           LDAA SCSR+REGBASE assume receiver caused it.
  58.           ANDA #RDRF
  59.           BEQ SCISRV        otherwise program will hang up
  60. *
  61. RXSRV     EQU *             Talker code processes received data.
  62.           LDAA SCDR+REGBASE Read command byte, & echo it as acknowledge
  63.           BSR OUTSCI        to host.
  64.           BMI INH1      If command bit 7 set, then process inherent command
  65.           BSR INSCI     else read byte count from host into ACCB.(0=256)
  66.           XGDX          Save command and byte count.
  67.           BSR INSCI     Read high address byte
  68.           TBA           into ACCA
  69.           BSR INSCI     then low address byte into ACCB
  70.           XGDX          Restore command in ACCA,count in ACCB,address in X
  71.           CMPA #$01
  72.           BNE RXSRV1    If command is memory read, then
  73. *
  74. TREADMEM  EQU *         REPEAT
  75.           LDAA ,X       read required address
  76.           BSR OUTSCI    send it to host
  77.           TBA           (save byte count)
  78.           BSR INSCI     and wait for acknowledge
  79.           TAB           (restore byte count)
  80.           INX           Increment address
  81.           DECB          Decrement byte count
  82.           BNE TREADMEM  UNTIL all done
  83.           RTI           and return to idle loop or user code.
  84. *
  85. RXSRV1    EQU *
  86.           CMPA #$41
  87.           BNE RXSRVEX    If command is memory write then
  88. *
  89.           TBA           move byte count to ACCA
  90. TWRITMEM  EQU *         REPEAT
  91.           BSR INSCI     Read next byte from host into ACCB,
  92.           STAB ,X       and store at required address.
  93.           LDY #$0001    Set up wait loop to allow for 28C64 prog time, where
  94. WAITPOLL  DEY           Y operand must be manually set to $0359 (3mS)
  95.           BNE WAITPOLL
  96.           LDAB ,X       Read stored byte and
  97.           STAB SCDR+REGBASE   echo it back to host,
  98.           INX
  99.           DECA          Decrement byte count
  100.           BNE TWRITMEM  UNTIL all done
  101. RXSRVEX   EQU *         and return
  102. NULLSRV   RTI
  103. *
  104. INSCI     EQU *
  105.           LDAB SCSR+REGBASE   Wait for RDRF=1
  106.           BITB #$0A           If break detected then
  107.           BNE TLKRSTART       restart talker
  108.           ANDB #RDRF
  109.           BEQ INSCI
  110.           LDAB SCDR+REGBASE   then read data received from host
  111.           RTS                 and return with data in ACCB
  112. *
  113. OUTSCI    EQU *               Only register Y modified.
  114.           XGDY                Enter with data to send in ACCA.
  115. OUTSCI1   LDAA SCSR+REGBASE
  116.           BPL OUTSCI1         MS bit is TDRE flag
  117.           XGDY
  118.           STAA SCDR+REGBASE   Important - Updates CCR!
  119.           RTS
  120. *
  121. INH1      EQU *
  122.           CMPA #$81     If command is read MCU registers then
  123.           BNE INH2
  124. *
  125. INH1A     TSX           Move stack pointer to X
  126.           XGDX          then to ACCD
  127.           BSR OUTSCI    send stack pointer to host (high byte first)
  128.           TBA
  129.           BSR OUTSCI    then low byte
  130.           TSX           Restore X (=stack pointer)
  131.           LDAB #9       then return 9 bytes on stack
  132.           BRA TREADMEM  i.e. CCR,ACCB,ACCA,IXH,IXL,IYH,IYL,PCH,PCL
  133. *
  134. INH2      EQU *
  135.           CMPA #$C1     If command is write MCU registers then
  136.           BNE SWISRV1
  137. *
  138.           BSR INSCI     get stack pointer from host (High byte first)
  139.           TBA
  140.           BSR INSCI
  141.           XGDX          Move to X reg
  142.           TXS           and copy to stack pointer
  143.           LDAA #9       Then put next 9 bytes from host on to stack
  144.           BRA TWRITMEM
  145. *
  146. SWISRV    EQU *         Breakpoints generated by host-placed SWI instruction.
  147.           LDAA #BRKCODE Force host to process breakpoints
  148.           BSR OUTSCI    by sending it the break signal
  149. SWIIDLE   CLI
  150.           BRA SWIIDLE   Wait for response from host. (Ibit=0,Xbit=1)
  151. *
  152. SWISRV1   EQU *
  153.           CMPA #BRKACK  If host has acknowledged breakpoint state then
  154.           BNE RXSRVEX
  155.           TSX           move stack pointer to SWI stack frame and
  156.           LDAB #9
  157.           ABX
  158.           TXS
  159.           LDD 7,X       Send user code breakpoint return address to host
  160.           BSR OUTSCI    (high byte first)
  161.           TBA
  162.           BSR OUTSCI    (low byte next)
  163.           LDD #IDLE     force idle loop on return from breakpoint processing
  164.           STD 7,X
  165.           BRA INH1A     but first return all MCU registers to host
  166. *
  167.           ORG BOOTVECT  Boot vector jump table set up only during bootstrap.
  168.           FCB JMPEXT    SCI
  169.           FDB SCISRV
  170.           FCB JMPEXT    SPI  (Unused vectors point to RTI)
  171.           FDB NULLSRV
  172.           FCB JMPEXT    Pulse acc. Input Edge
  173.           FDB NULLSRV
  174.           FCB JMPEXT    Pulse acc. Overflow
  175.           FDB NULLSRV
  176.           FCB JMPEXT    Timer Overflow
  177.           FDB NULLSRV
  178.           FCB JMPEXT    OC5
  179.           FDB NULLSRV
  180.           FCB JMPEXT    OC4
  181.           FDB NULLSRV
  182.           FCB JMPEXT    OC3
  183.           FDB NULLSRV
  184.           FCB JMPEXT    OC2
  185.           FDB NULLSRV
  186.           FCB JMPEXT    OC1
  187.           FDB NULLSRV
  188.           FCB JMPEXT    IC3
  189.           FDB NULLSRV
  190.           FCB JMPEXT    IC2
  191.           FDB NULLSRV
  192.           FCB JMPEXT    IC1
  193.           FDB NULLSRV
  194.           FCB JMPEXT    Real Time Intr
  195.           FDB NULLSRV
  196.           FCB JMPEXT    IRQ
  197.           FDB NULLSRV
  198.           FCB JMPEXT    XIRQ   SCI RX line must be connected to XIRQ input.
  199.           FDB NULLSRV
  200.           FCB JMPEXT    SWI    N.B. Changed by monitor Break point and Trace !
  201.           FDB NULLSRV
  202.           FCB JMPEXT    ILLOP
  203.           FDB TLKRSTART
  204.           FCB JMPEXT    COP Fail
  205.           FDB NULLSRV
  206.           FCB JMPEXT    Clock Monitor N.B. Changed by monitor Reset operation !
  207.           FDB NULLSRV
  208. *
  209.           END
  210.