home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsinit.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  10.9 KB  |  402 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. INCLUDE mixed.inc
  34.  
  35. IFDEF   ALLPUBLIC
  36. INCLUDE tsinit.pub      ;public definitions (uses Periscope PUBLIC.COM /E)
  37. ENDIF
  38.  
  39. .MODEL small
  40.  
  41. EXTRN TSRCLEANUP:FAR
  42.  
  43. .CODE
  44.  
  45. EXTRN _TESSSETUPINTS:near
  46. EXTRN _TESSGETPSP:near
  47. EXTRN _TESS_TEMPPARMS:byte
  48. EXTRN _TESS_CPYRT:byte
  49. EXTRN TESSBEEP:FAR
  50.  
  51. EXTRN TESS_GLOBALS:byte
  52. EXTRN TESS_USERPARMS:byte
  53.  
  54. ENDIF
  55.  
  56. IFNDEF ASMCOM
  57.  
  58. hProc <TSDOINIT FAR>, <USES SI,DI>, HotKeyScan:byte, ShiftStateFlag:byte, TSRFlags:word, MemoryTop:word
  59.  
  60. ELSE
  61.  
  62. ;
  63. ;       In the assembler version, parameters are passed in registers; note 
  64. ;           that this function should not return unless there was a major
  65. ;           problem!
  66. ;
  67. ;       On entry:
  68. ;               AH = Scan Code of hotkey
  69. ;               AL = Shift State of hotkey
  70. ;               BX = TSR Activation Flags
  71. ;               DX = offset of Top of Memory
  72. ;
  73.  
  74. PUBLIC TSDOINIT
  75. TSDOINIT proc near
  76.  
  77. ENDIF
  78.  
  79. IFNDEF ASMCOM
  80.  
  81.         ASSUMENODS
  82.         mov     ax,ds
  83.         push    ds                      ;save data segment
  84.  
  85.         mov     WPTR [OURDSEG],ax       ;save default data segment
  86.  
  87.         push    cs
  88.         pop     ds                      ;address our segments
  89.  
  90.         ASSUMEDS
  91.  
  92. ELSE
  93.  
  94.         ASSUMEDS
  95.  
  96.         mov     WPTR [OURDSEG],cs       ;save default data segment
  97.  
  98.         push    dx
  99.         push    bx
  100.         push    ax                      ;save parameters for later!
  101. ENDIF
  102.  
  103.         mov     ax,3000h                ;get DOS version number
  104.         int     21h
  105.         mov     BPTR [DOSVERSION],al    ;0=1+,2=2.0+,3=3.0+
  106.  
  107.         push    cs
  108.         pop     es                      ;address our segments
  109.  
  110.         lea     si,_TESS_TEMPPARMS
  111.         lea     di,[USERPARMS]
  112.         mov     cx,0ah
  113.  
  114.         rep     movsb
  115.  
  116.         mov     ax,3400h                ;find the DOS Indos Byte
  117.         int     21h
  118.  
  119.         mov     WPTR [INDOSFLAG],bx     ;offset returned in BX
  120.         mov     WPTR [INDOSFLAG+2],es ;segment returned in ES
  121.  
  122.  
  123.         cmp     BPTR [DOSVERSION],4     ;if we're running OS/2
  124.         ja      criterr_not_needed      ;fake the criterr byte
  125.  
  126.         mov     WPTR [DOSCRITERR+2],es  ;as well as the segment for the critical flag
  127.  
  128.         mov     cx,8000h                ;search for instruction: CMP [crit flag],00
  129.  
  130.         mov     bx,0                    ;start search at beginning of segment
  131. Find_Critical_flag:
  132.         mov     ax,3e80h                ;3e80 is opcode to search for
  133.         mov     di,bx                   ;start search here
  134.         repnz   scasw                   ;search until a match is found
  135.  
  136.         jz      save_critical
  137.         jmp     short next_try          ;couldn't find critical byte
  138.  
  139. save_critical:
  140.  
  141.                                         ;now we're going to search for the
  142.                                         ;address of the critical flag
  143.  
  144.                                         ;es:[di-2] now points to:
  145.                                         ;       CMP [crit flag],00
  146.                                         ;       JNZ ...
  147.                                         ;       MOV SP,indos stack address
  148.  
  149.         mov     al,BPTR es:[di+5]       ;MOV SP,xxxx
  150.         cmp     al,0bch                 ;opcode for MOV SP
  151.         je      Found_Critical
  152. ;..lf                                   ;not right opcode, seach again
  153.         mov     bx,di                   ;restart search from last byte
  154. next_try:
  155.         push    bx
  156.         rcr     bx,1                    ;see if first or second time
  157.         pop     bx
  158.         jc      try_again
  159.         jcxz    bump_bx                 ;make sure we have more to search for
  160.         jmp short Find_Critical_flag    
  161. bump_bx:
  162.         mov     bx,1                    ;start on odd boundary
  163.         mov     cx,8000h                ;odd bytes of segment
  164. try_again:
  165.         jcxz    skip2                   ;make sure we have more to search for
  166.         jmp short Find_Critical_flag    
  167. skip2:
  168.         jmp     no_crit_found
  169.  
  170. criterr_not_needed:
  171.         mov     WPTR [DOSCRITERR+2],cs  ;fake everyone out by setting
  172.                                         ;criterr to a known zero value
  173.         mov     WPTR [DOSCRITERR],offset TESS_GLOBALS - 1
  174.         jmp     short init_continue
  175.  
  176. Found_Critical:
  177.         mov     ax,WPTR es:[di] ;here's the critical byte address
  178.         mov     WPTR [DOSCRITERR],ax
  179. init_continue:
  180.  
  181. IFNDEF ASMCOM
  182.         mov     al,HotKeyScan
  183.         mov     BPTR [HOTKEY],al
  184.         mov     al,ShiftStateFlag
  185.         mov     BPTR [SHIFTST],al
  186.  
  187. ELSE
  188.         pop     ax                      ;recover hotkey stuff
  189.         mov     BPTR [HOTKEY],al
  190.         mov     BPTR [SHIFTST],ah
  191. ENDIF
  192.         xor     ax,ax
  193.         mov     WPTR [STATUS],ax        ;clear status flags
  194.  
  195. get_psp_dta:
  196.  
  197.         getdta  <[OURDTA]>
  198.  
  199.         call    _TESSGETPSP
  200.         mov     WPTR [OURPSP],bx
  201.  
  202. set_popup:
  203.  
  204. IFNDEF ASMCOM
  205.         mov     ax,TSRFlags
  206. ELSE
  207.         pop     ax                      ;recover Tsr Activation info
  208. ENDIF
  209.         mov     WPTR [STATUS],ax        ;turn on appropriate flags
  210.  
  211. IFNDEF NOCKSUM
  212.         push    cs
  213.         pop     ds                      ;our segment
  214.         mov     si,offset _TESS_CPYRT   ;address to check
  215.  
  216.         xor     ax,ax
  217.  
  218. CK      equ     0e0h
  219.  
  220. ck_1:
  221.         lodsb                           ;get the byte
  222.         or      al,al                   ;are we at end?
  223.         jz      c_ck                    ;yep
  224.  
  225.         add     ah,al                   ;add it in
  226.         jmp     ck_1
  227.  
  228. c_ck:
  229.  
  230.         cmp     ah,CK
  231.         je      ck_ok
  232.  
  233.         call    TESSBEEP
  234.         jmp     c_ck
  235. ck_ok:
  236. ENDIF
  237.  
  238. save_hdl:
  239.         push    ds
  240.         mov     ax,WPTR [OURPSP]        ;get our PSP segment
  241.         mov     ds,ax
  242.         mov     bx,18h                  ;offset of handle table
  243.         mov     cx,3
  244. save_hdl_loop:
  245.         push    [bx]                    ;save each handle on stack
  246.         inc     bx
  247.         inc     bx
  248.         loop    save_hdl_loop
  249.  
  250.         mov     cx,5
  251. close_loop:
  252.         push    cx                      ;close the DOS pre-opened
  253.         mov     bx,cx                   ;handles
  254.         dec     bx
  255.         mov     ah,03eh
  256.  
  257.         int     21h
  258.  
  259.         pop     cx
  260.         loop    close_loop
  261.  
  262. restore_hdl_tbl:
  263.  
  264.         mov     bx,1Ch                  ;restore the handles
  265.         mov     cx,3
  266. rest_hdl_loop:
  267.         pop     [bx]
  268.         dec     bx
  269.         dec     bx
  270.         loop    rest_hdl_loop
  271.  
  272.         pop     ds
  273.  
  274. ;
  275. ;This patch courtesy of Brian Foley of TurboPower Software
  276. ;
  277. patch_sidekick:
  278.  
  279.         mov     ax,3508h
  280.         int     21h
  281.  
  282.         cmp     WPTR es:[bx-4],4b53h
  283.         jne     go_resident
  284.  
  285.         cmp     WPTR es:[bx-2],4942h
  286.         jne     go_resident
  287.  
  288.         mov     cx,100d                 ;it's early in the handler
  289.  
  290.         mov     al,1fh                  ;1f8c is opcode to search for
  291.         mov     di,bx                   ;start search here
  292.  
  293. not_this_opcode:
  294.         repnz   scasb                   ;search until a match is found
  295.         jz      found_sk        
  296.  
  297.         jcxz    go_resident             ;must be SK+
  298.  
  299. found_sk:
  300.         cmp     BPTR es:[di+4],74h      ;is it the JZ code?
  301.         jne     not_this_opcode         ;already changed!
  302.  
  303.         mov     BPTR es:[di+4],0ebh
  304.  
  305. go_resident:
  306.  
  307.         push    ds
  308.         mov     ax,40h
  309.         mov     ds,ax
  310.  
  311.         ASSUMENODS
  312.  
  313.         mov     si,80h                  ;check the BIOS data area
  314.         lodsw                           ;to make sure it supports
  315.         or      ax,ax                   ;the points to the keyboard
  316.         jnz     ok_kbd                  ;buffer
  317.  
  318.         mov     di,80h                  ;not OK, so
  319.         push    ds                      ;load the pointers in 
  320.         pop     es                      ;the correct place
  321.  
  322.         cli
  323.         mov     ax,1eh
  324.         stosw
  325.         add     ax,20h
  326.         stosw
  327.         mov     di,1ah
  328.         sub     ax,20h
  329.         stosw
  330.         stosw
  331.         sti
  332. ok_kbd:
  333.         pop     ds
  334.         ASSUMEDS
  335.  
  336.         xor     ax,ax                   ;start with our interrupts
  337.         inc     ax
  338.         call    _TESSSETUPINTS          ;setup interrupts
  339.  
  340.         mov     ax,5453h                ;call multiplex
  341.         mov     bx,10h                  ;  to enable TSR
  342.         mov     cx,WPTR [IDNUM]         ; our ID Number
  343.         int     2fh
  344.  
  345.         push    ds
  346.         mov     ax,WPTR [OURDSEG]
  347.         mov     ds,ax
  348.  
  349.         ASSUMENODS
  350.  
  351.         xor     ax,ax
  352.  
  353. IFNDEF ASMCOM
  354.         push    ax                      ;AX=0, initialize routine
  355. ENDIF
  356.  
  357. IFDEF   TP4
  358. IFNDEF ASMCOM
  359.         call    DPTR PCLEANUP           ;call user routine (TP4 version)
  360. ELSE
  361.         call    TSRCLEANUP              ;call user routine
  362. ENDIF
  363. ELSE
  364.         call    TSRCLEANUP              ;call user routine
  365. ENDIF
  366.  
  367.         pop     ds
  368.  
  369.         ASSUMEDS
  370.  
  371. IFNDEF ASMCOM
  372.         mov     dx,MemoryTop
  373. ELSE
  374.         pop     dx                      ;recover top of memory
  375.         shr     dx,1
  376.         shr     dx,1
  377.         shr     dx,1
  378.         shr     dx,1                    ;convert to paragraphs (DX / 16)
  379.         inc     dx                      ;round up!!
  380. ENDIF
  381.  
  382.         xor     al,al                   ; no errors
  383.         mov     ah,31h                  ; load terminate & stay resident code
  384.         int     21h
  385.  
  386. no_crit_found:                          ;exiting 'cause we couldn't find the critical
  387.                                         ;error flag byte
  388. abort_out:
  389. IFNDEF ASMCOM
  390.         mov     ax,-1
  391.         pop     ds
  392.         hRet
  393. hEndp
  394.  
  395. ELSE
  396.         ret
  397. TSDOINIT endp
  398.  
  399. ENDIF
  400.  
  401. ENDIT
  402.