home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
PC Press 1998 September
/
Sezamfile98_2.iso
/
UPDATE
/
W95
/
VLXAUSB.EXE
/
MKUSBF.BAT
next >
Wrap
DOS Batch File
|
1996-10-24
|
2KB
|
82 lines
@echo off
rem ====================================================
rem = Microsoft OEM Kit USB Floppy Disk Creation Tool =
rem = Copyright (C) Microsoft Corporation 1996 =
rem ====================================================
rem
if "%1"=="/?" goto Syntax
if "%1"=="?" goto Syntax
rem Confirm that we are on a valid USB folder
if not exist usbsupp.exe goto badstart
if not exist readme.txt echo WARNING! No end-user readme.txt file to copy.
echo.
echo USB Floppy Disk Creation Tool
echo ─────────────────────────────
set drv=%1
if "%drv%"=="" goto askdrv
:noaskdrv
if "%drv%"=="a:" set drv=a:
if "%drv%"=="A:" set drv=a:
if "%drv%"=="b:" set drv=b:
if "%drv%"=="B:" set drv=b:
if not "%drv%"=="a:" if not "%drv%"=="b:" goto baddrv
goto drvok
:askdrv
echo.
choice /n /c:ABQ "Create Preload Boot Floppy in drive A, B (Q)uit? "
set drv=Q
if errorlevel 3 goto quit
set drv=a:
if errorlevel 2 set drv=b:
echo.
:drvok
echo Ready to Make USB Floppy Disk.
echo Insert a formatted, blank diskette in Drive %drv%
echo.
echo Press a key when ready...
pause >nul
echo.
rem ===============================
rem = Copy files to floppy drive =
rem ===============================
rem
copy usbsupp.exe %drv%\
copy readme.txt %drv%\
copy rem.pss %drv%\
goto quit
:badstart
echo.
echo The current directory is incorrect for MAKE_USBF operation.
echo.
goto quit
:baddrv
echo.
echo The drive letter parameter is not correct. Use only A: or B:
echo.
goto quit
:Syntax
echo ────────────────────────────────────────────────────────────
echo Syntax: MKUSBF {Drive:}
echo.
echo Drive: (Required) = Drive Letter of Diskette drive
echo.
echo Example: MKUSBF A:
echo.
echo ────────────────────────────────────────────────────────────
goto quit
:quit
echo.
echo.