home *** CD-ROM | disk | FTP | other *** search
/ Shareware Supreme Volume 6 #1 / swsii.zip / swsii / 178 / JRMUSIC.ZIP / ANITRA.BAS next >
BASIC Source File  |  1984-05-19  |  3KB  |  72 lines
  1. 10 ' ANITRA = Music          from  P. Fraundorf         2/83
  2. 20 ' anitra.bas: Anitra's Dance from "Peer Gynt" by Edvard Grieg
  3. 30 CLS
  4. 40 LOCATE 12,30
  5. 50 PRINT "A N I T R A ' S   D A N C E"
  6. 60 PRINT
  7. 70 PRINT
  8. 80 PRINT
  9. 90 ' ----------------------define manuscript phrases----------------------
  10. 100 A$ = "MLO5e2. e4p2 MSO1a4O3c4dd O1a4O3e4ff O1a4O3e4dd O1a4O3c4"
  11. 110 B1$ = "O3e4 MLa64b64a16.MSg#abO4cd MLeae4Xtd$; cac4O3Xtb$; MNa2p4"
  12. 120 B2$ = "MLaO4cO3a4Xtg$; f#O4cO3MNf#2 MLfO4cO3f4Xte$; d#bMNd#2"
  13. 130 B3$ = "MSba#f#baf bg#ebgd# bf#dbfc# becbd#O2b"
  14. 140 B4$ = "MLO3e64f#64e16.MSd#ef#ga bO4eO3bagf# ef#gab4 O4e4p4"
  15. 150 B$ = B1$ + B2$ + B3$ + B4$
  16. 160 C1$ = "MLf4.MNeMLeMNd MLd4.MNeMLeMNf f2. MSe4p2 p8O3fdcO2bMLO3f"
  17. 170 C2$ = "MSdcO2bO3dO2ba g#MLO3dMSO2bag#b g#fedcO1b"
  18. 180 C3$ = "O4MLb-4.MNaMLaMNg MLg4.MNaMLaMNb- b-2. MSa4p2 p8O3b-gfeMLb-"
  19. 190 C4$ = "MSgfeged c#MLgMSedc#e c#O2b-agfe"
  20. 200 C$ = C1$ + C2$ + C3$ + C4$
  21. 210 D1$ = "MSO2d4O3f#4g4 O2d4O3a4b4 O2d4O3a4a4 O4d64e64d16.c#def#g"
  22. 220 D2$ = "MLaO5dO4a4Xtg$; f#O5dO4f#4Xte$; MNd2."
  23. 230 D3$ = "MSO2d4O3f4g4 O2d4O3a4b-4 O2d4O3a4a4 O4d64e64d16.c#defg"
  24. 240 D4$ = "MLaO5dO4a4Xtg$; fO5dO4f4Xte$; MNd2."
  25. 250 D$ = D1$ + D2$ + D3$ + D4$
  26. 260 E1$ = "MSO1d-O2e-aO3cfO4c MLf64g64f16.MSefgab- MLO5cfcMSO3gab-"
  27. 270 E2$ = "MLO4cfc2 MSO1fO2f#aO3ceO4e MLa64b64a16.MSg#abO5cd"
  28. 280 E3$ = "MLeaeMSO3bO4cd MLeae2 MSO1bO2bO3d#f#ab MLO4f#64g64f#16.MSff#gab"
  29. 290 E$ = E1$ + E2$ + E3$
  30. 300 F1$ = "MLO5cO4cf#MSO3g#ab MLO4cO3cf#2 MSO1eO2eg#bO3de"
  31. 310 F2$ = "T=T2; MLb64O4c64O3b16.MSa#bO4cde"
  32. 320 F3$ = "T=T3; MLfO3fbMScde T=T4; MLfO2fb4MNO3e4"
  33. 330 F$ = F1$ + F2$ + F3$
  34. 340 G1$ = "T=T1; MLa64b64a16.MSg#abO4cd MLeae4Xtd$; cec4O3Xtb$; MNa2."
  35. 350 G2$ = "MLO4aO5cO4a4Xtg$; f#O5cO4f#2 fO5cO4f4Xte$; d#bd#2 dfd4Xtc$;"
  36. 360 G3$ = "O3bO4fO3b2 b-O4fo3b-4Xta$; g#O4eO3g#2 MSO4ed#O3bO4edO3b-"
  37. 370 G4$ = "O4ec#O3aO4ecO3g# O4eO3bgO4eO3a#f# O4eO3afO4eO3g#e"
  38. 380 G$ = G1$ + G2$ + G3$ + G4$
  39. 390 H$ = "MLa64b64a16.MSg#abO4cd eaedcO3b abO4cde4 a4p4"
  40. 400 ' -------------------define qtr-note trill substrings------------------
  41. 410 TA$ = "a16b32a32b32a32b32a32"
  42. 420 TB$ = "b16O4c32O3b32O4c32O3b32O4c32O3b32"
  43. 430 TC$ = "c16d32c32d32c32d32c32"
  44. 440 TD$ = "d16e32d32e32d32e32d32"
  45. 450 TE$ = "e16f32e32f32e32f32e32"
  46. 460 TG$ = "g16a32g32a32g32a32g32"
  47. 470 ' ----------------------------determine tempo--------------------------
  48. 480 INPUT "tempo (80-255 qtr notes/min, rtn=160)";T1
  49. 490 IF T1 = 0 THEN T1 = 160
  50. 500 T2 = .8 * T1
  51. 510 T3 = .6 * T1
  52. 520 T4 = .4 * T1
  53. 530 ' ----------------------------play the dance---------------------------
  54. 540 I$ = "p4"
  55. 550 PLAY "T=T1; L8"
  56. 560 PLAY A$
  57. 570 PLAY B$
  58. 580 PLAY B$ + "p4"
  59. 590 FOR I = 1 TO 2
  60. 600   PLAY C$
  61. 610   PLAY D$
  62. 620   PLAY E$
  63. 630   PLAY F$
  64. 640   PLAY G$
  65. 650   PLAY H$
  66. 660   PLAY I$
  67. 670   I$ = "O1E4 O0A4P2 MLO4A2. A4"
  68. 680 NEXT
  69. 690 PRINT " Play it again? (Y/N) ";
  70. 700 ANS$ = INPUT$(1)
  71. 710 IF ANS$ = "Y" OR ANS$ = "y" THEN 480
  72.