home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tsdobeep.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  5.9 KB  |  154 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. INCLUDE mixed.inc
  34.  
  35. .MODEL small
  36. .CODE
  37.  
  38. ENDIF
  39.  
  40. IFNDEF ASMCOM
  41.  
  42. hProc <TESSBEEP FAR>  <USES SI,DI>
  43.         call    error_beep
  44.         hRet
  45. hEndp
  46.  
  47. ENDIF
  48.  
  49. ;*** ERROR_BEEP *************************************************************
  50. ;  This routines sends a beep-beep to the speaker; it is called when        *
  51. ;      Ringmaster determines it cannot pop up for any reason whatsoever.    *
  52. ;                                                                           *
  53. ;  Registers Modified:                                                      *
  54. ;      AX, BX, CX, DX trashed; all others unmodified                        *
  55. ;************************************************************************CR*/
  56. IFDEF ASMCOM
  57.  
  58. PUBLIC TESSBEEP
  59. TESSBEEP:
  60.  
  61. ENDIF
  62.  
  63. error_beep proc near
  64.         pushf
  65.         sti
  66.         mov     cx,420h                 ;start at high C
  67.  
  68. sound_again:
  69.         mov     dx,12h
  70.         mov     ax,34dch
  71.         div     cx
  72.         call    speakeron
  73. s10:
  74.         mov     ax,1                    ;put counter into delay loop
  75.         call    timer
  76.  
  77.         cmp     cx,300h                 ;are we at middle C?
  78.         je      exit_sound
  79.  
  80.         sub     cx,30h
  81.  
  82.         jmp     short sound_again
  83.  
  84. exit_sound:
  85.         xor     ax,ax
  86.         call    speakeron
  87.  
  88.         POPFF
  89.         ret
  90. error_beep endp
  91.  
  92. ;*** SPEAKERON **************************************************************
  93. ;  Routine to turn the speaker on or off at the appropriate frequency       *
  94. ;      (passed in AX).  If AX is zero (0), the speaker is turned off;       *
  95. ;      otherwise, the speaker is set to the appropriate pitch.              *
  96. ;                                                                           *
  97. ;  Registers Modified:                                                      *
  98. ;      AX trashed; all others unchanged                                     *
  99. ;************************************************************************CR*/
  100. speakeron proc near
  101.         push    ax                      ;save frequency
  102.         in      al,61h                  ;get current port setting
  103.         and     al,0fch                 ;setting to turn off speaker
  104.         out     61h,al                  ;turn off speaker
  105.         mov     al,10110110b
  106.         out     43h,al
  107.         pop     ax                      ;recover frequency
  108.         cmp     ax,0                    ;is it = 0?
  109.         je      sp10                    ;if yes, just exit
  110.         out     42h,al                  ;output low order byte to port first
  111.         mov     al,ah                   ;prepare high order byte for out instruction
  112.         out     42h,al                  ;output high order byte to timer port
  113.         in      al,61h                  ;get current port setting
  114.         or      al,3                    ;turn on two low order bits for speaker on
  115.                                         ;under control of timer port
  116.         out     61h,al                  ;turn speaker on
  117. sp10:
  118.         ret
  119. speakeron endp
  120.  
  121. ;*** TIMER ******************************************************************
  122. ; Provide a timed delay of 1/18.2 second intervals.  Delay count is passed  *
  123. ;     to the function in the AX register.  Maximum delay possible is        *
  124. ;     approximately 14 (255/18.2) seconds.                                  *
  125. ;                                                                           *
  126. ; Registers Modified:                                                       *
  127. ;    AX, BX, DX trashed; All others preserved                               *
  128. ;************************************************************************CR*/
  129. timer   proc    near
  130.         push    di                      ; save registers
  131.         push    cx
  132.         or      ax,ax                   ; make sure we have a value
  133.         jz      tout
  134.         mov     di,ax                   ; save counter
  135.         xor     ah,ah                   ; see what ticker says first
  136.         int     1Ah                     ; CX:DX is starting point.
  137.         mov     bx,dx                   ; save initial low order count
  138. tloop:
  139.         xor     ah,ah                   ; function to get timer
  140.         int     1Ah                     ; get timer tiks to CX:DX
  141.         cmp     bx,dx                   ; see if low order has changed
  142.         jz      tloop                   ; if not get it again
  143.         mov     bx,dx                   ; update bx with new low order count
  144.         dec     di                      ; --interval
  145.         jnz     tloop                   ; if not down to 0
  146. tout:
  147.         pop     cx
  148.         pop     di
  149.         ret
  150.         timer   endp
  151.  
  152.  
  153. ENDIT
  154.