home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol247 / pass.aq6 / PASS.A86
Encoding:
Text File  |  1986-02-28  |  2.8 KB  |  112 lines
  1. ;
  2. ;
  3. ; This program allows you to set the default password for a given process
  4. ; (console), without using the SET utility. SET forces you to type the
  5. ; password, as in SET [DEFAULT=TEST]. This utility prompts you, but types
  6. ; a # in response to each key pressed. This permits passwords to be used
  7. ; on files, even when someone "is looking" at your screen.
  8. ;
  9. ;  Dave Rand
  10. ;  72 Longfellow St.
  11. ;  Thousand Oaks, CA  91360
  12. ;  805-493-1987
  13. ; 
  14. ;  05/29/85 - Version 1.0
  15. ;
  16.  
  17. ccpm        equ    224
  18.  
  19. f_passwd    equ    106
  20. c_writestr    equ    9
  21. c_rawio        equ    6
  22.  
  23. p_pdadr        equ    156
  24.  
  25.  
  26.     cseg
  27.  
  28. begin:    mov    dx,offset message    ;Ask the user for the password
  29.     mov    cl,c_writestr        ;print the message on the cosole
  30.     int    ccpm
  31.  
  32.     mov    bx,offset buffer    ;point to our local buffer
  33.     mov    cx,8            ;max of 8 chars
  34.  
  35. lp1:    push    bx            ;save the pointer
  36.     push    cx            ;and the current count
  37.     mov    dl,0fdh            ;get input from CCPM
  38.     mov    cl,c_rawio        ;via raw I/O
  39.     int    ccpm
  40.     pop    cx            ;restore the count
  41.     pop    bx            ;and the pointer
  42.     cmp    al,3            ;was it a ^C?
  43.     jz    exit            ;yes, exit
  44.     cmp    al,13            ;was it a return?
  45.     jz    done            ;yes, do the password
  46.     cmp    al,8            ;was it a backspace?
  47.     jnz    lp2            ;no, must be a valid char
  48.     cmp    cx,8            ;It is a backspace. Are we at left
  49.     jz    lp1            ;edge already? Yes, ignore key
  50.     dec    bx            ;no, so decrement pointer
  51.     inc    cx            ;and increment count
  52.     mov    dl,8            ;display a BS
  53.     call    dchar
  54.     mov    dl,' '            ;SP
  55.     call    dchar
  56.     mov    dl,8            ;BS triplet to erase char displayed
  57.     call    dchar
  58.     jmps    lp1            ;and loop for more input
  59.  
  60. lp2:    cmp    al,'a'            ;Since it is a good char, convert
  61.     jb    lp3            ;lower to uppercase
  62.     cmp    al,'z'
  63.     jae    lp3
  64.     and    al,5fh            ;by anding with 5f
  65. lp3:    mov    byte ptr [bx],al    ;store the char in the buffer
  66.     mov    dl,'#'            ;and display a # to tell the world
  67.     call    dchar
  68.     inc    bx            ;increment the buffer pointer
  69.     loop    lp1            ;and loop for more chars
  70.  
  71. done:    jcxz    done1            ;we are done, so fill the
  72.     mov    byte ptr [bx],' '    ;rest of the buffer with spaces
  73.     inc    bx            ;increment pointer
  74.     loop    done            ;and loop for rest
  75. done1:
  76.     mov    dx,offset buffer    ;point to buffer
  77.     mov    cl,f_passwd        ;and issue a password call
  78.     int    ccpm
  79.  
  80.     mov    cl,p_pdadr
  81.     int    ccpm            ;get address of calling PD
  82.     push    es:word ptr 10h[bx]    ;save my UDA address
  83.     mov    bx,es:word ptr 1eh[bx]    ;get parent PD address
  84.     mov    bx,es:word ptr 10h[bx]    ;BX -> parents UDA
  85.     pop    ds            ;DS -> my UDA
  86.     mov    es,bx            ;ES -> parents UDA
  87.     mov    si,12h            ;point to reserved PASSWORD area
  88.     mov    di,12h            ;point to reserved PASSWORD area
  89.     mov    cx,8            ;move 8 bytes
  90.     rep    movsb            ;with a rep.
  91.  
  92.     
  93.  
  94. exit:    mov    cl,0
  95.     mov    dl,0
  96.     int    ccpm
  97.  
  98. dchar:    push    bx            ;display a char on the console
  99.     push    cx
  100.     mov    cl,c_rawio
  101.     int    ccpm
  102.     pop    cx
  103.     pop    bx
  104.     ret
  105.  
  106.     dseg
  107.  
  108. message    db    'Enter password: $'
  109.  
  110. buffer    rs    8
  111.     end
  112.