rem **************************************************
rem *** Set for local environment changes only ***
rem **************************************************
SETLOCAL
rem *******************************
rem *** Set up our commands ***
rem *******************************
set releasename=NetWare Client for Windows NT Update
set shtools=nwmv reboot
set copycmd=copy
set moveboot=nwmv
set rebootcmd=reboot
rem *******************************************
rem *** Set up file names to be updated ***
rem *******************************************
set netwaresysfiles=ipxapi ipxspx nwfs nwip vmlid
set netwaredllfiles=supwin32 nwapi32
echo This command file will initiate the installation of the
echo %releasename%.
echo.
echo You must be logged into your NT workstation as the Administrator
echo or as a user with Administrator equivalent rights. If you do not
echo have sufficient rights, press Ctrl-C to abort this command file,
echo login as Administrator, and then re-run this command file
echo to continue installation.
echo.
pause
:check_tools
rem *********************************************************
rem *** Check to make sure needed tools are available ***
rem *********************************************************
echo Checking for needed tools...
for %%i in (%shtools%) do (if NOT exist .\%%i.exe goto missing_tools)
goto check_files
:missing_tools
rem
echo.
echo Files are missing. One (or more) of the following files could not
echo be found in the current directory. To successfully install the
echo %releasename%, make sure you are running
echo this script from the same directory where all the distrubition
echo files are located.
echo.
echo %0 could not find one (or more) of the following files:
echo.
echo %shtools%
echo.
goto end
:check_files
rem *************************************************************
rem *** Check for all files required by the client update ***
rem *************************************************************
echo Checking for %releasename% files...
for %%i in (%netwaresysfiles%) do (if NOT exist .\%%i.sys goto missing_files)
for %%i in (%netwaredllfiles%) do (if NOT exist .\%%i.dll goto missing_files)
goto copy_files
:missing_files
echo.
echo Files are missing. One (or more) of the following files could not
echo be found in the current directory. To successfully install the
echo %releasename%, make sure you are running
echo this script from the same directory where all the distrubition
echo files are located.
echo.
echo %0 could not find one (or more) of the following files:
echo.
echo .SYSs:
echo %netwaresysfiles%
echo.
echo .DLLs:
echo %netwaredllfiles%
echo.
goto end
:copy_files
rem *****************************************************
rem *** Copy all needed files to proper locations ***
rem *****************************************************
echo Copying files...
echo.
for %%i in (%netwaresysfiles%) do (%copycmd% .\%%i.sys %SystemRoot%\system32\netware\~%%i.sys && %moveboot% %SystemRoot%\system32\netware\~%%i.sys %SystemRoot%\system32\netware\%%i.sys)
for %%i in (%netwaredllfiles%) do (%copycmd% .\%%i.dll %SystemRoot%\system32\~%%i.dll && %moveboot% %SystemRoot%\system32\~%%i.dll %SystemRoot%\system32\%%i.dll)
echo.
:needreboot
rem ******************************************
rem *** Let user know they must reboot ***
rem ******************************************
echo %releasename% has been installed.
echo You must now REBOOT the system for changes to become active.