Stars of Shareware: Raytrace & Morphing/SOS-RAYTRACE.ISO/programm/scripts/pov/bathroom/bathroom.pov

Text File | 1980-03-09 | 10.9 KB | 674 lines

// Bathroom by Marc Gumpinger 1993 [100114,2165]

#declare Clear = color red 1 green 1 blue 1 alpha 1
#declare White = color red 1 green 1 blue 1
#declare Black = color

#include "shapes.inc"
#include "shapesq.inc"


/****************************************
          D E C L A R A T I O N S
****************************************/


// -------------- TEXTURES --------------

#declare Wall_Texture =
texture
{
    agate
    turbulence 1000
    color_map
    {
        [0 0.75 color red 0.9 green 0.9 blue 0.9 color red 0.85 green 0.85 blue 0.8]
        [0.75 0.95 color red 0.85 green 0.85 blue 0.8 color red 0.725 green 0.725 blue 0.725]
        [0.95 1 color red 0.725 green 0.725 blue 0.725 color red 0.3 green 0.3 blue 0.2]
    }
    roughness 3
    scale <0.5 0.5 0.5>
    ambient 0.2
    diffuse 1
}
texture
{
    spotted
    turbulence 0.3
    color_map
    {
        [0 0.8 color Clear color Clear]
        [0.8 0.8 color red 0.7 green 0.7 blue 0.7 color red 0.4 green 0.4 blue 0.4 alpha 0.5]
        [0.8 1 color red 0.4 green 0.4 blue 0.4 alpha 0.5 color red 0.35 green 0.35 blue 0.35]
    }
    dents 0.1
    ripples 0.1
    scale <0.01 0.01 0.01>
    ambient 0.2
    diffuse 1
}
texture
{
    agate
    turbulence 1
    color_map
    {
        [0 0.75 color Clear color Clear]
        [0.75 1 color red 0.1 green 0.1 blue 0.1 alpha 0.3 color red 0.1 green 0.1 blue 0.1 alpha 0.4]
    }
    scale <1.5 1.5 1.5>
    dents 0.1
    bumps 0.1
    ambient 0.2
    diffuse 1
}
texture
{
    marble
    turbulence 1000
    color_map
    {
        [0 0.7 color Clear color Clear]
        [0.7 1 color red 0.5 green 0.5 blue 0.5 alpha 0.9 color red 0.5 green 0.5 blue 0.5 alpha 1]
    }
    dents 0.1
    bumps 0.1
    scale <20 20 20>
    ambient 0.2
    diffuse 1
    reflection 0.15
}
texture
{
    marble
    turbulence 0.95
    color_map
    {
        [0 0.995 color Clear color Clear]
        [0.995 1 color Black alpha 0.1 color Black alpha 0.1]
    }
    scale <18 8 10>
    translate <-3 0 0>
    ambient 0
    diffuse 0.5
}

#declare Blob_Texture =
texture
{
    turbulence 2
    color color red 0.9 green 0.9 blue 1 alpha 0.875
    waves 1
    scale <0.15 0.15 0.15>
    ambient 0.25
    diffuse 1
    refraction 1
    ior 1.33
}
texture
{
    turbulence 0.25
    gradient <0 1 0>
    color_map
    {
        [0 0.3 color Clear color Clear]
        [0.3 0.45 color Clear color red 0.1 green 0.1 blue 0.75 alpha 0.8]
        [0.45 1 color red 0.1 green 0.1 blue 0.75 alpha 0.9 color red 0.05 green 0.05 blue 0.45 alpha 0.9]
    }
    ambient 0.2
    diffuse 1
    refraction 1
    ior 1.33
    scale <0.25 1.3 1>
    translate <0 -0.225 0>
    waves 1
}
texture
{
    turbulence 1.5
    bozo
    color_map
    {
        [0 0.8 color Clear color Clear]
        [0.8 1 color green 0.4 alpha 0.3 color green 0.15 alpha 0.1]
    }
    ambient 0.2
    diffuse 1
    refraction 1
    ior 1.33
    waves 1
    scale <0.4 0.4 0.4>
    translate <-0.35 0.6 0>
}

#declare TapTexture =
texture
{
    metallic
    color red 0.95 green 0.95 blue 0.95
    reflection 0.95
    ambient 0.05
    diffuse 0.2
    brilliance 8.0
 specular 0.8
 roughness 0.0005
}

#declare basinTextureOut =
texture
{

    color White
    bumps 0.05
    ambient 0.05
    diffuse 1
    specular 0.45
    roughness 0.4
    reflection 0.175
    brilliance 3
    phong 0.75
 phong_size 100
}

#declare basinTextureIn =
texture
{

    color White
    bumps 0.05
    ambient 0.05
    diffuse 0.75
    specular 0.25
    roughness 0.2
    reflection 0.175
    brilliance 3
    phong 0.75
 phong_size 80
}


// -------------- OBJECTS --------------

declare Torus =
quartic
{
    < 1 0 0 0 2 0 0 2 0 -52.84
   0 0 0 0 0 0 0 0 0 0
   1 0 0 2 0 49.595 0 0 0 0
   1 0 -52.84 0 614.9160063 >
}

declare Torus2 =
quartic
{
    < 1 0 0 0 2 0 0 2 0 -51
   0 0 0 0 0 0 0 0 0 0
   1 0 0 2 0 50 0 0 0 0
   1 0 -51 0 615 >
}

#declare tap =
composite
{
    object
    {
        union
        {
            difference
            {
                difference
                {
                    sphere { <0 0 11> 6.5 }
                    sphere { <0 0 10.25> 6 }
                }
                quadric { Cylinder_Z scale <3 3 3> inverse }
                quadric { Cylinder_Z scale <4 4 4> translate <4.8 3.2 0> }
                quadric { Cylinder_Z scale <4 4 4> translate <-4.8 3.2 0> }
                quadric { Cylinder_Z scale <4 4 4> translate <0 -5 0> }
            }
            translate <0 0 -17>
            rotate <0 -75 0>
            scale <0.5 0.5 0.5>
        }
        translate <-1 0 0>
        scale <1.25 1.25 1.25>
        texture
        {
            TapTexture
        }
    }
    object
    {
        difference
        {
            quadric { QCone_X scale <0.5 0.09 0.09> translate <-1.6 0 0> }
            plane { <1 0 0> 0 }
            plane { <1 0 0> 2 inverse }
        }
        translate <-1 0 0>
        texture
        {
            TapTexture
        }
    }
    object
    {
        difference
        {
            quartic { Torus_40_12 scale <0.05 0.025 0.05> rotate <90 0 90> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <0.6 0 0> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <-0.6 0 0> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <0 0.6 0> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <0 -0.6 0> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <0.45 0.45 0> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <-0.45 0.45 0> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <-0.45 -0.45 0> }
            quadric { Cylinder_Z scale <0.2 0.2 0.2> translate <0.45 -0.45 0> }
        }
        rotate <0 90 0>
        translate <0.5 0 0>
        scale <2 2 2>
        texture
        {
            TapTexture
        }
    }
    object
    {
        difference
        {
            blob
            {
                threshold 0.5
                component 1.25 0.75 <0 2 0>
                component 2 1 <0 1 0>
                component 1 0.75 <0 0.25 0>
                component 1 0.5 <-0.7 1 0>
                sturm
            }
            quadric { Ellipsoid scale <2 1.9 2> inverse }
            plane { <1 0 0> -1.15 }
            }
        scale <2 4 2>
        translate <3 -4 0>
        texture
        {
            TapTexture
        }
    }
    object
    {
        difference
        {
            quadric { Cylinder_Y translate <3.3 2 0> scale <0.9 0.9 0.9> }
            plane { <0 1 0> 0 }
            plane { <0 1 0> 6 inverse }
        }
        texture
        {
            TapTexture
        }
    }
    object
    {
        difference
        {
            quartic { Lemniscate scale <1.5 4 4> rotate <0 0 90> sturm }
            plane { <0 1 0> 0 inverse }
        }
        translate <3 -3.5 0>
        texture
        {
            TapTexture
        }
    }
    object
    {
        difference
        {
            quartic { Torus scale <1 1 1> rotate <90 0 0> }
            plane {<0 1 0> 0 }
        }
        rotate <0 -135 0>
        translate <6.545 6 -3.575>
        texture
        {
            TapTexture
        }
    }
    object
    {
        quartic { Torus2 scale <0.175 0.175 0.175> translate <10.125 6 -7.1> }
        texture
        {
            TapTexture
        }
    }
}

#declare basin =
object
{
    difference
    {
        union
        {
            difference
            {
                difference
                {
                    quartic
                    {
                        Piriform
                        scale <1 1.75 1>
                        rotate <0 0 90>
                        translate <0 -1 0>
                        sturm
                        texture
                        {
                            basinTextureOut
                        }
                    }
                    difference
                    {
                        quartic { Witch_Hat scale <2.2 0.55 1.45> translate <0 0 -0.05> inverse sturm }
                        plane { <0 1 0> -0.75 }
                    }
                    scale < 1 1 1.5 >
                }
                plane { <0 0 1> 0.25 inverse }
            }
            box { UnitBox scale <1.15 0.2 0.2> translate <0 -0.3 0.5> texture { basinTextureOut } }
        }
        quadric { Cylinder_X scale <0.075 0.1 0.1> translate <0 -0.1 0.35> }
    }
    texture
    {
        basinTextureIn
    }
}

#declare Eye =
composite
{
    object
    {
        quadric
        {
            Ellipsoid scale <0.3 0.3 0.3> translate <0 0.7 -0.5>
            texture
            {
                marble
                turbulence 1
                reflection 0.35
                specular 0.5
                brilliance 0.5
                ambient 0.15
                diffuse 1
                bumps 0.1
                color_map
                {
                    [0 0.9 color red 1 green 1 blue 1 color red 1 green 1 blue 1]
                    [0.9 1.01 color red 1 color red 0.5]
                }
                scale <0.2 0.2 0.2>
                rotate <0 5 0>
            }
        }
    }
    object
    {
        quadric { Ellipsoid scale <0.29 0.29 0.29> translate <0 0.7 -0.51075>}
        texture
        {
            marble
            turbulence 1
            ambient 0.1
            diffuse 0.8
            phong 1
            phong_size 50
            specular 1
            reflection 0.5
            color_map
            {
                [0 0.9 color blue 0.4 color blue 0.3]
                [0.9 1.01 color red 0 green 0 blue 0 color red 0 green 0 blue 0]
            }
            bumps 0.1
            scale <0.02 0.02 0.02>
        }
    }
    object
    {
        quadric { Ellipsoid scale <0.28 0.28 0.28> translate <0 0.7 -0.5209>}
        texture
        {
            ambient 0.1
            diffuse 0.8
            phong 1
            phong_size 50
            specular 1
            reflection 0.8
            bumps 0.1
            scale <0.2 0.2 0.2>
            color red 0 green 0 blue 0
        }
    }
    scale <2 2 2>
    translate <0 -1.5 0>
}

#declare Monster =
composite
{
    composite
    {
        #include "Blob.inc"
    }
    composite
    {
        Eye // left
        scale <0.175 0.175 0.175>
        translate <-0.1 1 -0.1>
        rotate <-10 0 0>
    }
    composite
    {
        Eye // right
        scale <0.175 0.175 0.175>
        translate <0.25 0.775 0.05> //0.25 0.775 0.075
        rotate <-8 -10 0>
    }
}

#declare Soap_Dispenser =
composite
{
    object
    {
        union
        {
            difference
            {
                quadric
                {
                    Cylinder_Y scale <1.5 1.5 1.5>
                    texture
                    {
                        color White
                        metallic
                        roughness 0.0001
                        specular 0.6
                        phong 1
                        phong_size 100
                        ambient 0
                        diffuse 1
                        reflection 0.1
                        brilliance 1.5
                    }
                    texture
                    {
                        image_map
                        {
                            2 gif "Label.gif" once alpha 0 1 interpolate 4
                        }
                        scale <0.5 3 0.5>
                        rotate <0 -120 0>
                        translate <0 -1.25 0>
                    }
                }
                plane { <0 1 0> -1.5 }
                plane { <0 1 0> 2 inverse }
            }
            difference
            {
                quadric { Ellipsoid scale <1.5 0.5 1.5> translate <0 2 0> }
                plane { <0 1 0> 2 }
            }
            difference
            {
                quadric { Cylinder_Y scale <0.6 1 0.6> }
                plane { <0 1 0> 1 }
                plane { <0 1 0> 3 inverse }
            }
            difference
            {
                quadric { Cylinder_Y scale <0.4 1 0.4> }
                plane { <0 1 0> 1 }
                plane { <0 1 0> 3.3 inverse }
            }
            difference
            {
                quadric { Cylinder_Y scale <0.325 1 0.325> }
                plane { <0 1 0> 1 }
                plane { <0 1 0> 3.8 inverse }
            }
        }
        texture
        {
            color White
            roughness 0.3
            specular 0.6
            phong 1
            phong_size 100
            ambient 0
            diffuse 0.8
            reflection 0.1
            brilliance 1.5
        }
    }
    object
    {
        difference
        {
            union
            {
                difference
                {
                    quadric { QCone_X scale <4 1 1> translate <0 3.5 0>}
                    plane { <1 0 0> -0.2╩inverse }
                    plane { <1 0 0> -1.25 }
                }
                quadric { Ellipsoid scale <0.3 0.3 0.3> translate <-1.25 3.5 0> }
            }
            plane { <0 1 0> 3.4 }
            plane { <0 1 0> 3.6 inverse }
            quadric { Ellipsoid scale <0.25 0.1 0.25> translate <-1.25 3.625 0> }
            quadric { Cylinder_Z scale <0.5 0.1 1> translate <-0.75 3.365 0> }
        }
        texture
        {
            color White
            roughness 0.3
            specular 0.6
            phong 1
            phong_size 100
            ambient 0
            diffuse 0.8
            reflection 0.1
            brilliance 1.5
        }
        scale <1.5 1.5 1.5>
        translate <1.85 -1.375 0.15>
    }
    rotate <0 15 0>
    scale <0.25 0.25 0.25>
}



/****************************************
                S C E N E
****************************************/


camera
{
    location <-8 5.1 -28>
    right <1.499267936 0 0> // the 35mm slide ratio
    up <0 1 0>
    direction <0 0 5>
    look_at <-0.2 1.1 0>
}

object
{
    light_source
    {
     <0 5 -20> //0 20 -20
  color red 0.9 green 0.9 blue 0.9
  spotlight
  point_at <0 1 1>
  tightness 0.01
  radius 6
  falloff 11
    }
}

composite
{
    Soap_Dispenser
    translate <1.775 0 1.5>
}

composite
{
    tap
    scale <0.125 0.125 0.125>
    translate <-1.5 0.35 1.5>
}

object
{
    basin
    scale <2.25 2.5 2.5>
}

composite
{
    Monster
    scale <2 2 2>
    translate <0.25 1.5 0.1>
    rotate <0 20 0>
}

object
{
    box { UnitBox scale <35 20 35> translate <-31.5 0 -33> }
    texture
    {
        Wall_Texture
    }
}