home *** CD-ROM | disk | FTP | other *** search
/ Amiga Developer CD 2.1 / Amiga Developer CD v2.1.iso / Extras / Development / RKM_Companion_v2.04 / Clipboard / hookface.a < prev    next >
Encoding:
Text File  |  1999-10-27  |  4.0 KB  |  117 lines
  1. *
  2. * Copyright (c) 1992-1999 Amiga, Inc.
  3. * 
  4. * This example is provided in electronic form by Amiga, Inc. for 
  5. * use with the "Amiga ROM Kernel Reference Manual: Devices", 3rd Edition, 
  6. * published by Addison-Wesley (ISBN 0-201-56775-X).
  7. * 
  8. * The "Amiga ROM Kernel Reference Manual: Devices" contains additional 
  9. * information on the correct usage of the techniques and operating system 
  10. * functions presented in these examples.  The source and executable code 
  11. * of these examples may only be distributed in free electronic form, via 
  12. * bulletin board or as part of a fully non-commercial and freely 
  13. * redistributable diskette.  Both the source and executable code (including 
  14. * comments) must be included, without modification, in any copy.  This 
  15. * example may not be published in printed form or distributed with any
  16. * commercial product.  However, the programming techniques and support
  17. * routines set forth in these examples may be used in the development
  18. * of original executable software products for Amiga computers.
  19. * 
  20. * All other rights reserved.
  21. * 
  22. * This example is provided "as-is" and is subject to change; no
  23. * warranties are made.  All use is at your own risk. No liability or
  24. * responsibility is assumed.
  25. *
  26. *
  27. ****************************************************************************
  28. *
  29. *        Hookface.asm
  30. *        assembly routines for Chtest
  31. *
  32. *        Assemble with Adapt  hx68 hookface.a to hookface.o
  33. *
  34. *        Link with Changehook_Test.o as shown in Changehook_Test.c header
  35. *
  36. ****************************************************************************
  37. *
  38. *       CSECT   hookface                 ;SAS/Lattice ASM command needs this
  39. *
  40. *       INCDIR  'include:'               ;HX68 assembler needs this
  41.  
  42.     section    text,code
  43.  
  44.         INCLUDE 'exec/types.i'
  45.         INCLUDE 'utility/hooks.i'
  46.         xdef    _callHook
  47.         xdef    _callHookPkt
  48.         xdef    _hookEntry
  49.         xdef    _stubReturn
  50.  
  51. ***************************************************************************
  52. * new hook standard
  53. * use struct Hook (with minnode at the top)
  54. *
  55. * *** register calling convention: ***
  56. *       A0 - pointer to hook itself
  57. *       A1 - pointer to parameter packed ("message")
  58. *       A2 - Hook specific address data ("object," e.g, gadget )
  59. *
  60. * ***  C conventions: ***
  61. * Note that parameters are in unusual register order: a0, a2, a1.
  62. * This is to provide a performance boost for assembly language
  63. * programming (the object in a2 is most frequently untouched).
  64. * It is also no problem in "register direct" C function parameters.
  65. *
  66. * calling through a hook
  67. *       callHook( hook, object, msgid, p1, p2, ... );
  68. *       callHookPkt( hook, object, msgpkt );
  69. *
  70. * using a C function:   CFunction( hook, object, message );
  71. *       hook.h_Entry = hookEntry;
  72. *       hook.h_SubEntry = CFunction;
  73. ****************************************************************************
  74.  
  75. * C calling hook interface for prepared message packet
  76. _callHookPkt:
  77.         movem.l a2/a6,-(sp)     ; protect
  78.         move.l  12(sp),a0       ; hook
  79.         move.l  16(sp),a2       ; object
  80.         move.l  20(sp),a1       ; message
  81.         ; ------ now have registers ready, invoke function
  82.         pea.l   hreturn(pc)
  83.         move.l  h_Entry(a0),-(sp)       ; old rts-jump trick
  84.         rts
  85. hreturn:
  86.         movem.l (sp)+,a2/a6
  87.         rts
  88.  
  89. * C calling hook interface for "varargs message packet"
  90. _callHook:
  91.         movem.l a2/a6,-(sp)     ; protect
  92.         move.l  12(sp),a0       ; hook
  93.         move.l  16(sp),a2       ; object
  94.         lea.l   20(sp),a1       ; message
  95.         ; ------ now have registers ready, invoke function
  96.         pea.l   hpreturn(pc)
  97.         move.l  h_Entry(a0),-(sp)       ; old rts-jump trick
  98.         rts
  99. hpreturn:
  100.         movem.l (sp)+,a2/a6
  101.         rts
  102.  
  103. * entry interface for C code (large-code, stack parameters)
  104. _hookEntry:
  105.         move.l  a1,-(sp)
  106.         move.l  a2,-(sp)
  107.         move.l  a0,-(sp)
  108.         move.l  h_SubEntry(a0),a0       ; C entry point
  109.         jsr     (a0)
  110.         lea     12(sp),sp
  111. _stubReturn:
  112.         rts
  113. *
  114. *                                        ;SAS/Lattice ASM command needs this
  115.         END
  116.  
  117.