Turbo Toolbox/Turbo_Toolbox.iso/dtx9302/tvision/install/install.pas

Pascal/Delphi Source File | 1993-03-08 | 5.3 KB | 163 lines

(* ****************************************************** *)
(*                    INSTALL.PAS                         *)
(*         Installationsprogramm mit Turbo Vision         *)
(*         (c) 1993 Dieter Craasmann & DMV                *)
(* ****************************************************** *)
PROGRAM Install;

{$M 32768,8192,655360}
{$X+,S-}

USES Crt, Dos, Objects, Drivers, Views,
     Menus, Dialogs, Neu_StdD, MsgBox,
     App;

CONST
  cmInfo       = 104; {Konstante für Menü}
  cmPara       = 105;

TYPE
  OAnwendungsTyp = OBJECT (tApplication)
                     PROCEDURE HandleEvent(VAR Event: TEvent); virtual;
                     PROCEDURE InitMenuBar; virtual;
                     PROCEDURE InitStatusLine; virtual;
                     PROCEDURE OutOfMemory; virtual;
                     PROCEDURE Installiere;
                     PROCEDURE HILFE;
                   END;

VAR
  Anwendung       : OAnwendungsTyp;

  PROCEDURE OAnwendungsTyp.InitMenuBar;
  VAR
    R: TRect;
  BEGIN
    GetExtent(R);
    R.B.Y := R.A.Y + 1;
    MenuBar := New(PMenuBar, Init(R, NewMenu(
      NewSubMenu('~I~nstallation', hcNoContext, NewMenu(
        NewItem('~I~nstallieren', '', kbnoKey, cmPara, hcNoContext,
        NewItem('E~x~it', 'ESC', kbESC, cmQuit, hcNoContext,
      NIL))),
      NewSubMenu('~H~ilfen ', hcNoContext, NewMenu(
        NewItem('~I~nstallations-Hilfen', 'F1', kbF1, cmHelp, hcNoContext,
        NewItem('~D~ruckerauswahl-Hilfen', 'F2', kbF2, cmHelpD, hcNoContext,
      NIL))),
    NIL)))));
  END;

  PROCEDURE OAnwendungsTyp.Hilfe;
  VAR
    Msg  : STRING;
    Msg2 : STRING;
    Msg3 : STRING;
  BEGIN
    Msg :=^C'Installations-Hinweise'#13 +
    ^C'Wählen Sie aus den Laufwerken das aus, in das das Programm installiert  '#13 +
    ^C'werden soll. Als Beispiel "C:\" oder "D:\",  etc. wie vorgegeben. Mit   '#13 +
    ^C'dem Cursor treffen Sie die Wahl und mit "Return" erfolgt die Gesamtwahl.';
    Msg2 :=^C'Mit der Tabulator-Taste können Sie in das nächste Auswahlfeld wechseln '#13 +
    ^C'oder durch anklicken der Punkte und der Wahlknöpfe mit der Mouse wird  '#13 +
    ^C'der entsprechende Befehl ausgeführt.'#13 +
    ^C'Wechsel zum Einfügen/Überschreiben mit der Einfügetaste.';
    Msg3 :=^C'Durch die Anwahl mit den Tasten "ALT" + "gekennzeichnetem" Buchstaben'#13 +
    ^C'kann auch ein Feld oder Befehlsknopf direkt angesprochen werden.'#13 +
    ^C'Wählen Sie den Monitor ihres PCs und Ihren entsprechenden Drucker aus.'#13 +
    ^C'Druckerhilfen siehe Hilfe 2 im Menü.';
    MessageBoxGross(Msg, NIL,Msg2, NIL,Msg3, NIL,80,23, mfHelp + mfOkButton);
  END;

  PROCEDURE HilfeD;
  VAR
    Msg  : STRING;
    Msg2 : STRING;
    Msg3 : STRING;
  BEGIN
    Msg :=^C'AUSWAHL DRUCKER/MODUS:   SCHRIFTARTEN:        ZEILEN JE SEITE:             '#13 +
    ^C''#13 +
    ^C'1. Epson       Schmalschrift #15    #27,#67,#72       '#13 +
    ^C'               Normalschrift #18    (#72 = Zeilenzahl)'#13 +
    ^C'               Blattvorschub #12                       ';
    Msg2 :=^C'2. IBM         Schmalschrift #15    #27,#91,72,#116   '#13 +
    ^C'               Normalschrift #18    (72 = Zeilenzahl) '#13 +
    ^C'               Blattvorschub #12                      ';
    Msg3 :=^C'3. Laser KYOCERA EPSON über Font: !R! FRPO U7,5; EXIT;'#13 +
    ^C'           Sonst wie unter 1. Epson (#72 =Zeilenzahl) '#13 +
    ^C'    '#13 +
    ^C'    ';
    MessageBoxGross(Msg, NIL,Msg2, NIL,Msg3, NIL,80,23, mfHelp + mfOkButton);
END;

  PROCEDURE Copyright;
  VAR
    Msg : STRING;
  BEGIN
    Msg := ^C'Copyright (c) 1993 Dieter Craasmann & DMV '#13 +
           ^C'Mit Turbo - Vision erstellt'#13;
    MessageBox(Msg, NIL, 39, 9, mfInformation + mfOkButton);
  END;

  PROCEDURE OAnwendungsTyp.installiere;
  VAR
    D: PFileDialog;  {Zeiger für File-Box}
  BEGIN
    D:=New(PFileDialog,NewParameter('C:\','INSTALL','INSTALL'));
    Redraw;            {Ausgangslaufwerk,Ausgangspfad,Zielpfad}
  END;

  PROCEDURE OAnwendungsTyp.HandleEvent(VAR Event: TEvent);
  BEGIN
    TApplication.HandleEvent(Event);
    CASE Event.What OF
      evCommand:
        CASE Event.Command OF
          cmPara     :  Installiere;
          cmHelp     :  Hilfe;
          cmHelpD    :  HilfeD;
          cmInfo     :  Copyright;
          cmMenu     :  Hilfe;
        ELSE
          Exit;
        END;
    ELSE
      Exit;
    END;
    ClearEvent(Event);
  END;

  PROCEDURE OAnwendungsTyp.InitStatusLine;
  VAR
    R : TRect;
  BEGIN
    GetExtent(R);
    R.A.Y := R.B.Y - 1;
    New(StatusLine, Init(R,
      NewStatusDef(0, $FFFF,
        NewStatusKey('~ESC~ Beenden', kbEsc, cmClose,
        NewStatusKey('~F1~ Hilfe', kbF1, cmHelp,
        NewStatusKey('~F2~ Hilfe Druckerwahl', kbF2, cmHelpD,
        NewStatusKey('~F10~ Menü ', kbF10, cmMenu,
        NewStatusKey(' ~INSTALL~ - Copyright', kbNoKey, cmInfo,
      NIL))))),
    NIL)));
  END;

  PROCEDURE OAnwendungsTyp.OutOfMemory;
  VAR
    Msg : STRING;
  BEGIN
    Msg := ^C'Nicht genug Arbeitsspeicher'#13 +
           ^C'vorhanden';
    MessageBox(Msg, NIL,36,9, mfError + mfOkButton);
  END;

BEGIN
  Anwendung.Init;
  Anwendung.Run;
  Anwendung.Done;
END.
(* ****************************************************** *)
(*               Ende vonINSTALL.PAS                      *)