home *** CD-ROM | disk | FTP | other *** search
/ Turbo Toolbox / Turbo_Toolbox.iso / tasm / obytenrm.asm < prev    next >
Assembly Source File  |  1988-08-28  |  3KB  |  128 lines
  1.  
  2. ;    FILENAME: OBYTENRM.ASM
  3. ;    Copyright (c) 1988 by Borland International, Inc.
  4. ;
  5. ;    Description: This module implements the routine ByteNorm. ByteNorm
  6. ;    processes the current normal byte value in al.
  7. ;    This module uses MASM mode syntax and standard segment directives. 
  8. ; 
  9. ;    ASSEMBLY INSTRUCTIONS: To assemble this module use the following 
  10. ;    TASM command line. 
  11. ; 
  12. ;        TASM obytenrm
  13.  
  14. include globals.inc
  15.  
  16. _TEXT   segment
  17.  
  18.     ByteNorm proc
  19.  
  20.     ;    This procedure processes a normal byte character 
  21.     ;    (31 < ASCII value < 128) in al.
  22.     ;
  23.     ;    Input 
  24.     ;       al - normal byte character
  25.     ;       EOL -  defined to be the end of line character
  26.     ;       InpSta - input status
  27.     ;       INP_EOL - designates an end-of-line condition
  28.     ;       Options - the options being used
  29.     ;       REP_SPC - replace spaces with tabs
  30.     ;       SpcCnt - space count (for compressing spaces)
  31.     ;       TabOff - tab offset (decrements the tab column number)
  32.     ;       MAK_LWR - designates character is to be shifted to lower-case
  33.     ;       MAK_UPR - designates character is to be shifted to upper-case
  34.     ;       MAK_CAP - designates character is to be capitalized
  35.     ;       LAS_LET - designates the last character was a letter
  36.     ;
  37.     ;    Output 
  38.     ;       al - normal byte processed
  39.     ;       cx - byte count incremented
  40.     ;    Registers modified 
  41.     ;       ax, cx
  42.  
  43.  
  44.     ; Process normal byte.
  45.  
  46.     ;--- end of line
  47.  
  48.     cmp      al, EOL         ;check if end of line
  49.     jne      bytnor1
  50.     or       InpSta, INP_EOL
  51.     ret
  52.  
  53.     ;--- replace spaces with tabs
  54.  
  55. bytnor1:
  56.     test     Options, REP_SPC ;test if replace spaces
  57.     jz       bytnor4
  58.  
  59.     ;------ write tab stop
  60.  
  61.     call     TabNext        ;get next tab stop
  62.     jnc      bytnor2        ;jump if not at stop
  63.     call     StoreTab       ;store a tab
  64.  
  65.     ;------ space
  66.  
  67. bytnor2:
  68.     cmp      al, ' '         ;check if really space
  69.     jne      bytnor3         ;jump if not
  70.     inc      SpcCnt          ;increment space count
  71.     inc      TabOff          ;increment column
  72.     ret
  73.  
  74.     ;------ non-space
  75.  
  76. bytnor3:
  77.     call     StoreSpc        ;store any spaces
  78.  
  79.     ;--- convert to lower case
  80.  
  81. bytnor4:
  82.     test     Options, MAK_LWR ;test if make lower-case
  83.     jz       bytnor5
  84.     call     LoCase
  85.     stosb
  86.     inc      cx
  87.     ret
  88.  
  89.     ;--- convert to upper case
  90.  
  91. bytnor5:
  92.     test     Options, MAK_UPR ;test if make upper-case
  93.     jz       bytnor6
  94.     call     UpCase
  95.     stosb
  96.     inc      cx
  97.     ret
  98.  
  99.     ;--- capitalize
  100.  
  101. bytnor6:
  102.     test     Options, MAK_CAP ;test if capitalize
  103.     jz       bytnor8
  104.     test     InpSta, LAS_LET ;check if last character was letter
  105.     jz       bytnor7
  106.     call     LoCase
  107.     stosb
  108.     inc      cx
  109.     ret
  110.  
  111. bytnor7:
  112.     call     UpCase
  113.     stosb
  114.     inc      cx
  115.     ret
  116.  
  117.     ;--- write byte
  118.  
  119. bytnor8:
  120.     stosb
  121.     inc      cx
  122.     ret
  123.     ByteNorm endp
  124.  
  125. _TEXT    ends
  126.  
  127. end
  128.