home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol263 / slib2.lbr / SLHL5DC.Z80 < prev    next >
Encoding:
Text File  |  1986-03-23  |  1.6 KB  |  91 lines
  1. ;
  2. ; SYSLIB Module Name:  SLHL5DC
  3. ; Author:  Richard Conn
  4. ; SYSLIB Version Number:  3.6
  5. ; Module Version Number:  1.2
  6.  
  7.     public    lhl5dc,lhldc
  8.  
  9.     EXT    LOUT
  10.  
  11. PUTRG    MACRO
  12.     PUSH    BC    ; SAVE BC, DE, HL
  13.     PUSH    DE
  14.     PUSH    HL
  15.     ENDM
  16. GETRG    MACRO
  17.     POP    HL    ; RESTORE HL, DE, BC
  18.     POP    DE
  19.     POP    BC
  20.     ENDM
  21.  
  22.  
  23. ;
  24. ;  LHL5DC --
  25. ;    PRINT HL AS 5 DECIMAL CHARACTERS ON LST:
  26. ;
  27. LHL5DC:
  28.     PUSH    AF    ; SAVE ALL REGS
  29.     PUTRG
  30.     LD    B,0    ; B=0 FOR NO LEADING <SP>
  31.     JP    LHDC
  32. ;
  33. ;  LHLDC --
  34. ;    PRINT HL AS DECIMAL CHARACTERS W/LEADING SPACES IN 5-CHAR FIELD
  35. ;        ON LST:
  36. ;
  37. LHLDC:
  38.     PUSH    AF    ; SAVE ALL REGS
  39.     PUTRG
  40.     LD    B,1    ; A=1 FOR LEADING <SP>
  41. ;
  42. ;  PRINT HL USING LEADING <SP> FLAG IN B
  43. ;
  44. LHDC:    LD    DE,10000    ; PRINT 10000'S
  45.     CALL    PHDC1
  46.     LD    DE,1000    ; PRINT 1000'S
  47.     CALL    PHDC1
  48.     LD    DE,100    ; PRINT 100'S
  49.     CALL    PHDC1
  50.     LD    DE,10    ; PRINT 10'S
  51.     CALL    PHDC1
  52.     LD    A,L    ; PRINT 1'S
  53.     ADD    '0'    ; CONVERT TO ASCII
  54.     CALL    LOUT
  55.     GETRG        ; RESTORE ALL REGS
  56.     POP    AF
  57.     RET
  58.  
  59. ;
  60. ;  DIVIDE HL BY DE AND PRINT QUOTIENT WITH LEADING <SP>S
  61. ;
  62. PHDC1:    LD    C,0    ; SET COUNT
  63. PHDC2:    LD    A,L    ; SUB E FROM L
  64.     SUB    E
  65.     LD    L,A    ; RESULT IN L
  66.     LD    A,H    ; SUB D FROM H W/BORROW
  67.     SBC    A,D
  68.     LD    H,A    ; RESULT IN H
  69.     JP    C,PHDC3    ; DONE IF CARRY SET (FURTHER BORROW)
  70.     INC    C    ; INCR COUNT
  71.     JP    PHDC2
  72. PHDC3:    LD    A,L    ; ADD E TO L
  73.     ADD    A,E
  74.     LD    L,A    ; RESULT IN L
  75.     LD    A,H    ; ADD D TO H W/CARRY
  76.     ADC    A,D
  77.     LD    H,A    ; RESULT IN H
  78.     LD    A,C    ; GET RESULT
  79.     OR    A    ; CHECK FOR ZERO
  80.     JP    NZ,PHDC4
  81.     OR    B    ; 0 = NO LEADING <SP> (A=0, A OR B = 0 IF B=0)
  82.     JP    Z,PHDC4
  83.     LD    A,' '    ; PRINT <SP>
  84.     JP    LOUT
  85. PHDC4:    LD    B,0    ; TURN OFF LEADING <SP>
  86.     LD    A,C    ; GET VALUE
  87.     ADD    '0'    ; CONVERT TO ASCII
  88.     JP    LOUT
  89.  
  90.     END
  91.