home *** CD-ROM | disk | FTP | other *** search
/ ticalc.org / ticalc_org_rev_b.iso / archives / 82 / asm / source / ash / irchat82.asm < prev    next >
Encoding:
Assembly Source File  |  2001-07-01  |  12.8 KB  |  551 lines
  1.  
  2. ; InfraRed Chat for the IR Link (http://unet.univie.ac.at/~a9501901/irlink)
  3. ;   by Sami Khawam (sKhawam@bigfoot.com)
  4. ;   http://unet.univie.ac.at/~a9501901
  5. ;
  6. ; NOTE: The Keys indexes are had been fixed.
  7. ; 
  8. ; This is for ASH.
  9. ;
  10. ; No WhiteBoard support! (Chat can be made with a TI85 or TI85, but
  11. ; no drawings ... :( 
  12. ;
  13. ; Thanks for Randy Gluvna (gluvna@home.com) for his recieve routine.
  14. ; Thanks for Osma Suominen (ozone@clinet.fi) for his keys scaning
  15. ; codes for the TI85, and for his MChat.
  16. ;
  17. ;
  18. ;                               - Sami Khawam
  19.  
  20. #INCLUDE "TI82.H"
  21. #INCLUDE "KEYS.INC"
  22.  
  23. PORT = 000H
  24.  
  25. .ORG START_ADDR
  26. .db "IR Chat v.12 ",0
  27. BySK:
  28. .db "by Sami Khawam", 0
  29.  
  30.  
  31. BufferLen       =       APD_BUF    ; String length
  32. TextBuffer      =       APD_BUF+1
  33.  
  34. KeyFlags        =       GRAPH_MEM        ; 0000xxxx
  35.                                         ; bit 0 = Alpha
  36.                                         ; bit 1 = Num
  37.                                         ; bit 2 = Lock
  38. CursorX         =       KeyFlags + 1
  39. ScreenX         =       CursorX + 1
  40. ScreenY         =       ScreenX + 1
  41. iCursor         =       ScreenY + 1
  42.  
  43.  
  44.  
  45. Init:
  46.         ROM_CALL(CLEARLCD)
  47.  
  48.         ld      a, 4
  49.         out     (5), a
  50.  
  51.         ld      de, $0102
  52.         ld      (CURSOR_ROW), de
  53.         ld      hl, ProgName
  54.         ROM_CALL(D_ZT_STR)            
  55.         ld      de, $0103
  56.         ld      (CURSOR_ROW), de
  57.         ld      hl, BySK
  58.         ROM_CALL(D_ZT_STR)            
  59.  
  60.         ld      hl, $0004
  61.         ld      (ScreenX), hl
  62.         xor     a           
  63.         ld      (KeyFlags), a
  64.         ld      a, $DC
  65.         ld      (iCursor), a
  66.         jp      ClearInput
  67.  
  68.  
  69.  
  70.  
  71. MainLoop:
  72.         ld      a, $C0          ; Set W1 and R1
  73.         out     (0), a
  74.  
  75.         in      a, (0)
  76.         and     3
  77.         cp      3
  78.         jp      nz, ReceiveLine ; Only one line low.
  79.  
  80.  
  81.  
  82. GetKey:
  83.         call GET_KEY
  84.         or a                    ; No key pressed
  85.         jr z, MainLoop
  86.         cp G_MODE
  87.         ret z
  88.         cp G_DEL
  89.         jp z, BackSpace
  90.         cp G_ENTER
  91.         jp z, SendLine
  92.         cp G_CLEAR
  93.         jp z, ClearInput
  94.         cp G_2nd
  95.         jp z, SetNumber
  96.         cp G_ALPHA
  97.         jp z, SetAlpha
  98.  
  99.         cp      $0a                 ; Ignore the arrows and 'Enter'.
  100.         jp      c, MainLoop
  101.  
  102.         sub     $0a     
  103.  
  104.         ld      hl, Scan2Index
  105.         ld      d,0
  106.         ld      e,a
  107.         add     hl,de
  108.         ld      a,(hl)               ; a=ascii value of key
  109.         or      a
  110.         jp      z, MainLoop          ; Invalid key - loop
  111.         ld      c, a
  112.  
  113.         ld      a, (KeyFlags)
  114.         and     1
  115.         jr      nz, AlphaSet
  116.         ld      a, (KeyFlags)
  117.         and     2
  118.         jr      nz, NumSet
  119.  
  120.  
  121.         ld      a, c
  122.         ld      hl, Index2Ascii
  123.         ld      d,0
  124.         ld      e,a
  125.         add     hl,de
  126.         ld      a,(hl)               ; a=ascii value of key
  127.         or      a
  128.         jp      z, MainLoop          ; Invalid key - loop
  129.         jr      Continue2
  130.  
  131.  
  132. AlphaSet:
  133.         ld      a, c
  134.         ld      hl, Index2Shift
  135.         ld      d,0
  136.         ld      e,a
  137.         add     hl,de
  138.         ld      a,(hl)               ; a=ascii value of key
  139.         or      a
  140.         jp      z, MainLoop          ; Invalid key - loop
  141.         ld      c, a
  142.         jr      Continue
  143.  
  144. NumSet:
  145.         ld      a, c
  146.         ld      hl, Index2Num
  147.         ld      d,0
  148.         ld      e,a
  149.         add     hl,de
  150.         ld      a,(hl)               ; a=ascii value of key
  151.         or      a
  152.         jp      z, MainLoop          ; Invalid key - loop
  153.         ld      c, a
  154.  
  155.  
  156. Continue:
  157.         ld      a, (KeyFlags)
  158.         and     4
  159.         jr      nz, IsLocked
  160.         xor     a
  161.         ld      (KeyFlags), a
  162.         ld      a, $DC
  163.         ld      (iCursor), a
  164.         call    PrintInput
  165.  
  166. IsLocked:
  167.         ld      a, c
  168. Continue2:
  169.         ld      b, a
  170.         ld      hl, TextBuffer
  171.         ld      d, 0
  172.         ld      a, (BufferLen)
  173.         ld      e, a
  174.         add     hl, de
  175.         ld      (hl), b
  176.  
  177.         ld      a, (BufferLen)
  178.         inc     a
  179.         ld      (BufferLen), a
  180.  
  181.         ld      a, (CursorX)
  182.         cp      12
  183.         jr      nz, NoDecal
  184.  
  185. PrintInputLine:
  186.         ld      hl, $0000
  187.         ld      (CURSOR_ROW), hl
  188.  
  189.         ld      a, (BufferLen)
  190.         sub     12
  191.         ld      hl, TextBuffer
  192.         ld      d, 0
  193.         ld      e, a
  194.         add     hl, de
  195.  
  196.         ld      b, 12
  197.         ld      a, $CE
  198.         ROM_CALL(TX_CHARPUT)            
  199. NextChar:
  200.         ld      a, (hl)
  201.         ROM_CALL(TX_CHARPUT)            
  202.         inc     hl
  203.         djnz    NextChar
  204.         call    PrintInput
  205.         jp      MainLoop
  206.  
  207. NoDecal:
  208.         inc     a
  209.         ld      (CursorX), a
  210.         ld      a, b
  211.         ROM_CALL(TX_CHARPUT)            
  212.         call    PrintInput
  213.         jp      MainLoop
  214.  
  215.  
  216. BackSpace:
  217.         ld      a, (BufferLen)
  218.         or      a
  219.         jp      z, MainLoop
  220.         dec     a
  221.         ld      (BufferLen), a
  222.  
  223.         ld      a, (CursorX)
  224.         cp      12
  225.         jr      nz, FirstCh
  226.         ld      a, (BufferLen)
  227.         cp      11              ; !!!!!!
  228.         jp      nz, PrintInputLine
  229. FirstCh
  230.         dec     a
  231.         ld      (CursorX), a
  232.         ld      a, ' '
  233.         ROM_CALL(TX_CHARPUT)            
  234.         ld      a, (CURSOR_COL)
  235.         dec     a
  236.         dec     a
  237.         ld      (CURSOR_COL), a
  238.         call    PrintInput
  239.         jp      MainLoop
  240.  
  241.  
  242. SetAlpha:
  243.         ld      a, (KeyFlags)
  244.         and     1
  245.         jr      z, ASet
  246.         ld      a, (KeyFlags)
  247.         and     4                       
  248.         jr      z, ALock
  249.         xor     a
  250.         ld      (KeyFlags), a           ; Normal set
  251.         ld      a, $DC
  252.         jr      ANEnd
  253. ASet
  254.         ld      a, 1
  255.         ld      (KeyFlags), a           ; Alpha set
  256.         ld      a, $DF
  257.         jr      ANEnd
  258. ALock
  259.         ld      a, 5
  260.         ld      (KeyFlags), a           ; Alpha locked
  261.         ld      a, $DB
  262. ANEnd
  263.         ld      (iCursor), a
  264.         call    PrintInput
  265.         jp      MainLoop
  266.  
  267.  
  268. SetNumber:
  269.         ld      a, (KeyFlags)
  270.         and     2
  271.         jr      z, NSet
  272.         ld      a, (KeyFlags)
  273.         and     4                       
  274.         jr      z, NLock
  275.         xor     a
  276.         ld      (KeyFlags), a           ; Normal set
  277.         ld      a, $DC
  278.         jr      SNEnd
  279. NSet
  280.         ld      a, 2
  281.         ld      (KeyFlags), a           ; Num set
  282.         ld      a, $DD
  283.         jr      SNEnd
  284. NLock
  285.         ld      a, 6
  286.         ld      (KeyFlags), a           ; Num locked
  287.         ld      a, $D9
  288. SNEnd
  289.         ld      (iCursor), a
  290.         call    PrintInput
  291.         jp      MainLoop
  292.  
  293.  
  294.  
  295. SendLine
  296.         ld      a, (BufferLen)
  297.         or      a
  298.         jp      z, MainLoop
  299.         ld      b, a
  300.         call    ScrollPage
  301.         ld      hl, TextBuffer
  302. NextByte
  303.         ld      a,   (hl)              
  304.         ROM_CALL(TX_CHARPUT)            
  305.         call    PutByte           ; Now we send all bytes.
  306.         inc     hl
  307.         djnz    NextByte
  308.         ld      de, (CURSOR_ROW)
  309.         inc     de
  310.         ld      d, 0
  311.         ld      (CURSOR_ROW), de
  312.         ld      (ScreenX), de
  313.         ld      a, $FE
  314.         call    PutByte           ; Send 'Enter'.
  315.  
  316.  
  317. ClearInput:
  318.         xor     a               ;ld      a, 0
  319.         ld      (BufferLen), a
  320.         inc     a
  321.         ld      (CursorX), a
  322.         ld      hl, $0200
  323.         ld      (CURSOR_ROW), hl
  324.         ld      b, 12
  325.         ld      a, ' '
  326. NextBlank:
  327.         ROM_CALL(TX_CHARPUT)            
  328.         djnz    NextBlank
  329.         ld      hl, $0000
  330.         ld      (CURSOR_ROW), hl
  331.         ld      a, '>'
  332.         ROM_CALL(TX_CHARPUT)            
  333.         call    PrintInput
  334.         jp      MainLoop
  335.  
  336.  
  337. PrintInput
  338.         ld      a, (iCursor)
  339.         ROM_CALL(TX_CHARPUT)            
  340.         ld      a, (CURSOR_COL)
  341.         dec     a
  342.         ld      (CURSOR_COL), a
  343.         ret
  344.  
  345.  
  346. ScrollPage:
  347.         ld      hl, (ScreenX)
  348.         ld      (CURSOR_ROW), hl
  349.         ld      a, l                   
  350.         cp      8
  351.         ret     nz
  352.         dec     hl
  353.         ld      (CURSOR_ROW), hl
  354.         ld      a, 1
  355.         ld      ($8C8F),a         ;Starting row is 1
  356.         ld      a, 8
  357.         ld      ($8C90),a         ;Last row to scroll is 7
  358.         res     1, (IY+0D)      ; don't scroll the text memory!!!!!!!!!!!!!
  359.         ROM_CALL(SCROLL_UP)  
  360.         ret
  361.  
  362.  
  363.  
  364. ReceiveLine:
  365.         call    GetByte
  366.         or      a
  367.         jp      z, MainLoop     
  368.  
  369.         ld      c, a
  370.         call    ScrollPage
  371.         ld      a, c
  372.         cp      $FE
  373.         jr      z, NextLine
  374.         ROM_CALL(TX_CHARPUT)            
  375.         jr      NoNextLine
  376. NextLine:
  377.         inc     hl
  378.         ld      h, 0
  379.         ld      (CURSOR_ROW), hl
  380. NoNextLine:
  381.         ld      hl, (CURSOR_ROW)
  382.         ld      (ScreenX), hl
  383.         ld      a, (CursorX)
  384.         ld      d, a
  385.         ld      e, 0
  386.         ld      (CURSOR_ROW), de
  387.         jp      MainLoop
  388.  
  389.  
  390.  
  391. ; Thanks for Randy Gluvna (gluvna@home.com) for this recieve routine.
  392.  
  393.  
  394.  
  395. GetByte:
  396.         LD      B,008H
  397. R0:
  398.         LD      DE,0FFFFH       
  399.         JR      R2              
  400. R1:
  401.         IN      A,(PORT)        
  402.         AND     003H            
  403.         RET     Z               
  404.         CP      003H            
  405.         JR      NZ,R3           
  406.         IN      A,(PORT)        
  407.         AND     003H            
  408.         RET     Z               
  409.         CP      003H            
  410.         JR      NZ,R3           
  411. R2:
  412.         DEC     DE              
  413.         LD      A,D             
  414.         OR      E               
  415.         JR      NZ,R1           
  416.         RET                     
  417. R3:
  418.         SUB     002H            
  419.         JR      NC,R8           
  420.         LD      A,0D4H          
  421.         OUT     (PORT),A        
  422.         RR      C               
  423.         LD      DE,0FFFFH       
  424. R4:
  425.         IN      A,(PORT)        
  426.         AND     003H            
  427.         CP      002H            
  428.         JR      Z,R5            
  429.         DEC     DE              
  430.         LD      A,D             
  431.         OR      E               
  432.         JR      NZ,R4           
  433.         RET                     
  434. R5:
  435.         LD      A,0C0H          
  436.         OUT     (PORT),A        
  437.         LD      D,004H          
  438. R6:
  439.         DEC     D               
  440.         JR      Z,R7            
  441.         IN      A,(PORT)        
  442.         AND     003H            
  443.         CP      003H            
  444.         JR      NZ,R6           
  445. R7:
  446.         DJNZ    R0              
  447.         LD      A,C             
  448.         RET                     
  449. R8:
  450.         LD      A,0E8H          
  451.         OUT     (PORT),A        
  452.         RR      C               
  453.         LD      DE,0FFFFH       
  454. R9:
  455.         IN      A,(PORT)        
  456.         AND     003H            
  457.         CP      001H            
  458.         JR      Z,R5            
  459.         DEC     DE              
  460.         LD      A,D             
  461.         OR      E               
  462.         JR      NZ,R9           
  463.         RET                     
  464.  
  465.  
  466. PutByte:
  467.         push bc
  468.         LD      C,A
  469.         LD      B,8             ; 8 Bits
  470. PB_Next_Bit:
  471.         LD      A, $C0          ; Set W1 and R1
  472.         OUT     (0),A
  473.  
  474. Cont:
  475.         RR      C
  476.         JR      NC, PB_SendZero
  477. PB_SendOne:
  478.         LD      A, $E8
  479.         JR      PB_Output_val
  480. PB_SendZero:
  481.         LD      A, $D4
  482. PB_Output_val:
  483.         OUT     (0),A
  484.  
  485.         LD      DE, $FFFF       ; For time-out
  486. PB_Wait_for_W0_and_R0:
  487.         IN      A,(0)
  488.         AND     3
  489.         JR      Z, PB_Continue
  490.         IN      A,(0)
  491.         AND     3
  492.         JR      Z, PB_Continue
  493.         DEC     DE
  494.         LD      A,D
  495.         OR      E
  496.         JR      NZ, PB_Wait_for_W0_and_R0
  497.         JR      PB_End          ; If error return.
  498.  
  499. PB_Continue:
  500.         LD      A, $C0          ; Set W1 and R1
  501.         OUT     (0),A
  502.  
  503.         LD      DE, $FFFF       ; Reload time-out
  504. PB_Wait_for_W1_and_R1:
  505.         DEC     DE
  506.         LD      A,D
  507.         OR      E
  508.         JR      Z, PB_End
  509.         IN      A,(0)
  510.         AND     3
  511.         CP      3
  512.         JR      NZ, PB_Wait_for_W1_and_R1
  513.  
  514.         DJNZ    PB_Next_Bit
  515. PB_End:
  516.         POP    BC
  517.         RET
  518.  
  519.  
  520. Scan2Index:
  521. .db 1, 2, 3, 4, 5, 0, 0, 6, 7, 8, 9, 10, 11
  522. .db 1, 2, 12, 13, 14, 15, 16, 17, 18
  523. .db 0, 19, 20, 21, 22, 23, 24, 25, 0
  524. .db 0, 26, 27, 28, 29, 30, 31
  525.  
  526.  
  527.  
  528. Index2Ascii:
  529. ; Plain
  530. .db 0,$22, "wrmh?", $c1,
  531. .db "vqlg:zupkfc yto"
  532. .db "jebxsnida"
  533.  
  534. Index2Shift:
  535. .db 0,$22, "WRMH?", $c1,
  536. .db "VQLG:ZYPKFC YTO"
  537. .db "JEBXSNIDA"
  538.  
  539. Index2Num:
  540. .db 0,"+-*/^-3"
  541. .db "69)", 34, ".258(", 196, "!0147"
  542. .db "E<>=e", $1D, $D3, 206, "?"
  543.  
  544.  
  545.  
  546. ProgName:
  547. .db "InfraRed Chat", 0
  548.  
  549. .end
  550.  
  551.