home *** CD-ROM | disk | FTP | other *** search
/ Oakland CPM Archive / oakcpm.iso / sigm / vol235 / bctest.aqm / BCTEST.ASM
Encoding:
Assembly Source File  |  1986-02-10  |  5.3 KB  |  265 lines
  1. ;**************************************************
  2. ;
  3. ;        BASICODE TEST
  4. ;
  5. ;  DIT OPENBAAR PROGRAMMA MAG GECOPIEERD EN GEDISTRIBEERD
  6. ;  WORDEN,  MITS INHOUDENDE DE VOLGENDE COPYRIGHT NOTICE
  7. ;
  8. ;   "         DIT PROGRAMMA
  9. ;     BETREFFENDE EEN IMPLEMENTATIE VAN DE
  10. ;        NOS BASICODE
  11. ;
  12. ;   IS TER BESCHIKKING GESTELD DOOR DE
  13. ;    HOBBY COMPUTER CLUB (HOLLAND)      "
  14. ;
  15. ;
  16. ;  NOS     P.O. 1200     1200BE HILVERSUM    (HOBBYSCOOP)
  17. ;  HCC  P.O. 149    2250AC VOORSCHOTEN    (CP/M gg)
  18. ;
  19. ;   Implementatie:
  20. ;        Albert van der Horst
  21. ;    t.b.v.  FORTH gebruikersgroep (HCC)
  22. ;
  23. ;**************************************************
  24. ;
  25. ;  Test een bandje geschreven volgens het
  26. ;         BASICODE protocol
  27. ;  De sterretjes die op het scherm verschijnen,
  28. ;  moeten zo goed mogelijk onder elkaar komen.
  29. ;  Dit programma is waarschijnlijk niet goed aan 
  30. ;  te passen wanneer er geen memory mapped video is.
  31. ;
  32. ;**************************************************
  33. ;
  34. ;    Algemene opmerking:
  35. ;    Daar ook CP/M de registers van de Z80 niet
  36. ;    intact laat bij aanroepen naar het systeem,
  37. ;    is hier de regel aanhouden dat registers altijd
  38. ;    verpest worden door subroutines, tenzij anders
  39. ;    vermeld.
  40. ;
  41. ;*************************************************
  42.  
  43. ;------------- VERANDERLIJKE EQUATES ---------------
  44. ;
  45. ;     In het algemeen zal men voor ieder type computer
  46. ;       een verantwoorde keus moeten maken uit de volgende
  47. ;    opties, alsmede hardware adressen in moeten vullen.
  48. ;
  49. ; ASSEMBLER SWITCH      ALS HIJ 1 IS, BETEKENT HET DAT 
  50. MEMMAP    EQU 1    ; De Centronics poort is 'memory mapped'
  51. OSBRN    EQU 1    ; Speciaal voor OSBORNE: bank switching    
  52.  
  53. ; HARDWARE EQUATES
  54. PAPORT    EQU    2900H    ; Parallel port (memory mapped)
  55. SCREEN    EQU    0F000H    ; Memory mapped video screen
  56. DEL12    EQU    90    ; Delay loop voor '0' bit (4 MHz)
  57. DEL24    EQU    44    ; Delay loop voor '1' bit (4 MHz)
  58.  
  59. ;
  60. ;------------- VASTE EQUATES --------------------------------
  61.  
  62. BDOS    EQU    5H
  63. DMA    EQU    80H
  64. STX    EQU    02H
  65. ETX    EQU    03H
  66. LF    EQU    0AH
  67. CR    EQU    0DH
  68. CTRLZ    EQU    1AH    ; Control-Z
  69. FCB    EQU    5CH    ; Standaard file control block
  70.  
  71. ;-------------------------------------------------
  72.  
  73.     ORG    100H
  74.     CALL    PRINT
  75.  DB CTRLZ,LF,LF,LF,LF,LF,' ** CPM BASICODE TEST '
  76.  DB '**  RELEASE 1.0',CR,LF,LF,0
  77.  
  78.     JMP    STACK    
  79.  
  80. ;
  81. ; ================================================
  82. ;
  83.  
  84.     IF    NOT OSBRN    ; Normale situatie
  85.     DS    20H        ; Reserveer stack ruimte
  86.     ENDIF
  87.  
  88.     IF    OSBRN    ; Programma moet boven 4000H draaien
  89.     ORG    4020H    ; wegens Osborne bankswitching
  90.     ENDIF
  91.  
  92. STACK:    
  93.     LXI    H,STACK    ; Initialiseer stack
  94.     SPHL
  95.  
  96.     IF    OSBRN
  97.         CALL    BANK2
  98.        ENDIF
  99.  
  100. ; - - - - - INITIALISATIE - - - - - - - - - - - - 
  101. ;
  102. ;     Tellers gaan mis bij interrupts
  103.  
  104.     DI 
  105.  
  106. ; - - - - - TESTEN VAN INPUT SIGNAAL - - - - - - 
  107.  
  108.     LXI    H,PAPORT+2
  109. REP1:    CALL    BITPS
  110.     JZ    OUT1    ; Z: Timeout
  111. ;
  112. ; - - - - - BEREKEN NIEUW ADRES OP VIDEO PAG - - - - - -
  113.  
  114.     ANI    40H    ; 0 of 1 fase ingangssignaal?
  115.     RAL
  116.     RAL
  117.     RAL
  118.     ADI    0F0H    ; kies uit 1e of 3e regel
  119.     MOV    D,A
  120.  
  121. ; - - - - - WIS OUDE STERRETJE - - - - - - - - - -
  122.  
  123.     MVI    A,' '
  124.     STAX    B
  125.  
  126. ; - - - - - ZET NIEUW STERRETJE - - - - - - - - - 
  127.  
  128.     MOV    A,E        ; deel E door 2
  129.     RAR
  130.     MOV    E,A
  131.  
  132.     MOV    C,E
  133.     MOV    B,D
  134.     MVI    A,'*'
  135.     STAX    B
  136.     JMP    REP1
  137.  
  138. ; - - - - - AFBREKEN? - - - - - - - - - - - - 
  139. ; 
  140. ;    ( OSBORNE :Schakel even terug naar de andere bank
  141. ;    Kijk of er een toets is ingedrukt,
  142. ;    dan ophouden.
  143.  
  144. OUT1:    
  145.     IF    OSBRN
  146.     CALL    BANK1
  147.     ENDIF
  148.  
  149.     CALL    KBD
  150.     PUSH    PSW
  151.  
  152.     IF    OSBRN
  153.     CALL    BANK2
  154.     ENDIF
  155.  
  156.     POP    PSW
  157.     JNC    REP1
  158.     CALL    BANK1
  159.     JMP    0    ; STOP
  160.  
  161. ;**************************************************
  162. ;
  163. ;     subroutine gebied
  164. ;
  165. ;**************************************************
  166. ;
  167. ;--------------  SWITCH NAAR BANK 2 -------------
  168. ;    
  169. ;  Zie OSBORNE User Guide 262 ( REV.12/15/82)
  170. ;  interrupts zijn al disabled!
  171. ;  En moeten dat blijven !
  172.                  
  173.     IF    OSBRN
  174. BANK2:    OUT    0
  175.     MVI    A,0
  176.     STA    0EF08H    
  177.     RET
  178.  
  179. ; -------------  SWITCH NAAR BANK 1 -------------  
  180. ;
  181. ;  Zie BANK2
  182.  
  183. BANK1:    OUT    1
  184.     MVI    A,1
  185.     STA    0EF08H    
  186.     RET
  187.     ENDIF
  188.  
  189.  
  190. ; - - - - - -  MEET LENGTE PERIODE - - - - - 
  191. ;
  192. ; Normaal ca. 23 perioden (1) of 46 (0) 
  193. ; Geeft gemeten lengte terug in E
  194. ; HL wijst al naar de poort
  195. ; Z bij return wijst op time-out
  196. ;
  197. BITPS:    MOV    A,M    ; Lees poort
  198.     MVI    E,0    ; Init teller
  199.  
  200. REP5:    INR    E    ; Meet lengte
  201.     RZ        ; Timeout
  202.     CMP    M    ; Veranderd?
  203.     JZ    REP5    ; Zo niet herhaal
  204.     RET
  205.  
  206. ; - - - - - - PRINT AN INLINE STRING - - - - - - - - - -
  207.  
  208. PRINT    POP    H    ; HAAL RETURN ADDRESS OP
  209.     MOV    A,M    ; GET CHARACTER
  210.     INX    H
  211.     ORA    A
  212.     JZ    END5
  213.     PUSH    H
  214.     CALL    CRT
  215.     JMP    PRINT
  216. END5    PCHL        ; RETURN
  217.  
  218.  
  219. ;=================================================
  220. ;
  221. ;            INTERFACING WITH CP/M
  222. ;            ---------------------
  223. ;
  224. ;=================================================
  225.  
  226. ;----------------  FUNKTIE SCAN FOR CHAR ----------------
  227. ;
  228. KBD    PUSH    H
  229.     PUSH    B
  230.     EI
  231.     MVI    C,0BH    ; Als de carry op staat is er een 
  232.     CALL    BDOS    ;  toets ingedrukt
  233.     ANI    1
  234.     JZ    NOCHAR
  235.     MVI    C,1
  236.     CALL    BDOS
  237.     STC
  238.     JMP    RETURN
  239. NOCHAR    XRA    A    ; Clear carry
  240. RETURN    POP    B
  241.     POP    H
  242.     DI
  243.     RET    
  244.  
  245. ;   zero flag : geen character ingetoetst
  246.  
  247. KEYBRD    PUSH    H
  248.     PUSH    B
  249.     MVI    C,0BH    
  250.     CALL    BDOS
  251.     ANI    1
  252.     POP    B
  253.     POP    H
  254.     RET    
  255.  
  256. ; -------------  FUNKTIE PRINT A CHAR ------------- - 
  257.    
  258. CRT    MOV    E,A    ; OUTPUTS 'A' IN ASCII
  259.     MVI    C,2    
  260.     CALL    BDOS    
  261.     RET
  262.  
  263.  
  264.  
  265.