home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
SeeIn AO
/
ALICE-CD.BIN
/
Šj”ƒlƒbƒg�•‚»‚Ì‘¼
/
nv_mini
/
source
/
nvfile.adv
< prev
next >
Wrap
Text File
|
1998-08-31
|
11KB
|
419 lines
;===============================================================================
; NVSYSTEM-mini âtâ@âCâïè╓îW programmed by ALICE SOFT
;===============================================================================
**InitFile:
~LoadAllEnvFile:
~0,0:
**RemoveFile:
~SaveAllEnvFile:
~0,0:
;===============================================================================
; SaveLoad
; out ~~Res = True(Save) / False(Load)
**SaveLoad:
US a01,30:
*SLLp: ~SLMainGrp:~~a01:
*SLLp0: ~Select 1,a01,FALSE:~~a02:
{ a02=0xffff:!Res:0xffff!@SLout:}
!a02:a02+1!
~SLDialog a02:~~a03:
*SLLp1: ~Select 1,a03,FALSE:~~a04:
{ a04=0:
MS SysStrBuffTop,âZü[âué╡é▄é╖é⌐üH:~YnDialog SysStrBuffTop:~~Res:
{ Res=TRUE:
~SLSave a02:~~Res:@SLout:}
@SLLp:}
{ a04=1:
MS SysStrBuffTop,âìü[âhé╡é▄é╖é⌐üH:~YnDialog SysStrBuffTop:~~Res:
{ Res=TRUE:
~SLLoad a02:~~Res:@SLout:}
@SLLp:}
{ a04=2:~SLMsg a02:@SLLp:}
{ a04=3:!Res:0xffff!@SLout:}
@SLLp:
*SLout: UG a01,30:
~0,Res:
**SLSave f01:
!SfFlag:TRUE!~SaveFile f01:
!SfFlag:FALSE!
~0,0:
**SLLoad f01:
~LoadFile f01:
~0,0:
**SLMsg f01:
MI SfComStrTop+f01-1,23-7,âRâüâôâgé≡ôⁿù═é╡é─é¡é╛é│éó:
~SaveCommentStr:
~0,0:
;===============================================================================
**SLMainGrp:
US a01,30:
CF XSize, 0,XSize,YSize,0: ;âVâXâeâÇëµû╩âìü[âh
CF 0,YSize,XSize,YSize,0: ;
~SetSystemGrp XSize,0: ;
CC XSize,0,XSize,YSize,0,YSize: ;
!a02:24!
!a03:a02*23+16!
!a04:(a02+StrYSpace)*3+16!
!a05:(XSize-a03)/2!
!a06:(YSize-(a04*3+a02+StrYSpace))/2!
~SetFSize a02:
!a06:a06+a02+StrYSpace!
< a01,1,3,1,1:
~SLMainGrpSub a01,a02,a05,a06,a03,a04:
! eX[a01-1]:a05!
! eY[a01-1]:a06!
!eLx[a01-1]:a03!
!eLy[a01-1]:a04!
!eSx[a01-1]:a05+XSize!
!eSy[a01-1]:a06!
!eUx[a01-1]:a05!
!eUy[a01-1]:a06+YSize!
!a06:a06+a04!
>
CC 0,YSize,XSize,YSize,0,0:
!Res:3!
UG a01,30:
~0,Res:
**SLMainGrpSub f01,f02,f03,f04,f05,f06:
US a01,30:
NB a01,f01,6:
CK 1,a03+XSize,a04,a05,a06,SelStrColor,224,0,0:
MS SysStrBuffTop,üââfü[â^:
MH SysStrBuffTop+1,1,a01:
MA SysStrBuffTop,SysStrBuffTop+1:
MS SysStrBuffTop+1,üä:
MA SysStrBuffTop,SysStrBuffTop+1:
~SetFColor StrFontColor:T a03+8+XSize,a04+8 :X SysStrBuffTop:
~SetFColor SelStrColor: T a03+8 ,a04+8+YSize:X SysStrBuffTop:
~CheckSfExist a01:~~a10:
{ a10=TRUE:~GetSfTime a01,10:} ; 10 = a11
MS SysStrBuffTop,ü@âZü[âuÄ₧è╘üF:
~SetFColor StrFontColor:T a03+8+XSize,a04+8+a02+StrYSpace :X SysStrBuffTop:
~SetFColor SelStrColor: T a03+8 ,a04+8+a02+StrYSpace+YSize:X SysStrBuffTop:
ZH TRUE:
MS SysStrBuffTop+1,ü^:
MS SysStrBuffTop+2,üF:
MS SysStrBuffTop,ü|ü|ü|ü|:{ a10=TRUE:MH SysStrBuffTop,4,a11[0]:} ;öN
MA SysStrBuffTop,SysStrBuffTop+1:
MS SysStrBuffTop+3,ü|ü|: { a10=TRUE:MH SysStrBuffTop+3,2,a11[1]:};îÄ
MA SysStrBuffTop,SysStrBuffTop+3:
MA SysStrBuffTop,SysStrBuffTop+1:
MS SysStrBuffTop+3,ü|ü|: { a10=TRUE:MH SysStrBuffTop+3,2,a11[2]:};ô·
MA SysStrBuffTop,SysStrBuffTop+3:
MA SysStrBuffTop,SysStrBuffTop+1:
MS SysStrBuffTop+3,ü@:
MA SysStrBuffTop,SysStrBuffTop+3:
MS SysStrBuffTop+3,ü|ü|: { a10=TRUE:MH SysStrBuffTop+3,2,a11[3]:};Ä₧
MA SysStrBuffTop,SysStrBuffTop+3:
MA SysStrBuffTop,SysStrBuffTop+2:
MS SysStrBuffTop+3,ü|ü|: { a10=TRUE:MH SysStrBuffTop+3,2,a11[4]:};ò¬
MA SysStrBuffTop,SysStrBuffTop+3:
MA SysStrBuffTop,SysStrBuffTop+2:
MS SysStrBuffTop+3,ü|ü|: { a10=TRUE:MH SysStrBuffTop+3,2,a11[5]:};òb
MA SysStrBuffTop,SysStrBuffTop+3:
~SetFColor StrFontColor:T a03+8+a02*7+XSize,a04+8+a02+StrYSpace :X SysStrBuffTop:
~SetFColor SelStrColor: T a03+8+a02*7 ,a04+8+a02+StrYSpace+YSize:X SysStrBuffTop:
ZH FALSE:
MS SysStrBuffTop,ü@âRâüâôâgü@üF:
MA SysStrBuffTop,SfComStrTop+a01-1:
~SetFColor StrFontColor:T a03+8+XSize,a04+8+(a02+StrYSpace)*2 :X SysStrBuffTop:
~SetFColor SelStrColor: T a03+8 ,a04+8+(a02+StrYSpace)*2+YSize:X SysStrBuffTop:
CB a03+1+XSize,a04+1,a05-1,a06-1,SelStrColor:
CB a03 +XSize,a04 ,a05-1,a06-1,StrFontColor:
UG a01,30:
~0,0:
;===============================================================================
**SLDialog f01:
US a01,30:
!a06:f01!
!a01:24!
!a02:a01*4+16!
!a03:(a01+StrYSpace)*4+16!
!a04:Msx!{(a04+a02)>XSize:!a04:XSize-a02!} ;Clipping
!a05:Msy!{(a05+a03)>YSize:!a05:YSize-a03!} ;Clipping
CC a04,a05,a02,a03,XSize ,YSize:
CC a04,a05,a02,a03,XSize+a02 ,YSize:
CC a04,a05,a02,a03,XSize+a02*2,YSize: ;
CK 1,XSize,YSize,a02*2,a03,SelStrColor,224,0,0: ;
CB XSize+1 ,YSize+1,a02-1,a03-1,SelStrColor:
CB XSize ,YSize ,a02-1,a03-1,StrFontColor:
CB XSize+1+a02,YSize+1,a02-1,a03-1,SelStrColor:
CB XSize +a02,YSize ,a02-1,a03-1,StrFontColor:
< a11,0,3,1,1:
#SLDialogTbl,1:
F1,SysStrBuffTop,a11:
T XSize +8,YSize+(a01+StrYSpace)*a11+8:~SetFColor StrFontColor:X SysStrBuffTop:
T XSize+a02+8,YSize+(a01+StrYSpace)*a11+8:~SetFColor SelStrColor: X SysStrBuffTop:
! eX[a11]:a04+8!
! eY[a11]:a05+(a01+StrYSpace)*a11+8!
!eLx[a11]:a02-16!
!eLy[a11]:a01+StrYSpace!
!eSx[a11]:XSize+8!
!eSy[a11]:YSize+(a01+StrYSpace)*a11+8!
!eUx[a11]:XSize+a02+8!
!eUy[a11]:YSize+(a01+StrYSpace)*a11+8!
~CheckSfExist a06:~~a07:
{((a11=1)+(a11=2))*(a07=FALSE):
!eX [a11]:0x8000!
!eY [a11]:0x8000!
!eLx[a11]:0x1000!
!eLy[a11]:0x1000!
}
>
CC XSize+a02,YSize,a02,a03,a04,a05:
!Res:4!
UG a01,30:
~0,Res:
**YnDialog f01:
US a01,30:
NB a01,f01,1:
~SetYnDialog a01:
~Select 2,1,FALSE:~~a02:
!Res:FALSE!{ a02=0:!Res:TRUE!}
~RecoverYnDialog:
UG a01,30:
~0,Res:
**SetYnDialog f01:
US a01,30:
NB a01,f01,1:
ML a02,f01:!a03:6!{ a02>a03:!a03:a02!}
!a11:24! ; font-size
!a12:Msx!
!a13:Msy!
!a14:a03*a11+16!
!a15:(a11+StrYSpace)*2+16!
{(a12+a14)>XSize:!a12:XSize-a14!} ;Clipping
{(a13+a15)>YSize:!a13:YSize-a15!} ;
~SetFSize a11:
CC a12,a13,a14,a15,XSize,YSize:
CC a12,a13,a14,a15,XSize,YSize+a15:
CC a12,a13,a14,a15,XSize,YSize+a15*2:
CK 1,XSize,YSize,a14,a15*2,SelStrColor,224,0,0:
CB XSize+1,YSize+1 ,a14-1,a15-1,SelStrColor:
CB XSize ,YSize ,a14-1,a15-1,StrFontColor:
CB XSize+1,YSize+1+a15,a14-1,a15-1,SelStrColor:
CB XSize ,YSize +a15,a14-1,a15-1,StrFontColor:
~SetYnDialogXTop a01,0,a14:~~a16:
~SetFColor StrFontColor:
T XSize+a16,YSize+8 :X a01:
T XSize+a16,YSize+8+a15:X a01:
MS SysStrBuffTop,é═éó:
MS SysStrBuffTop+1,éóéóéª:
< a04,0,1,1,1:
~SetYnDialogXTop SysStrBuffTop+a04,a14/2*a04,a14/2:~~a16:
T XSize+a16,YSize+a11+StrYSpace+8 :~SetFColor StrFontColor:
X SysStrBuffTop+a04:
T XSize+a16,YSize+a11+StrYSpace+8+a15:~SetFColor SelStrColor:
X SysStrBuffTop+a04:
ML a05,SysStrBuffTop+a04:
! eX[a04]:a12+a16!
! eY[a04]:a13+a11+StrYSpace+8!
!eLx[a04]:a05*a11+StrYSpace!
!eLy[a04]:a11+StrYSpace!
!eSx[a04]:XSize+a16!
!eSy[a04]:YSize+a11+StrYSpace+8!
!eUx[a04]:XSize+a16!
!eUy[a04]:YSize+a15+a11+StrYSpace+8!
>
! eX[2]:a12!
! eY[2]:a13!
!eLx[2]:a14!
!eLy[2]:a15!
!eSx[2]:XSize!
!eSy[2]:YSize+a15*2!
CC XSize,YSize+a15,a14,a15,a12,a13:
UG a01,30:
~0,0:
**RecoverYnDialog:
CC eSx[2],eSy[2],eLx[2],eLy[2],eX[2],eY[2]:
~0,0:
**SetYnDialogXTop f01,f02,f03:
US a01,30:
NB a01,f01,3:
ML a11,f01:
!Res:a02+(a03-a11*24)/2!
UG a01,30:
~0,Res:
*SLDialogTbl:
_SLDialogStrTbl:
*SLDialogStrTbl:
"âZü[âu"
"âìü[âh"
"âRâüâôâg"
"ÅIù╣"
;===============================================================================
**CheckSfExist f01:
US a01,30:
LP f01,SfFlag,1:
!Res:SfFlag!{ RND>200:!Res:FALSE!}
UG a01,30:
~0,Res:
**GetSfTime f01,f02:
US SfYear,6:
LP f01,SfYear,6:
NB a01[f02],SfYear,6:
UG SfYear,6:
~0,0:
**SetSfTime:
US a01,30:
ZT 0,a01:
NB SfYear,a01,6:
UG a01,30:
~0,0:
;===============================================================================
**SaveFile f01:
US a01,30:
NB a01,f01,1:
~SaveAllEnvFile:
~SetSfTime:
*SFLp: QD a01:
{ RND>200:
MS DebugMsgStr,âZü[âuâtâ@âCâïé¬âZü[âué┼é½é▄é╣é±üB:
~AbortMsgPut DebugMsgStr:@SFLp:}
{ RND=TRUE:
!Res:TRUE!
@ExitSF:}
{ RND=FALSE:
!Res:FALSE!
~LoadAllEnvFile:
~RecoverAll:
@ExitSF:}
*ExitSF:UG a01,30:
~0,Res:
**LoadFile f01:
US a01,30:
NB a01,f01,1:
~SaveAllEnvFile:
LD a01:
UG a01,30:
~0,Res:
;===============================================================================
**LoadAllEnvFile:
~LoadGlobalData:
~LoadReadPageFlag:
~LoadCommentStr:
~0,0:
**LoadEnvFile f01:
US a01,30:
NB a01,f01,1:
{ a01=1:LE 0,nvdat01.asd,GlDat[0],GlMax: !Res:RND!}
{ a01=2:LE 0,nvdat02.asd,RpFlag[0],RpMax:!Res:RND!}
{ a01=3:LE 1,nvdat03.asd,SfComStrTop,3: !Res:RND!}
UG a01,30:
~0,Res:
**LoadGlobalData:
US a01,30:
~LoadEnvFile 1:~~Res:{ Res>200:~SaveGlobalData:}
!GrpBrightMode:GlDat[0]!
!GrpBright:GlDat[1]!
!FastReadFlag:GlDat[2]!
UG a01,30:
~0,0:
**LoadReadPageFlag:
US a01,30:
~LoadEnvFile 2:~~Res:{ Res>200:~SaveReadPageFlag:}
UG a01,30:
~0,0:
**LoadCommentStr:
US a01,30:
~LoadEnvFile 3:~~Res:{ Res>200:~SaveCommentStr:}
UG a01,30:
~0,0:
;===============================================================================
**SaveAllEnvFile:
~SaveGlobalData:
~SaveReadPageFlag:
~SaveCommentStr:
~0,0:
**SaveEnvFile f01:
US a01,30:
NB a01,f01,1:
*SEFlp: { a01=1:QE 0,nvdat01.asd,GlDat[0],GlMax: !Res:RND!@SEFChk:}
{ a01=2:QE 0,nvdat02.asd,RpFlag[0],RpMax: !Res:RND!@SEFChk:}
{ a01=3:QE 1,nvdat03.asd,SfComStrTop,3: !Res:RND!@SEFChk:}
@SEFOut:
*SEFChk:{ Res>200:
MS DebugMsgStr,è┬ï½âfü[â^é¬âZü[âué┼é½é▄é╣é±:~AbortMsgPut DebugMsgStr:@SEFlp:}
*SEFOut:UG a01,30:
~0,Res:
**SaveGlobalData:
US a01,30:
!GlDat[0]:GrpBrightMode!
!GlDat[1]:GrpBright!
!GlDat[2]:FastReadFlag!
!Res:0xffff!
<@ Res>200:~SaveEnvFile 1:~~Res:>
UG a01,30:
~0,0:
**SaveReadPageFlag:
US a01,30:
!Res:0xffff!
<@ Res>200:~SaveEnvFile 2:~~Res:>
UG a01,30:
~0,0:
**SaveCommentStr:
US a01,30:
!Res:0xffff!
<@ Res>200:~SaveEnvFile 3:~~Res:>
UG a01,30:
~0,0:
;===============================================================================
**RecoverAll:
US a01,30:
~SetPalAll:
~RecoverSound:
; ~SetGrpToDib:
; CC XSize,0,XSize,YSize,0,YSize:
; ~SetStrToDib:
; !GrpRewriteFlag:FALSE!
; !StrHideFlag:FALSE!
; CC 0,YSize,XSize,YSize,0,0:
UG a01,30:
~0,0: