home *** CD-ROM | disk | FTP | other *** search
/ Stars of Shareware: Raytrace & Morphing / SOS-RAYTRACE.ISO / programm / source / radsrc22 / src / px / normpat.csh < prev    next >
Encoding:
Linux/UNIX/POSIX Shell Script  |  1992-01-06  |  4.1 KB  |  146 lines
  1. #!/bin/csh -f
  2. # SCCSid "@(#)normpat.csh 2.2 1/5/92 LBL"
  3. #
  4. # Normalize a pattern for tiling (-b option blends edges) by removing
  5. # lowest frequencies from image (-f option) and reducing to
  6. # standard size (-r option)
  7. #
  8. set ha=$0
  9. set ha=$ha:t
  10. set pf="pfilt -e 2"
  11. while ($#argv > 0)
  12.     switch ($argv[1])
  13.     case -r:
  14.         shift argv
  15.         set pf="$pf -x $argv[1] -y $argv[1] -p 1 -r .67"
  16.         breaksw
  17.     case -f:
  18.         set ha="$ha -f"
  19.         set dofsub
  20.         breaksw
  21.     case -b:
  22.         set ha="$ha -b"
  23.         set blend
  24.         breaksw
  25.     case -v:
  26.         set verb
  27.         breaksw
  28.     case -*:
  29.         echo bad option $argv[1]
  30.         exit 1
  31.     default:
  32.         goto dofiles
  33.     endsw
  34.     shift argv
  35. end
  36. dofiles:
  37. onintr quit
  38. set td=/usr/tmp/np$$
  39. mkdir $td
  40. cat > $td/coef.fmt << '_EOF_'
  41.    rm:${  $25   };    gm:${  $26   };    bm:${  $27   };
  42.   rcx:${   $1   };   gcx:${   $9   };   bcx:${  $17   };
  43.   rcy:${   $2   };   gcy:${  $10   };   bcy:${  $18   };
  44.   rsx:${   $3   };   gsx:${  $11   };   bsx:${  $19   };
  45.   rsy:${   $4   };   gsy:${  $12   };   bsy:${  $20   };
  46. rcxcy:${   $5   }; gcxcy:${  $13   }; bcxcy:${  $21   };
  47. rcxsy:${   $6   }; gcxsy:${  $14   }; bcxsy:${  $22   };
  48. rsxcy:${   $7   }; gsxcy:${  $15   }; bsxcy:${  $23   };
  49. rsxsy:${   $8   }; gsxsy:${  $16   }; bsxsy:${  $24   };
  50. '_EOF_'
  51. cat > $td/coef.cal << '_EOF_'
  52. $1=$3*2*cx; $2=$3*2*cy; $3=$3*2*sx; $4=$3*2*sy;
  53. $5=$3*4*cx*cy; $6=$3*4*cx*sy; $7=$3*4*sx*cy; $8=$3*4*sx*sy;
  54. $9=$4*2*cx; $10=$4*2*cy; $11=$4*2*sx; $12=$4*2*sy;
  55. $13=$4*4*cx*cy; $14=$4*4*cx*sy; $15=$4*4*sx*cy; $16=$4*4*sx*sy;
  56. $17=$5*2*cx; $18=$5*2*cy; $19=$5*2*sx; $20=$5*2*sy;
  57. $21=$5*4*cx*cy; $22=$5*4*cx*sy; $23=$5*4*sx*cy; $24=$5*4*sx*sy;
  58. $25=$3; $26=$4; $27=$5;
  59. cx=cos(wx); cy=cos(wy);
  60. sx=sin(wx); sy=sin(wy);
  61. wx=2*PI*($1+.5)/xres; wy=2*PI*($2+.5)/yres;
  62. '_EOF_'
  63. cat > $td/fsub.cal << '_EOF_'
  64. PI:3.14159265358979323846;
  65. ro=ri(1)*rm/(rm+rcx*cx+rcy*cy+rsx*sx+rsy*sy
  66.         +rcxcy*cx*cy+rcxsy*cx*sy+rsxcy*sx*cy+rsxsy*sx*sy);
  67. go=gi(1)*gm/(gm+gcx*cx+gcy*cy+gsx*sx+gsy*sy
  68.         +gcxcy*cx*cy+gcxsy*cx*sy+gsxcy*sx*cy+gsxsy*sx*sy);
  69. bo=bi(1)*bm/(bm+bcx*cx+bcy*cy+bsx*sx+bsy*sy
  70.         +bcxcy*cx*cy+bcxsy*cx*sy+bsxcy*sx*cy+bsxsy*sx*sy);
  71. cx=cos(wx); cy=cos(wy);
  72. sx=sin(wx); sy=sin(wy);
  73. wx=2*PI*(x+.5)/xres; wy=2*PI*(y+.5)/yres;
  74. '_EOF_'
  75. foreach f ($*)
  76.     if ( $?verb ) then
  77.         echo $f\:
  78.         echo adjusting exposure/size...
  79.     endif
  80.     $pf $f > $td/pf
  81.     getinfo < $td/pf > $f
  82.     ed - $f << _EOF_
  83. i
  84. $ha
  85. .
  86. w
  87. q
  88. _EOF_
  89.     set resolu=`getinfo -d < $td/pf | sed 's/-Y \([0-9]*\) +X \([0-9]*\)/\2 \1/'`
  90.     if ( ! $?dofsub ) then
  91.         mv $td/pf $td/hf
  92.         goto donefsub
  93.     endif
  94.     if ( $?verb ) then
  95.         echo computing Fourier coefficients...
  96.     endif
  97.     pfilt -1 -x 32 -y 32 $td/pf | pvalue -h \
  98.         | rcalc -f $td/coef.cal -e 'xres=32;yres=32' \
  99.         | total -m | rcalc -o $td/coef.fmt \
  100.         > $td/coef
  101.     if ( $?verb ) then
  102.         cat $td/coef
  103.         echo removing low frequencies...
  104.     endif
  105.     pcomb -f $td/coef -f $td/fsub.cal \
  106.         -e "xres=$resolu[1];yres=$resolu[2]" \
  107.         $td/pf > $td/hf
  108.     donefsub:
  109.     if ( $?blend ) then
  110.         if ( $?verb ) then
  111.             echo blending edges...
  112.         endif
  113.         @ mar= $resolu[1] - 3
  114.         @ les= $resolu[1] - 1
  115.         pcompos -x 1 $td/hf 0 0 | pfilt -1 -x 3 > $td/left
  116.         pcompos $td/hf -$les 0 | pfilt -1 -x 3 > $td/right
  117.         pcomb -e 'ro=f(ri);go=f(gi);bo=f(bi)' \
  118.             -e 'f(p)=(3-x)/7*p(1)+(4+x)/7*p(2)' \
  119.             $td/right $td/left > $td/left.patch
  120.         pcomb -e 'ro=f(ri);go=f(gi);bo=f(bi)' \
  121.             -e 'f(p)=(1+x)/7*p(1)+(6-x)/7*p(2)' \
  122.             $td/left $td/right > $td/right.patch
  123.         pcompos $td/hf 0 0 $td/left.patch 0 0 $td/right.patch $mar 0 \
  124.             > $td/hflr
  125.         @ mar= $resolu[2] - 3
  126.         @ les= $resolu[2] - 1
  127.         pcompos -y 1 $td/hflr 0 0 | pfilt -1 -y 3 > $td/bottom
  128.         pcompos $td/hflr 0 -$les | pfilt -1 -y 3 > $td/top
  129.         pcomb -e 'ro=f(ri);go=f(gi);bo=f(bi)' \
  130.             -e 'f(p)=(3-y)/7*p(1)+(4+y)/7*p(2)' \
  131.             $td/top $td/bottom > $td/bottom.patch
  132.         pcomb -e 'ro=f(ri);go=f(gi);bo=f(bi)' \
  133.             -e 'f(p)=(1+y)/7*p(1)+(6-y)/7*p(2)' \
  134.             $td/bottom $td/top > $td/top.patch
  135.         pcompos $td/hflr 0 0 $td/bottom.patch 0 0 $td/top.patch 0 $mar \
  136.             | getinfo - >> $f
  137.     else
  138.         getinfo - < $td/hf >> $f
  139.     endif
  140.     if ( $?verb ) then
  141.         echo $f done.
  142.     endif
  143. end
  144. quit:
  145. rm -rf $td
  146.