home *** CD-ROM | disk | FTP | other *** search
/ Programmer 7500 / MAX_PROGRAMMERS.iso / INFO / CLIPPER / NFSRC.ZIP / SHADOW.ASM < prev    next >
Encoding:
Assembly Source File  |  1991-08-16  |  8.8 KB  |  200 lines
  1. ; File......: SHADOW.ASM
  2. ; Author....: Reginald B. Walton; Modified by Ted Means
  3. ; Date......: $Date:   15 Aug 1991 23:07:26  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   E:/nanfor/src/shadow.asv  $
  6. ; 
  7. ; This is an original work by Reginald B. Walton and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   E:/nanfor/src/shadow.asv  $
  14. ;  
  15. ;     Rev 1.2   15 Aug 1991 23:07:26   GLENN
  16. ;  Forest Belt proofread/edited/cleaned up doc
  17. ;  
  18. ;     Rev 1.1   11 May 1991 00:29:22   GLENN
  19. ;  Major re-write by Ted Means.  He sped it up.  It will also cooperate
  20. ;  with Clipper's internal _gtmaxrow and _gtmaxcol settings.  
  21. ;  
  22. ;     Rev 1.0   02 Apr 1991 18:25:40   GLENN
  23. ;  Nanforum Toolkit
  24. ;
  25. ;
  26.  
  27.  
  28. ;  $DOC$
  29. ;  $FUNCNAME$
  30. ;      FT_SHADOW()
  31. ;  $CATEGORY$
  32. ;      Video
  33. ;  $ONELINER$
  34. ;      Draw a non-destructive shadow on the screen
  35. ;  $SYNTAX$
  36. ;     FT_SHADOW( <nTop>, <nLeft>, <nBottom>, <nRight> ) -> NIL
  37. ;  $ARGUMENTS$
  38. ;     <nTop>    is the top row of the shadow area.
  39. ;
  40. ;     <nLeft>   is the upper left column of the shadow area.
  41. ;
  42. ;     <nBottom> is the bottom row of the shadow area.
  43. ;
  44. ;     <nRight>  is the lower right column of the shadow area.
  45. ;  $RETURNS$
  46. ;     NIL
  47. ;  $DESCRIPTION$
  48. ;     This function was designed to have my application emulate the 
  49. ;     non-destructive shadowing of the PC-TOOLS application. This function
  50. ;     was written in Assembly language for speed since, the same function
  51. ;     written in Clipper was too slow. The size of this function could be
  52. ;     reduced by re-writing the SET_CUR_POSITION, READ_CHARACTER, and 
  53. ;     WRITE_CHARACTER macros as procedures. Note: this will slow it down
  54. ;     a tad, since stack manipulation will be involved.
  55. ;
  56. ;     1.  If you are using the SAVESCREEN() function to save your screen,
  57. ;         remember to save enough screen for the shadow. The shadow will
  58. ;         require 1 row and 2 columns.
  59. ;
  60. ;             save_win = SAVESCREEN(Trow,Tcol,Brow+1,Bcol+2)
  61. ;
  62. ;     2.  *** INTERNALS ALERT ***  This function uses several Clipper internal 
  63. ;         routines.  If using internals scares you, then stay away from this
  64. ;         function, you gutless weasel.
  65. ;
  66. ;     The source code is written to MASM specifications.  To use another
  67. ;     assembler, either invoke that assembler's MASM compatibility switch,
  68. ;     or make the required modifications to the source code.
  69. ;  $EXAMPLES$
  70. ;     LOCAL Save_Win := SaveScreen(10,10,21,52)  // save enough for the shadow
  71. ;     FT_SHADOW(10,10,20,50)                     // draw shadow
  72. ;
  73. ;        ...
  74. ;          do what ya' like
  75. ;        ...
  76. ;
  77. ;     RestScreen(10,10,21,52,Save_Win)        // restore screen
  78. ;     RETURN
  79. ;  $END$
  80.  
  81.  
  82. Public   FT_SHADOW
  83.  
  84. TopRow   EQU       Word Ptr BP - 2           ; Top row
  85. TopCol   EQU       Word Ptr BP - 4           ; Top column
  86. BotRow   EQU       Word Ptr BP - 6           ; Bottom row
  87. BotCol   EQU       Word Ptr BP - 8           ; Bottom column
  88. MaxRow   EQU       Word Ptr BP - 10          ; MaxRow()
  89. MaxCol   EQU       Word Ptr BP - 12          ; MaxCol()
  90.  
  91. Extrn    __ParNI:Far
  92. Extrn    __Ret:Far
  93. Extrn    __gtMaxRow:Far                      ; INTERNAL!!! INTERNAL!!!
  94. Extrn    __gtMaxCol:Far                      ; INTERNAL!!! INTERNAL!!!
  95. Extrn    __No_Snow:Word                      ; INTERNAL!!! INTERNAL!!!
  96.  
  97. _NanFor  Segment   Word      PUBLIC    'CODE'
  98.          Assume    CS:_NanFor
  99.  
  100. FT_SHADOW          Proc      Far
  101.  
  102.          Push      BP                        ; Save BP
  103.          Mov       BP,SP                     ; Set up stack reference
  104.          Sub       SP,12                     ; Allocate room for locals
  105.  
  106.          Call      __gtMaxRow                ; Get maxrow()
  107.          Mov       [MaxRow],AX               ; Store it
  108.          Call      __gtMaxCol                ; Get maxcol()
  109.          Mov       [MaxCol],AX               ; Store it
  110.  
  111.          Mov       AX,1                      ; Specify param #
  112.          Push      AX                        ; Put on stack
  113.          Call      __ParNI                   ; Retrieve value
  114.          Mov       [TopRow],AX               ; Store it in TopRow
  115.  
  116.          Mov       AX,2                      ; Specify param #
  117.          Push      AX                        ; Put on stack
  118.          Call      __ParNI                   ; Retrieve value
  119.          Mov       [TopCol],AX               ; Store it in TopCol
  120.  
  121.          Mov       AX,3                      ; Specify param #
  122.          Push      AX                        ; Put on stack
  123.          Call      __ParNI                   ; Retrieve value
  124.          Mov       [BotRow],AX               ; Store it in BotRow
  125.  
  126.          Mov       AX,4                      ; Specify param #
  127.          Push      AX                        ; Put on stack
  128.          Call      __ParNI                   ; Retrieve value
  129.          Mov       [BotCol],AX               ; Store it in BotCol
  130.  
  131.          Xor       AX,AX                     ; Clear AX
  132.          Mov       ES,AX                     ; Set ES to low memory
  133.          Mov       AX,0B800h                 ; Default to color
  134.          Cmp       [ES:463h],3B4h            ; Monochrome present?
  135.          JNE       Vertical                  ; If not, continue
  136.          Mov       AX,0B000h                 ; Switch to mono video base
  137.  
  138. Vertical:Mov       ES,AX                     ; Initalize video base
  139.          Mov       AX,[TopRow]               ; Get top row
  140.          Inc       AX                        ; Start one row down
  141.          Mov       DX,[MaxCol]               ; Get maxcol()
  142.          Inc       DX                        ; Compensate for zero start
  143.          Mul       DX                        ; Calculate offset of row, 0
  144.          Add       AX,[BotCol]               ; Now get offset of last column
  145.          Inc       AX                        ; Go one past for shadow location
  146.          SHL       AX,1                      ; Multiply by two
  147.          Inc       AX                        ; Point to attribute byte
  148.          Mov       BX,AX                     ; Move offset to BX
  149.          Mov       CX,[BotRow]               ; Get last row
  150.          Sub       CX,[TopRow]               ; Subtract first row
  151.  
  152. VTop:    Cmp       [__No_Snow],0             ; Snow check in effect?
  153.          JE        VSetAttr                  ; If not, continue
  154.          Mov       DX,3DAh                   ; Specify status port
  155. VWait:   In        AL,DX                     ; Get status
  156.          Test      AL,8                      ; Vertical retrace in progress?
  157.          JZ        VWait                     ; No, so wait for it
  158. VSetAttr:Mov       Byte Ptr [ES:BX],7        ; Set shadow attribute
  159.          Mov       Byte Ptr [ES:BX + 2],7    ; Set shadow attribute
  160.          Mov       DX,[MaxCol]               ; Get maxcol
  161.          Inc       DX                        ; Compensate for zero start
  162.          SHL       DX,1                      ; Multiply by two
  163.          Add       BX,DX                     ; Set offset to next column
  164.          Loop      VTop                      ; Do next row
  165.  
  166. Horizontal:
  167.          Mov       AX,[BotRow]               ; Get bottom row
  168.          Inc       AX                        ; Go one past for shadow
  169.          Mov       DX,[MaxCol]               ; Get maxcol()
  170.          Inc       DX                        ; Compensate for zero start
  171.          Mul       DX                        ; Calculate offset of row, 0
  172.          Add       AX,[TopCol]               ; Now get offset of first column
  173.          Inc       AX                        ; Start one column in
  174.          SHL       AX,1                      ; Multiply by two
  175.          Inc       AX                        ; Point to attribute byte
  176.          Mov       BX,AX                     ; Move offset to BX
  177.          Mov       CX,[BotCol]               ; Get last column
  178.          Sub       CX,[TopCol]               ; Subtract first column
  179.          Add       CX,2                      ; Calulate loop terminal value
  180.  
  181. HTop:    Cmp      [__No_Snow],0              ; Snow check in effect?
  182.          JE       HSetAttr                   ; If not, continue
  183.          Mov      DX,3DAh                    ; Specify status port
  184. HWait:   In       AL,DX                      ; Get status
  185.          Test     AL,8                       ; Vertical retrace in progress?
  186.          JZ       HWait                      ; No, so wait for it
  187. HSetAttr:Mov      Byte Ptr [ES:BX],7         ; Set shadow attribute
  188.          Add      BX,2                       ; Set offset to next column
  189.          Loop     HTop                       ; Do next row
  190.  
  191. Exit:    Mov       SP,BP
  192.          Pop       BP
  193.          Call      __Ret                     ; Return NIL
  194.          Ret                                 ; Go on back to Clipper
  195.  
  196. FT_SHADOW          Endp
  197. _NanFor            Ends
  198. End
  199. 
  200.