home *** CD-ROM | disk | FTP | other *** search
/ Usenet 1994 January / usenetsourcesnewsgroupsinfomagicjanuary1994.iso / sources / unix / volume5 / smallc / part3 / 6809 / sdiv.u < prev    next >
Encoding:
Text File  |  1986-11-30  |  812 b   |  56 lines
  1. |    signed divide
  2. |    calling: (left / right)
  3. |        push left
  4. |        ldd right
  5. |        jsr sdiv
  6. |    result in d, arg popped.
  7. |
  8.     left=6
  9.     right=2
  10.     sign=1
  11.     count=0
  12.     return=4
  13.     CARRY=1
  14. .globl sdiv,div,ASSERTFAIL
  15. .globl prabs
  16. sdiv:    leas    -4(s)
  17.     std    right(s)
  18.     bne    nozero
  19.     swi2
  20.     .byte    ASSERTFAIL
  21. nozero:    jsr    prabs
  22. div:    clr    count(s)    | prescale divisor
  23.     inc    count(s)
  24. mscl:    inc    count(s)
  25.     aslb
  26.     rola
  27.     bpl    mscl
  28.     std    right(s)
  29.     ldd    left(s)
  30.     clr    left(s)
  31.     clr    left+1(s)
  32. div1:    subd    right(s)    | check subtract
  33.     bcc    div2
  34.     addd    right(s)
  35.     andcc    #~CARRY
  36.     bra    div3
  37. div2:    orcc    #CARRY
  38. div3:    rol    left+1(s)    | roll in carry
  39.     rol    left(s)
  40.     lsr    right(s)
  41.     ror    right+1(s)
  42.     dec    count(s)
  43.     bne    div1
  44.     ldd    left(s)
  45.     tst    sign(s)        | sign fiddle
  46.     beq    nochg
  47.     nega
  48.     negb
  49.     sbca    #0
  50. nochg:    std    right(s)    | move return addr
  51.     ldd    return(s)
  52.     std    left(s)
  53.     ldd    right(s)
  54.     leas    6(s)
  55.     rts
  56.