Programming Tool Box/SIMS_2.iso/code/cdspy/editfile.frm

Text File | 1995-02-26 | 6KB | 199 lines

VERSION 2.00
Begin Form EditFile
   BackColor       =   &H00C0C0C0&
   Caption         =   "Code-Editor"
   ClientHeight    =   4485
   ClientLeft      =   2295
   ClientTop       =   1845
   ClientWidth     =   6060
   Height          =   5175
   Icon            =   EDITFILE.FRX:0000
   KeyPreview      =   -1  'True
   Left            =   2235
   LinkTopic       =   "Form1"
   ScaleHeight     =   299
   ScaleMode       =   3  'Pixel
   ScaleWidth      =   404
   Tag             =   "EditForm"
   Top             =   1215
   Width           =   6180
   Begin TextBox Text1
      BorderStyle     =   0  'None
      Height          =   3915
      Left            =   120
      MultiLine       =   -1  'True
      ScrollBars      =   3  'Both
      TabIndex        =   0
      Tag             =   "Editor"
      Text            =   "Text1"
      Top             =   480
      Width           =   5835
   End
   Begin Menu MnuDatei
      Caption         =   "&Datei"
      Begin Menu MnuDateiItem
         Caption         =   "Sch&liessen"
      End
   End
   Begin Menu MnuEdit
      Caption         =   "&Bearbeiten"
      Begin Menu MnuEditItem
         Caption         =   "&Kopieren"
         Index           =   0
         Shortcut        =   ^C
      End
      Begin Menu MnuEditItem
         Caption         =   "-"
         Index           =   1
      End
      Begin Menu MnuEditItem
         Caption         =   "Alles &markieren"
         Index           =   2
      End
   End
   Begin Menu MnuSearch
      Caption         =   "&Suchen"
      Begin Menu MnuSearchItem
         Caption         =   "&Suchen ..."
         Index           =   0
      End
      Begin Menu MnuSearchItem
         Caption         =   "&Weitersuchen"
         Index           =   1
         Shortcut        =   {F3}
      End
   End
   Begin Menu MnuPage
      Caption         =   "Speicherseite"
      Visible         =   0   'False
      Begin Menu MnuPageItem
         Caption         =   "vorhergehende"
         Enabled         =   0   'False
         Index           =   0
      End
      Begin Menu MnuPageItem
         Caption         =   "nΣchste"
         Index           =   1
      End
   End
End
Option Explicit
Option Compare Text

Sub Form_KeyDown (KeyCode As Integer, Shift As Integer)
  Dim Pos%, OldPos%, tmp$
  If KeyCode = 114 Then ' Weitersuchen F3
    If Shift = 1 Then ' Retour suchen
      tmp$ = Left$(EditFile!Text1, EditFile!Text1.SelStart)
      Do
        Pos% = InStr(OldPos% + 1, tmp$, GM_SeekString$)
        If Pos% = 0 Then
          If OldPos% = 0 Then ' Keine Vorkommnisse
            MsgBox "Textanfang erreicht, ohne Suchbegriff zu finden.", 48, "Suchen"
            Exit Sub
          End If
        Else
          OldPos% = Pos%
        End If
      Loop Until Pos% = 0
      EditFile!Text1.SelStart = OldPos% - 1
      EditFile!Text1.SelLength = Len(GM_SeekString$)
    Else ' vorwΣrts suchen
      Pos% = InStr(EditFile!Text1.SelStart + FM_Max((EditFile!Text1.SelLength), 2), EditFile!Text1, GM_SeekString$)
      If Pos% = 0 Then
        MsgBox "Textende erreicht, ohne Suchbegriff zu finden.", 48, "Suchen"
        Exit Sub
      Else
        EditFile!Text1.SelStart = Pos% - 1
        EditFile!Text1.SelLength = Len(GM_SeekString$)
      End If
    End If
  End If
End Sub

Sub Form_Load ()
  PM_LiesForm Me
  PM_LiesControl Text1
  EditFile.Text1.Text = G_EditFile$
  PM_SetReadOnly EditFile!Text1
  MnuPage.Visible = GM_HugeFile%
  screen.MousePointer = 0
End Sub

Sub Form_Resize ()
  If F_CheckFormSize(Me, 3000, 3000) = True Then
    P_ResizeObjectToForm Me, Text1, 8
    Rem Show3d Me
    Me.AutoRedraw = True
    Me.Cls
    P_Show3dObjectPixel Me, Text1, 0
  End If

End Sub

Sub Form_Unload (Cancel As Integer)
  Me.Visible = False
  PM_SchreibForm Me
End Sub

Sub MnuDateiItem_Click ()
  Unload Me
End Sub

Sub MnuEditItem_Click (Index As Integer)
  Select Case Index%
    Case Is = 0 ' Markierung in Zwischenablage kopieren
      clipboard.SetText Me!Text1.SelText
    Case Is = 2 ' Alles markieren
      Me!Text1.SelStart = 0
      Me!Text1.SelLength = Len(Me!Text1)
  End Select
End Sub

Sub MnuPageItem_Click (Index As Integer)
  Static PageNr%
  Dim L_LengthOfFile&
  Dim L_Editfile$
  Dim L_FileHandle%
  PageNr% = FM_Max(PageNr%, 1)
  Select Case Index%
    Case Is = 0 ' Zurⁿck
      PageNr% = PageNr% - 1
    Case Is = 1 ' VorwΣrts
      PageNr% = PageNr% + 1
  End Select
  MnuPageItem(0).Enabled = (PageNr% <> 1)
  L_LengthOfFile& = FileLen(Me.Caption)
  MnuPageItem(1).Enabled = (((L_LengthOfFile& \ 32000) + 1) <> PageNr%)
  L_Editfile$ = Space$(FM_Min(L_LengthOfFile&, 32000))
  L_FileHandle% = FreeFile
  Open Me.Caption For Binary As L_FileHandle% Len = FM_Min(L_LengthOfFile&, 32000)
  Get L_FileHandle%, (PageNr% - 1) * 32000 + 1, L_Editfile$
  Me.Text1 = L_Editfile$
  Close L_FileHandle%
  G_EditFile$ = L_Editfile$

End Sub

Sub MnuSearchItem_Click (Index As Integer)
  If Index = 0 Then ' Suchen
    F_Seek.Show 1
  Else ' Weitersuchen
    Form_KeyDown 114, 0' F3-Taste simulieren
  End If
End Sub

Sub Text1_KeyDown (KeyCode As Integer, Shift As Integer)
  If KeyCode = 17 And Shift = 2 Then
    MnuEditItem_Click 0 ' in clipboard Kopieren
  End If
End Sub

Sub Text1_MouseDown (Button As Integer, Shift As Integer, X As Single, Y As Single)
  If Button And 2 Then
    Set G_Control = Text1
    PopupMenu MDICDSpy!MnuSetup
  End If
End Sub