home *** CD-ROM | disk | FTP | other *** search
/ Programming Languages Suite / ProgLangD.iso / Assembly / DISPAT22.ASM < prev    next >
Assembly Source File  |  1986-09-25  |  3KB  |  97 lines
  1. CGROUP    GROUP    CODE_SEG, DATA_SEG
  2.     ASSUME    CS:CGROUP, DS:CGROUP
  3.  
  4.  
  5. CODE_SEG    SEGMENT PUBLIC
  6.  
  7.     PUBLIC    DISPATCHER
  8.     EXTRN    READ_BYTE:NEAR, EDIT_BYTE:NEAR
  9. ;-----------------------------------------------------------------------;
  10. ; This is the central dispatcher. During normal editing and viewing,    ;
  11. ; this procedure reads characters from the keybaord and, if the char    ;
  12. ; is a command key (such as a cursor key), DISPATCHER calls the        ;
  13. ; procedures that do the actual work.  This dispatching is done for    ;
  14. ; special keys listed in the table DISPATCH_TABLE, where the procedure    ;
  15. ; addresses are stored just after the key names.            ;
  16. ;   If the character is not a special key, then it should be placed    ;
  17. ; directly into the sector buffer--this is the editing mode.        ;
  18. ;                                    ;
  19. ; Uses:        READ_BYTE, EDIT_BYTE                    ;
  20. ;-----------------------------------------------------------------------;
  21. DISPATCHER    PROC    NEAR
  22.     PUSH    AX
  23.     PUSH    BX
  24.     PUSH    DX
  25. DISPATCH_LOOP:
  26.     CALL    READ_BYTE        ;Read character into AX
  27.     OR    AH,AH            ;AX = 0 if no character read, -1
  28.                     ; for an extended code.
  29.     JZ    DISPATCH_LOOP        ;No character read, try again
  30.     JS    SPECIAL_KEY        ;Read extended code
  31.     MOV    DL,AL
  32.     CALL    EDIT_BYTE        ;Was normal character, edit byte
  33.     JMP    DISPATCH_LOOP        ;Read another character
  34. SPECIAL_KEY:
  35.     CMP    AL,68            ;F10--exit?
  36.     JE    END_DISPATCH        ;Yes, leave
  37.                     ;Use BX to look through table
  38.     LEA    BX,DISPATCH_TABLE
  39. SPECIAL_LOOP:
  40.     CMP    BYTE PTR [BX],0        ;End of table?
  41.     JE    NOT_IN_TABLE        ;Yes, key was not in the table
  42.     CMP    AL,[BX]            ;Is it this table entry?
  43.     JE    DISPATCH        ;Yes, then dispatch
  44.     ADD    BX,3            ;No, try next entry
  45.     JMP    SPECIAL_LOOP        ;Check next table entry
  46.  
  47. DISPATCH:
  48.     INC    BX            ;Point to address of procedure
  49.     CALL    WORD PTR [BX]        ;Call procedure
  50.     JMP    DISPATCH_LOOP        ;Wait for another key
  51.  
  52. NOT_IN_TABLE:                ;Do nothing, just read next character
  53.     JMP    DISPATCH_LOOP
  54.  
  55. END_DISPATCH:
  56.     POP    BX
  57.     POP    AX
  58.     RET
  59. DISPATCHER    ENDP
  60.  
  61. CODE_SEG    ENDS
  62.  
  63.  
  64. DATA_SEG    SEGMENT PUBLIC
  65.  
  66.  
  67. CODE_SEG    SEGMENT PUBLIC
  68.     EXTRN    NEXT_SECTOR:NEAR            ;In DISK_IO.ASM
  69.     EXTRN    PREVIOUS_SECTOR:NEAR            ;In DISK_IO.ASM
  70.     EXTRN    PHANTOM_UP:NEAR, PHANTOM_DOWN:NEAR    ;In PHANTOM.ASM
  71.     EXTRN    PHANTOM_LEFT:NEAR, PHANTOM_RIGHT:NEAR
  72. CODE_SEG    ENDS
  73. ;-----------------------------------------------------------------------;
  74. ; This table contains the legal extended ASCII keys and the addresses    ;
  75. ; of the procedures that should be called when each key is pressed.    ;
  76. ;    The format of the table is                    ;
  77. ;        DB    72        ;Extended code for cursor up    ;
  78. ;        DW    OFFSET CGROUP:PHANTOM_UP            ;
  79. ;-----------------------------------------------------------------------;
  80. DISPATCH_TABLE    LABEL    BYTE
  81.     DB    59                ;F1
  82.     DW    OFFSET CGROUP:PREVIOUS_SECTOR
  83.     DB    60                ;F2
  84.     DW    OFFSET CGROUP:NEXT_SECTOR
  85.     DB    72                ;Cursor up
  86.     DW    OFFSET CGROUP:PHANTOM_UP
  87.     DB    80                ;Cursor down
  88.     DW    OFFSET CGROUP:PHANTOM_DOWN
  89.     DB    75                ;Cursor left
  90.     DW    OFFSET CGROUP:PHANTOM_LEFT
  91.     DB    77                ;Cursor right
  92.     DW    OFFSET CGROUP:PHANTOM_RIGHT
  93.     DB    0                ;End of the table
  94. DATA_SEG    ENDS
  95.  
  96.     END
  97.