Usenet 1994 January/usenetsourcesnewsgroupsinfomagicjanuary1994.iso/sources/misc/volume29/parseargs/part02/VMSbuild.com

Text File | 1992-05-19 | 2KB | 79 lines

$! --- VMSbuild.com ---
$!
$! Build the ParseArgs suite under VMS
$!
$! Luke Brennan                             e-mail: [e-mail]
$! EDP Unit, S209                                   [e-mail]
$!                                    [e-mail]
$! Cumberland College of Health Sciences,                              ,-_|\
$! The University of Sydney                  voice: [phone]    /     \
$! East Street, Lidcombe, NSW 2141             fax: [phone]    \_,-._*
$! AUSTRALIA                                                               v
$!
$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
$!
$ If (P1 .nes. "")
$ Then OPSYS := 'P1'
$ Else OPSYS := 'f$getsyi("node_SWtype")'
$ EndIF
$!
$!
$ If (OPSYS .eqs. "UNIX")
$ Then use_pager := /Define="""USE_PAGER"""
$ Else use_pager :=
$ EndIF
$ os_style    = f$edit(OPSYS,"LOWERCASE") + "_style"
$ os_library := LIB'opsys'ARGS.OLB
$!
$!
$! compile the appropriate source files
$!
$ CC /Include=([]) 'OPSYS'_Args    /Define="''os_style'"
$ CC /Include=([]) Xparse        /Define="''os_style'"
$ CC /Include=([]) ArgType        /Define="''os_style'"
$ CC /Include=([]) STRfuncs        /Define="''os_style'"
$ CC /Include=([]) ArgList
$ CC /Include=([]) PgOpen        'use_pager'
$ CC /Include=([]) SYSerr
$ CC /Include=([]) Vprintf
$ CC /Include=([]) WinSize
$!
$! make the archive library
$!
$ If (f$search("''os_library'") .nes. "") Then Delete 'os_library';
$ Library/Object/Create 'os_library'        -
    'opsys'_args, arglist, argtype, pgopen,    -
     strfuncs, syserr, vprintf, winsize, xparse
$!
$!
$! VMS requires an OPTIONS file for correct linkage with the C libraries
$ If (f$search("VMS_C_OPTIONS.OPT") .eqs. "") Then GoSub Make_Opts_File
$!
$!
$! now we can build the actual executables..
$!
$ CC /Include=([]) Stest
$ Link /Executable='OPSYS'_test -
        Stest,'os_library'/Library,VMS_C_Options/OPTION
$!
$ CC /Include=([]) Unix_Man
$ CC /Include=([]) ParseArgs
$ Link /Executable=ParseArgs -
        ParseArgs,Unix_Man,'os_library'/Library,VMS_C_Options/OPTION
$!
$ Exit
$!
$!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
$!
$MAKE_OPTS_FILE:
$ Open/WRITE fd VMS_C_Options.opt
$ Write fd -
"! Default system options file to link against the sharable C runtime library"
$ Write fd "!"
$ Write fd "Sys$Share:VaxCrtl/share"
$ Write fd " "
$ Close fd
$!
$ Return