home *** CD-ROM | disk | FTP | other *** search
/ World of A1200 / World_Of_A1200.iso / programs / communic / mosaic1.2 / startmosaic < prev    next >
Text File  |  1995-02-27  |  3KB  |  130 lines
  1. .bra {
  2. .ket }
  3.  
  4. FailAt 25
  5.  
  6. ;
  7. ; $VER: StartMosaic 1.1 (23.6.94)
  8. ;
  9. ; Starter for AMosaic
  10. ;
  11. ; (C) 1994 by Bernhard Möllemann
  12. ;
  13. ; You may use it for any purpose,
  14. ; but this Copyright notice must be included and left intact
  15. ;
  16.  
  17. ; make sure we have the config
  18.  
  19. If NOT EXISTS ENV:Mosaic
  20.   MakeDir ENV:Mosaic
  21.   Copy ENVARC/Mosaic ENV:Mosaic CLONE QUIET
  22.   Version >NIL: exec.library 39
  23.   If WARN
  24.     Copy ENVARC/Mosaic/mailcap2.x ENV:Mosaic/mailcap CLONE QUIET
  25.   EndIf
  26. Else
  27.   SetEnv Mosaic/HomeDocument file://localhost/:index.html ; mosaic seems to ignore Set
  28. EndIf
  29.  
  30. ; adjust image cache on small Amiga
  31.  
  32. Avail TOTAL >ENV:__freespace
  33. If NOT VAL ${__freespace} GT 1000000
  34.   SetEnv Mosaic/ImageCacheSize 200
  35. EndIf
  36. Delete >NIL: ENV:__freespace
  37.  
  38. ; on 68000/10 delay the image loads
  39.  
  40. CPU >NIL: CHECK 68020
  41. If WARN
  42.   SetEnv Mosaic/DelayImageLoads true
  43. EndIf
  44.  
  45. ; set initial window position
  46.  
  47. If NOT EXISTS ENV:MUI/AMOSAIC.1.wini
  48.   If NOT EXISTS ENV:MUI
  49.     MakeDir ENV:MUI
  50.   EndIf
  51.   Copy ENVARC/MUI/AMOSAIC.1.wini ENV:MUI CLONE QUIET
  52. EndIf
  53.  
  54. ; add some settings
  55.  
  56. ; IconX does not copy Workbenchs path, so we have to handcraft a minimal path
  57. ; "${Mosaic/SetPath}" is a hook for you!
  58. If NOT "${Mosaic/SetPath}" EQ "*${Mosaic/SetPath}"
  59.   Execute "${Mosaic/SetPath}"
  60. Else
  61.   Path :C Rexx: S:
  62.   If EXISTS SYS:Rexxc
  63.     Path SYS:Rexxc
  64.   EndIf
  65.   If EXISTS SYS:System
  66.     Path SYS:System
  67.   EndIf
  68.   If EXISTS SYS:Utilities
  69.     Path SYS:Utilities
  70.   EndIf
  71.   If EXISTS SYS:Tools
  72.     Path SYS:Tools
  73.   EndIf
  74.   If EXISTS SYS:WBStartup
  75.     Path SYS:WBStartup
  76.   EndIf
  77.   If EXISTS SYS:Tools/Commodities
  78.     Path SYS:Tools/Commodities
  79.   EndIf
  80. EndIf
  81.  
  82. CD :HTML            ; we must start one level below the root
  83. Stack 8192
  84.  
  85. ;
  86. ; Try to find the right Mosaic version for yor System
  87. ;
  88.  
  89. ; ${Moasic/Binary} is a hook in case of the script guesses the wrong Version
  90. ; or an update arrives before Meeting-Pearls Volume 2 is released 8-)
  91.  
  92. If NOT "${Mosaic/Binary}" EQ "*${Mosaic/Binary}"
  93.   "${Mosaic/Binary}"
  94.   Skip MosaicDone
  95. EndIf
  96.  
  97. ; check for AmiTCP
  98. ; Note, that Mosaic 1.2 wants AmiTCP 3.0beta
  99. ; I try to ensure this with the check or the usergroup.library
  100.  
  101. Status >NIL: COMMAND=AmiTCP:bin/inetd
  102. If NOT WARN
  103.   Version >NIL: AmiTCP:libs/usergroup.library 4
  104.   If NOT WARN
  105.     :Installed_Progs/comm/Mosaic1.2/Mosaic-AmiTCP
  106.     Skip MosaicDone
  107.   EndIf
  108. EndIf
  109.  
  110. ; check for AS225
  111.  
  112. Status >NIL: COMMAND=INet:bin/inetd
  113. If NOT Warn
  114.   :Installed_Progs/comm/Mosaic1.2/Mosaic-AS225
  115.   Skip MosaicDone
  116. EndIf
  117.  
  118. ; else use plain version
  119.  
  120. :Installed_Progs/comm/Mosaic1.2/Mosaic-NoNet
  121.  
  122.  
  123. LAB MosaicDone
  124.  
  125. ; clean up
  126.  
  127. rx >NIL: "if GetClip('__Mosaic_started_DT2')='TRUE' then do ; Address DELITRACKER QUIT; Call SetClip('__Mosaic_started_DT2',''); end;"
  128.  
  129. EndCLI
  130.