home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Share Gallery 1
/
share_gal_1.zip
/
share_gal_1
/
DT
/
DT019.ZIP
/
INSTALL.BAT
< prev
next >
Wrap
DOS Batch File
|
1990-10-01
|
5KB
|
175 lines
echo off
cls
echo ▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄▄
echo ▌Early Bird Home/Business Reminder Program ▐
echo ▌INSTALLATION ▐
echo ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
if not exist install.bat goto baddir
if not exist ebdoc.exe goto baddir
if not exist eb.exe goto baddir
if "%1"=="" goto nodrive
for %%a in ("help" "HELP") do if "%1"==%%a goto help
for %%a in (A B a b) do if "%1"=="%%a:" goto floppy
for %%a in (C D E F G H I J K L M c d e f g h i j k l m) do if "%1"=="%%a:" goto hard
echo
echo "%1" is an invalid drive designator.
goto help
:floppy
echo
echo ──── FLOPPY DRIVE Installation ────
echo
echo The Early Bird Program files will be copied to floppy disk drive "%1".
echo You must have a formatted floppy disk ready to continue.
echo
ebdoc /PD
echo
if errorlevel 88 goto end
cd %1\
goto final
:hard
if not "%2"=="" goto hardd
echo
echo ──── HARD DISK Installation ────
echo
echo Early Bird Program files will be copied to hard disk drive "%1" into
echo the directory "%1\EB".
echo
ebdoc /PD
echo
if errorlevel 88 goto end
ctty nul
mkdir %1\EB
ctty con
cd %1\EB
goto final
:hardd
echo
echo ──── HARD DISK (Specific Drive) Installation ────
echo
echo Early Bird Program files will be copied to the hard disk drive
echo directory "%1%2".
echo
ebdoc /PD
if errorlevel 88 goto end
ctty nul
mkdir %1%2
ctty con
cd %1%2
:final
if exist eb.exe goto ok
echo Sorry, cannot install from a disk to itself. Just "copy" the files.
goto end
:ok
echo
if not exist %1eb.rem goto overwrite
echo Warning, EB.REM already exists in %1%2.
ebdoc /P "Do you wish to OVERWRITE it with the default sample EB.REM file? (Y/N): " YN
echo
if not errorlevel 89 goto skipit
:overwrite
echo Copying EB.REM file to %1%2...
copy EB.REM %1%2
:skipit
echo
ebdoc /P "Enter \"A\" to copy All files or \"O\" to copy Only EB.EXE and EB.HLP: " AO
echo
echo Copying files to %1%2...
if errorlevel 79 goto only3
for %%a in (CHANGES.DOC EB.CMP EB.HLP HOLIDAYS.REM EBDOC.EXE GO.BAT) do copy %%a %1
for %%a in (GO.DOC INSTALL.BAT ORDER.DOC README.DOC EB.EXE) do copy %%a %1
if not exist %1EB.EXE goto prob
goto doneit
:only3
for %%a in (EB.HLP EBDOC.EXE EB.EXE) do copy %%a %1
if not exist %1eb.exe goto prob
:doneit
%1
echo
ebdoc /P "Does your monitor display colors? (Y/N): " YN
echo
if errorlevel 89 goto color
ebdoc /P "Does your monochrome monitor display shades between black and white? (Y/N): " YN
echo
if errorlevel 89 goto bw
%1eb /LCD /STOREOPTIONS
goto chkmouse
:color
%1eb /COLOR /STOREOPTIONS
goto chkmouse
:bw
%1eb /BW /STOREOPTIONS
:chkmouse
echo
ebdoc /P "Do you have a mouse? (Y/N): " YN
echo
if errorlevel 89 goto yesmouse
%1eb /NOMOUSE /STOREOPTIONS
goto complete
:yesmouse
%1eb /MOUSE /STOREOPTIONS
:complete
echo
echo Early Bird Program Installation is now complete to %1.
echo
if not exist EB.CMP goto nodoc
ebdoc /P "Press \"D\" to view or print documentation or \"C\" to continue: " DC
echo
if errorlevel 68 ebdoc
:nodoc
echo
echo ──── INSTALLATION COMPLETE ────
echo
echo Type "EB" and press Enter to enter the Early Bird Editor.
echo Type "EB SCAN" and press Enter to scan reminders.
echo Type "EB ?" and press Enter to get details on how to run the program.
goto end
:prob
echo
echo There was a problem copying to %1%2. You may not have enough disk space
echo on drive %1 or you may have specified an invalid drive to copy to.
echo Please check the syntax from the following summary screen.
goto help
:baddir
echo
echo This installation program must be run from the current drive and
echo directory. Type the drive letter (A: or B: or C:, etc...) at the
echo DOS prompt of the drive containing the installation program and
echo press the Enter key. Then re-run INSTALL.
goto end
:nodrive
echo
echo You must specify a drive (e.g. A:, C:,...) to copy the Early Bird files to.
:help
echo
echo TO INSTALL TO A FLOPPY DRIVE:
echo ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
echo Enter "INSTALL A:" or "INSTALL B:" at the DOS prompt and press the Enter key.
echo NOTE: If you have only one floppy drive, A:, then use the command INSTALL B:
echo and simply insert the proper disks into drive A: when DOS tells you to.
echo
echo TO INSTALL TO A HARD DISK:
echo ▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀▀
echo Enter "INSTALL" followed by the hard drive letter: (e.g.: C:,D:,...,M:) at
echo the DOS prompt and press the Enter key. (e.g: "INSTALL C:") The files will
echo be copied into the directory \EB on the selected hard disk.
echo
echo To install to a directory other that \EB, enter a space after the drive
echo letter followed by the directory name (e.g., "INSTALL C: \MYDIR").
:end
echo on