home *** CD-ROM | disk | FTP | other *** search
/ Set of Apple II Hard Drive Images / hard.hdv / HARD / PROJECT / SOURCE / EDIT.SRC3 < prev    next >
Encoding:
Text File  |  1992-07-08  |  7.8 KB  |  214 lines  |  [04] ASCII Text (0x0000)
  1. ;
  2. ; EDIT.SRC3
  3. ;
  4. ;==================================================
  5. INSERT              JSR   FINDEND      ;START AT END AND MOVE 4 BYTES FORWARD
  6. INSERT1             DEC   MISCPTR      ;UNTIL YOU REACH CURRENT ADDRESS
  7.                     LDA   MISCPTR
  8.                     CMP   #$FF
  9.                     BNE   INSERT2
  10.                     DEC   MISCPTR+1
  11. INSERT2             LDY   #$00         
  12.                     LDA   (MISCPTR),Y
  13.                     LDY   #$04
  14.                     STA   (MISCPTR),Y
  15.                     LDA   MISCPTR
  16.                     CMP   PTR
  17.                     BNE   INSERT1
  18.                     LDA   MISCPTR+1
  19.                     CMP   PTR+1
  20.                     BNE   INSERT1
  21.                     LDA   #$80         ;AT CURRENT ADRS, INSERT MARKER
  22.                     LDY   #$00         ; $80 $00 $00 $00
  23.                     STA   (PTR),Y
  24.                     LDA   #$00
  25.                     INY   
  26.                     STA   (PTR),Y
  27.                     INY   
  28.                     STA   (PTR),Y
  29.                     INY   
  30.                     STA   (PTR),Y
  31.                     RTS   
  32. ;
  33. ;================================================== *KEY*
  34. ESC                 JSR   FINDEND
  35.                     LDA   #$C5         ;PRINT E=
  36.                     JSR   $FDED
  37.                     LDA   #$A4
  38.                     JSR   $FDED
  39.                     LDA   MISCPTR+1    ;PRINT ENDING ADDRESS
  40.                     JSR   $FDDA
  41.                     LDA   MISCPTR
  42.                     JSR   $FDDA
  43.                     PLA                ;POP OUTTA HERE
  44.                     PLA   
  45.                     PLA   
  46.                     PLA   
  47.                     RTS                ;THIS IS THE END.
  48. ;==================================================
  49. FINDMARK            LDA   SRCHSTRT
  50.                     STA   SRCHPTR
  51.                     LDA   SRCHSTRT+1
  52.                     STA   SRCHPTR+1
  53.                     CLV   
  54.                     BVC   STARSRCH
  55. ;
  56. INCSPTR             CLC   
  57.                     LDA   SRCHPTR
  58.                     ADC   #$04
  59.                     STA   SRCHPTR
  60.                     LDA   SRCHPTR+1
  61.                     ADC   #$00
  62.                     STA   SRCHPTR+1
  63. ;
  64. STARSRCH            LDA   SRCHPTR
  65.                     STA   MISCPTR
  66.                     LDA   SRCHPTR+1
  67.                     STA   MISCPTR+1
  68.                     LDY   #$00
  69.                     LDA   (MISCPTR),Y
  70.                     BEQ   BELL         ;IF NOT FOUND, BEEP
  71.                     CMP   PATTERN
  72.                     BNE   INCSPTR
  73.                     INY   
  74.                     LDA   (MISCPTR),Y
  75.                     CMP   PATTERN+1
  76.                     BNE   INCSPTR
  77.                     INY   
  78.                     LDA   (MISCPTR),Y
  79.                     CMP   PATTERN+2
  80.                     BNE   INCSPTR
  81.                     INY   
  82.                     LDA   (MISCPTR),Y
  83.                     CMP   PATTERN+3
  84.                     BNE   INCSPTR
  85.                     LDA   MISCPTR      ;FOUND IT! LET'S GO THERE!
  86.                     STA   PTR
  87.                     LDA   MISCPTR+1
  88.                     STA   PTR+1
  89.                     RTS   
  90. ;
  91. BELL                LDA   #$87         ;SORRY, NOT FOUND
  92.                     JSR   $FDED
  93.                     RTS   
  94. ;================================================== *KEY*
  95. RTPAREN             LDY   #$03         ;ADD TO VOLUME
  96.                     LDA   (PTR),Y
  97.                     CLC   
  98.                     ADC   #$01
  99.                     STA   (PTR),Y
  100.                     JMP   BREAKOUT
  101.                     RTS   
  102. ;================================================== *KEY*
  103. LTPAREN             LDY   #$03         ;SUBTR FROM VOLUME
  104.                     LDA   (PTR),Y
  105.                     SEC   
  106.                     SBC   #$01
  107.                     STA   (PTR),Y
  108.                     JMP   BREAKOUT
  109.                     RTS   
  110. ;================================================== *KEY*
  111. CTRLI               JSR   INSERT
  112. ;
  113. BREAKOUT            JSR   DISPNOTE
  114.                     JMP   WAITKEY
  115. ;
  116. ;==================================================
  117. HEXERROR            LDA   #$87         ;DING DONG THE STUPID USER
  118.                     JSR   $FDED
  119. HEXINPUT            LDA   $C000
  120.                     BPL   HEXINPUT
  121.                     STA   $C010
  122.                     AND   #$7F
  123.                     CMP   #$30         ;LESS THAN 0?
  124.                     BCC   HEXERROR
  125.                     CMP   #$47         ;GREATER THAN F?
  126.                     BCS   HEXERROR
  127.                     CMP   #$3A         
  128.                     BCC   GOODHEX
  129.                     CMP   #$41
  130.                     BCC   HEXERROR     ;AFTER 9 OR BEFORE A?
  131.                     SEC   
  132.                     SBC   #$07         ;IF BETWEEN A AND F, SUBTR 7
  133. ;
  134. GOODHEX             SEC                
  135.                     SBC   #$30         ;CONVERT ASCII TO BINARY
  136.                     PHA   
  137.                     JSR   $FDE3        ;PRINT ONE HEX NIBBLE 
  138.                     PLA
  139.                     RTS   
  140. ;================================================== *KEY*
  141. GKEY                LDA   #$C7         ;PRINT GO=
  142.                     JSR   $FDED
  143.                     LDA   #$CF
  144.                     JSR   $FDED
  145.                     LDA   #$BA
  146.                     JSR   $FDED
  147.                     JSR   HEXINPUT     ;GET USER'S ADDRESS 
  148.                     ASL   A            ;SHIFT INTO HER HI NIBBLE
  149.                     ASL   A   
  150.                     ASL   A   
  151.                     ASL   A   
  152.                     STA   PATTERN+3    ;SET UP SEARCH PATTERN
  153.                     JSR   HEXINPUT     ;GET SECOND BYTE FROM USER
  154.                     ORA   PATTERN+3    ;NOW DO HER LOW NIBBLE
  155.                     STA   PATTERN+3
  156.                     LDA   #$8D         ;RETURN HER CARRIAGE
  157.                     JSR   $FDED
  158.                     JSR   CLEANUP      ;AND CLEAN UP THE MESS YOU MADE
  159.                     JMP   FINDMARK
  160. ;================================================== *KEY*
  161. TKEY                LDA   #$D4         ;PRINT TM=
  162.                     JSR   $FDED
  163.                     LDA   #$CD
  164.                     JSR   $FDED
  165.                     LDA   #$BA
  166.                     JSR   $FDED
  167.                     JSR   HEXINPUT     ;ASK USER
  168.                     ASL   A   
  169.                     ASL   A   
  170.                     ASL   A   
  171.                     ASL   A   
  172.                     STA   MEASLEN+1
  173.                     JSR   HEXINPUT     ;GET SECOND BYTE
  174.                     ORA   MEASLEN+1
  175.                     STA   MEASLEN+1
  176.                     JSR   HEXINPUT     ;AND A THIRD
  177.                     ASL   A   
  178.                     ASL   A   
  179.                     ASL   A   
  180.                     ASL   A   
  181.                     STA   MEASLEN
  182.                     JSR   HEXINPUT     ;ONE MORE
  183.                     ORA   MEASLEN
  184.                     STA   MEASLEN
  185.                     JMP   WHAMBAM      ;GET OUTTA HERE
  186. ;================================================== *KEY*
  187. AKEY                LDA   #$C1         ;THIS TIME ASK HER NICELY FOR HER
  188.                     JSR   $FDED        ;ADDRESS
  189.                     LDA   #$C4
  190.                     JSR   $FDED        ;PRINT AD=
  191.                     LDA   #$BA
  192.                     JSR   $FDED
  193.                     JSR   HEXINPUT     ;THEN SHE'LL GIVE YOU SOME HEX
  194.                     ASL   A   
  195.                     ASL   A   
  196.                     ASL   A   
  197.                     ASL   A   
  198.                     STA   PTR+1
  199.                     JSR   HEXINPUT
  200.                     ORA   PTR+1
  201.                     STA   PTR+1
  202.                     JSR   HEXINPUT
  203.                     ASL   A   
  204.                     ASL   A   
  205.                     ASL   A   
  206.                     ASL   A   
  207.                     STA   PTR
  208.                     JSR   HEXINPUT
  209.                     ORA   PTR
  210.                     AND   #$FC         ;MASK HER LOWER HALF NIBBLE
  211.                     STA   PTR          ;SO YOU'RE POINTING TO 1ST BYTE OF CELL
  212. ;
  213.                     CHN   EDIT.SRC4
  214.