home *** CD-ROM | disk | FTP | other *** search
/ Source Code 1992 March / Source_Code_CD-ROM_Walnut_Creek_March_1992.iso / usenet / altsrcs / 3 / 3168 / jarg2get.icn < prev    next >
Encoding:
Text File  |  1991-04-08  |  1.6 KB  |  61 lines
  1. ############################################################################
  2. #
  3. #    Name:     1.1
  4. #
  5. #    Title:     jargon to gettext format converter
  6. #
  7. #    Author:     Richard L. Goerwitz
  8. #
  9. #    Version: jarg2get.icn
  10. #
  11. ############################################################################
  12. #  
  13. #  Converts jargon.ascii (stdin) to a format suitable for use by gettext.
  14. #  Writes to stdout.  Jargon.ascii was posted recently (c. March 1, 1991)
  15. #  to alt.sources.
  16. #
  17. ############################################################################
  18.  
  19. procedure main()
  20.  
  21.     local line, KEY, key_set, no, yes, blank_count
  22.  
  23.     blank_count := 0
  24.     key_set := set()
  25.     no := &ucase || "-/"; yes := &lcase || "  "
  26.     # Isn't goal-directed evaluation nice?
  27.     (match("= A =", !&input), "" == !&input)
  28.  
  29.     # Read stdin, looking for entries.  Entries can be distinguished
  30.     # a) by a preceding blank line, and b) by the presence of charac-
  31.     # ters beginning immediately at the margin, and c) by the presence
  32.     # of a colon plus a space on the line.
  33.     while line := trim(read(), '\t \xFF\r') do {
  34.  
  35.     if "" == line then {
  36.         if (blank_count +:= 1) > 2
  37.         then exit(0)
  38.         else write()
  39.     }
  40.     else {
  41.         line ? {
  42.             if match("Hacker Folklore"|"Appendix A: ")
  43.         then exit(0)
  44.         if blank_count > 0 &
  45.            KEY :=
  46.                trim(map(tab(any(&letters)) || tab(find(": ")),no,yes))
  47.         then {
  48.             if not member(key_set, KEY)
  49.             then write("::", KEY)
  50.             insert(key_set, KEY)
  51.         }
  52.         (="= ", tab(any(&ucase)), =" =", !&input) | write(line)
  53.         }
  54.         blank_count := 0
  55.     }
  56.     }
  57.  
  58.     stop("jarg2get:  aborting (are you sure you have the correct file?)")
  59.  
  60. end
  61.