home *** CD-ROM | disk | FTP | other *** search
/ Visual Basic Graphics Programming (2nd Edition) / Visual Basic Graphics Programming 2nd Edition.iso / OldSrc / CH5 / SRC / TRCONFIG.CLS < prev    next >
Encoding:
Text File  |  1996-02-28  |  11.0 KB  |  330 lines
  1. VERSION 1.0 CLASS
  2. BEGIN
  3.   MultiUse = -1  'True
  4. END
  5. Attribute VB_Name = "RobotConfig"
  6. Attribute VB_Creatable = False
  7. Attribute VB_Exposed = False
  8. ' ************************************************
  9. ' A robot configuration.
  10. ' ************************************************
  11. Option Explicit
  12.  
  13. Public Cx As Integer    ' Location of top of head.
  14. Public Cy As Integer
  15. Public LShoulderAngle As Single
  16. Public RShoulderAngle As Single
  17. Public LElbowAngle As Single
  18. Public RElbowAngle As Single
  19. Public LHipAngle As Single
  20. Public RHipAngle As Single
  21. Public LKneeAngle As Single
  22. Public RKneeAngle As Single
  23. ' ************************************************
  24. ' Fill in this configuration's parameters by
  25. ' copying from another.
  26. ' ************************************************
  27. Public Sub CopyFrame(from_me As RobotConfig)
  28.     With from_me
  29.         Cx = .Cx
  30.         Cy = .Cy
  31.         LShoulderAngle = .LShoulderAngle
  32.         RShoulderAngle = .RShoulderAngle
  33.         LElbowAngle = .LElbowAngle
  34.         RElbowAngle = .RElbowAngle
  35.         LHipAngle = .LHipAngle
  36.         RHipAngle = .RHipAngle
  37.         LKneeAngle = .LKneeAngle
  38.         RKneeAngle = .RKneeAngle
  39.     End With
  40. End Sub
  41.  
  42.  
  43. ' ************************************************
  44. ' Return the position of part of the robot.
  45. ' ************************************************
  46. Public Sub Position(part As Integer, x As Integer, y As Integer)
  47.     Select Case part
  48.         Case PART_HEAD
  49.             x = Cx
  50.             y = Cy
  51.         Case PART_NECK
  52.             x = Cx
  53.             y = Cy + 2 * HEAD_RAD
  54.         Case PART_SHOULDERS
  55.             x = Cx
  56.             y = Cy + 2 * HEAD_RAD + NECK_LEN
  57.         Case PART_LELBOW
  58.             x = Cx + _
  59.                 UARM_LEN * Cos(LShoulderAngle)
  60.             y = Cy + 2 * HEAD_RAD + NECK_LEN - _
  61.                 UARM_LEN * Sin(LShoulderAngle)
  62.         Case PART_RELBOW
  63.             x = Cx + _
  64.                 UARM_LEN * Cos(RShoulderAngle)
  65.             y = Cy + 2 * HEAD_RAD + NECK_LEN - _
  66.                 UARM_LEN * Sin(RShoulderAngle)
  67.         Case PART_LHAND
  68.             x = Cx + _
  69.                 UARM_LEN * Cos(LShoulderAngle) + _
  70.                 LARM_LEN * Cos(LElbowAngle)
  71.             y = Cy + 2 * HEAD_RAD + NECK_LEN - _
  72.                 UARM_LEN * Sin(LShoulderAngle) - _
  73.                 LARM_LEN * Sin(LElbowAngle)
  74.         Case PART_RHAND
  75.             x = Cx + _
  76.                 UARM_LEN * Cos(RShoulderAngle) + _
  77.                 LARM_LEN * Cos(RElbowAngle)
  78.             y = Cy + 2 * HEAD_RAD + NECK_LEN - _
  79.                 UARM_LEN * Sin(RShoulderAngle) - _
  80.                 LARM_LEN * Sin(RElbowAngle)
  81.         Case PART_HIPS
  82.             x = Cx
  83.             y = Cy + 2 * HEAD_RAD + BODY_LEN
  84.         Case PART_LKNEE
  85.             x = Cx + _
  86.                 ULEG_LEN * Cos(LHipAngle)
  87.             y = Cy + 2 * HEAD_RAD + BODY_LEN - _
  88.                 ULEG_LEN * Sin(LHipAngle)
  89.         Case PART_RKNEE
  90.             x = Cx + _
  91.                 ULEG_LEN * Cos(RHipAngle)
  92.             y = Cy + 2 * HEAD_RAD + BODY_LEN - _
  93.                 ULEG_LEN * Sin(RHipAngle)
  94.         Case PART_LFOOT
  95.             x = Cx + _
  96.                 ULEG_LEN * Cos(LHipAngle) + _
  97.                 LLEG_LEN * Cos(LKneeAngle)
  98.             y = Cy + 2 * HEAD_RAD + BODY_LEN - _
  99.                 ULEG_LEN * Sin(LHipAngle) - _
  100.                 LLEG_LEN * Sin(LKneeAngle)
  101.         Case PART_RFOOT
  102.             x = Cx + _
  103.                 ULEG_LEN * Cos(RHipAngle) + _
  104.                 LLEG_LEN * Cos(RKneeAngle)
  105.             y = Cy + 2 * HEAD_RAD + BODY_LEN - _
  106.                 ULEG_LEN * Sin(RHipAngle) - _
  107.                 LLEG_LEN * Sin(RKneeAngle)
  108.     End Select
  109. End Sub
  110.  
  111.  
  112.  
  113. ' ************************************************
  114. ' Draw the robot.
  115. ' ************************************************
  116. Public Sub Draw(pic As PictureBox, handles As Boolean)
  117. Dim x1 As Integer
  118. Dim y1 As Integer
  119. Dim x2 As Integer
  120. Dim y2 As Integer
  121. Dim x3 As Integer
  122. Dim y3 As Integer
  123.  
  124.     ' Draw the head.
  125.     x1 = Cx
  126.     y1 = Cy + HEAD_RAD
  127.     pic.Circle (x1, y1), HEAD_RAD
  128.     If handles Then _
  129.         pic.Line (Cx - NEAR, Cy - NEAR)- _
  130.                 Step(NEAR2, NEAR2), , BF
  131.     
  132.     ' Draw the body.
  133.     y1 = y1 + HEAD_RAD
  134.     pic.Line (x1, y1)-Step(0, BODY_LEN)
  135.     
  136.     ' Draw the left arm.
  137.     y1 = y1 + NECK_LEN
  138.     x2 = x1 + UARM_LEN * Cos(LShoulderAngle)
  139.     y2 = y1 - UARM_LEN * Sin(LShoulderAngle)
  140.     pic.Line (x1, y1)-(x2, y2)
  141.     x3 = x2 + LARM_LEN * Cos(LElbowAngle)
  142.     y3 = y2 - LARM_LEN * Sin(LElbowAngle)
  143.     pic.Line -(x3, y3)
  144.     If handles Then _
  145.         pic.Line (x2 - NEAR, y2 - NEAR)- _
  146.                 Step(NEAR2, NEAR2), , BF
  147.     If handles Then _
  148.         pic.Line (x3 - NEAR, y3 - NEAR)- _
  149.                 Step(NEAR2, NEAR2), , BF
  150.  
  151.     ' Draw the right arm.
  152.     x2 = x1 + UARM_LEN * Cos(RShoulderAngle)
  153.     y2 = y1 - UARM_LEN * Sin(RShoulderAngle)
  154.     pic.Line (x1, y1)-(x2, y2)
  155.     x3 = x2 + LARM_LEN * Cos(RElbowAngle)
  156.     y3 = y2 - LARM_LEN * Sin(RElbowAngle)
  157.     pic.Line -(x3, y3)
  158.     If handles Then _
  159.         pic.Line (x2 - NEAR, y2 - NEAR)- _
  160.                 Step(NEAR2, NEAR2), , BF
  161.     If handles Then _
  162.         pic.Line (x3 - NEAR, y3 - NEAR)- _
  163.                 Step(NEAR2, NEAR2), , BF
  164.  
  165.     ' Draw the left leg.
  166.     y1 = y1 + TRUNK_LEN
  167.     x2 = x1 + ULEG_LEN * Cos(LHipAngle)
  168.     y2 = y1 - ULEG_LEN * Sin(LHipAngle)
  169.     pic.Line (x1, y1)-(x2, y2)
  170.     x3 = x2 + LLEG_LEN * Cos(LKneeAngle)
  171.     y3 = y2 - LLEG_LEN * Sin(LKneeAngle)
  172.     pic.Line -(x3, y3)
  173.     If handles Then _
  174.         pic.Line (x2 - NEAR, y2 - NEAR)- _
  175.                 Step(NEAR2, NEAR2), , BF
  176.     If handles Then _
  177.         pic.Line (x3 - NEAR, y3 - NEAR)- _
  178.                 Step(NEAR2, NEAR2), , BF
  179.  
  180.     ' Draw the right leg.
  181.     x2 = x1 + ULEG_LEN * Cos(RHipAngle)
  182.     y2 = y1 - ULEG_LEN * Sin(RHipAngle)
  183.     pic.Line (x1, y1)-(x2, y2)
  184.     x3 = x2 + LLEG_LEN * Cos(RKneeAngle)
  185.     y3 = y2 - LLEG_LEN * Sin(RKneeAngle)
  186.     pic.Line -(x3, y3)
  187.     If handles Then _
  188.         pic.Line (x2 - NEAR, y2 - NEAR)- _
  189.                 Step(NEAR2, NEAR2), , BF
  190.     If handles Then _
  191.         pic.Line (x3 - NEAR, y3 - NEAR)- _
  192.                 Step(NEAR2, NEAR2), , BF
  193. End Sub
  194.  
  195.  
  196.  
  197. ' ************************************************
  198. ' Move the control point to this location.
  199. ' ************************************************
  200. Public Sub MoveControlPoint(part As Integer, Ax As Integer, Ay As Integer, x As Integer, y As Integer)
  201.     Select Case part
  202.         Case PART_HEAD
  203.             Cx = x
  204.             Cy = y
  205.         Case PART_LELBOW
  206.             LShoulderAngle = Arctan2(x - Ax, Ay - y)
  207.         Case PART_RELBOW
  208.             RShoulderAngle = Arctan2(x - Ax, Ay - y)
  209.         Case PART_LHAND
  210.             LElbowAngle = Arctan2(x - Ax, Ay - y)
  211.         Case PART_RHAND
  212.             RElbowAngle = Arctan2(x - Ax, Ay - y)
  213.         Case PART_LKNEE
  214.             LHipAngle = Arctan2(x - Ax, Ay - y)
  215.         Case PART_RKNEE
  216.             RHipAngle = Arctan2(x - Ax, Ay - y)
  217.         Case PART_LFOOT
  218.             LKneeAngle = Arctan2(x - Ax, Ay - y)
  219.         Case PART_RFOOT
  220.             RKneeAngle = Arctan2(x - Ax, Ay - y)
  221.     End Select
  222. End Sub
  223.  
  224. ' ************************************************
  225. ' Initialize the robot's parameters.
  226. ' ************************************************
  227. Public Sub SetParameters(x As Integer, y As Integer, ls As Single, rs As Single, le As Single, re As Single, lh As Single, rh As Single, lk As Single, rk As Single)
  228.     Cx = x
  229.     Cy = y
  230.     LShoulderAngle = ls * DEG_TO_RAD
  231.     RShoulderAngle = rs * DEG_TO_RAD
  232.     LElbowAngle = le * DEG_TO_RAD
  233.     RElbowAngle = re * DEG_TO_RAD
  234.     LHipAngle = lh * DEG_TO_RAD
  235.     RHipAngle = rh * DEG_TO_RAD
  236.     LKneeAngle = lk * DEG_TO_RAD
  237.     RKneeAngle = rk * DEG_TO_RAD
  238. End Sub
  239.  
  240. ' ************************************************
  241. ' Return the distance between the top of the head
  242. ' and the top of the robot when its height is as
  243. ' large as possible.
  244. ' ************************************************
  245. Property Get HeadRoom()
  246.     HeadRoom = (UARM_LEN + LARM_LEN) - _
  247.         (2 * HEAD_RAD + NECK_LEN)
  248. End Property
  249. ' ************************************************
  250. ' Return the maximum possible height the robot
  251. ' can have.
  252. ' ************************************************
  253. Property Get MaxHeight()
  254.     MaxHeight = TRUNK_LEN + UARM_LEN + LARM_LEN + _
  255.                 ULEG_LEN + LLEG_LEN
  256. End Property
  257.  
  258. ' ************************************************
  259. ' Return the maximum possible width the robot
  260. ' can have.
  261. ' ************************************************
  262. Property Get MaxWidth()
  263.     MaxWidth = 2 * (UARM_LEN + LARM_LEN)
  264. End Property
  265.  
  266.  
  267. ' ************************************************
  268. ' Read the configuration data from a file.
  269. ' ************************************************
  270. Sub FileInput(fnum)
  271.     Input #fnum, Cx, Cy, _
  272.         LShoulderAngle, RShoulderAngle, _
  273.         LElbowAngle, RElbowAngle, _
  274.         LHipAngle, RHipAngle, _
  275.         LKneeAngle, RKneeAngle
  276. End Sub
  277. ' ************************************************
  278. ' Write the configuration data to a file.
  279. ' ************************************************
  280. Sub FileWrite(fnum)
  281.     Write #fnum, Cx, Cy, _
  282.         LShoulderAngle, RShoulderAngle, _
  283.         LElbowAngle, RElbowAngle, _
  284.         LHipAngle, RHipAngle, _
  285.         LKneeAngle, RKneeAngle
  286. End Sub
  287.  
  288. ' ************************************************
  289. ' Create a tween with fraction frac1 of the first
  290. ' configuration and (1 - frac1) of the second.
  291. ' ************************************************
  292. Public Sub Tween(f1 As Single, config1 As RobotConfig, config2 As RobotConfig)
  293. Dim f2 As Single
  294.  
  295.     f2 = 1# - f1
  296.     With config1
  297.         Cx = f1 * .Cx + f2 * config2.Cx
  298.         Cy = f1 * .Cy + f2 * config2.Cy
  299.         LShoulderAngle = CombinedAngle(.LShoulderAngle, config2.LShoulderAngle, f1, f2)
  300.         RShoulderAngle = CombinedAngle(.RShoulderAngle, config2.RShoulderAngle, f1, f2)
  301.         LElbowAngle = CombinedAngle(.LElbowAngle, config2.LElbowAngle, f1, f2)
  302.         RElbowAngle = CombinedAngle(.RElbowAngle, config2.RElbowAngle, f1, f2)
  303.         LHipAngle = CombinedAngle(.LHipAngle, config2.LHipAngle, f1, f2)
  304.         RHipAngle = CombinedAngle(.RHipAngle, config2.RHipAngle, f1, f2)
  305.         LKneeAngle = CombinedAngle(.LKneeAngle, config2.LKneeAngle, f1, f2)
  306.         RKneeAngle = CombinedAngle(.RKneeAngle, config2.RKneeAngle, f1, f2)
  307.     End With
  308. End Sub
  309. ' ************************************************
  310. ' Convert the angles so they differ by no more
  311. ' than PI. Then combine them using fraction f1 of
  312. ' angle a1 and fraction f2 of a2.
  313. ' ************************************************
  314. Function CombinedAngle(ByVal a1 As Single, ByVal a2 As Single, f1 As Single, f2 As Single) As Single
  315.     If Abs(a1 - a2) > PI Then
  316.         If a1 > a2 Then
  317.             Do
  318.                 a1 = a1 - PI_TIMES_2
  319.             Loop While a1 > a2
  320.         Else
  321.             Do
  322.                 a2 = a2 - PI_TIMES_2
  323.             Loop While a2 > a1
  324.         End If
  325.     End If
  326.     
  327.     CombinedAngle = f1 * a1 + f2 * a2
  328. End Function
  329.  
  330.