home *** CD-ROM | disk | FTP | other *** search
/ Usenet 1994 January / usenetsourcesnewsgroupsinfomagicjanuary1994.iso / sources / unix / volume21 / rayshade / part02 / nff2shade.awk
Encoding:
AWK Script  |  1990-03-21  |  3.1 KB  |  127 lines
  1. #
  2. # This awk script will convert an NFF-format input file (as output by
  3. # Eric Haines' SPD) to something rayshade can understand.
  4. # The World object will be enclosed in a single grid of 22*22*22 voxels.
  5. #
  6. # Example usage:
  7. #    mountains | awk -f nff2shade.awk | rayshade > mountains.rle
  8. #
  9. # For best results, one should modify the output for all but the tetra
  10. # and mountain databases to provide a tighter bounding box around the
  11. # object of interest (tree, gears, etc.).  This is done by placing
  12. # all primitives but the ground pologon into an object stored as a Grid,
  13. # and then instantiating that object once.  This will decrease ray-tracing
  14. # time dramatically.
  15. #
  16. # $Id: nff2shade.awk,v 3.0 89/10/27 01:30:24 craig Exp $
  17. #
  18. # $Log:    nff2shade.awk,v $
  19. # Revision 3.0  89/10/27  01:30:24  craig
  20. # Baseline for first official release.
  21. # 
  22. # C. Kolb 9/21/89
  23. # Fixed comment bug; check first character rather than first field for "#".
  24. # Keep track of defined surfaces in associative array so if one is used
  25. # again we don't create another copy.
  26. # Halved ambient intensity of surfaces.
  27. # C. Kolb 10/12/89
  28. # Added "adaptive 0" and "cutoff 0" to BEGIN and removed "endfile" from END.
  29. # C. Kolb 2/89
  30. # First version.
  31. #
  32. BEGIN{
  33.     lights = 0;
  34.     surfs = 0;
  35.     print "maxdepth 4"
  36.     print "adaptive 0"
  37.     print "cutoff 0."
  38. }
  39. substr($1, 1, 1) == "#" { print "/* " $0 " */"; next;}
  40. $1 == "v" { next;}
  41. $1 == "from" { print "eyep " $2 " "$3 " " $4; next;}
  42. $1 == "at" {print "lookp " $2 " "$3 " "$4; next;}
  43. $1 == "up" {print; next;}
  44. $1 == "angle" { print "fov " $2; next;}
  45. $1 == "hither" {next;}
  46. $1 == "resolution" {print "screen " $2 " "$3; next;}
  47.  
  48. $1 == "l" { lightd[lights] = $2 " "$3 " "$4; lights++; next; }
  49. $1 == "b" {print "background " $2 " "$3 " "$4; next; }
  50. $1 == "f" {
  51.     if (surfaces[$2 $3 $4 $5 $6 $7 $8] != 0) {
  52.         cursurf = surfaces[$2 $3 $4 $5 $6 $7 $8];
  53.         next;
  54.     }
  55.     surfs++;
  56.     surfaces[$2 $3 $4 $5 $6 $7 $8] = surfs;
  57.     cursurf = surfs;
  58.     aintens = sqrt(lights) / (4*lights);
  59.     dr = $2*$5;
  60.     dg = $3*$5;
  61.     db = $4*$5;
  62. # this is a good guess....
  63.     ar = aintens*dr;
  64.     ag = aintens*dg;
  65.     ab = aintens*db;
  66. #
  67. # We set "reflectance" to the minimum of Ks and 1. - T, as
  68. # Eric Haines' SPD includes several objects which have Ks + T > 1.
  69. #
  70.     if ($6 < 1. - $8)
  71.         reflect = $6;
  72.     else
  73.         reflect = 1. - $8;
  74.     printf("surface s%d  %f %f %f  %f %f %f  %f %f %f  %f %f %f %f\n", \
  75.         cursurf, ar, ag, ab, dr, dg, db, $6, $6, $6, $7, reflect, $8, $9);
  76.     next;
  77. }
  78.  
  79. $1 == "c" {
  80.     getline;
  81.     x1 = $1;
  82.     y1 = $2;
  83.     z1 = $3;
  84.     br = $4;
  85.     getline;
  86.     printf("cone s%d %f %f %f %f %f %f %f %f\n", \
  87.         cursurf, x1, y1, z1, $1, $2, $3, br, $4);
  88.     next;
  89. }
  90. $1 == "s" {
  91.     print "sphere s"cursurf " "$5 " "$2 " "$3 " "$4;
  92.     next;
  93. }
  94. $1 == "pp" {
  95.     if ($2 == 3)
  96.         print "triangle s"cursurf;
  97.     else
  98.         print "poly s"cursurf;
  99.     next;
  100. }
  101. $1 == "p" {
  102. #
  103. # Polygon -- the vertices will print out in the default statement.
  104. # If there are three vertices, make it a triangle.
  105. #
  106.     if ($2 == 3)
  107.         print "triangle s"cursurf;
  108.     else
  109.         print "poly s"cursurf;
  110.     next;
  111. }
  112. {
  113. # Matched nothing (or is a vertex data) -- print it.
  114.     print;
  115.     next;
  116. }
  117. END{
  118. #
  119. # Output light definitions.
  120. #
  121.     intens = sqrt(lights) / (lights);
  122.     for (i = 0; i < lights; i++) {
  123.         print "light " intens " point " lightd[i]
  124.     }
  125.     print "grid 22 22 22"
  126. }
  127.