home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD2.mdf / c / library / dos / diverses / cexpress / bits / intbits.asm < prev    next >
Encoding:
Assembly Source File  |  1989-05-04  |  2.1 KB  |  77 lines
  1. ;void  set_int_bits(value,bits,position);
  2. ;  unsigned short  *value;
  3. ;  unsigned char   *bits,position;
  4.  
  5.     EXTRN  _memory_model:byte
  6.     EXTRN  _error_code:byte
  7.  
  8. _TEXT    SEGMENT  BYTE PUBLIC 'CODE'
  9.     ASSUME CS:_TEXT
  10.     PUBLIC _set_int_bits
  11. _set_int_bits proc near
  12.     push bp            ;
  13.     mov  bp,sp        ;set stack frame
  14.     push di            ;
  15.     push si            ;
  16.     push ds            ;save DS
  17.     mov  _error_code,1    ;flag error
  18.     cmp  _memory_model,0    ;near or far?
  19.     jle  begin        ;jump if near
  20.     inc  bp            ;else add 2 to BP
  21.     inc  bp            ;
  22. begin:    cmp  _memory_model,2    ;data near or far?
  23.     jb   L1            ;jump if near
  24.     les  di,dword ptr[bp+4] ;get addr of the word
  25.     lds  si,dword ptr[bp+8] ;DS:SI pts to bit_string
  26.     add  bp,4        ;forward BP to compensate for dbl words
  27.     jmp  short L2        ;jump ahead
  28. L1:    mov  ax,ds        ;ES = DS
  29.     mov  es,ax        ;
  30.     mov  di,[bp+4]        ;near case
  31.     mov  si,[bp+6]        ;
  32. L2:    sub  dx,dx        ;will count number bits in field
  33.     push si            ;
  34. L3:    cmp  byte ptr[si],0    ;end of string?
  35.     je   L4            ;jump if so
  36.     inc  dx            ;inc counter
  37.     inc  si            ;forward ptr
  38.     cmp  dx,16        ;reached maximum yet?
  39.     jne  L3            ;loop if not
  40. L4:    pop  si            ;restore si
  41.     mov  bx,1        ;BX is mask
  42.     sub  cx,cx        ;clear CX
  43.     mov  cl,[bp+8]        ;get field start pos
  44.     add  cx,dx        ;add start position to number bits
  45.     cmp  cx,16        ;in range?
  46.     ja   L8            ;quit routine if not
  47.     dec  cx            ;adjust for shift
  48.     shl  bx,cl        ;mov mask bit to 1st pos
  49.     mov  cx,dx        ;get string length
  50.     jcxz L8            ;quit if null
  51.     mov  ax,es:[di]        ;fetch value
  52. L5:    cmp  byte ptr[si],'1'    ;test a byte of the string
  53.     jne  L6            ;jump if not a '1'
  54.     or   ax,bx        ;else, set the bit
  55.     jmp  short L7        ;jump ahead
  56. L6:    not  bx            ;reverse the mask
  57.     and  ax,bx        ;clear the bit
  58.     not  bx            ;re-reverse the mask
  59. L7:    shr  bx,1        ;shift bit mask 1 to right
  60.     inc  si            ;pt to next byte of strg
  61.     loop L5            ;go do next byte
  62.     mov  es:[di],ax        ;write the changed value
  63.     pop  ds            ;restore DS
  64.     dec  _error_code    ;0 = no error
  65.     jmp  short L9        ;jump ahead
  66. L8:    pop  ds            ;restore DS
  67. L9:    pop  si            ;
  68.     pop  di            ;
  69.     pop  bp            ;
  70.     cmp  _memory_model,0    ;quit
  71.     jle  quit        ;
  72.     db   0CBh        ;RET far
  73. quit:    ret            ;RET near
  74. _set_int_bits endp
  75. _TEXT    ENDS
  76.     END
  77.