home *** CD-ROM | disk | FTP | other *** search
/ Power-Programmierung / CD1.mdf / pascal / library / dos / teseract / source / tschkres.asm < prev    next >
Encoding:
Assembly Source File  |  1988-10-02  |  4.5 KB  |  170 lines
  1. IFNDEF TP4
  2.         PAGE 60,132
  3. ;----------------------------------------------------------------------------
  4. SUBTTL  TesSeRact Revision Level 1
  5. ;-----------------------------------------------------------------------------
  6. ;   TesSeRact(tm) -- A Library of Routines for Creating Ram-Resident (TSR)
  7. ;                    programs for the IBM PC and compatible Personal
  8. ;                    Computers.
  9. ;
  10. ;The software, documentation and source code are: 
  11. ; 
  12. ;       Copyright (C) 1986, 1987, 1988 Tesseract Development Team
  13. ;       All Rights Reserved 
  14. ; 
  15. ;       c/o Chip Rabinowitz
  16. ;       Innovative Data Concepts
  17. ;       2084 Woodlawn Avenue
  18. ;       Glenside, PA 19038
  19. ;       1-215-884-3373
  20. ;
  21. ;-----------------------------------------------------------------------------
  22. ;   This product supports the TesSeRact Standard for Ram-Resident Program 
  23. ;   Communication.  For information about TesSeRact, contact the TesSeRact 
  24. ;   Development Team at:
  25. ;       Compuserve:    70731,20
  26. ;       MCIMAIL:       315-5415
  27. ;   This MCIMAIL Account has been provided to the TesSeRact Development
  28. ;   Team by Borland International, Inc.  The TesSeRact Development Team
  29. ;   is in no way associated with Borland International, Inc.
  30. ;-----------------------------------------------------------------------------
  31.  
  32. INCLUDE TESS.INC
  33. INCLUDE mixed.inc
  34.  
  35. IFDEF   ALLPUBLIC
  36. INCLUDE tschkres.pub    ;public definitions (uses Periscope PUBLIC.COM /E)
  37. ENDIF
  38.  
  39. .MODEL small
  40. .CODE
  41.  
  42. EXTRN _TESS_INTERRUPTRETURN:near
  43.  
  44. PUBLIC _TESS_TEMPPARMS
  45.  
  46. ENDIF
  47.  
  48. IFNDEF ASMCOM
  49.  
  50. hProc <TSVERIFY2F FAR>
  51.  
  52. ELSE
  53.  
  54. hProc <TSVERIFY2F NEAR>                 ; This procedure is used internally
  55.                                         ;   by TsCheckResident to ensure
  56. ENDIF                                   ;   that a valid INT 2Fh vector 
  57.         ASSUMENODS                      ;   exists.  DOS 2.x initializes
  58.                                         ;   this vector to 00 00
  59.         xor     ax,ax
  60.         mov     es,ax
  61.         mov     bx,2fh
  62.         shl     bx,1
  63.         shl     bx,1
  64.         mov     ax,es:[bx]
  65.         or      ax,es:[bx+2]
  66.         jnz     ok_2f
  67.  
  68.         mov     ax,offset _TESS_INTERRUPTRETURN
  69.         mov     es:[bx],ax
  70.         mov     es:[bx+2],cs
  71. ok_2f:
  72.  
  73.         hRet
  74. hEndp
  75.  
  76.  
  77. _TESS_TEMPPARMS   db  10 dup(0)         ; temporary data area to hold
  78.                                         ; ID String and ID Number on return
  79.                                         ; from TSCHECKRESIDENT before TsDoInit 
  80.                                         ;   v0.66
  81.  
  82.  
  83. IFNDEF ASMCOM
  84.  
  85. hProc <TSCHECKRESIDENT FAR> <USES SI, DI>, UserName:dword, IDNumber:dword
  86.  
  87. else
  88.  
  89. PUBLIC TSCHECKRESIDENT 
  90. TSCHECKRESIDENT proc near
  91. ;
  92. ;       in the assembler version, ES=DS=CS on entry, and SI should 
  93. ;           the offset of the UserName, DI should contain the address
  94. ;           to store the returned ID number
  95. ;
  96. ENDIF
  97.         push    ds
  98.  
  99. IFDEF ASMCOM
  100.         push    di
  101.         push    si                      ;save parms for later
  102. ENDIF
  103.  
  104.         ASSUMENODS
  105.  
  106.         call    TSVERIFY2F
  107.  
  108. IFNDEF ASMCOM
  109.         lds     si,UserName
  110. ELSE
  111.         pop     si                      ;get UserName back
  112. ENDIF
  113.         push    ds
  114.         push    si
  115.         xor     cx,cx                   ;call Multiplex Function 0
  116.         xor     bx,bx
  117.         mov     ax,5453h
  118.         int     2fh
  119.  
  120.         pop     si
  121.         pop     ds
  122.  
  123.         cmp     ax,-1                   ; if AX==ffff, we're already
  124.         je      already_res             ;     resident
  125.  
  126.         push    cx
  127.         lea     di,_TESS_TEMPPARMS
  128.         push    cs
  129.         pop     es
  130.         mov     cx,8                    ;store the user name in TsrParms
  131.         rep     movsb                   ;structure
  132.         pop     ax
  133.  
  134.         stosw                           ;store the ID Number returned by
  135.                                         ;function 0 in TsrParms
  136. IFNDEF ASMCOM
  137.         les     di,IDNumber
  138. ELSE
  139.         pop     di
  140. ENDIF
  141.  
  142.         stosw                           ;also store ID number in user's
  143.                                         ;pointer
  144.         xor     ax,ax
  145.         jmp     short check_out
  146.  
  147. already_res:
  148. IFNDEF ASMCOM
  149.         les     di,IDNumber             ;store returned id number of 
  150.         mov     es:[di],cx              ;already loaded TSR in user data
  151. ELSE
  152.         pop     di
  153.         mov     [di],cx
  154. ENDIF
  155.  
  156. check_out:
  157.         pop     ds
  158. IFNDEF ASMCOM
  159.         hRet
  160. hEndp
  161.  
  162. ELSE
  163.         ret
  164. TSCHECKRESIDENT endp
  165.  
  166. ENDIF
  167.  
  168. ENDIT
  169.  
  170.