home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Network Support Encyclopedia 96-1
/
novell-nsepro-1996-1-cd2.iso
/
download
/
netware
/
ptf422.exe
/
SSMPATCH.BAT
< prev
Wrap
DOS Batch File
|
1993-09-16
|
5KB
|
170 lines
@echo off
echo off
cls
echo.
echo NetWare for SAA Services Manager v2.0.11 (PTF)
echo.
echo Copyright (c) 1990-1993, Novell, Inc. All Rights Reserved.
echo.
echo.
echo STATUS: Checking PTF files ...
rem Check that all the necessary files are in the current directory.
if not exist csm.res goto PTFnotfound
if not exist csmauth.dll goto PTFnotfound
if not exist csmres.dll goto PTFnotfound
if not exist csmvpl.dll goto PTFnotfound
if not exist nwsaa20.dll goto PTFnotfound
if not exist csmmib.dat goto PTFnotfound
if not exist ce.mib goto PTFnotfound
if not exist sna.mib goto PTFnotfound
if not exist nwsaamgr.exe goto PTFnotfound
if not exist dcsmcat.exe goto PTFnotfound
rem Check that parameter 1 points to the SSM directory.
if exist %1\base\csm.res goto setupSSM
if %1.==. goto defaultBoth
goto help
:defaultBoth
set SSM=c:\nwsaamgr
set NMS=c:\nms
goto SSMCheck
:setupSSM
set SSM=%1
goto SSMCheck
:SSMCheck
if not exist %SSM%\base\csm.res goto SSMnotfound
if not exist %SSM%\base\csmauth.dll goto SSMnotfound
if not exist %SSM%\base\csmres.dll goto SSMnotfound
if not exist %SSM%\base\csmvpl.dll goto SSMnotfound
if not exist %SSM%\base\nwsaa20.dll goto SSMnotfound
if not exist %SSM%\base\csmmib.dat goto SSMnotfound
rem Check that parameter 2 points to the NMS directory.
if %1.==. goto NMSCheck
if %2.==. goto defaultNMS
set NMS=%2
goto NMSCheck
:defaultNMS
set NMS=c:\nms
goto NMSCheck
:NMSCheck
set NMS20=FALSE
if not exist %NMS%\bin\nwsaamgr.exe goto NMSnotfound
rem
rem NMS 1.15B trap MIB files reside in a different place than
rem NMS 2.0 so check both locations.
rem
if not exist %NMS%\snmpmibs\trapmibs\ce.mib goto NMS115notfound
if not exist %NMS%\snmpmibs\trapmibs\sna.mib goto NMSnotfound
goto NMS115found
:NMS115notfound
if not exist %NMS%\snmpmibs\current\ce.mib goto NMSnotfound
if not exist %NMS%\snmpmibs\current\sna.mib goto NMSnotfound
set NMS20=TRUE
:NMS115found
echo STATUS: Verifying product ...
rem ------------------------------------------------------------
rem Now that everything is verified.
rem 1) Patch the new .EXE using the one in the NMS directory.
rem 2) Extract the Services list from the old .RES file.
rem 3) Copy all the files from the diskette.
rem 4) Catalog the old Services list into the new .RES file.
attrib -r nwsaamgr.exe
ptf %NMS%\bin\nwsaamgr.exe nwsaamgr.exe
if ERRORLEVEL 1 goto help
dcsmcat -xServices -n%SSM%\base\csm.res -o%SSM%\base\junk.cls
echo STATUS: Copying PTF files...
attrib -r %SSM%\base\*.*
if %NMS20%==FALSE goto NMS115
attrib -r %NMS%\snmpmibs\current\*.mib
copy ce.mib %NMS%\snmpmibs\current\. /v >nul
copy sna.mib %NMS%\snmpmibs\current\. /v >nul
goto NMSDone
:NMS115
attrib -r %NMS%\snmpmibs\trapmibs\*.mib
copy ce.mib %NMS%\snmpmibs\trapmibs\. /v >nul
copy sna.mib %NMS%\snmpmibs\trapmibs\. /v >nul
:NMSDone
copy csm.res %SSM%\base\. /v >nul
copy *.dll %SSM%\base\. /v >nul
copy *.dat %SSM%\base\. /v >nul
copy nwsaamgr.exe %NMS%\bin\. /v >nul
dcsmcat -a -n%SSM%\base\csm.res -i%SSM%\base\junk.cls
del %SSM%\base\junk.cls
echo STATUS: PTF Complete ...
if not exist %SSM%\hostprt.10\hostprt.dll goto NMS20Check
echo.
echo NOTE: %0 determined that NetWare for SAA Services Manager
echo HostPrint management was previously installed on this workstation.
echo This PTF requires that it be reinstalled from the product disks.
echo.
:NMS20Check
echo.
if %NMS20%==FALSE goto NMSDisplay115
echo NOTE: Please run the SNMP MIB Compiler from the Tools menu in
echo the NMS product to update the NetWare for SAA alarms.
goto exit
:NMSDisplay115
echo NOTE: Please run the SNMP Alarm Integrater from the Tools menu
echo in the NMS product for both the CE.MIB and SNA.MIB files.
echo This updates the NetWare for SAA alarms.
goto exit
rem ------------------------------------------------------------
:PTFnotfound
echo.
echo ERROR: Patch files appear to be missing from the current directory.
goto help
:SSMnotfound
echo.
echo ERROR: Unable to verify that %SSM% contains the SSM product.
goto help
:NMSnotfound
echo.
echo ERROR: Unable to verify that %NMS% contains the NMS product.
goto help
:help
echo.
echo This program patches: NetWare for SAA Services Manager v2.0.10 (SSM)
echo.
echo Both the NetWare Management System (NMS) and the SSM products
echo must have been previously installed on this workstation.
echo.
echo Switch to the drive and directory where the PTF files are located.
echo Enter the directory where SSM was installed as parameter 1.
echo Enter the directory where NMS was installed as parameter 2.
echo.
echo ex. %0 c:\nwsaamgr c:\nms
echo.
goto exit
:exit
set SSM=
set NMS=
set NMS20=